core/math/math.factor

   1 ! Copyright (C) 2003, 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: kernel math.private ;
   4 IN: math
   5
   6 GENERIC: >fixnum ( x -- n ) foldable
   7 GENERIC: >bignum ( x -- n ) foldable
   8 GENERIC: >integer ( x -- n ) foldable
   9 GENERIC: >float ( x -- y ) foldable
  10
  11 GENERIC: numerator ( a/b -- a )
  12 GENERIC: denominator ( a/b -- b )
  13
  14 GENERIC: real-part ( z -- x )
  15 GENERIC: imaginary-part ( z -- y )
  16
  17 MATH: number= ( x y -- ? ) foldable
  18
  19 M: object number= 2drop f ;
  20
  21 MATH: <  ( x y -- ? ) foldable
  22 MATH: <= ( x y -- ? ) foldable
  23 MATH: >  ( x y -- ? ) foldable
  24 MATH: >= ( x y -- ? ) foldable
  25
  26 MATH: +   ( x y -- z ) foldable
  27 MATH: -   ( x y -- z ) foldable
  28 MATH: *   ( x y -- z ) foldable
  29 MATH: /   ( x y -- z ) foldable
  30 MATH: /f  ( x y -- z ) foldable
  31 MATH: /i  ( x y -- z ) foldable
  32 MATH: mod ( x y -- z ) foldable
  33
  34 MATH: /mod ( x y -- z w ) foldable
  35
  36 MATH: bitand ( x y -- z ) foldable
  37 MATH: bitor  ( x y -- z ) foldable
  38 MATH: bitxor ( x y -- z ) foldable
  39 GENERIC# shift 1 ( x n -- y ) foldable
  40 GENERIC: bitnot ( x -- y ) foldable
  41 GENERIC# bit? 1 ( x n -- ? ) foldable
  42
  43 GENERIC: abs ( x -- y ) foldable
  44
  45 <PRIVATE
  46
  47 GENERIC: (log2) ( x -- n ) foldable
  48
  49 PRIVATE>
  50
  51 ERROR: log2-expects-positive x ;
  52
  53 : log2 ( x -- n )
  54     dup 0 <= [
  55         log2-expects-positive
  56     ] [
  57         (log2)
  58     ] if ; inline
  59
  60 : zero? ( x -- ? ) 0 number= ; inline
  61 : 1+ ( x -- y ) 1 + ; inline
  62 : 1- ( x -- y ) 1 - ; inline
  63 : 2/ ( x -- y ) -1 shift ; inline
  64 : sq ( x -- y ) dup * ; inline
  65 : neg ( x -- -x ) -1 * ; inline
  66 : recip ( x -- y ) 1 swap / ; inline
  67 : sgn ( x -- n ) dup 0 < [ drop -1 ] [ 0 > 1 0 ? ] if ; inline
  68 : ?1+ ( x -- y ) [ 1 + ] [ 0 ] if* ; inline
  69 : rem ( x y -- z ) abs [ mod ] [ + ] [ mod ] tri ; foldable
  70 : 2^ ( n -- 2^n ) 1 swap shift ; inline
  71 : even? ( n -- ? ) 1 bitand zero? ;
  72 : odd? ( n -- ? ) 1 bitand 1 number= ;
  73
  74 UNION: integer fixnum bignum ;
  75
  76 TUPLE: ratio { numerator integer read-only } { denominator integer read-only } ;
  77
  78 UNION: rational integer ratio ;
  79
  80 UNION: real rational float ;
  81
  82 TUPLE: complex { real real read-only } { imaginary real read-only } ;
  83
  84 UNION: number real complex ;
  85
  86 : fp-bitwise= ( x y -- ? ) [ double>bits ] bi@ = ; inline
  87
  88 GENERIC: fp-special? ( x -- ? )
  89 GENERIC: fp-nan? ( x -- ? )
  90 GENERIC: fp-qnan? ( x -- ? )
  91 GENERIC: fp-snan? ( x -- ? )
  92 GENERIC: fp-infinity? ( x -- ? )
  93 GENERIC: fp-nan-payload ( x -- bits )
  94
  95 M: object fp-special?
  96     drop f ;
  97 M: object fp-nan?
  98     drop f ;
  99 M: object fp-qnan?
 100     drop f ;
 101 M: object fp-snan?
 102     drop f ;
 103 M: object fp-infinity?
 104     drop f ;
 105 M: object fp-nan-payload
 106     drop f ;
 107
 108 M: float fp-special?
 109     double>bits -52 shift HEX: 7ff [ bitand ] keep = ;
 110
 111 M: float fp-nan-payload
 112     double>bits HEX: fffffffffffff bitand ; foldable flushable
 113
 114 M: float fp-nan?
 115     dup fp-special? [ fp-nan-payload zero? not ] [ drop f ] if ;
 116
 117 M: float fp-qnan?
 118     dup fp-nan? [ fp-nan-payload HEX: 8000000000000 bitand zero? not ] [ drop f ] if ;
 119
 120 M: float fp-snan?
 121     dup fp-nan? [ fp-nan-payload HEX: 8000000000000 bitand zero? ] [ drop f ] if ;
 122
 123 M: float fp-infinity?
 124     dup fp-special? [ fp-nan-payload zero? ] [ drop f ] if ;
 125
 126 : <fp-nan> ( payload -- nan )
 127     HEX: 7ff0000000000000 bitor bits>double ; foldable flushable
 128
 129 : next-float ( m -- n )
 130     double>bits
 131     dup -0.0 double>bits > [ 1 - bits>double ] [ ! negative non-zero
 132         dup -0.0 double>bits = [ drop 0.0 ] [ ! negative zero
 133             1 + bits>double ! positive
 134         ] if
 135     ] if ; foldable flushable
 136
 137 : prev-float ( m -- n )
 138     double>bits
 139     dup -0.0 double>bits >= [ 1 + bits>double ] [ ! negative
 140         dup 0.0 double>bits = [ drop -0.0 ] [ ! positive zero
 141             1 - bits>double ! positive non-zero
 142         ] if
 143     ] if ; foldable flushable
 144
 145 : next-power-of-2 ( m -- n )
 146     dup 2 <= [ drop 2 ] [ 1 - log2 1 + 2^ ] if ; inline
 147
 148 : power-of-2? ( n -- ? )
 149     dup 0 <= [ drop f ] [ dup 1 - bitand zero? ] if ; foldable
 150
 151 : align ( m w -- n )
 152     1 - [ + ] keep bitnot bitand ; inline
 153
 154 <PRIVATE
 155
 156 : iterate-prep ( n quot -- i n quot ) [ 0 ] 2dip ; inline
 157
 158 : if-iterate? ( i n true false -- ) [ 2over < ] 2dip if ; inline
 159
 160 : iterate-step ( i n quot -- i n quot )
 161     #! Apply quot to i, keep i and quot, hide n.
 162     [ nip call ] 3keep ; inline
 163
 164 : iterate-next ( i n quot -- i' n quot ) [ 1 + ] 2dip ; inline
 165
 166 PRIVATE>
 167
 168 : (each-integer) ( i n quot: ( i -- ) -- )
 169     [ iterate-step iterate-next (each-integer) ]
 170     [ 3drop ] if-iterate? ; inline recursive
 171
 172 : (find-integer) ( i n quot: ( i -- ? ) -- i )
 173     [
 174         iterate-step roll
 175         [ 2drop ] [ iterate-next (find-integer) ] if
 176     ] [ 3drop f ] if-iterate? ; inline recursive
 177
 178 : (all-integers?) ( i n quot: ( i -- ? ) -- ? )
 179     [
 180         iterate-step roll
 181         [ iterate-next (all-integers?) ] [ 3drop f ] if
 182     ] [ 3drop t ] if-iterate? ; inline recursive
 183
 184 : each-integer ( n quot -- )
 185     iterate-prep (each-integer) ; inline
 186
 187 : times ( n quot -- )
 188     [ drop ] prepose each-integer ; inline
 189
 190 : find-integer ( n quot -- i )
 191     iterate-prep (find-integer) ; inline
 192
 193 : all-integers? ( n quot -- ? )
 194     iterate-prep (all-integers?) ; inline
 195
 196 : find-last-integer ( n quot: ( i -- ? ) -- i )
 197     over 0 < [
 198         2drop f
 199     ] [
 200         [ call ] 2keep rot [
 201             drop
 202         ] [
 203             [ 1 - ] dip find-last-integer
 204         ] if
 205     ] if ; inline recursive