core/math/math.factor

   1 ! Copyright (C) 2003, 2009 Slava Pestov, Joe Groff.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: kernel ;
   4 IN: math
   5
   6 GENERIC: >fixnum ( x -- n ) foldable
   7 GENERIC: >bignum ( x -- n ) foldable
   8 GENERIC: >integer ( x -- n ) foldable
   9 GENERIC: >float ( x -- y ) foldable
  10 GENERIC: integer>fixnum ( x -- y ) foldable
  11 GENERIC: integer>fixnum-strict ( x -- y ) foldable
  12
  13 GENERIC: numerator ( a/b -- a )
  14 GENERIC: denominator ( a/b -- b )
  15
  16 GENERIC: real-part ( z -- x )
  17 GENERIC: imaginary-part ( z -- y )
  18
  19 MATH: number= ( x y -- ? ) foldable
  20
  21 M: object number= 2drop f ;
  22
  23 MATH: <  ( x y -- ? ) foldable
  24 MATH: <= ( x y -- ? ) foldable
  25 MATH: >  ( x y -- ? ) foldable
  26 MATH: >= ( x y -- ? ) foldable
  27
  28 MATH: unordered? ( x y -- ? ) foldable
  29 MATH: u<  ( x y -- ? ) foldable
  30 MATH: u<= ( x y -- ? ) foldable
  31 MATH: u>  ( x y -- ? ) foldable
  32 MATH: u>= ( x y -- ? ) foldable
  33
  34 M: object unordered? 2drop f ;
  35
  36 MATH: +   ( x y -- z ) foldable
  37 MATH: -   ( x y -- z ) foldable
  38 MATH: *   ( x y -- z ) foldable
  39 MATH: /   ( x y -- z ) foldable
  40 MATH: /f  ( x y -- z ) foldable
  41 MATH: /i  ( x y -- z ) foldable
  42 MATH: mod ( x y -- z ) foldable
  43
  44 MATH: /mod ( x y -- z w ) foldable
  45
  46 MATH: bitand ( x y -- z ) foldable
  47 MATH: bitor  ( x y -- z ) foldable
  48 MATH: bitxor ( x y -- z ) foldable
  49 GENERIC# shift 1 ( x n -- y ) foldable
  50 GENERIC: bitnot ( x -- y ) foldable
  51 GENERIC# bit? 1 ( x n -- ? ) foldable
  52
  53 GENERIC: abs ( x -- y ) foldable
  54
  55 <PRIVATE
  56
  57 GENERIC: (log2) ( x -- n ) foldable
  58
  59 PRIVATE>
  60
  61 ERROR: out-of-fixnum-range n ;
  62
  63 ERROR: log2-expects-positive x ;
  64
  65 : log2 ( x -- n )
  66     dup 0 <= [ log2-expects-positive ] [ (log2) ] if ; inline
  67
  68 : zero? ( x -- ? ) 0 number= ; inline
  69 : 2/ ( x -- y ) -1 shift ; inline
  70 : sq ( x -- y ) dup * ; inline
  71 : neg ( x -- -x ) -1 * ; inline
  72 : sgn ( x -- n ) dup 0 < [ drop -1 ] [ 0 > 1 0 ? ] if ; inline
  73 : ?1+ ( x -- y ) [ 1 + ] [ 0 ] if* ; inline
  74 : rem ( x y -- z ) abs [ mod ] [ + ] [ mod ] tri ; foldable
  75 : 2^ ( n -- 2^n ) 1 swap shift ; inline
  76 : even? ( n -- ? ) 1 bitand zero? ; inline
  77 : odd? ( n -- ? ) 1 bitand 1 number= ; inline
  78
  79 GENERIC: neg? ( x -- -x )
  80
  81 : if-zero ( ..a n quot1: ( ..a -- ..b ) quot2: ( ..a n -- ..b ) -- ..b )
  82     [ dup zero? ] [ [ drop ] prepose ] [ ] tri* if ; inline
  83
  84 : when-zero ( ..a n quot: ( ..a -- ..b ) -- ..b ) [ ] if-zero ; inline
  85
  86 : unless-zero ( ..a n quot: ( ..a -- ..b ) -- ..b ) [ ] swap if-zero ; inline
  87
  88 UNION: integer fixnum bignum ;
  89
  90 TUPLE: ratio { numerator integer read-only } { denominator integer read-only } ;
  91
  92 UNION: rational integer ratio ;
  93
  94 M: rational neg? 0 < ; inline
  95
  96 UNION: real rational float ;
  97
  98 TUPLE: complex { real real read-only } { imaginary real read-only } ;
  99
 100 UNION: number real complex ;
 101
 102 GENERIC: recip ( x -- y )
 103
 104 M: number recip 1 swap / ; inline
 105
 106 : fp-bitwise= ( x y -- ? ) [ double>bits ] same? ; inline
 107
 108 GENERIC: fp-special? ( x -- ? )
 109 GENERIC: fp-nan? ( x -- ? )
 110 GENERIC: fp-qnan? ( x -- ? )
 111 GENERIC: fp-snan? ( x -- ? )
 112 GENERIC: fp-infinity? ( x -- ? )
 113 GENERIC: fp-nan-payload ( x -- bits )
 114 GENERIC: fp-sign ( x -- ? )
 115
 116 M: object fp-special? drop f ; inline
 117 M: object fp-nan? drop f ; inline
 118 M: object fp-qnan? drop f ; inline
 119 M: object fp-snan? drop f ; inline
 120 M: object fp-infinity? drop f ; inline
 121
 122 : <fp-nan> ( payload -- nan )
 123     0x7ff0000000000000 bitor bits>double ; inline
 124
 125 GENERIC: next-float ( m -- n )
 126 GENERIC: prev-float ( m -- n )
 127
 128 : next-power-of-2 ( m -- n )
 129     dup 2 <= [ drop 2 ] [ 1 - log2 1 + 2^ ] if ; inline
 130
 131 : power-of-2? ( n -- ? )
 132     dup 0 <= [ drop f ] [ dup 1 - bitand zero? ] if ; foldable
 133
 134 : align ( m w -- n )
 135     1 - [ + ] keep bitnot bitand ; inline
 136
 137 <PRIVATE
 138
 139 : iterate-prep ( n quot -- i n quot ) [ 0 ] 2dip ; inline
 140
 141 : if-iterate? ( i n true false -- ) [ 2over < ] 2dip if ; inline
 142
 143 : iterate-step ( i n quot -- i n quot )
 144     #! Apply quot to i, keep i and quot, hide n.
 145     [ nip call ] 3keep ; inline
 146
 147 : iterate-next ( i n quot -- i' n quot ) [ 1 + ] 2dip ; inline
 148
 149 PRIVATE>
 150
 151 : (each-integer) ( ... i n quot: ( ... i -- ... ) -- ... )
 152     [ iterate-step iterate-next (each-integer) ]
 153     [ 3drop ] if-iterate? ; inline recursive
 154
 155 : (find-integer) ( ... i n quot: ( ... i -- ... ? ) -- ... i )
 156     [
 157         iterate-step
 158         [ [ ] ] 2dip
 159         [ iterate-next (find-integer) ] 2curry bi-curry if
 160     ] [ 3drop f ] if-iterate? ; inline recursive
 161
 162 : (all-integers?) ( ... i n quot: ( ... i -- ... ? ) -- ... ? )
 163     [
 164         iterate-step
 165         [ iterate-next (all-integers?) ] 3curry
 166         [ f ] if
 167     ] [ 3drop t ] if-iterate? ; inline recursive
 168
 169 : each-integer ( ... n quot: ( ... i -- ... ) -- ... )
 170     iterate-prep (each-integer) ; inline
 171
 172 : times ( ... n quot: ( ... -- ... ) -- ... )
 173     [ drop ] prepose each-integer ; inline
 174
 175 : find-integer ( ... n quot: ( ... i -- ... ? ) -- ... i )
 176     iterate-prep (find-integer) ; inline
 177
 178 : all-integers? ( ... n quot: ( ... i -- ... ? ) -- ... ? )
 179     iterate-prep (all-integers?) ; inline
 180
 181 : find-last-integer ( ... n quot: ( ... i -- ... ? ) -- ... i )
 182     over 0 < [
 183         2drop f
 184     ] [
 185         [ call ] 2keep rot [
 186             drop
 187         ] [
 188             [ 1 - ] dip find-last-integer
 189         ] if
 190     ] if ; inline recursive