core/memoize/memoize.factor

   1 ! Copyright (C) 2007, 2010 Slava Pestov, Daniel Ehrenberg.
   2 ! See https://factorcode.org/license.txt for BSD license.
   3 USING: accessors arrays assocs definitions effects hashtables
   4 kernel kernel.private math sequences sequences.private words ;
   5 IN: memoize
   6
   7 <PRIVATE
   8
   9 ! We can't use n*quot, narray and firstn from generalizations because
  10 ! they're macros, and macros use memoize!
  11 : (n*quot) ( n quot -- quotquot )
  12     <repetition> [ ] concat-as ;
  13
  14 : [nsequence] ( length exemplar -- quot )
  15     [ [ [ 1 - ] keep ] dip '[ _ _ _ new-sequence ] ]
  16     [ drop [ [ set-nth-unsafe ] 2keep [ 1 - ] dip ] (n*quot) ] 2bi
  17     [ nip ] 3append ;
  18
  19 : [firstn] ( length -- quot )
  20     [ 0 swap ] swap
  21     [ [ nth-unsafe ] 2keep [ 1 + ] dip ] (n*quot)
  22     [ 2drop ] 3append ;
  23
  24 : packer ( seq -- quot )
  25     length dup 4 <=
  26     [ { [ f ] [ ] [ 2array ] [ 3array ] [ 4array ] } nth ]
  27     [ { } [nsequence] ] if ;
  28
  29 : unpacker ( seq -- quot )
  30     length dup dup 4 <=
  31     [ { [ drop ] [ ] [ first2-unsafe ] [ first3-unsafe ] [ first4-unsafe ] } nth ]
  32     [ [firstn] ] if swap 1 >
  33     [ [ { array } declare ] prepose ] when ;
  34
  35 : pack/unpack ( quot effect -- newquot )
  36     [ in>> packer ] [ out>> unpacker ] bi surround ;
  37
  38 : unpack/pack ( quot effect -- newquot )
  39     [ in>> unpacker ] [ out>> packer ] bi surround ;
  40
  41 : make/n ( table quot effect -- quot )
  42     [ unpack/pack '[ _ _ cache ] ] keep pack/unpack ;
  43
  44 : make/0 ( table quot effect -- quot )
  45     out>> [
  46         packer '[
  47             _ dup first-unsafe [ second-unsafe ] [
  48                 @ @ [
  49                     1 pick set-nth-unsafe t 0 rot set-nth-unsafe
  50                 ] keep
  51             ] if
  52         ]
  53     ] keep unpacker compose ;
  54
  55 : make-memoizer ( table quot effect -- quot )
  56     dup in>> length zero? [ make/0 ] [ make/n ] if ;
  57
  58 PRIVATE>
  59
  60 : (define-memoized) ( word quot effect hashtable -- )
  61     [ [ drop "memo-quot" set-word-prop ] ] dip
  62     '[ 2drop _ "memoize" set-word-prop ]
  63     [ [ [ dup "memoize" word-prop ] 2dip make-memoizer ] keep define-declared ]
  64     3tri ;
  65
  66 : define-memoized ( word quot effect -- )
  67     dup in>> length zero? [ f f 2array ] [ H{ } clone ] if
  68     (define-memoized) ;
  69
  70 : define-identity-memoized ( word quot effect -- )
  71     dup in>> length zero? [ f f 2array ] [ IH{ } clone ] if
  72     (define-memoized) ;
  73
  74 PREDICATE: memoized < word "memoize" word-prop >boolean ;
  75
  76 M: memoized definer
  77     def>> 3 from-tail swap ?nth hashtable?
  78     \ MEMO: \ IDENTITY-MEMO: ? \ ; ;
  79
  80 M: memoized definition "memo-quot" word-prop ;
  81
  82 M: memoized reset-word
  83     [ call-next-method ]
  84     [ { "memoize" "memo-quot" } remove-word-props ]
  85     bi ;
  86
  87 : memoize-quot ( quot effect -- memo-quot )
  88     dup in>> length zero? [ f f 2array ] [ H{ } clone ] if
  89     -rot make-memoizer ;
  90
  91 : reset-memoized ( word -- )
  92     "memoize" word-prop dup sequence?
  93     [ f swap set-first ] [ clear-assoc ] if ;
  94
  95 : invalidate-memoized ( inputs... word -- )
  96     [ stack-effect in>> packer call ]
  97     [
  98         "memoize" word-prop dup sequence?
  99         [ f swap set-first ] [ delete-at ] if
 100     ]
 101     bi ;
 102
 103 \ invalidate-memoized t "no-compile" set-word-prop