core/math/math.factor

   1 ! Copyright (C) 2003, 2009 Slava Pestov, Joe Groff.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: kernel ;
   4 IN: math
   5
   6 GENERIC: >fixnum ( x -- n ) foldable
   7 GENERIC: >bignum ( x -- n ) foldable
   8 GENERIC: >integer ( x -- n ) foldable
   9 GENERIC: >float ( x -- y ) foldable
  10
  11 GENERIC: numerator ( a/b -- a )
  12 GENERIC: denominator ( a/b -- b )
  13
  14 GENERIC: real-part ( z -- x )
  15 GENERIC: imaginary-part ( z -- y )
  16
  17 MATH: number= ( x y -- ? ) foldable
  18
  19 M: object number= 2drop f ;
  20
  21 MATH: <  ( x y -- ? ) foldable
  22 MATH: <= ( x y -- ? ) foldable
  23 MATH: >  ( x y -- ? ) foldable
  24 MATH: >= ( x y -- ? ) foldable
  25
  26 MATH: unordered? ( x y -- ? ) foldable
  27 MATH: u<  ( x y -- ? ) foldable
  28 MATH: u<= ( x y -- ? ) foldable
  29 MATH: u>  ( x y -- ? ) foldable
  30 MATH: u>= ( x y -- ? ) foldable
  31
  32 M: object unordered? 2drop f ;
  33
  34 MATH: +   ( x y -- z ) foldable
  35 MATH: -   ( x y -- z ) foldable
  36 MATH: *   ( x y -- z ) foldable
  37 MATH: /   ( x y -- z ) foldable
  38 MATH: /f  ( x y -- z ) foldable
  39 MATH: /i  ( x y -- z ) foldable
  40 MATH: mod ( x y -- z ) foldable
  41
  42 MATH: /mod ( x y -- z w ) foldable
  43
  44 MATH: bitand ( x y -- z ) foldable
  45 MATH: bitor  ( x y -- z ) foldable
  46 MATH: bitxor ( x y -- z ) foldable
  47 GENERIC# shift 1 ( x n -- y ) foldable
  48 GENERIC: bitnot ( x -- y ) foldable
  49 GENERIC# bit? 1 ( x n -- ? ) foldable
  50
  51 GENERIC: abs ( x -- y ) foldable
  52
  53 <PRIVATE
  54
  55 GENERIC: (log2) ( x -- n ) foldable
  56
  57 PRIVATE>
  58
  59 ERROR: not-an-integer n ;
  60
  61 ERROR: out-of-fixnum-range n ;
  62
  63 ERROR: log2-expects-positive x ;
  64
  65 : log2 ( x -- n )
  66     dup 0 <= [ log2-expects-positive ] [ (log2) ] if ; inline
  67
  68 : zero? ( x -- ? ) 0 number= ; inline
  69 : 2/ ( x -- y ) -1 shift ; inline
  70 : sq ( x -- y ) dup * ; inline
  71 : neg ( x -- -x ) -1 * ; inline
  72 : sgn ( x -- n ) dup 0 < [ drop -1 ] [ 0 > 1 0 ? ] if ; inline
  73 : ?1+ ( x -- y ) [ 1 + ] [ 0 ] if* ; inline
  74 : rem ( x y -- z ) abs [ mod ] [ + ] [ mod ] tri ; foldable
  75 : 2^ ( n -- 2^n ) 1 swap shift ; inline
  76 : even? ( n -- ? ) 1 bitand zero? ; inline
  77 : odd? ( n -- ? ) 1 bitand 1 number= ; inline
  78
  79 GENERIC: neg? ( x -- -x )
  80
  81 : if-zero ( ..a n quot1: ( ..a -- ..b ) quot2: ( ..a n -- ..b ) -- ..b )
  82     [ dup zero? ] [ [ drop ] prepose ] [ ] tri* if ; inline
  83
  84 : when-zero ( ..a n quot: ( ..a -- ..b ) -- ..b ) [ ] if-zero ; inline
  85
  86 : unless-zero ( ..a n quot: ( ..a -- ..b ) -- ..b ) [ ] swap if-zero ; inline
  87
  88 UNION: integer fixnum bignum ;
  89
  90 : integer>fixnum ( m -- n )
  91     dup fixnum? [
  92         dup bignum? [ bignum>fixnum ] [ not-an-integer ] if
  93     ] unless ; inline foldable
  94
  95 : integer>fixnum-strict ( m -- n )
  96     dup fixnum? [
  97         dup bignum? [
  98             dup bignum>fixnum 2dup number=
  99             [ nip ] [ drop out-of-fixnum-range ] if
 100         ] [ not-an-integer ] if
 101     ] unless ; inline foldable
 102
 103 TUPLE: ratio { numerator integer read-only } { denominator integer read-only } ;
 104
 105 UNION: rational integer ratio ;
 106
 107 M: rational neg? 0 < ; inline
 108
 109 UNION: real rational float ;
 110
 111 TUPLE: complex { real real read-only } { imaginary real read-only } ;
 112
 113 UNION: number real complex ;
 114
 115 GENERIC: recip ( x -- y )
 116
 117 M: number recip 1 swap / ; inline
 118
 119 : fp-bitwise= ( x y -- ? ) [ double>bits ] same? ; inline
 120
 121 GENERIC: fp-special? ( x -- ? )
 122 GENERIC: fp-nan? ( x -- ? )
 123 GENERIC: fp-qnan? ( x -- ? )
 124 GENERIC: fp-snan? ( x -- ? )
 125 GENERIC: fp-infinity? ( x -- ? )
 126 GENERIC: fp-nan-payload ( x -- bits )
 127 GENERIC: fp-sign ( x -- ? )
 128
 129 M: object fp-special? drop f ; inline
 130 M: object fp-nan? drop f ; inline
 131 M: object fp-qnan? drop f ; inline
 132 M: object fp-snan? drop f ; inline
 133 M: object fp-infinity? drop f ; inline
 134
 135 : <fp-nan> ( payload -- nan )
 136     0x7ff0000000000000 bitor bits>double ; inline
 137
 138 GENERIC: next-float ( m -- n )
 139 GENERIC: prev-float ( m -- n )
 140
 141 : next-power-of-2 ( m -- n )
 142     dup 2 <= [ drop 2 ] [ 1 - log2 1 + 2^ ] if ; inline
 143
 144 : power-of-2? ( n -- ? )
 145     dup 0 <= [ drop f ] [ dup 1 - bitand zero? ] if ; foldable
 146
 147 : align ( m w -- n )
 148     1 - [ + ] keep bitnot bitand ; inline
 149
 150 <PRIVATE
 151
 152 : iterate-prep ( n quot -- i n quot ) [ 0 ] 2dip ; inline
 153
 154 : if-iterate? ( i n true false -- ) [ 2over < ] 2dip if ; inline
 155
 156 : iterate-step ( i n quot -- i n quot )
 157     #! Apply quot to i, keep i and quot, hide n.
 158     [ nip call ] 3keep ; inline
 159
 160 : iterate-next ( i n quot -- i' n quot ) [ 1 + ] 2dip ; inline
 161
 162 PRIVATE>
 163
 164 : (each-integer) ( ... i n quot: ( ... i -- ... ) -- ... )
 165     [ iterate-step iterate-next (each-integer) ]
 166     [ 3drop ] if-iterate? ; inline recursive
 167
 168 : (find-integer) ( ... i n quot: ( ... i -- ... ? ) -- ... i )
 169     [
 170         iterate-step
 171         [ [ ] ] 2dip
 172         [ iterate-next (find-integer) ] 2curry bi-curry if
 173     ] [ 3drop f ] if-iterate? ; inline recursive
 174
 175 : (all-integers?) ( ... i n quot: ( ... i -- ... ? ) -- ... ? )
 176     [
 177         iterate-step
 178         [ iterate-next (all-integers?) ] 3curry
 179         [ f ] if
 180     ] [ 3drop t ] if-iterate? ; inline recursive
 181
 182 : each-integer ( ... n quot: ( ... i -- ... ) -- ... )
 183     iterate-prep (each-integer) ; inline
 184
 185 : times ( ... n quot: ( ... -- ... ) -- ... )
 186     [ drop ] prepose each-integer ; inline
 187
 188 : find-integer ( ... n quot: ( ... i -- ... ? ) -- ... i )
 189     iterate-prep (find-integer) ; inline
 190
 191 : all-integers? ( ... n quot: ( ... i -- ... ? ) -- ... ? )
 192     iterate-prep (all-integers?) ; inline
 193
 194 : find-last-integer ( ... n quot: ( ... i -- ... ? ) -- ... i )
 195     over 0 < [
 196         2drop f
 197     ] [
 198         [ call ] 2keep rot [
 199             drop
 200         ] [
 201             [ 1 - ] dip find-last-integer
 202         ] if
 203     ] if ; inline recursive