core/math/integers/integers.factor

   1 ! Copyright (C) 2004, 2010 Slava Pestov.
   2 ! Copyright (C) 2008, Doug Coleman.
   3 ! See http://factorcode.org/license.txt for BSD license.
   4 USING: kernel kernel.private sequences sequences.private math
   5 math.private math.order combinators ;
   6 IN: math.integers.private
   7
   8 : fixnum-min ( x y -- z ) [ fixnum< ] most ; foldable
   9 : fixnum-max ( x y -- z ) [ fixnum> ] most ; foldable
  10
  11 M: integer numerator ; inline
  12 M: integer denominator drop 1 ; inline
  13
  14 M: fixnum >fixnum ; inline
  15 M: fixnum >bignum fixnum>bignum ; inline
  16 M: fixnum >integer ; inline
  17
  18 M: fixnum hashcode* nip ; inline
  19 M: fixnum equal? over bignum? [ >bignum bignum= ] [ 2drop f ] if ; inline
  20 M: fixnum number= eq? ; inline
  21
  22 M: fixnum < fixnum< ; inline
  23 M: fixnum <= fixnum<= ; inline
  24 M: fixnum > fixnum> ; inline
  25 M: fixnum >= fixnum>= ; inline
  26
  27 M: fixnum u< fixnum< ; inline
  28 M: fixnum u<= fixnum<= ; inline
  29 M: fixnum u> fixnum> ; inline
  30 M: fixnum u>= fixnum>= ; inline
  31
  32 M: fixnum min over fixnum? [ fixnum-min ] [ call-next-method ] if ; inline
  33 M: fixnum max over fixnum? [ fixnum-max ] [ call-next-method ] if ; inline
  34
  35 M: fixnum + fixnum+ ; inline
  36 M: fixnum - fixnum- ; inline
  37 M: fixnum * fixnum* ; inline
  38 M: fixnum /i fixnum/i ; inline
  39
  40 DEFER: bignum/f
  41 CONSTANT: bignum/f-threshold HEX: 20,0000,0000,0000
  42
  43 : fixnum/f ( m n -- m/n )
  44     [ >float ] bi@ float/f ; inline
  45
  46 M: fixnum /f
  47     2dup [ abs bignum/f-threshold >= ] either?
  48     [ bignum/f ] [ fixnum/f ] if ; inline
  49
  50 M: fixnum mod fixnum-mod ; inline
  51
  52 M: fixnum /mod fixnum/mod ; inline
  53
  54 M: fixnum bitand fixnum-bitand ; inline
  55 M: fixnum bitor fixnum-bitor ; inline
  56 M: fixnum bitxor fixnum-bitxor ; inline
  57 M: fixnum shift >fixnum fixnum-shift ; inline
  58
  59 M: fixnum bitnot fixnum-bitnot ; inline
  60
  61 : fixnum-bit? ( n m -- b )
  62     neg shift 1 bitand 0 > ;
  63
  64 M: fixnum bit? fixnum-bit? ; inline
  65
  66 : fixnum-log2 ( x -- n )
  67     0 swap [ dup 1 eq? ] [ [ 1 + ] [ 2/ ] bi* ] until drop ;
  68
  69 M: fixnum (log2) fixnum-log2 ; inline
  70
  71 M: bignum >fixnum bignum>fixnum ; inline
  72 M: bignum >bignum ; inline
  73
  74 M: bignum hashcode* nip >fixnum ;
  75
  76 M: bignum equal?
  77     over bignum? [ bignum= ] [
  78         swap dup fixnum? [ >bignum bignum= ] [ 2drop f ] if
  79     ] if ; inline
  80
  81 M: bignum number= bignum= ; inline
  82
  83 M: bignum < bignum< ; inline
  84 M: bignum <= bignum<= ; inline
  85 M: bignum > bignum> ; inline
  86 M: bignum >= bignum>= ; inline
  87
  88 M: bignum u< bignum< ; inline
  89 M: bignum u<= bignum<= ; inline
  90 M: bignum u> bignum> ; inline
  91 M: bignum u>= bignum>= ; inline
  92
  93 M: bignum + bignum+ ; inline
  94 M: bignum - bignum- ; inline
  95 M: bignum * bignum* ; inline
  96 M: bignum /i bignum/i ; inline
  97 M: bignum mod bignum-mod ; inline
  98
  99 M: bignum /mod bignum/mod ; inline
 100
 101 M: bignum bitand bignum-bitand ; inline
 102 M: bignum bitor bignum-bitor ; inline
 103 M: bignum bitxor bignum-bitxor ; inline
 104 M: bignum shift >fixnum bignum-shift ; inline
 105
 106 M: bignum bitnot bignum-bitnot ; inline
 107 M: bignum bit? bignum-bit? ; inline
 108 M: bignum (log2) bignum-log2 ; inline
 109
 110 ! Converting ratios to floats. Based on FLOAT-RATIO from
 111 ! sbcl/src/code/float.lisp, which has the following license:
 112
 113 ! "The software is in the public domain and is
 114 ! provided with absolutely no warranty."
 115
 116 ! First step: pre-scaling
 117 : twos ( x -- y ) dup 1 - bitxor log2 ; inline
 118
 119 : scale-denonimator ( den -- scaled-den scale' )
 120     dup twos neg [ shift ] keep ; inline
 121
 122 : pre-scale ( num den -- scale shifted-num scaled-den )
 123     2dup [ log2 ] bi@ -
 124     [ neg 54 + shift ] [ [ scale-denonimator ] dip + ] bi-curry bi*
 125     -rot ; inline
 126
 127 ! Second step: loop
 128 : shift-mantissa ( scale mantissa -- scale' mantissa' )
 129     [ 1 + ] [ 2/ ] bi* ; inline
 130
 131 : /f-loop ( scale mantissa den -- scale' fraction-and-guard rem )
 132     [ 2dup /i log2 53 > ]
 133     [ [ shift-mantissa ] dip ]
 134     while /mod ; inline
 135
 136 ! Third step: post-scaling
 137 : unscaled-float ( mantissa -- n )
 138     52 2^ 1 - bitand 1022 52 shift bitor bits>double ; inline
 139
 140 : scale-float ( scale mantissa -- float' )
 141     [ dup 0 < [ neg 2^ recip ] [ 2^ ] if ] dip * ; inline
 142
 143 : post-scale ( scale mantissa -- n )
 144     2/ dup log2 52 > [ shift-mantissa ] when
 145     unscaled-float scale-float ; inline
 146
 147 ! Main word
 148 : /f-abs ( m n -- f )
 149     over zero? [
 150         2drop 0.0
 151     ] [
 152         [
 153             drop 1/0.
 154         ] [
 155             pre-scale
 156             /f-loop over odd?
 157             [ zero? [ 1 + ] unless ] [ drop ] if
 158             post-scale
 159         ] if-zero
 160     ] if ; inline
 161
 162 : bignum/f ( m n -- f )
 163     [ [ abs ] bi@ /f-abs ] [ [ 0 < ] bi@ xor ] 2bi [ neg ] when ;
 164
 165 M: bignum /f ( m n -- f )
 166     bignum/f ;