core/math/parser/parser.factor

   1 ! Copyright (C) 2004, 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: kernel math.private namespaces sequences sequences.private
   4 strings arrays combinators splitting math assocs byte-arrays make ;
   5 IN: math.parser
   6
   7 : digit> ( ch -- n )
   8     H{
   9         { CHAR: 0 0 }
  10         { CHAR: 1 1 }
  11         { CHAR: 2 2 }
  12         { CHAR: 3 3 }
  13         { CHAR: 4 4 }
  14         { CHAR: 5 5 }
  15         { CHAR: 6 6 }
  16         { CHAR: 7 7 }
  17         { CHAR: 8 8 }
  18         { CHAR: 9 9 }
  19         { CHAR: A 10 }
  20         { CHAR: B 11 }
  21         { CHAR: C 12 }
  22         { CHAR: D 13 }
  23         { CHAR: E 14 }
  24         { CHAR: F 15 }
  25         { CHAR: a 10 }
  26         { CHAR: b 11 }
  27         { CHAR: c 12 }
  28         { CHAR: d 13 }
  29         { CHAR: e 14 }
  30         { CHAR: f 15 }
  31         { CHAR: , f }
  32     } at* [ drop 255 ] unless ; inline
  33
  34 : string>digits ( str -- digits )
  35     [ digit> ] B{ } map-as ; inline
  36
  37 : (digits>integer) ( valid? accum digit radix -- valid? accum )
  38     over [
  39         2dup < [ swapd * + ] [ 2drop 2drop f 0 ] if
  40     ] [ 2drop ] if ; inline
  41
  42 : each-digit ( seq radix quot -- n/f )
  43     [ t 0 ] 3dip curry each swap [ drop f ] unless ; inline
  44
  45 : digits>integer ( seq radix -- n/f )
  46     [ (digits>integer) ] each-digit ; inline
  47
  48 DEFER: base>
  49
  50 <PRIVATE
  51
  52 SYMBOL: radix
  53 SYMBOL: negative?
  54
  55 : string>natural ( seq radix -- n/f )
  56     over empty? [ 2drop f ] [
  57         [ [ digit> ] dip (digits>integer) ] each-digit
  58     ] if ; inline
  59
  60 : sign ( -- str ) negative? get "-" "+" ? ;
  61
  62 : with-radix ( radix quot -- )
  63     radix swap with-variable ; inline
  64
  65 : (base>) ( str -- n ) radix get base> ;
  66
  67 : whole-part ( str -- m n )
  68     sign split1 [ (base>) ] dip
  69     dup [ (base>) ] [ drop 0 swap ] if ;
  70
  71 : string>ratio ( str radix -- a/b )
  72     [
  73         "-" ?head dup negative? set swap
  74         "/" split1 (base>) [ whole-part ] dip
  75         3dup and and [ / + swap [ neg ] when ] [ 2drop 2drop f ] if
  76     ] with-radix ;
  77
  78 : string>integer ( str radix -- n/f )
  79     over first-unsafe CHAR: - = [
  80         [ rest-slice ] dip string>natural dup [ neg ] when
  81     ] [
  82         string>natural
  83     ] if ; inline
  84
  85 : string>float ( str -- n/f )
  86     [ CHAR: , eq? not ] filter
  87     >byte-array 0 suffix (string>float) ;
  88
  89 PRIVATE>
  90
  91 : base> ( str radix -- n/f )
  92     over empty? [ 2drop f ] [
  93         over [ "/." member? ] find nip {
  94             { CHAR: / [ string>ratio ] }
  95             { CHAR: . [ drop string>float ] }
  96             [ drop string>integer ]
  97         } case
  98     ] if ;
  99
 100 : string>number ( str -- n/f ) 10 base> ;
 101 : bin> ( str -- n/f ) 2 base> ;
 102 : oct> ( str -- n/f ) 8 base> ;
 103 : hex> ( str -- n/f ) 16 base> ;
 104
 105 : >digit ( n -- ch )
 106     dup 10 < [ CHAR: 0 + ] [ 10 - CHAR: a + ] if ;
 107
 108 : positive>base ( num radix -- str )
 109     dup 1 <= [ "Invalid radix" throw ] when
 110     [ dup 0 > ] swap [ /mod >digit ] curry "" produce-as nip
 111     dup reverse-here ; inline
 112
 113 PRIVATE>
 114
 115 GENERIC# >base 1 ( n radix -- str )
 116
 117 <PRIVATE
 118
 119 : (>base) ( n -- str ) radix get positive>base ;
 120
 121 PRIVATE>
 122
 123 M: integer >base
 124     over 0 = [
 125         2drop "0"
 126     ] [
 127         over 0 > [
 128             positive>base
 129         ] [
 130             [ neg ] dip positive>base CHAR: - prefix
 131         ] if
 132     ] if ;
 133
 134 M: ratio >base
 135     [
 136         dup 0 < negative? set
 137         abs 1 /mod
 138         [ [ "" ] [ (>base) sign append ] if-zero ]
 139         [
 140             [ numerator (>base) ]
 141             [ denominator (>base) ] bi
 142             "/" glue
 143         ] bi* append
 144         negative? get [ CHAR: - prefix ] when
 145     ] with-radix ;
 146
 147 : fix-float ( str -- newstr )
 148     {
 149         {
 150             [ CHAR: e over member? ]
 151             [ "e" split1 [ fix-float "e" ] dip 3append ]
 152         } {
 153             [ CHAR: . over member? ]
 154             [ ]
 155         }
 156         [ ".0" append ]
 157     } cond ;
 158
 159 : float>string ( n -- str )
 160     (float>string)
 161     [ 0 = ] trim-tail >string
 162     fix-float ;
 163
 164 M: float >base
 165     drop {
 166         { [ dup fp-nan? ] [ drop "0/0." ] }
 167         { [ dup 1/0. = ] [ drop "1/0." ] }
 168         { [ dup -1/0. = ] [ drop "-1/0." ] }
 169         { [ dup double>bits HEX: 8000000000000000 = ] [ drop "-0.0" ] }
 170         [ float>string ]
 171     } cond ;
 172
 173 : number>string ( n -- str ) 10 >base ;
 174 : >bin ( n -- str ) 2 >base ;
 175 : >oct ( n -- str ) 8 >base ;
 176 : >hex ( n -- str ) 16 >base ;
 177
 178 : # ( n -- ) number>string % ;