core/math/math.factor

   1 ! Copyright (C) 2003, 2009 Slava Pestov, Joe Groff.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: kernel ;
   4 IN: math
   5
   6 GENERIC: >fixnum ( x -- n ) foldable
   7 GENERIC: >bignum ( x -- n ) foldable
   8 GENERIC: >integer ( x -- n ) foldable
   9 GENERIC: >float ( x -- y ) foldable
  10
  11 GENERIC: numerator ( a/b -- a )
  12 GENERIC: denominator ( a/b -- b )
  13
  14 GENERIC: real-part ( z -- x )
  15 GENERIC: imaginary-part ( z -- y )
  16
  17 MATH: number= ( x y -- ? ) foldable
  18
  19 M: object number= 2drop f ;
  20
  21 MATH: <  ( x y -- ? ) foldable
  22 MATH: <= ( x y -- ? ) foldable
  23 MATH: >  ( x y -- ? ) foldable
  24 MATH: >= ( x y -- ? ) foldable
  25
  26 MATH: unordered? ( x y -- ? ) foldable
  27 MATH: u<  ( x y -- ? ) foldable
  28 MATH: u<= ( x y -- ? ) foldable
  29 MATH: u>  ( x y -- ? ) foldable
  30 MATH: u>= ( x y -- ? ) foldable
  31
  32 M: object unordered? 2drop f ;
  33
  34 MATH: +   ( x y -- z ) foldable
  35 MATH: -   ( x y -- z ) foldable
  36 MATH: *   ( x y -- z ) foldable
  37 MATH: /   ( x y -- z ) foldable
  38 MATH: /f  ( x y -- z ) foldable
  39 MATH: /i  ( x y -- z ) foldable
  40 MATH: mod ( x y -- z ) foldable
  41
  42 MATH: /mod ( x y -- z w ) foldable
  43
  44 MATH: bitand ( x y -- z ) foldable
  45 MATH: bitor  ( x y -- z ) foldable
  46 MATH: bitxor ( x y -- z ) foldable
  47 GENERIC# shift 1 ( x n -- y ) foldable
  48 GENERIC: bitnot ( x -- y ) foldable
  49 GENERIC# bit? 1 ( x n -- ? ) foldable
  50
  51 GENERIC: abs ( x -- y ) foldable
  52
  53 <PRIVATE
  54
  55 GENERIC: (log2) ( x -- n ) foldable
  56
  57 PRIVATE>
  58
  59 ERROR: log2-expects-positive x ;
  60
  61 : log2 ( x -- n )
  62     dup 0 <= [ log2-expects-positive ] [ (log2) ] if ; inline
  63
  64 : zero? ( x -- ? ) 0 number= ; inline
  65 : 2/ ( x -- y ) -1 shift ; inline
  66 : sq ( x -- y ) dup * ; inline
  67 : neg ( x -- -x ) -1 * ; inline
  68 : recip ( x -- y ) 1 swap / ; inline
  69 : sgn ( x -- n ) dup 0 < [ drop -1 ] [ 0 > 1 0 ? ] if ; inline
  70 : ?1+ ( x -- y ) [ 1 + ] [ 0 ] if* ; inline
  71 : rem ( x y -- z ) abs [ mod ] [ + ] [ mod ] tri ; foldable
  72 : 2^ ( n -- 2^n ) 1 swap shift ; inline
  73 : even? ( n -- ? ) 1 bitand zero? ; inline
  74 : odd? ( n -- ? ) 1 bitand 1 number= ; inline
  75
  76 : if-zero ( ..a n quot1: ( ..a -- ..b ) quot2: ( ..a n -- ..b ) -- ..b )
  77     [ dup zero? ] [ [ drop ] prepose ] [ ] tri* if ; inline
  78
  79 : when-zero ( ..a n quot: ( ..a -- ..b ) -- ..b ) [ ] if-zero ; inline
  80
  81 : unless-zero ( ..a n quot: ( ..a -- ..b ) -- ..b ) [ ] swap if-zero ; inline
  82
  83 UNION: integer fixnum bignum ;
  84
  85 TUPLE: ratio { numerator integer read-only } { denominator integer read-only } ;
  86
  87 UNION: rational integer ratio ;
  88
  89 UNION: real rational float ;
  90
  91 TUPLE: complex { real real read-only } { imaginary real read-only } ;
  92
  93 UNION: number real complex ;
  94
  95 : fp-bitwise= ( x y -- ? ) [ double>bits ] bi@ = ; inline
  96
  97 GENERIC: fp-special? ( x -- ? )
  98 GENERIC: fp-nan? ( x -- ? )
  99 GENERIC: fp-qnan? ( x -- ? )
 100 GENERIC: fp-snan? ( x -- ? )
 101 GENERIC: fp-infinity? ( x -- ? )
 102 GENERIC: fp-nan-payload ( x -- bits )
 103 GENERIC: fp-sign ( x -- ? )
 104
 105 M: object fp-special? drop f ; inline
 106 M: object fp-nan? drop f ; inline
 107 M: object fp-qnan? drop f ; inline
 108 M: object fp-snan? drop f ; inline
 109 M: object fp-infinity? drop f ; inline
 110
 111 : <fp-nan> ( payload -- nan )
 112     0x7ff0000000000000 bitor bits>double ; inline
 113
 114 GENERIC: next-float ( m -- n )
 115 GENERIC: prev-float ( m -- n )
 116
 117 : next-power-of-2 ( m -- n )
 118     dup 2 <= [ drop 2 ] [ 1 - log2 1 + 2^ ] if ; inline
 119
 120 : power-of-2? ( n -- ? )
 121     dup 0 <= [ drop f ] [ dup 1 - bitand zero? ] if ; foldable
 122
 123 : align ( m w -- n )
 124     1 - [ + ] keep bitnot bitand ; inline
 125
 126 <PRIVATE
 127
 128 : iterate-prep ( n quot -- i n quot ) [ 0 ] 2dip ; inline
 129
 130 : if-iterate? ( i n true false -- ) [ 2over < ] 2dip if ; inline
 131
 132 : iterate-step ( i n quot -- i n quot )
 133     #! Apply quot to i, keep i and quot, hide n.
 134     [ nip call ] 3keep ; inline
 135
 136 : iterate-next ( i n quot -- i' n quot ) [ 1 + ] 2dip ; inline
 137
 138 PRIVATE>
 139
 140 : (each-integer) ( ... i n quot: ( ... i -- ... ) -- ... )
 141     [ iterate-step iterate-next (each-integer) ]
 142     [ 3drop ] if-iterate? ; inline recursive
 143
 144 : (find-integer) ( ... i n quot: ( ... i -- ... ? ) -- ... i )
 145     [
 146         iterate-step
 147         [ [ ] ] 2dip
 148         [ iterate-next (find-integer) ] 2curry bi-curry if
 149     ] [ 3drop f ] if-iterate? ; inline recursive
 150
 151 : (all-integers?) ( ... i n quot: ( ... i -- ... ? ) -- ... ? )
 152     [
 153         iterate-step
 154         [ iterate-next (all-integers?) ] 3curry
 155         [ f ] if
 156     ] [ 3drop t ] if-iterate? ; inline recursive
 157
 158 : each-integer ( ... n quot: ( ... i -- ... ) -- ... )
 159     iterate-prep (each-integer) ; inline
 160
 161 : times ( ... n quot: ( ... -- ... ) -- ... )
 162     [ drop ] prepose each-integer ; inline
 163
 164 : find-integer ( ... n quot: ( ... i -- ... ? ) -- ... i )
 165     iterate-prep (find-integer) ; inline
 166
 167 : all-integers? ( ... n quot: ( ... i -- ... ? ) -- ... ? )
 168     iterate-prep (all-integers?) ; inline
 169
 170 : find-last-integer ( ... n quot: ( ... i -- ... ? ) -- ... i )
 171     over 0 < [
 172         2drop f
 173     ] [
 174         [ call ] 2keep rot [
 175             drop
 176         ] [
 177             [ 1 - ] dip find-last-integer
 178         ] if
 179     ] if ; inline recursive