core/math/math.factor

   1 ! Copyright (C) 2003, 2008 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: kernel math.private ;
   4 IN: math
   5
   6 GENERIC: >fixnum ( x -- n ) foldable
   7 GENERIC: >bignum ( x -- n ) foldable
   8 GENERIC: >integer ( x -- n ) foldable
   9 GENERIC: >float ( x -- y ) foldable
  10
  11 GENERIC: numerator ( a/b -- a )
  12 GENERIC: denominator ( a/b -- b )
  13
  14 GENERIC: real-part ( z -- x )
  15 GENERIC: imaginary-part ( z -- y )
  16
  17 MATH: number= ( x y -- ? ) foldable
  18
  19 M: object number= 2drop f ;
  20
  21 MATH: <  ( x y -- ? ) foldable
  22 MATH: <= ( x y -- ? ) foldable
  23 MATH: >  ( x y -- ? ) foldable
  24 MATH: >= ( x y -- ? ) foldable
  25
  26 MATH: +   ( x y -- z ) foldable
  27 MATH: -   ( x y -- z ) foldable
  28 MATH: *   ( x y -- z ) foldable
  29 MATH: /   ( x y -- z ) foldable
  30 MATH: /f  ( x y -- z ) foldable
  31 MATH: /i  ( x y -- z ) foldable
  32 MATH: mod ( x y -- z ) foldable
  33
  34 MATH: /mod ( x y -- z w ) foldable
  35
  36 MATH: bitand ( x y -- z ) foldable
  37 MATH: bitor  ( x y -- z ) foldable
  38 MATH: bitxor ( x y -- z ) foldable
  39 GENERIC# shift 1 ( x n -- y ) foldable
  40 GENERIC: bitnot ( x -- y ) foldable
  41 GENERIC# bit? 1 ( x n -- ? ) foldable
  42
  43 GENERIC: abs ( x -- y ) foldable
  44
  45 <PRIVATE
  46
  47 GENERIC: (log2) ( x -- n ) foldable
  48
  49 PRIVATE>
  50
  51 : log2 ( x -- n )
  52     dup 0 <= [
  53         "log2 expects positive inputs" throw
  54     ] [
  55         (log2)
  56     ] if ; foldable
  57
  58 : zero? ( x -- ? ) 0 number= ; inline
  59 : 1+ ( x -- y ) 1 + ; inline
  60 : 1- ( x -- y ) 1 - ; inline
  61 : 2/ ( x -- y ) -1 shift ; inline
  62 : sq ( x -- y ) dup * ; inline
  63 : neg ( x -- -x ) 0 swap - ; inline
  64 : recip ( x -- y ) 1 swap / ; inline
  65 : sgn ( x -- n ) dup 0 < [ drop -1 ] [ 0 > 1 0 ? ] if ; inline
  66
  67 : ?1+ [ 1+ ] [ 0 ] if* ; inline
  68
  69 : rem ( x y -- z ) abs tuck mod over + swap mod ; foldable
  70
  71 : 2^ ( n -- 2^n ) 1 swap shift ; inline
  72
  73 : even? ( n -- ? ) 1 bitand zero? ;
  74
  75 : odd? ( n -- ? ) 1 bitand 1 number= ;
  76
  77 UNION: integer fixnum bignum ;
  78
  79 UNION: rational integer ratio ;
  80
  81 UNION: real rational float ;
  82
  83 UNION: number real complex ;
  84
  85 GENERIC: fp-nan? ( x -- ? )
  86
  87 M: object fp-nan?
  88     drop f ;
  89
  90 M: float fp-nan?
  91     double>bits -51 shift HEX: fff [ bitand ] keep = ;
  92
  93 GENERIC: fp-infinity? ( x -- ? )
  94
  95 M: object fp-infinity?
  96     drop f ;
  97
  98 M: float fp-infinity? ( float -- ? )
  99     double>bits
 100     dup -52 shift HEX: 7ff [ bitand ] keep = [
 101         HEX: fffffffffffff bitand 0 =
 102     ] [
 103         drop f
 104     ] if ;
 105
 106 : (next-power-of-2) ( i n -- n )
 107     2dup >= [
 108         drop
 109     ] [
 110         >r 1 shift r> (next-power-of-2)
 111     ] if ;
 112
 113 : next-power-of-2 ( m -- n ) 2 swap (next-power-of-2) ; foldable
 114
 115 : power-of-2? ( n -- ? )
 116     dup 0 <= [ drop f ] [ dup 1- bitand zero? ] if ; foldable
 117
 118 : align ( m w -- n )
 119     1- [ + ] keep bitnot bitand ; inline
 120
 121 <PRIVATE
 122
 123 : iterate-prep 0 -rot ; inline
 124
 125 : if-iterate? >r >r 2over < r> r> if ; inline
 126
 127 : iterate-step ( i n quot -- i n quot )
 128     #! Apply quot to i, keep i and quot, hide n.
 129     swap >r 2dup 2slip r> swap ; inline
 130
 131 : iterate-next >r >r 1+ r> r> ; inline
 132
 133 PRIVATE>
 134
 135 : (each-integer) ( i n quot: ( i -- ) -- )
 136     [ iterate-step iterate-next (each-integer) ]
 137     [ 3drop ] if-iterate? ; inline recursive
 138
 139 : (find-integer) ( i n quot: ( i -- ? ) -- i )
 140     [
 141         iterate-step roll
 142         [ 2drop ] [ iterate-next (find-integer) ] if
 143     ] [ 3drop f ] if-iterate? ; inline recursive
 144
 145 : (all-integers?) ( i n quot: ( i -- ? ) -- ? )
 146     [
 147         iterate-step roll
 148         [ iterate-next (all-integers?) ] [ 3drop f ] if
 149     ] [ 3drop t ] if-iterate? ; inline recursive
 150
 151 : each-integer ( n quot -- )
 152     iterate-prep (each-integer) ; inline
 153
 154 : times ( n quot -- )
 155     [ drop ] prepose each-integer ; inline
 156
 157 : find-integer ( n quot -- i )
 158     iterate-prep (find-integer) ; inline
 159
 160 : all-integers? ( n quot -- ? )
 161     iterate-prep (all-integers?) ; inline
 162
 163 : find-last-integer ( n quot: ( i -- ? ) -- i )
 164     over 0 < [
 165         2drop f
 166     ] [
 167         2dup 2slip rot [
 168             drop
 169         ] [
 170             >r 1- r> find-last-integer
 171         ] if
 172     ] if ; inline recursive