core/math/integers/integers.factor

   1 ! Copyright (C) 2004, 2010 Slava Pestov.
   2 ! Copyright (C) 2008, Doug Coleman.
   3 ! See http://factorcode.org/license.txt for BSD license.
   4 USING: kernel kernel.private sequences sequences.private math
   5 math.private math.order combinators ;
   6 IN: math.integers.private
   7
   8 : fixnum-min ( x y -- z ) [ fixnum< ] most ; foldable
   9 : fixnum-max ( x y -- z ) [ fixnum> ] most ; foldable
  10
  11 M: integer numerator ; inline
  12 M: integer denominator drop 1 ; inline
  13
  14 M: fixnum >fixnum ; inline
  15 M: fixnum >bignum fixnum>bignum ; inline
  16 M: fixnum >integer ; inline
  17 M: fixnum >float fixnum>float ; inline
  18
  19 M: fixnum hashcode* nip ; inline
  20 M: fixnum equal? over bignum? [ >bignum bignum= ] [ 2drop f ] if ; inline
  21 M: fixnum number= eq? ; inline
  22
  23 M: fixnum < fixnum< ; inline
  24 M: fixnum <= fixnum<= ; inline
  25 M: fixnum > fixnum> ; inline
  26 M: fixnum >= fixnum>= ; inline
  27
  28 M: fixnum u< fixnum< ; inline
  29 M: fixnum u<= fixnum<= ; inline
  30 M: fixnum u> fixnum> ; inline
  31 M: fixnum u>= fixnum>= ; inline
  32
  33 M: fixnum min over fixnum? [ fixnum-min ] [ call-next-method ] if ; inline
  34 M: fixnum max over fixnum? [ fixnum-max ] [ call-next-method ] if ; inline
  35
  36 M: fixnum + fixnum+ ; inline
  37 M: fixnum - fixnum- ; inline
  38 M: fixnum * fixnum* ; inline
  39 M: fixnum /i fixnum/i ; inline
  40
  41 M: fixnum mod fixnum-mod ; inline
  42
  43 M: fixnum /mod fixnum/mod ; inline
  44
  45 M: fixnum bitand fixnum-bitand ; inline
  46 M: fixnum bitor fixnum-bitor ; inline
  47 M: fixnum bitxor fixnum-bitxor ; inline
  48 M: fixnum shift >fixnum fixnum-shift ; inline
  49
  50 M: fixnum bitnot fixnum-bitnot ; inline
  51
  52 : fixnum-bit? ( n m -- b )
  53     neg shift 1 bitand 0 > ; inline
  54
  55 M: fixnum bit? fixnum-bit? ; inline
  56
  57 : fixnum-log2 ( x -- n )
  58     0 swap [ dup 1 eq? ] [ [ 1 + ] [ 2/ ] bi* ] until drop ;
  59
  60 M: fixnum (log2) fixnum-log2 ; inline
  61
  62 M: bignum >fixnum bignum>fixnum ; inline
  63 M: bignum >bignum ; inline
  64
  65 M: bignum hashcode* nip >fixnum ;
  66
  67 M: bignum equal?
  68     over bignum? [ bignum= ] [
  69         swap dup fixnum? [ >bignum bignum= ] [ 2drop f ] if
  70     ] if ; inline
  71
  72 M: bignum number= bignum= ; inline
  73
  74 M: bignum < bignum< ; inline
  75 M: bignum <= bignum<= ; inline
  76 M: bignum > bignum> ; inline
  77 M: bignum >= bignum>= ; inline
  78
  79 M: bignum u< bignum< ; inline
  80 M: bignum u<= bignum<= ; inline
  81 M: bignum u> bignum> ; inline
  82 M: bignum u>= bignum>= ; inline
  83
  84 M: bignum + bignum+ ; inline
  85 M: bignum - bignum- ; inline
  86 M: bignum * bignum* ; inline
  87 M: bignum /i bignum/i ; inline
  88 M: bignum mod bignum-mod ; inline
  89
  90 M: bignum /mod bignum/mod ; inline
  91
  92 M: bignum bitand bignum-bitand ; inline
  93 M: bignum bitor bignum-bitor ; inline
  94 M: bignum bitxor bignum-bitxor ; inline
  95 M: bignum shift >fixnum bignum-shift ; inline
  96
  97 M: bignum bitnot bignum-bitnot ; inline
  98 M: bignum bit? bignum-bit? ; inline
  99 M: bignum (log2) bignum-log2 ; inline
 100
 101 ! Converting ratios to floats. Based on FLOAT-RATIO from
 102 ! sbcl/src/code/float.lisp, which has the following license:
 103
 104 ! "The software is in the public domain and is
 105 ! provided with absolutely no warranty."
 106
 107 ! First step: pre-scaling
 108 : twos ( x -- y ) dup 1 - bitxor log2 ; inline
 109
 110 : scale-denonimator ( den -- scaled-den scale' )
 111     dup twos neg [ shift ] keep ; inline
 112
 113 : pre-scale ( num den -- mantissa den' scale )
 114     2dup [ log2 ] bi@ -
 115     [ neg 54 + shift ] [ [ scale-denonimator ] dip + ] bi-curry bi* ; inline
 116
 117 ! Second step: loop
 118 : /f-loop ( mantissa den scale -- fraction-and-guard rem scale' )
 119     [ 2over /i log2 53 > ]
 120     [ [ 2/ ] [ ] [ 1 + ] tri* ] while
 121     [ /mod ] dip ; inline
 122
 123 ! Third step: post-scaling
 124 : scale-float ( mantissa scale -- float' )
 125     {
 126         { [ dup 1024 > ] [ 2drop 1/0. ] }
 127         { [ dup -1023 < ] [ 1021 + shift bits>double ] }
 128         [ [ 52 2^ 1 - bitand ] dip 1022 + 52 shift bitor bits>double ]
 129     } cond ; inline
 130
 131 : post-scale ( mantissa scale -- n )
 132     [ 2/ ] dip over log2 52 > [ [ 2/ ] [ 1 + ] bi* ] when
 133     scale-float ; inline
 134
 135 : round-to-nearest ( fraction-and-guard rem -- fraction-and-guard' )
 136     over odd?
 137     [ zero? [ dup zero? [ 1 + ] unless ] [ 1 + ] if ] [ drop ] if ;
 138     inline
 139
 140 ! Main word
 141 : /f-abs ( m n -- f )
 142     over zero? [ nip zero? 0/0. 0.0 ? ] [
 143         [ drop 1/0. ] [
 144             pre-scale
 145             /f-loop
 146             [ round-to-nearest ] dip
 147             post-scale
 148         ] if-zero
 149     ] if ; inline
 150
 151 : bignum/f ( m n -- f )
 152     [ [ abs ] bi@ /f-abs ] [ [ 0 < ] bi@ xor ] 2bi [ neg ] when ; inline
 153
 154 M: bignum /f ( m n -- f ) { bignum bignum } declare bignum/f ;
 155
 156 CONSTANT: bignum/f-threshold 0x20,0000,0000,0000
 157
 158 : fixnum/f ( m n -- m/n )
 159     [ >float ] bi@ float/f ; inline
 160
 161 M: fixnum /f
 162     { fixnum fixnum } declare
 163     2dup [ abs bignum/f-threshold >= ] either?
 164     [ bignum/f ] [ fixnum/f ] if ; inline
 165
 166 : bignum>float ( bignum -- float )
 167     { bignum } declare 1 >bignum bignum/f ;
 168
 169 M: bignum >float bignum>float ; inline