core/math/math.factor

   1 ! Copyright (C) 2003, 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: kernel math.private ;
   4 IN: math
   5
   6 GENERIC: >fixnum ( x -- n ) foldable
   7 GENERIC: >bignum ( x -- n ) foldable
   8 GENERIC: >integer ( x -- n ) foldable
   9 GENERIC: >float ( x -- y ) foldable
  10
  11 GENERIC: numerator ( a/b -- a )
  12 GENERIC: denominator ( a/b -- b )
  13
  14 GENERIC: real-part ( z -- x )
  15 GENERIC: imaginary-part ( z -- y )
  16
  17 MATH: number= ( x y -- ? ) foldable
  18
  19 M: object number= 2drop f ;
  20
  21 MATH: <  ( x y -- ? ) foldable
  22 MATH: <= ( x y -- ? ) foldable
  23 MATH: >  ( x y -- ? ) foldable
  24 MATH: >= ( x y -- ? ) foldable
  25
  26 MATH: +   ( x y -- z ) foldable
  27 MATH: -   ( x y -- z ) foldable
  28 MATH: *   ( x y -- z ) foldable
  29 MATH: /   ( x y -- z ) foldable
  30 MATH: /f  ( x y -- z ) foldable
  31 MATH: /i  ( x y -- z ) foldable
  32 MATH: mod ( x y -- z ) foldable
  33
  34 MATH: /mod ( x y -- z w ) foldable
  35
  36 MATH: bitand ( x y -- z ) foldable
  37 MATH: bitor  ( x y -- z ) foldable
  38 MATH: bitxor ( x y -- z ) foldable
  39 GENERIC# shift 1 ( x n -- y ) foldable
  40 GENERIC: bitnot ( x -- y ) foldable
  41 GENERIC# bit? 1 ( x n -- ? ) foldable
  42
  43 GENERIC: abs ( x -- y ) foldable
  44
  45 <PRIVATE
  46
  47 GENERIC: (log2) ( x -- n ) foldable
  48
  49 PRIVATE>
  50
  51 ERROR: log2-expects-positive x ;
  52
  53 : log2 ( x -- n )
  54     dup 0 <= [
  55         log2-expects-positive
  56     ] [
  57         (log2)
  58     ] if ; inline
  59
  60 : zero? ( x -- ? ) 0 number= ; inline
  61 : 2/ ( x -- y ) -1 shift ; inline
  62 : sq ( x -- y ) dup * ; inline
  63 : neg ( x -- -x ) -1 * ; inline
  64 : recip ( x -- y ) 1 swap / ; inline
  65 : sgn ( x -- n ) dup 0 < [ drop -1 ] [ 0 > 1 0 ? ] if ; inline
  66 : ?1+ ( x -- y ) [ 1 + ] [ 0 ] if* ; inline
  67 : rem ( x y -- z ) abs [ mod ] [ + ] [ mod ] tri ; foldable
  68 : 2^ ( n -- 2^n ) 1 swap shift ; inline
  69 : even? ( n -- ? ) 1 bitand zero? ;
  70 : odd? ( n -- ? ) 1 bitand 1 number= ;
  71
  72 : if-zero ( n quot1 quot2 -- )
  73     [ dup zero? ] [ [ drop ] prepose ] [ ] tri* if ; inline
  74
  75 : when-zero ( n quot -- ) [ ] if-zero ; inline
  76
  77 : unless-zero ( n quot -- ) [ ] swap if-zero ; inline
  78
  79 UNION: integer fixnum bignum ;
  80
  81 TUPLE: ratio { numerator integer read-only } { denominator integer read-only } ;
  82
  83 UNION: rational integer ratio ;
  84
  85 UNION: real rational float ;
  86
  87 TUPLE: complex { real real read-only } { imaginary real read-only } ;
  88
  89 UNION: number real complex ;
  90
  91 : fp-bitwise= ( x y -- ? ) [ double>bits ] bi@ = ; inline
  92
  93 GENERIC: fp-special? ( x -- ? )
  94 GENERIC: fp-nan? ( x -- ? )
  95 GENERIC: fp-qnan? ( x -- ? )
  96 GENERIC: fp-snan? ( x -- ? )
  97 GENERIC: fp-infinity? ( x -- ? )
  98 GENERIC: fp-nan-payload ( x -- bits )
  99
 100 M: object fp-special? drop f ; inline
 101 M: object fp-nan? drop f ; inline
 102 M: object fp-qnan? drop f ; inline
 103 M: object fp-snan? drop f ; inline
 104 M: object fp-infinity? drop f ; inline
 105 M: object fp-nan-payload drop f ; inline
 106
 107 : <fp-nan> ( payload -- nan )
 108     HEX: 7ff0000000000000 bitor bits>double ; inline
 109
 110 GENERIC: next-float ( m -- n )
 111 GENERIC: prev-float ( m -- n )
 112
 113 : next-power-of-2 ( m -- n )
 114     dup 2 <= [ drop 2 ] [ 1 - log2 1 + 2^ ] if ; inline
 115
 116 : power-of-2? ( n -- ? )
 117     dup 0 <= [ drop f ] [ dup 1 - bitand zero? ] if ; foldable
 118
 119 : align ( m w -- n )
 120     1 - [ + ] keep bitnot bitand ; inline
 121
 122 <PRIVATE
 123
 124 : iterate-prep ( n quot -- i n quot ) [ 0 ] 2dip ; inline
 125
 126 : if-iterate? ( i n true false -- ) [ 2over < ] 2dip if ; inline
 127
 128 : iterate-step ( i n quot -- i n quot )
 129     #! Apply quot to i, keep i and quot, hide n.
 130     [ nip call ] 3keep ; inline
 131
 132 : iterate-next ( i n quot -- i' n quot ) [ 1 + ] 2dip ; inline
 133
 134 PRIVATE>
 135
 136 : (each-integer) ( i n quot: ( i -- ) -- )
 137     [ iterate-step iterate-next (each-integer) ]
 138     [ 3drop ] if-iterate? ; inline recursive
 139
 140 : (find-integer) ( i n quot: ( i -- ? ) -- i )
 141     [
 142         iterate-step roll
 143         [ 2drop ] [ iterate-next (find-integer) ] if
 144     ] [ 3drop f ] if-iterate? ; inline recursive
 145
 146 : (all-integers?) ( i n quot: ( i -- ? ) -- ? )
 147     [
 148         iterate-step roll
 149         [ iterate-next (all-integers?) ] [ 3drop f ] if
 150     ] [ 3drop t ] if-iterate? ; inline recursive
 151
 152 : each-integer ( n quot -- )
 153     iterate-prep (each-integer) ; inline
 154
 155 : times ( n quot -- )
 156     [ drop ] prepose each-integer ; inline
 157
 158 : find-integer ( n quot -- i )
 159     iterate-prep (find-integer) ; inline
 160
 161 : all-integers? ( n quot -- ? )
 162     iterate-prep (all-integers?) ; inline
 163
 164 : find-last-integer ( n quot: ( i -- ? ) -- i )
 165     over 0 < [
 166         2drop f
 167     ] [
 168         [ call ] 2keep rot [
 169             drop
 170         ] [
 171             [ 1 - ] dip find-last-integer
 172         ] if
 173     ] if ; inline recursive