core/math/math.factor

   1 ! Copyright (C) 2003, 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: kernel math.private ;
   4 IN: math
   5
   6 GENERIC: >fixnum ( x -- n ) foldable
   7 GENERIC: >bignum ( x -- n ) foldable
   8 GENERIC: >integer ( x -- n ) foldable
   9 GENERIC: >float ( x -- y ) foldable
  10
  11 GENERIC: numerator ( a/b -- a )
  12 GENERIC: denominator ( a/b -- b )
  13
  14 GENERIC: real-part ( z -- x )
  15 GENERIC: imaginary-part ( z -- y )
  16
  17 MATH: number= ( x y -- ? ) foldable
  18
  19 M: object number= 2drop f ;
  20
  21 MATH: <  ( x y -- ? ) foldable
  22 MATH: <= ( x y -- ? ) foldable
  23 MATH: >  ( x y -- ? ) foldable
  24 MATH: >= ( x y -- ? ) foldable
  25
  26 MATH: +   ( x y -- z ) foldable
  27 MATH: -   ( x y -- z ) foldable
  28 MATH: *   ( x y -- z ) foldable
  29 MATH: /   ( x y -- z ) foldable
  30 MATH: /f  ( x y -- z ) foldable
  31 MATH: /i  ( x y -- z ) foldable
  32 MATH: mod ( x y -- z ) foldable
  33
  34 MATH: /mod ( x y -- z w ) foldable
  35
  36 MATH: bitand ( x y -- z ) foldable
  37 MATH: bitor  ( x y -- z ) foldable
  38 MATH: bitxor ( x y -- z ) foldable
  39 GENERIC# shift 1 ( x n -- y ) foldable
  40 GENERIC: bitnot ( x -- y ) foldable
  41 GENERIC# bit? 1 ( x n -- ? ) foldable
  42
  43 GENERIC: abs ( x -- y ) foldable
  44
  45 <PRIVATE
  46
  47 GENERIC: (log2) ( x -- n ) foldable
  48
  49 PRIVATE>
  50
  51 : log2 ( x -- n )
  52     dup 0 <= [
  53         "log2 expects positive inputs" throw
  54     ] [
  55         (log2)
  56     ] if ; inline
  57
  58 : zero? ( x -- ? ) 0 number= ; inline
  59 : 1+ ( x -- y ) 1 + ; inline
  60 : 1- ( x -- y ) 1 - ; inline
  61 : 2/ ( x -- y ) -1 shift ; inline
  62 : sq ( x -- y ) dup * ; inline
  63 : neg ( x -- -x ) 0 swap - ; inline
  64 : recip ( x -- y ) 1 swap / ; inline
  65 : sgn ( x -- n ) dup 0 < [ drop -1 ] [ 0 > 1 0 ? ] if ; inline
  66 : ?1+ ( x -- y ) [ 1 + ] [ 0 ] if* ; inline
  67 : rem ( x y -- z ) abs [ mod ] [ + ] [ mod ] tri ; foldable
  68 : 2^ ( n -- 2^n ) 1 swap shift ; inline
  69 : even? ( n -- ? ) 1 bitand zero? ;
  70 : odd? ( n -- ? ) 1 bitand 1 number= ;
  71
  72 UNION: integer fixnum bignum ;
  73
  74 TUPLE: ratio { numerator integer read-only } { denominator integer read-only } ;
  75
  76 UNION: rational integer ratio ;
  77
  78 UNION: real rational float ;
  79
  80 TUPLE: complex { real real read-only } { imaginary real read-only } ;
  81
  82 UNION: number real complex ;
  83
  84 GENERIC: fp-special? ( x -- ? )
  85 GENERIC: fp-nan? ( x -- ? )
  86 GENERIC: fp-qnan? ( x -- ? )
  87 GENERIC: fp-snan? ( x -- ? )
  88 GENERIC: fp-infinity? ( x -- ? )
  89 GENERIC: fp-nan-payload ( x -- bits )
  90
  91 M: object fp-special?
  92     drop f ;
  93 M: object fp-nan?
  94     drop f ;
  95 M: object fp-qnan?
  96     drop f ;
  97 M: object fp-snan?
  98     drop f ;
  99 M: object fp-infinity?
 100     drop f ;
 101 M: object fp-nan-payload
 102     drop f ;
 103
 104 M: float fp-special?
 105     double>bits -52 shift HEX: 7ff [ bitand ] keep = ;
 106
 107 M: float fp-nan-payload
 108     double>bits HEX: fffffffffffff bitand ; foldable flushable
 109
 110 M: float fp-nan?
 111     dup fp-special? [ fp-nan-payload zero? not ] [ drop f ] if ;
 112
 113 M: float fp-qnan?
 114     dup fp-nan? [ fp-nan-payload HEX: 8000000000000 bitand zero? not ] [ drop f ] if ;
 115
 116 M: float fp-snan?
 117     dup fp-nan? [ fp-nan-payload HEX: 8000000000000 bitand zero? ] [ drop f ] if ;
 118
 119 M: float fp-infinity?
 120     dup fp-special? [ fp-nan-payload zero? ] [ drop f ] if ;
 121
 122 : <fp-nan> ( payload -- nan )
 123     HEX: 7ff0000000000000 bitor bits>double ; foldable flushable
 124
 125 : next-float ( m -- n )
 126     double>bits
 127     dup -0.0 double>bits > [ 1 - bits>double ] [ ! negative non-zero
 128         dup -0.0 double>bits = [ drop 0.0 ] [ ! negative zero
 129             1 + bits>double ! positive
 130         ] if
 131     ] if ; foldable flushable
 132
 133 : prev-float ( m -- n )
 134     double>bits
 135     dup -0.0 double>bits >= [ 1 + bits>double ] [ ! negative
 136         dup 0.0 double>bits = [ drop -0.0 ] [ ! positive zero
 137             1 - bits>double ! positive non-zero
 138         ] if
 139     ] if ; foldable flushable
 140
 141 : next-power-of-2 ( m -- n )
 142     dup 2 <= [ drop 2 ] [ 1 - log2 1 + 2^ ] if ; inline
 143
 144 : power-of-2? ( n -- ? )
 145     dup 0 <= [ drop f ] [ dup 1 - bitand zero? ] if ; foldable
 146
 147 : align ( m w -- n )
 148     1 - [ + ] keep bitnot bitand ; inline
 149
 150 <PRIVATE
 151
 152 : iterate-prep ( n quot -- i n quot ) [ 0 ] 2dip ; inline
 153
 154 : if-iterate? ( i n true false -- ) [ 2over < ] 2dip if ; inline
 155
 156 : iterate-step ( i n quot -- i n quot )
 157     #! Apply quot to i, keep i and quot, hide n.
 158     [ nip call ] 3keep ; inline
 159
 160 : iterate-next ( i n quot -- i' n quot ) [ 1 + ] 2dip ; inline
 161
 162 PRIVATE>
 163
 164 : (each-integer) ( i n quot: ( i -- ) -- )
 165     [ iterate-step iterate-next (each-integer) ]
 166     [ 3drop ] if-iterate? ; inline recursive
 167
 168 : (find-integer) ( i n quot: ( i -- ? ) -- i )
 169     [
 170         iterate-step roll
 171         [ 2drop ] [ iterate-next (find-integer) ] if
 172     ] [ 3drop f ] if-iterate? ; inline recursive
 173
 174 : (all-integers?) ( i n quot: ( i -- ? ) -- ? )
 175     [
 176         iterate-step roll
 177         [ iterate-next (all-integers?) ] [ 3drop f ] if
 178     ] [ 3drop t ] if-iterate? ; inline recursive
 179
 180 : each-integer ( n quot -- )
 181     iterate-prep (each-integer) ; inline
 182
 183 : times ( n quot -- )
 184     [ drop ] prepose each-integer ; inline
 185
 186 : find-integer ( n quot -- i )
 187     iterate-prep (find-integer) ; inline
 188
 189 : all-integers? ( n quot -- ? )
 190     iterate-prep (all-integers?) ; inline
 191
 192 : find-last-integer ( n quot: ( i -- ? ) -- i )
 193     over 0 < [
 194         2drop f
 195     ] [
 196         [ call ] 2keep rot [
 197             drop
 198         ] [
 199             [ 1 - ] dip find-last-integer
 200         ] if
 201     ] if ; inline recursive