core/math/math.factor

   1 ! Copyright (C) 2003, 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: kernel math.private ;
   4 IN: math
   5
   6 GENERIC: >fixnum ( x -- n ) foldable
   7 GENERIC: >bignum ( x -- n ) foldable
   8 GENERIC: >integer ( x -- n ) foldable
   9 GENERIC: >float ( x -- y ) foldable
  10
  11 GENERIC: numerator ( a/b -- a )
  12 GENERIC: denominator ( a/b -- b )
  13
  14 GENERIC: real-part ( z -- x )
  15 GENERIC: imaginary-part ( z -- y )
  16
  17 MATH: number= ( x y -- ? ) foldable
  18
  19 M: object number= 2drop f ;
  20
  21 MATH: <  ( x y -- ? ) foldable
  22 MATH: <= ( x y -- ? ) foldable
  23 MATH: >  ( x y -- ? ) foldable
  24 MATH: >= ( x y -- ? ) foldable
  25
  26 MATH: +   ( x y -- z ) foldable
  27 MATH: -   ( x y -- z ) foldable
  28 MATH: *   ( x y -- z ) foldable
  29 MATH: /   ( x y -- z ) foldable
  30 MATH: /f  ( x y -- z ) foldable
  31 MATH: /i  ( x y -- z ) foldable
  32 MATH: mod ( x y -- z ) foldable
  33
  34 MATH: /mod ( x y -- z w ) foldable
  35
  36 MATH: bitand ( x y -- z ) foldable
  37 MATH: bitor  ( x y -- z ) foldable
  38 MATH: bitxor ( x y -- z ) foldable
  39 GENERIC# shift 1 ( x n -- y ) foldable
  40 GENERIC: bitnot ( x -- y ) foldable
  41 GENERIC# bit? 1 ( x n -- ? ) foldable
  42
  43 GENERIC: abs ( x -- y ) foldable
  44
  45 <PRIVATE
  46
  47 GENERIC: (log2) ( x -- n ) foldable
  48
  49 PRIVATE>
  50
  51 ERROR: log2-expects-positive x ;
  52
  53 : log2 ( x -- n )
  54     dup 0 <= [
  55         log2-expects-positive
  56     ] [
  57         (log2)
  58     ] if ; inline
  59
  60 : zero? ( x -- ? ) 0 number= ; inline
  61 : 2/ ( x -- y ) -1 shift ; inline
  62 : sq ( x -- y ) dup * ; inline
  63 : neg ( x -- -x ) -1 * ; inline
  64 : recip ( x -- y ) 1 swap / ; inline
  65 : sgn ( x -- n ) dup 0 < [ drop -1 ] [ 0 > 1 0 ? ] if ; inline
  66 : ?1+ ( x -- y ) [ 1 + ] [ 0 ] if* ; inline
  67 : rem ( x y -- z ) abs [ mod ] [ + ] [ mod ] tri ; foldable
  68 : 2^ ( n -- 2^n ) 1 swap shift ; inline
  69 : even? ( n -- ? ) 1 bitand zero? ;
  70 : odd? ( n -- ? ) 1 bitand 1 number= ;
  71
  72 : if-zero ( n quot1 quot2 -- )
  73     [ dup zero? ] [ [ drop ] prepose ] [ ] tri* if ; inline
  74
  75 : when-zero ( n quot -- ) [ ] if-zero ; inline
  76
  77 : unless-zero ( n quot -- ) [ ] swap if-zero ; inline
  78
  79 UNION: integer fixnum bignum ;
  80
  81 TUPLE: ratio { numerator integer read-only } { denominator integer read-only } ;
  82
  83 UNION: rational integer ratio ;
  84
  85 UNION: real rational float ;
  86
  87 TUPLE: complex { real real read-only } { imaginary real read-only } ;
  88
  89 UNION: number real complex ;
  90
  91 : fp-bitwise= ( x y -- ? ) [ double>bits ] bi@ = ; inline
  92
  93 GENERIC: fp-special? ( x -- ? )
  94 GENERIC: fp-nan? ( x -- ? )
  95 GENERIC: fp-qnan? ( x -- ? )
  96 GENERIC: fp-snan? ( x -- ? )
  97 GENERIC: fp-infinity? ( x -- ? )
  98 GENERIC: fp-nan-payload ( x -- bits )
  99
 100 M: object fp-special?
 101     drop f ; inline
 102 M: object fp-nan?
 103     drop f ; inline
 104 M: object fp-qnan?
 105     drop f ; inline
 106 M: object fp-snan?
 107     drop f ; inline
 108 M: object fp-infinity?
 109     drop f ; inline
 110 M: object fp-nan-payload
 111     drop f ; inline
 112
 113 M: float fp-special?
 114     double>bits -52 shift HEX: 7ff [ bitand ] keep = ; inline
 115
 116 M: float fp-nan-payload
 117     double>bits HEX: fffffffffffff bitand ; inline
 118
 119 M: float fp-nan?
 120     dup fp-special? [ fp-nan-payload zero? not ] [ drop f ] if ; inline
 121
 122 M: float fp-qnan?
 123     dup fp-nan? [ fp-nan-payload HEX: 8000000000000 bitand zero? not ] [ drop f ] if ; inline
 124
 125 M: float fp-snan?
 126     dup fp-nan? [ fp-nan-payload HEX: 8000000000000 bitand zero? ] [ drop f ] if ; inline
 127
 128 M: float fp-infinity?
 129     dup fp-special? [ fp-nan-payload zero? ] [ drop f ] if ; inline
 130
 131 : <fp-nan> ( payload -- nan )
 132     HEX: 7ff0000000000000 bitor bits>double ; inline
 133
 134 : next-float ( m -- n )
 135     double>bits
 136     dup -0.0 double>bits > [ 1 - bits>double ] [ ! negative non-zero
 137         dup -0.0 double>bits = [ drop 0.0 ] [ ! negative zero
 138             1 + bits>double ! positive
 139         ] if
 140     ] if ; inline
 141
 142 : prev-float ( m -- n )
 143     double>bits
 144     dup -0.0 double>bits >= [ 1 + bits>double ] [ ! negative
 145         dup 0.0 double>bits = [ drop -0.0 ] [ ! positive zero
 146             1 - bits>double ! positive non-zero
 147         ] if
 148     ] if ; inline
 149
 150 : next-power-of-2 ( m -- n )
 151     dup 2 <= [ drop 2 ] [ 1 - log2 1 + 2^ ] if ; inline
 152
 153 : power-of-2? ( n -- ? )
 154     dup 0 <= [ drop f ] [ dup 1 - bitand zero? ] if ; foldable
 155
 156 : align ( m w -- n )
 157     1 - [ + ] keep bitnot bitand ; inline
 158
 159 <PRIVATE
 160
 161 : iterate-prep ( n quot -- i n quot ) [ 0 ] 2dip ; inline
 162
 163 : if-iterate? ( i n true false -- ) [ 2over < ] 2dip if ; inline
 164
 165 : iterate-step ( i n quot -- i n quot )
 166     #! Apply quot to i, keep i and quot, hide n.
 167     [ nip call ] 3keep ; inline
 168
 169 : iterate-next ( i n quot -- i' n quot ) [ 1 + ] 2dip ; inline
 170
 171 PRIVATE>
 172
 173 : (each-integer) ( i n quot: ( i -- ) -- )
 174     [ iterate-step iterate-next (each-integer) ]
 175     [ 3drop ] if-iterate? ; inline recursive
 176
 177 : (find-integer) ( i n quot: ( i -- ? ) -- i )
 178     [
 179         iterate-step roll
 180         [ 2drop ] [ iterate-next (find-integer) ] if
 181     ] [ 3drop f ] if-iterate? ; inline recursive
 182
 183 : (all-integers?) ( i n quot: ( i -- ? ) -- ? )
 184     [
 185         iterate-step roll
 186         [ iterate-next (all-integers?) ] [ 3drop f ] if
 187     ] [ 3drop t ] if-iterate? ; inline recursive
 188
 189 : each-integer ( n quot -- )
 190     iterate-prep (each-integer) ; inline
 191
 192 : times ( n quot -- )
 193     [ drop ] prepose each-integer ; inline
 194
 195 : find-integer ( n quot -- i )
 196     iterate-prep (find-integer) ; inline
 197
 198 : all-integers? ( n quot -- ? )
 199     iterate-prep (all-integers?) ; inline
 200
 201 : find-last-integer ( n quot: ( i -- ? ) -- i )
 202     over 0 < [
 203         2drop f
 204     ] [
 205         [ call ] 2keep rot [
 206             drop
 207         ] [
 208             [ 1 - ] dip find-last-integer
 209         ] if
 210     ] if ; inline recursive