core/math/math.factor

   1 ! Copyright (C) 2003, 2007 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: kernel math.private ;
   4 IN: math
   5
   6 GENERIC: >fixnum ( x -- n ) foldable
   7 GENERIC: >bignum ( x -- n ) foldable
   8 GENERIC: >integer ( x -- n ) foldable
   9 GENERIC: >float ( x -- y ) foldable
  10
  11 GENERIC: numerator ( a/b -- a )
  12 GENERIC: denominator ( a/b -- b )
  13
  14 GENERIC: real-part ( z -- x )
  15 GENERIC: imaginary-part ( z -- y )
  16
  17 MATH: number= ( x y -- ? ) foldable
  18
  19 M: object number= 2drop f ;
  20
  21 MATH: <  ( x y -- ? ) foldable
  22 MATH: <= ( x y -- ? ) foldable
  23 MATH: >  ( x y -- ? ) foldable
  24 MATH: >= ( x y -- ? ) foldable
  25
  26 MATH: +   ( x y -- z ) foldable
  27 MATH: -   ( x y -- z ) foldable
  28 MATH: *   ( x y -- z ) foldable
  29 MATH: /   ( x y -- z ) foldable
  30 MATH: /f  ( x y -- z ) foldable
  31 MATH: /i  ( x y -- z ) foldable
  32 MATH: mod ( x y -- z ) foldable
  33
  34 MATH: /mod ( x y -- z w ) foldable
  35
  36 MATH: bitand ( x y -- z ) foldable
  37 MATH: bitor  ( x y -- z ) foldable
  38 MATH: bitxor ( x y -- z ) foldable
  39 GENERIC# shift 1 ( x n -- y ) foldable
  40 GENERIC: bitnot ( x -- y ) foldable
  41 GENERIC# bit? 1 ( x n -- ? ) foldable
  42
  43 GENERIC: abs ( x -- y ) foldable
  44
  45 <PRIVATE
  46
  47 GENERIC: (log2) ( x -- n ) foldable
  48
  49 PRIVATE>
  50
  51 : log2 ( x -- n )
  52     dup 0 <= [
  53         "log2 expects positive inputs" throw
  54     ] [
  55         (log2)
  56     ] if ; foldable
  57
  58 : zero? ( x -- ? ) 0 number= ; inline
  59 : 1+ ( x -- y ) 1 + ; inline
  60 : 1- ( x -- y ) 1 - ; inline
  61 : 2/ ( x -- y ) -1 shift ; inline
  62 : sq ( x -- y ) dup * ; inline
  63 : neg ( x -- -x ) 0 swap - ; inline
  64 : recip ( x -- y ) 1 swap / ; inline
  65 : sgn ( x -- n ) dup 0 < [ drop -1 ] [ 0 > 1 0 ? ] if ; inline
  66
  67 : ?1+ [ 1+ ] [ 0 ] if* ; inline
  68
  69 : rem ( x y -- z ) tuck mod over + swap mod ; foldable
  70
  71 : 2^ ( n -- 2^n ) 1 swap shift ; inline
  72
  73 : even? ( n -- ? ) 1 bitand zero? ;
  74
  75 : odd? ( n -- ? ) 1 bitand 1 number= ;
  76
  77 UNION: integer fixnum bignum ;
  78
  79 UNION: rational integer ratio ;
  80
  81 UNION: real rational float ;
  82
  83 UNION: number real complex ;
  84
  85 M: number equal? number= ;
  86
  87 M: real hashcode* nip >fixnum ;
  88
  89 GENERIC: fp-nan? ( x -- ? )
  90
  91 M: object fp-nan?
  92     drop f ;
  93
  94 M: float fp-nan?
  95     double>bits -51 shift BIN: 111111111111 [ bitand ] keep
  96     number= ;
  97
  98 : (next-power-of-2) ( i n -- n )
  99     2dup >= [
 100         drop
 101     ] [
 102         >r 1 shift r> (next-power-of-2)
 103     ] if ;
 104
 105 : next-power-of-2 ( m -- n ) 2 swap (next-power-of-2) ; foldable
 106
 107 : power-of-2? ( n -- ? )
 108     dup 0 <= [ drop f ] [ dup 1- bitand zero? ] if ; foldable
 109
 110 : align ( m w -- n )
 111     1- [ + ] keep bitnot bitand ; inline
 112
 113 <PRIVATE
 114
 115 : iterate-prep 0 -rot ; inline
 116
 117 : if-iterate? >r >r 2over < r> r> if ; inline
 118
 119 : iterate-step ( i n quot -- i n quot )
 120     #! Apply quot to i, keep i and quot, hide n.
 121     swap >r 2dup 2slip r> swap ; inline
 122
 123 : iterate-next >r >r 1+ r> r> ; inline
 124
 125 PRIVATE>
 126
 127 : (each-integer) ( i n quot -- )
 128     [ iterate-step iterate-next (each-integer) ]
 129     [ 3drop ] if-iterate? ; inline
 130
 131 : (find-integer) ( i n quot -- i )
 132     [
 133         iterate-step roll
 134         [ 2drop ] [ iterate-next (find-integer) ] if
 135     ] [ 3drop f ] if-iterate? ; inline
 136
 137 : (all-integers?) ( i n quot -- ? )
 138     [
 139         iterate-step roll
 140         [ iterate-next (all-integers?) ] [ 3drop f ] if
 141     ] [ 3drop t ] if-iterate? ; inline
 142
 143 : each-integer ( n quot -- )
 144     iterate-prep (each-integer) ; inline
 145
 146 : times ( n quot -- )
 147     [ drop ] prepose each-integer ; inline
 148
 149 : find-integer ( n quot -- i )
 150     iterate-prep (find-integer) ; inline
 151
 152 : all-integers? ( n quot -- ? )
 153     iterate-prep (all-integers?) ; inline
 154
 155 : find-last-integer ( n quot -- i )
 156     over 0 < [
 157         2drop f
 158     ] [
 159         2dup 2slip rot [
 160             drop
 161         ] [
 162             >r 1- r> find-last-integer
 163         ] if
 164     ] if ; inline