core/math/math.factor

   1 ! Copyright (C) 2003, 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: kernel math.private ;
   4 IN: math
   5
   6 GENERIC: >fixnum ( x -- n ) foldable
   7 GENERIC: >bignum ( x -- n ) foldable
   8 GENERIC: >integer ( x -- n ) foldable
   9 GENERIC: >float ( x -- y ) foldable
  10
  11 GENERIC: numerator ( a/b -- a )
  12 GENERIC: denominator ( a/b -- b )
  13
  14 GENERIC: real-part ( z -- x )
  15 GENERIC: imaginary-part ( z -- y )
  16
  17 MATH: number= ( x y -- ? ) foldable
  18
  19 M: object number= 2drop f ;
  20
  21 MATH: <  ( x y -- ? ) foldable
  22 MATH: <= ( x y -- ? ) foldable
  23 MATH: >  ( x y -- ? ) foldable
  24 MATH: >= ( x y -- ? ) foldable
  25 MATH: unordered? ( x y -- ? ) foldable
  26
  27 M: object unordered? 2drop f ;
  28
  29 MATH: +   ( x y -- z ) foldable
  30 MATH: -   ( x y -- z ) foldable
  31 MATH: *   ( x y -- z ) foldable
  32 MATH: /   ( x y -- z ) foldable
  33 MATH: /f  ( x y -- z ) foldable
  34 MATH: /i  ( x y -- z ) foldable
  35 MATH: mod ( x y -- z ) foldable
  36
  37 MATH: /mod ( x y -- z w ) foldable
  38
  39 MATH: bitand ( x y -- z ) foldable
  40 MATH: bitor  ( x y -- z ) foldable
  41 MATH: bitxor ( x y -- z ) foldable
  42 GENERIC# shift 1 ( x n -- y ) foldable
  43 GENERIC: bitnot ( x -- y ) foldable
  44 GENERIC# bit? 1 ( x n -- ? ) foldable
  45
  46 GENERIC: abs ( x -- y ) foldable
  47
  48 <PRIVATE
  49
  50 GENERIC: (log2) ( x -- n ) foldable
  51
  52 PRIVATE>
  53
  54 ERROR: log2-expects-positive x ;
  55
  56 : log2 ( x -- n )
  57     dup 0 <= [
  58         log2-expects-positive
  59     ] [
  60         (log2)
  61     ] if ; inline
  62
  63 : zero? ( x -- ? ) 0 number= ; inline
  64 : 2/ ( x -- y ) -1 shift ; inline
  65 : sq ( x -- y ) dup * ; inline
  66 : neg ( x -- -x ) -1 * ; inline
  67 : recip ( x -- y ) 1 swap / ; inline
  68 : sgn ( x -- n ) dup 0 < [ drop -1 ] [ 0 > 1 0 ? ] if ; inline
  69 : ?1+ ( x -- y ) [ 1 + ] [ 0 ] if* ; inline
  70 : rem ( x y -- z ) abs [ mod ] [ + ] [ mod ] tri ; foldable
  71 : 2^ ( n -- 2^n ) 1 swap shift ; inline
  72 : even? ( n -- ? ) 1 bitand zero? ;
  73 : odd? ( n -- ? ) 1 bitand 1 number= ;
  74
  75 : if-zero ( n quot1 quot2 -- )
  76     [ dup zero? ] [ [ drop ] prepose ] [ ] tri* if ; inline
  77
  78 : when-zero ( n quot -- ) [ ] if-zero ; inline
  79
  80 : unless-zero ( n quot -- ) [ ] swap if-zero ; inline
  81
  82 UNION: integer fixnum bignum ;
  83
  84 TUPLE: ratio { numerator integer read-only } { denominator integer read-only } ;
  85
  86 UNION: rational integer ratio ;
  87
  88 UNION: real rational float ;
  89
  90 TUPLE: complex { real real read-only } { imaginary real read-only } ;
  91
  92 UNION: number real complex ;
  93
  94 : fp-bitwise= ( x y -- ? ) [ double>bits ] bi@ = ; inline
  95
  96 GENERIC: fp-special? ( x -- ? )
  97 GENERIC: fp-nan? ( x -- ? )
  98 GENERIC: fp-qnan? ( x -- ? )
  99 GENERIC: fp-snan? ( x -- ? )
 100 GENERIC: fp-infinity? ( x -- ? )
 101 GENERIC: fp-nan-payload ( x -- bits )
 102
 103 M: object fp-special? drop f ; inline
 104 M: object fp-nan? drop f ; inline
 105 M: object fp-qnan? drop f ; inline
 106 M: object fp-snan? drop f ; inline
 107 M: object fp-infinity? drop f ; inline
 108 M: object fp-nan-payload drop f ; inline
 109
 110 : <fp-nan> ( payload -- nan )
 111     HEX: 7ff0000000000000 bitor bits>double ; inline
 112
 113 GENERIC: next-float ( m -- n )
 114 GENERIC: prev-float ( m -- n )
 115
 116 : next-power-of-2 ( m -- n )
 117     dup 2 <= [ drop 2 ] [ 1 - log2 1 + 2^ ] if ; inline
 118
 119 : power-of-2? ( n -- ? )
 120     dup 0 <= [ drop f ] [ dup 1 - bitand zero? ] if ; foldable
 121
 122 : align ( m w -- n )
 123     1 - [ + ] keep bitnot bitand ; inline
 124
 125 <PRIVATE
 126
 127 : iterate-prep ( n quot -- i n quot ) [ 0 ] 2dip ; inline
 128
 129 : if-iterate? ( i n true false -- ) [ 2over < ] 2dip if ; inline
 130
 131 : iterate-step ( i n quot -- i n quot )
 132     #! Apply quot to i, keep i and quot, hide n.
 133     [ nip call ] 3keep ; inline
 134
 135 : iterate-next ( i n quot -- i' n quot ) [ 1 + ] 2dip ; inline
 136
 137 PRIVATE>
 138
 139 : (each-integer) ( i n quot: ( i -- ) -- )
 140     [ iterate-step iterate-next (each-integer) ]
 141     [ 3drop ] if-iterate? ; inline recursive
 142
 143 : (find-integer) ( i n quot: ( i -- ? ) -- i )
 144     [
 145         iterate-step roll
 146         [ 2drop ] [ iterate-next (find-integer) ] if
 147     ] [ 3drop f ] if-iterate? ; inline recursive
 148
 149 : (all-integers?) ( i n quot: ( i -- ? ) -- ? )
 150     [
 151         iterate-step roll
 152         [ iterate-next (all-integers?) ] [ 3drop f ] if
 153     ] [ 3drop t ] if-iterate? ; inline recursive
 154
 155 : each-integer ( n quot -- )
 156     iterate-prep (each-integer) ; inline
 157
 158 : times ( n quot -- )
 159     [ drop ] prepose each-integer ; inline
 160
 161 : find-integer ( n quot -- i )
 162     iterate-prep (find-integer) ; inline
 163
 164 : all-integers? ( n quot -- ? )
 165     iterate-prep (all-integers?) ; inline
 166
 167 : find-last-integer ( n quot: ( i -- ? ) -- i )
 168     over 0 < [
 169         2drop f
 170     ] [
 171         [ call ] 2keep rot [
 172             drop
 173         ] [
 174             [ 1 - ] dip find-last-integer
 175         ] if
 176     ] if ; inline recursive