core/math/math.factor

   1 ! Copyright (C) 2003, 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: kernel math.private ;
   4 IN: math
   5
   6 GENERIC: >fixnum ( x -- n ) foldable
   7 GENERIC: >bignum ( x -- n ) foldable
   8 GENERIC: >integer ( x -- n ) foldable
   9 GENERIC: >float ( x -- y ) foldable
  10
  11 GENERIC: numerator ( a/b -- a )
  12 GENERIC: denominator ( a/b -- b )
  13
  14 GENERIC: real-part ( z -- x )
  15 GENERIC: imaginary-part ( z -- y )
  16
  17 MATH: number= ( x y -- ? ) foldable
  18
  19 M: object number= 2drop f ;
  20
  21 MATH: <  ( x y -- ? ) foldable
  22 MATH: <= ( x y -- ? ) foldable
  23 MATH: >  ( x y -- ? ) foldable
  24 MATH: >= ( x y -- ? ) foldable
  25
  26 MATH: +   ( x y -- z ) foldable
  27 MATH: -   ( x y -- z ) foldable
  28 MATH: *   ( x y -- z ) foldable
  29 MATH: /   ( x y -- z ) foldable
  30 MATH: /f  ( x y -- z ) foldable
  31 MATH: /i  ( x y -- z ) foldable
  32 MATH: mod ( x y -- z ) foldable
  33
  34 MATH: /mod ( x y -- z w ) foldable
  35
  36 MATH: bitand ( x y -- z ) foldable
  37 MATH: bitor  ( x y -- z ) foldable
  38 MATH: bitxor ( x y -- z ) foldable
  39 GENERIC# shift 1 ( x n -- y ) foldable
  40 GENERIC: bitnot ( x -- y ) foldable
  41 GENERIC# bit? 1 ( x n -- ? ) foldable
  42
  43 GENERIC: abs ( x -- y ) foldable
  44
  45 <PRIVATE
  46
  47 GENERIC: (log2) ( x -- n ) foldable
  48
  49 PRIVATE>
  50
  51 : log2 ( x -- n )
  52     dup 0 <= [
  53         "log2 expects positive inputs" throw
  54     ] [
  55         (log2)
  56     ] if ; inline
  57
  58 : zero? ( x -- ? ) 0 number= ; inline
  59 : 1+ ( x -- y ) 1 + ; inline
  60 : 1- ( x -- y ) 1 - ; inline
  61 : 2/ ( x -- y ) -1 shift ; inline
  62 : sq ( x -- y ) dup * ; inline
  63 : neg ( x -- -x ) 0 swap - ; inline
  64 : recip ( x -- y ) 1 swap / ; inline
  65 : sgn ( x -- n ) dup 0 < [ drop -1 ] [ 0 > 1 0 ? ] if ; inline
  66 : ?1+ ( x -- y ) [ 1 + ] [ 0 ] if* ; inline
  67 : rem ( x y -- z ) abs [ mod ] [ + ] [ mod ] tri ; foldable
  68 : 2^ ( n -- 2^n ) 1 swap shift ; inline
  69 : even? ( n -- ? ) 1 bitand zero? ;
  70 : odd? ( n -- ? ) 1 bitand 1 number= ;
  71
  72 UNION: integer fixnum bignum ;
  73
  74 TUPLE: ratio { numerator integer read-only } { denominator integer read-only } ;
  75
  76 UNION: rational integer ratio ;
  77
  78 UNION: real rational float ;
  79
  80 TUPLE: complex { real real read-only } { imaginary real read-only } ;
  81
  82 UNION: number real complex ;
  83
  84 : fp-bitwise= ( x y -- ? ) [ double>bits ] bi@ = ; inline
  85
  86 GENERIC: fp-special? ( x -- ? )
  87 GENERIC: fp-nan? ( x -- ? )
  88 GENERIC: fp-qnan? ( x -- ? )
  89 GENERIC: fp-snan? ( x -- ? )
  90 GENERIC: fp-infinity? ( x -- ? )
  91 GENERIC: fp-nan-payload ( x -- bits )
  92
  93 M: object fp-special?
  94     drop f ;
  95 M: object fp-nan?
  96     drop f ;
  97 M: object fp-qnan?
  98     drop f ;
  99 M: object fp-snan?
 100     drop f ;
 101 M: object fp-infinity?
 102     drop f ;
 103 M: object fp-nan-payload
 104     drop f ;
 105
 106 M: float fp-special?
 107     double>bits -52 shift HEX: 7ff [ bitand ] keep = ;
 108
 109 M: float fp-nan-payload
 110     double>bits HEX: fffffffffffff bitand ; foldable flushable
 111
 112 M: float fp-nan?
 113     dup fp-special? [ fp-nan-payload zero? not ] [ drop f ] if ;
 114
 115 M: float fp-qnan?
 116     dup fp-nan? [ fp-nan-payload HEX: 8000000000000 bitand zero? not ] [ drop f ] if ;
 117
 118 M: float fp-snan?
 119     dup fp-nan? [ fp-nan-payload HEX: 8000000000000 bitand zero? ] [ drop f ] if ;
 120
 121 M: float fp-infinity?
 122     dup fp-special? [ fp-nan-payload zero? ] [ drop f ] if ;
 123
 124 : <fp-nan> ( payload -- nan )
 125     HEX: 7ff0000000000000 bitor bits>double ; foldable flushable
 126
 127 : next-float ( m -- n )
 128     double>bits
 129     dup -0.0 double>bits > [ 1 - bits>double ] [ ! negative non-zero
 130         dup -0.0 double>bits = [ drop 0.0 ] [ ! negative zero
 131             1 + bits>double ! positive
 132         ] if
 133     ] if ; foldable flushable
 134
 135 : prev-float ( m -- n )
 136     double>bits
 137     dup -0.0 double>bits >= [ 1 + bits>double ] [ ! negative
 138         dup 0.0 double>bits = [ drop -0.0 ] [ ! positive zero
 139             1 - bits>double ! positive non-zero
 140         ] if
 141     ] if ; foldable flushable
 142
 143 : next-power-of-2 ( m -- n )
 144     dup 2 <= [ drop 2 ] [ 1 - log2 1 + 2^ ] if ; inline
 145
 146 : power-of-2? ( n -- ? )
 147     dup 0 <= [ drop f ] [ dup 1 - bitand zero? ] if ; foldable
 148
 149 : align ( m w -- n )
 150     1 - [ + ] keep bitnot bitand ; inline
 151
 152 <PRIVATE
 153
 154 : iterate-prep ( n quot -- i n quot ) [ 0 ] 2dip ; inline
 155
 156 : if-iterate? ( i n true false -- ) [ 2over < ] 2dip if ; inline
 157
 158 : iterate-step ( i n quot -- i n quot )
 159     #! Apply quot to i, keep i and quot, hide n.
 160     [ nip call ] 3keep ; inline
 161
 162 : iterate-next ( i n quot -- i' n quot ) [ 1 + ] 2dip ; inline
 163
 164 PRIVATE>
 165
 166 : (each-integer) ( i n quot: ( i -- ) -- )
 167     [ iterate-step iterate-next (each-integer) ]
 168     [ 3drop ] if-iterate? ; inline recursive
 169
 170 : (find-integer) ( i n quot: ( i -- ? ) -- i )
 171     [
 172         iterate-step roll
 173         [ 2drop ] [ iterate-next (find-integer) ] if
 174     ] [ 3drop f ] if-iterate? ; inline recursive
 175
 176 : (all-integers?) ( i n quot: ( i -- ? ) -- ? )
 177     [
 178         iterate-step roll
 179         [ iterate-next (all-integers?) ] [ 3drop f ] if
 180     ] [ 3drop t ] if-iterate? ; inline recursive
 181
 182 : each-integer ( n quot -- )
 183     iterate-prep (each-integer) ; inline
 184
 185 : times ( n quot -- )
 186     [ drop ] prepose each-integer ; inline
 187
 188 : find-integer ( n quot -- i )
 189     iterate-prep (find-integer) ; inline
 190
 191 : all-integers? ( n quot -- ? )
 192     iterate-prep (all-integers?) ; inline
 193
 194 : find-last-integer ( n quot: ( i -- ? ) -- i )
 195     over 0 < [
 196         2drop f
 197     ] [
 198         [ call ] 2keep rot [
 199             drop
 200         ] [
 201             [ 1 - ] dip find-last-integer
 202         ] if
 203     ] if ; inline recursive