core/math/integers/integers.factor

   1 ! Copyright (C) 2004, 2008 Slava Pestov.
   2 ! Copyright (C) 2008, Doug Coleman.
   3 ! See http://factorcode.org/license.txt for BSD license.
   4 USING: kernel kernel.private sequences
   5 sequences.private math math.private combinators ;
   6 IN: math.integers.private
   7
   8 M: integer numerator ;
   9 M: integer denominator drop 1 ;
  10
  11 M: fixnum >fixnum ;
  12 M: fixnum >bignum fixnum>bignum ;
  13 M: fixnum >integer ;
  14
  15 M: fixnum hashcode* nip ;
  16 M: fixnum equal? over bignum? [ >bignum bignum= ] [ 2drop f ] if ;
  17 M: fixnum number= eq? ;
  18
  19 M: fixnum < fixnum< ;
  20 M: fixnum <= fixnum<= ;
  21 M: fixnum > fixnum> ;
  22 M: fixnum >= fixnum>= ;
  23
  24 M: fixnum + fixnum+ ;
  25 M: fixnum - fixnum- ;
  26 M: fixnum * fixnum* ;
  27 M: fixnum /i fixnum/i ;
  28 M: fixnum /f >r >float r> >float float/f ;
  29
  30 M: fixnum mod fixnum-mod ;
  31
  32 M: fixnum /mod fixnum/mod ;
  33
  34 M: fixnum bitand fixnum-bitand ;
  35 M: fixnum bitor fixnum-bitor ;
  36 M: fixnum bitxor fixnum-bitxor ;
  37 M: fixnum shift >fixnum fixnum-shift ;
  38
  39 M: fixnum bitnot fixnum-bitnot ;
  40
  41 M: fixnum bit? neg shift 1 bitand 0 > ;
  42
  43 : (fixnum-log2) ( accum n -- accum )
  44     dup 1 number= [ drop ] [ >r 1+ r> 2/ (fixnum-log2) ] if ;
  45     inline recursive
  46
  47 M: fixnum (log2) 0 swap (fixnum-log2) ;
  48
  49 M: bignum >fixnum bignum>fixnum ;
  50 M: bignum >bignum ;
  51
  52 M: bignum hashcode* nip >fixnum ;
  53
  54 M: bignum equal?
  55     over bignum? [ bignum= ] [
  56         swap dup fixnum? [ >bignum bignum= ] [ 2drop f ] if
  57     ] if ;
  58
  59 M: bignum number= bignum= ;
  60
  61 M: bignum < bignum< ;
  62 M: bignum <= bignum<= ;
  63 M: bignum > bignum> ;
  64 M: bignum >= bignum>= ;
  65
  66 M: bignum + bignum+ ;
  67 M: bignum - bignum- ;
  68 M: bignum * bignum* ;
  69 M: bignum /i bignum/i ;
  70 M: bignum mod bignum-mod ;
  71
  72 M: bignum /mod bignum/mod ;
  73
  74 M: bignum bitand bignum-bitand ;
  75 M: bignum bitor bignum-bitor ;
  76 M: bignum bitxor bignum-bitxor ;
  77 M: bignum shift bignum-shift ;
  78
  79 M: bignum bitnot bignum-bitnot ;
  80 M: bignum bit? bignum-bit? ;
  81 M: bignum (log2) bignum-log2 ;
  82
  83 ! Converting ratios to floats. Based on FLOAT-RATIO from
  84 ! sbcl/src/code/float.lisp, which has the following license:
  85
  86 ! "The software is in the public domain and is
  87 ! provided with absolutely no warranty."
  88
  89 ! First step: pre-scaling
  90 : twos ( x -- y ) dup 1- bitxor log2 ; inline
  91
  92 : scale-denonimator ( den -- scaled-den scale' )
  93     dup twos neg [ shift ] keep ; inline
  94
  95 : pre-scale ( num den -- scale shifted-num scaled-den )
  96     2dup [ log2 ] bi@ -
  97     tuck [ neg 54 + shift ] [ >r scale-denonimator r> + ] 2bi*
  98     -rot ; inline
  99
 100 ! Second step: loop
 101 : shift-mantissa ( scale mantissa -- scale' mantissa' )
 102     [ 1+ ] [ 2/ ] bi* ; inline
 103
 104 : /f-loop ( scale mantissa den -- scale' fraction-and-guard rem )
 105     [ 2dup /i log2 53 > ]
 106     [ >r shift-mantissa r> ]
 107     [ ] while /mod ; inline
 108
 109 ! Third step: post-scaling
 110 : unscaled-float ( mantissa -- n )
 111     52 2^ 1- bitand 1022 52 shift bitor bits>double ; inline
 112
 113 : scale-float ( scale mantissa -- float' )
 114     >r dup 0 < [ neg 2^ recip ] [ 2^ ] if r> * ; inline
 115
 116 : post-scale ( scale mantissa -- n )
 117     2/ dup log2 52 > [ shift-mantissa ] when
 118     unscaled-float scale-float ; inline
 119
 120 ! Main word
 121 : /f-abs ( m n -- f )
 122     over zero? [
 123         2drop 0.0
 124     ] [
 125         dup zero? [
 126             2drop 1.0/0.0
 127         ] [
 128             pre-scale
 129             /f-loop over odd?
 130             [ zero? [ 1+ ] unless ] [ drop ] if
 131             post-scale
 132         ] if
 133     ] if ; inline
 134
 135 M: bignum /f ( m n -- f )
 136     [ [ abs ] bi@ /f-abs ] [ [ 0 < ] bi@ xor ] 2bi [ neg ] when ;