core/math/integers/integers.factor

   1 ! Copyright (C) 2004, 2009 Slava Pestov.
   2 ! Copyright (C) 2008, Doug Coleman.
   3 ! See http://factorcode.org/license.txt for BSD license.
   4 USING: kernel kernel.private sequences
   5 sequences.private math math.private combinators ;
   6 IN: math.integers.private
   7
   8 : fixnum-min ( x y -- z ) [ fixnum< ] most ; foldable
   9 : fixnum-max ( x y -- z ) [ fixnum> ] most ; foldable
  10
  11 M: integer numerator ; inline
  12 M: integer denominator drop 1 ; inline
  13
  14 M: fixnum >fixnum ; inline
  15 M: fixnum >bignum fixnum>bignum ; inline
  16 M: fixnum >integer ; inline
  17
  18 M: fixnum hashcode* nip ; inline
  19 M: fixnum equal? over bignum? [ >bignum bignum= ] [ 2drop f ] if ; inline
  20 M: fixnum number= eq? ; inline
  21
  22 M: fixnum < fixnum< ; inline
  23 M: fixnum <= fixnum<= ; inline
  24 M: fixnum > fixnum> ; inline
  25 M: fixnum >= fixnum>= ; inline
  26
  27 M: fixnum + fixnum+ ; inline
  28 M: fixnum - fixnum- ; inline
  29 M: fixnum * fixnum* ; inline
  30 M: fixnum /i fixnum/i ; inline
  31 M: fixnum /f [ >float ] dip >float float/f ; inline
  32
  33 M: fixnum mod fixnum-mod ; inline
  34
  35 M: fixnum /mod fixnum/mod ; inline
  36
  37 M: fixnum bitand fixnum-bitand ; inline
  38 M: fixnum bitor fixnum-bitor ; inline
  39 M: fixnum bitxor fixnum-bitxor ; inline
  40 M: fixnum shift >fixnum fixnum-shift ; inline
  41
  42 M: fixnum bitnot fixnum-bitnot ; inline
  43
  44 M: fixnum bit? neg shift 1 bitand 0 > ; inline
  45
  46 : fixnum-log2 ( x -- n )
  47     0 swap [ dup 1 eq? ] [ [ 1 + ] [ 2/ ] bi* ] until drop ;
  48
  49 M: fixnum (log2) fixnum-log2 ; inline
  50
  51 M: bignum >fixnum bignum>fixnum ; inline
  52 M: bignum >bignum ; inline
  53
  54 M: bignum hashcode* nip >fixnum ;
  55
  56 M: bignum equal?
  57     over bignum? [ bignum= ] [
  58         swap dup fixnum? [ >bignum bignum= ] [ 2drop f ] if
  59     ] if ; inline
  60
  61 M: bignum number= bignum= ; inline
  62
  63 M: bignum < bignum< ; inline
  64 M: bignum <= bignum<= ; inline
  65 M: bignum > bignum> ; inline
  66 M: bignum >= bignum>= ; inline
  67
  68 M: bignum + bignum+ ; inline
  69 M: bignum - bignum- ; inline
  70 M: bignum * bignum* ; inline
  71 M: bignum /i bignum/i ; inline
  72 M: bignum mod bignum-mod ; inline
  73
  74 M: bignum /mod bignum/mod ; inline
  75
  76 M: bignum bitand bignum-bitand ; inline
  77 M: bignum bitor bignum-bitor ; inline
  78 M: bignum bitxor bignum-bitxor ; inline
  79 M: bignum shift >fixnum bignum-shift ; inline
  80
  81 M: bignum bitnot bignum-bitnot ; inline
  82 M: bignum bit? bignum-bit? ; inline
  83 M: bignum (log2) bignum-log2 ; inline
  84
  85 ! Converting ratios to floats. Based on FLOAT-RATIO from
  86 ! sbcl/src/code/float.lisp, which has the following license:
  87
  88 ! "The software is in the public domain and is
  89 ! provided with absolutely no warranty."
  90
  91 ! First step: pre-scaling
  92 : twos ( x -- y ) dup 1 - bitxor log2 ; inline
  93
  94 : scale-denonimator ( den -- scaled-den scale' )
  95     dup twos neg [ shift ] keep ; inline
  96
  97 : pre-scale ( num den -- scale shifted-num scaled-den )
  98     2dup [ log2 ] bi@ -
  99     [ neg 54 + shift ] [ [ scale-denonimator ] dip + ] bi-curry bi*
 100     -rot ; inline
 101
 102 ! Second step: loop
 103 : shift-mantissa ( scale mantissa -- scale' mantissa' )
 104     [ 1 + ] [ 2/ ] bi* ; inline
 105
 106 : /f-loop ( scale mantissa den -- scale' fraction-and-guard rem )
 107     [ 2dup /i log2 53 > ]
 108     [ [ shift-mantissa ] dip ]
 109     while /mod ; inline
 110
 111 ! Third step: post-scaling
 112 : unscaled-float ( mantissa -- n )
 113     52 2^ 1 - bitand 1022 52 shift bitor bits>double ; inline
 114
 115 : scale-float ( scale mantissa -- float' )
 116     [ dup 0 < [ neg 2^ recip ] [ 2^ ] if ] dip * ; inline
 117
 118 : post-scale ( scale mantissa -- n )
 119     2/ dup log2 52 > [ shift-mantissa ] when
 120     unscaled-float scale-float ; inline
 121
 122 ! Main word
 123 : /f-abs ( m n -- f )
 124     over zero? [
 125         2drop 0.0
 126     ] [
 127         [
 128             drop 1/0.
 129         ] [
 130             pre-scale
 131             /f-loop over odd?
 132             [ zero? [ 1 + ] unless ] [ drop ] if
 133             post-scale
 134         ] if-zero
 135     ] if ; inline
 136
 137 M: bignum /f ( m n -- f )
 138     [ [ abs ] bi@ /f-abs ] [ [ 0 < ] bi@ xor ] 2bi [ neg ] when ;