core/parser/parser-docs.factor

   1 USING: help.markup help.syntax kernel sequences words
   2 math strings vectors quotations generic effects classes
   3 vocabs.loader definitions io vocabs source-files
   4 quotations namespaces compiler.units assocs lexer
   5 words.symbol words.alias words.constant vocabs.parser ;
   6 IN: parser
   7
   8 ARTICLE: "reading-ahead" "Reading ahead"
   9 "Parsing words can consume input:"
  10 { $subsection scan }
  11 { $subsection scan-word }
  12 "For example, the " { $link POSTPONE: HEX: } " word uses this feature to read hexadecimal literals:"
  13 { $see POSTPONE: HEX: }
  14 "It is defined in terms of a lower-level word that takes the numerical base on the data stack, but reads the number from the parser and then adds it to the parse tree:"
  15 { $see parse-base }
  16 "Another simple example is the " { $link POSTPONE: \ } " word:"
  17 { $see POSTPONE: \ } ;
  18
  19 ARTICLE: "parsing-word-nest" "Nested structure"
  20 "Recall that the parser loop calls parsing words with an accumulator vector on the stack. The parser loop can be invoked recursively with a new, empty accumulator; the result can then be added to the original accumulator. This is how parsing words for object literals are implemented; object literals can nest arbitrarily deep."
  21 $nl
  22 "A simple example is the parsing word that reads a quotation:"
  23 { $see POSTPONE: [ }
  24 "This word uses a utility word which recursively invokes the parser, reading objects into a new accumulator until an occurrence of " { $link POSTPONE: ] } ":"
  25 { $subsection parse-literal }
  26 "There is another, lower-level word for reading nested structure, which is also useful when called directly:"
  27 { $subsection parse-until }
  28 "Words such as " { $link POSTPONE: ] } " use a declaration which causes them to throw an error when an unpaired occurrence is encountered:"
  29 { $subsection POSTPONE: delimiter }
  30 { $see-also POSTPONE: { POSTPONE: H{ POSTPONE: V{ POSTPONE: W{ POSTPONE: T{ POSTPONE: } } ;
  31
  32 ARTICLE: "defining-words" "Defining words"
  33 "Defining words add definitions to the dictionary without modifying the parse tree. The simplest example is the " { $link POSTPONE: SYMBOL: } " word."
  34 { $see POSTPONE: SYMBOL: }
  35 "The key factor in the definition of " { $link POSTPONE: SYMBOL: } " is " { $link CREATE } ", which reads a token from the input and creates a word with that name. This word is then passed to " { $link define-symbol } "."
  36 { $subsection CREATE }
  37 { $subsection CREATE-WORD }
  38 "Colon definitions are defined in a more elaborate way:"
  39 { $subsection POSTPONE: : }
  40 "The " { $link POSTPONE: : } " word first calls " { $link CREATE } ", and then reads input until reaching " { $link POSTPONE: ; } " using a utility word:"
  41 { $subsection parse-definition }
  42 "The " { $link POSTPONE: ; } " word is just a delimiter; an unpaired occurrence throws a parse error:"
  43 { $see POSTPONE: ; }
  44 "There are additional parsing words whose syntax is delimited by " { $link POSTPONE: ; } ", and they are all implemented by calling " { $link parse-definition } "." ;
  45
  46 ARTICLE: "parsing-tokens" "Parsing raw tokens"
  47 "So far we have seen how to read individual tokens, or read a sequence of parsed objects until a delimiter. It is also possible to read raw tokens from the input and perform custom processing."
  48 $nl
  49 "One example is the " { $link POSTPONE: USING: } " parsing word."
  50 { $see POSTPONE: USING: }
  51 "It reads a list of vocabularies terminated by " { $link POSTPONE: ; } ". However, the vocabulary names do not name words, except by coincidence; so " { $link parse-until } " cannot be used here. Instead, a lower-level word is called:"
  52 { $subsection parse-tokens } ;
  53
  54 ARTICLE: "parsing-words" "Parsing words"
  55 "The Factor parser follows a simple recursive-descent design. The parser reads successive tokens from the input; if the token identifies a number or an ordinary word, it is added to an accumulator vector. Otherwise if the token identifies a parsing word, the parsing word is executed immediately."
  56 $nl
  57 "Parsing words are marked by suffixing the definition with a " { $link POSTPONE: parsing } " declaration. Here is the simplest possible parsing word; it prints a greeting at parse time:"
  58 { $code ": hello \"Hello world\" print ; parsing" }
  59 "Parsing words must not pop or push items from the stack; however, they are permitted to access the accumulator vector supplied by the parser at the top of the stack. That is, parsing words must have stack effect " { $snippet "( accum -- accum )" } ", where " { $snippet "accum" } " is the accumulator vector supplied by the parser."
  60 $nl
  61 "Parsing words can read input, add word definitions to the dictionary, and do anything an ordinary word can."
  62 $nl
  63 "Because of the stack restriction, parsing words cannot pass data to other words by leaving values on the stack; instead, use " { $link parsed } " to add the data to the parse tree so that it can be evaluated later."
  64 $nl
  65 "Parsing words cannot be called from the same source file where they are defined, because new definitions are only compiled at the end of the source file. An attempt to use a parsing word in its own source file raises an error:"
  66 { $subsection staging-violation }
  67 "Tools for implementing parsing words:"
  68 { $subsection "reading-ahead" }
  69 { $subsection "parsing-word-nest" }
  70 { $subsection "defining-words" }
  71 { $subsection "parsing-tokens" } ;
  72
  73 ARTICLE: "parser-files" "Parsing source files"
  74 "The parser can run source files:"
  75 { $subsection run-file }
  76 { $subsection parse-file }
  77 "The parser cross-references source files and definitions. This allows it to keep track of removed definitions, and prevent forward references and accidental redefinitions."
  78 $nl
  79 "While the above words are useful for one-off experiments, real programs should be written to use the vocabulary system instead; see " { $link "vocabs.loader" } "."
  80 { $see-also "source-files" } ;
  81
  82 ARTICLE: "top-level-forms" "Top level forms"
  83 "Any code outside of a definition is known as a " { $emphasis "top-level form" } "; top-level forms are run after the entire source file has been parsed, regardless of their position in the file."
  84 $nl
  85 "Top-level forms do not have access to the " { $link in } " and " { $link use } " variables that were set at parse time, nor do they run inside " { $link with-compilation-unit } "; so meta-programming might require extra work in a top-level form compared with a parsing word."
  86 $nl
  87 "Also, top-level forms run in a new dynamic scope, so using " { $link set } " to store values is almost always wrong, since the values will be lost after the top-level form completes. To save values computed by a top-level form, either use " { $link set-global } " or define a new word with the value." ;
  88
  89 ARTICLE: "parser" "The parser"
  90 "This parser is a general facility for reading textual representations of objects and definitions. The parser is implemented in the " { $vocab-link "parser" } " and " { $vocab-link "syntax" } " vocabularies."
  91 $nl
  92 "This section concerns itself with usage and extension of the parser. Standard syntax is described in " { $link "syntax" } "."
  93 { $subsection "vocabulary-search" }
  94 { $subsection "parser-files" }
  95 { $subsection "top-level-forms" }
  96 "The parser can be extended."
  97 { $subsection "parsing-words" }
  98 { $subsection "parser-lexer" }
  99 "The parser can be invoked reflectively;"
 100 { $subsection parse-stream }
 101 { $see-also "definitions" "definition-checking" } ;
 102
 103 ABOUT: "parser"
 104
 105 HELP: location
 106 { $values { "loc" "a " { $snippet "{ path line# }" } " pair" } }
 107 { $description "Outputs the current parser location. This value can be passed to " { $link set-where } " or " { $link remember-definition } "." } ;
 108
 109 HELP: save-location
 110 { $values { "definition" "a definition specifier" } }
 111 { $description "Saves the location of a definition and associates this definition with the current source file." } ;
 112
 113 HELP: parser-notes
 114 { $var-description "A boolean controlling whether the parser will print various notes and warnings. Switched on by default. If a source file is being run for its effect on " { $link output-stream } ", this variable should be switched off, to prevent parser notes from polluting the output." } ;
 115
 116 HELP: parser-notes?
 117 { $values { "?" "a boolean" } }
 118 { $description "Tests if the parser will print various notes and warnings. To disable parser notes, either set " { $link parser-notes } " to " { $link f } ", or pass the " { $snippet "-quiet" } " command line switch." } ;
 119
 120 HELP: bad-number
 121 { $error-description "Indicates the parser encountered an invalid numeric literal." } ;
 122
 123 HELP: use
 124 { $var-description "A variable holding the current vocabulary search path as a sequence of assocs." } ;
 125
 126 { use in use+ (use+) set-use set-in POSTPONE: USING: POSTPONE: USE: with-file-vocabs with-interactive-vocabs } related-words
 127
 128 HELP: in
 129 { $var-description "A variable holding the name of the current vocabulary for new definitions." } ;
 130
 131 HELP: current-vocab
 132 { $values { "str" "a vocabulary" } }
 133 { $description "Returns the vocabulary stored in the " { $link in } " symbol. Throws an error if the current vocabulary is " { $link f } "." } ;
 134
 135 HELP: (use+)
 136 { $values { "vocab" "an assoc mapping strings to words" } }
 137 { $description "Adds an assoc at the front of the search path." }
 138 $parsing-note ;
 139
 140 HELP: use+
 141 { $values { "vocab" string } }
 142 { $description "Adds a new vocabulary at the front of the search path after loading it if necessary. Subsequent word lookups by the parser will search this vocabulary first." }
 143 $parsing-note
 144 { $errors "Throws an error if the vocabulary does not exist." } ;
 145
 146 HELP: set-use
 147 { $values { "seq" "a sequence of strings" } }
 148 { $description "Sets the vocabulary search path. Later vocabularies take precedence." }
 149 { $errors "Throws an error if one of the vocabularies does not exist." }
 150 $parsing-note ;
 151
 152 HELP: add-use
 153 { $values { "seq" "a sequence of strings" } }
 154 { $description "Adds multiple vocabularies to the search path, with later vocabularies taking precedence." }
 155 { $errors "Throws an error if one of the vocabularies does not exist." }
 156 $parsing-note ;
 157
 158 HELP: set-in
 159 { $values { "name" string } }
 160 { $description "Sets the current vocabulary where new words will be defined, creating the vocabulary first if it does not exist." }
 161 $parsing-note ;
 162
 163 HELP: create-in
 164 { $values { "str" "a word name" } { "word" "a new word" } }
 165 { $description "Creates a word in the current vocabulary. Until re-defined, the word throws an error when invoked." }
 166 $parsing-note ;
 167
 168 HELP: CREATE
 169 { $values { "word" word } }
 170 { $description "Reads the next token from the line currently being parsed, and creates a word with that name in the current vocabulary." }
 171 { $errors "Throws an error if the end of the line is reached." }
 172 $parsing-note ;
 173
 174 HELP: no-word-error
 175 { $error-description "Thrown if the parser encounters a token which does not name a word in the current vocabulary search path. If any words with this name exist in vocabularies not part of the search path, a number of restarts will offer to add those vocabularies to the search path and use the chosen word." }
 176 { $notes "Apart from a missing " { $link POSTPONE: USE: } ", this error can also indicate an ordering issue. In Factor, words must be defined before they can be called. Mutual recursion can be implemented via " { $link POSTPONE: DEFER: } "." } ;
 177
 178 HELP: no-word
 179 { $values { "name" string } { "newword" word } }
 180 { $description "Throws a " { $link no-word-error } "." } ;
 181
 182 HELP: search
 183 { $values { "str" string } { "word/f" "a word or " { $link f } } }
 184 { $description "Searches for a word by name in the current vocabulary search path. If no such word could be found, outputs " { $link f } "." }
 185 $parsing-note ;
 186
 187 HELP: scan-word
 188 { $values { "word/number/f" "a word, number or " { $link f } } }
 189 { $description "Reads the next token from parser input. If the token is a valid number literal, it is converted to a number, otherwise the dictionary is searched for a word named by the token. Outputs " { $link f } " if the end of the input has been reached." }
 190 { $errors "Throws an error if the token does not name a word, and does not parse as a number." }
 191 $parsing-note ;
 192
 193 HELP: parse-step
 194 { $values { "accum" vector } { "end" word } { "?" "a boolean" } }
 195 { $description "Parses a token. If the token is a number or an ordinary word, it is added to the accumulator. If it is a parsing word, calls the parsing word with the accumulator on the stack. Outputs " { $link f } " if " { $snippet "end" } " is encountered, " { $link t } " otherwise." }
 196 $parsing-note ;
 197
 198 HELP: (parse-until)
 199 { $values { "accum" vector } { "end" word } }
 200 { $description "Parses objects from parser input until " { $snippet "end" } " is encountered, adding them to the accumulator." }
 201 $parsing-note ;
 202
 203 HELP: parse-until
 204 { $values { "end" word } { "vec" "a new vector" } }
 205 { $description "Parses objects from parser input until " { $snippet "end" } ". Outputs a new vector with the results." }
 206 { $examples "This word is used to implement " { $link POSTPONE: ARTICLE: } "." }
 207 $parsing-note ;
 208
 209 { parse-tokens (parse-until) parse-until } related-words
 210
 211 HELP: parsed
 212 { $values { "accum" vector } { "obj" object } }
 213 { $description "Convenience word for parsing words. It behaves exactly the same as " { $link push } ", except the accumulator remains on the stack." }
 214 $parsing-note ;
 215
 216 HELP: (parse-lines)
 217 { $values { "lexer" lexer } { "quot" "a new " { $link quotation } } }
 218 { $description "Parses Factor source code using a custom lexer. The vocabulary search path is taken from the current scope." }
 219 { $errors "Throws a " { $link lexer-error } " if the input is malformed." } ;
 220
 221 HELP: parse-lines
 222 { $values { "lines" "a sequence of strings" } { "quot" "a new " { $link quotation } } }
 223 { $description "Parses Factor source code which has been tokenized into lines. The vocabulary search path is taken from the current scope." }
 224 { $errors "Throws a " { $link lexer-error } " if the input is malformed." } ;
 225
 226 HELP: parse-base
 227 { $values { "base" "an integer between 2 and 36" } { "parsed" integer } }
 228 { $description "Reads an integer in a specific numerical base from the parser input." }
 229 $parsing-note ;
 230
 231 HELP: parse-literal
 232 { $values { "accum" vector } { "end" word } { "quot" { $quotation "( seq -- obj )" } } }
 233 { $description "Parses objects from parser input until " { $snippet "end" } ", applies the quotation to the resulting sequence, and adds the output value to the accumulator." }
 234 { $examples "This word is used to implement " { $link POSTPONE: [ } "." }
 235 $parsing-note ;
 236
 237 HELP: parse-definition
 238 { $values { "quot" "a new " { $link quotation } } }
 239 { $description "Parses objects from parser input until " { $link POSTPONE: ; } " and outputs a quotation with the results." }
 240 { $examples "This word is used to implement " { $link POSTPONE: : } "." }
 241 $parsing-note ;
 242
 243 HELP: bootstrap-syntax
 244 { $var-description "Only set during bootstrap. Stores a copy of the " { $link vocab-words } " of the host's syntax vocabulary; this allows the host's parsing words to be used during bootstrap source parsing, not the target's." } ;
 245
 246 HELP: with-file-vocabs
 247 { $values { "quot" quotation } }
 248 { $description "Calls the quotation in a scope with the initial the vocabulary search path for parsing a file. This consists of just the " { $snippet "syntax" } " vocabulary." } ;
 249
 250 HELP: parse-fresh
 251 { $values { "lines" "a sequence of strings" } { "quot" quotation } }
 252 { $description "Parses Factor source code in a sequence of lines. The initial vocabulary search path is used (see " { $link with-file-vocabs } ")." }
 253 { $errors "Throws a parse error if the input is malformed." } ;
 254
 255 HELP: filter-moved
 256 { $values { "assoc1" assoc } { "assoc2" assoc } { "seq" "an seqence of definitions" } }
 257 { $description "Removes all definitions from " { $snippet "assoc2" } " which are in " { $snippet "assoc1" } " or are are no longer present in the current " { $link file } "." } ;
 258
 259 HELP: forget-smudged
 260 { $description "Forgets removed definitions and prints a warning message if any of them are still referenced from other source files." } ;
 261
 262 HELP: finish-parsing
 263 { $values { "lines" "the lines of text just parsed" } { "quot" "the quotation just parsed" } }
 264 { $description "Records information to the current " { $link file } " and prints warnings about any removed definitions which are still in use." }
 265 { $notes "This is one of the factors of " { $link parse-stream } "." } ;
 266
 267 HELP: parse-stream
 268 { $values { "stream" "an input stream" } { "name" "a file name for error reporting and cross-referencing" } { "quot" quotation } }
 269 { $description "Parses Factor source code read from the stream. The initial vocabulary search path is used." }
 270 { $errors "Throws an I/O error if there was an error reading from the stream. Throws a parse error if the input is malformed." } ;
 271
 272 HELP: parse-file
 273 { $values { "file" "a pathname string" } { "quot" quotation } }
 274 { $description "Parses the Factor source code stored in a file. The initial vocabulary search path is used." }
 275 { $errors "Throws an I/O error if there was an error reading from the file. Throws a parse error if the input is malformed." } ;
 276
 277 HELP: run-file
 278 { $values { "file" "a pathname string" } }
 279 { $description "Parses the Factor source code stored in a file and runs it. The initial vocabulary search path is used." }
 280 { $errors "Throws an error if loading the file fails, there input is malformed, or if a runtime error occurs while calling the parsed quotation." }  ;
 281
 282 HELP: ?run-file
 283 { $values { "path" "a pathname string" } }
 284 { $description "If the file exists, runs it with " { $link run-file } ", otherwise does nothing." } ;
 285
 286 HELP: staging-violation
 287 { $values { "word" word } }
 288 { $description "Throws a " { $link staging-violation } " error." }
 289 { $error-description "Thrown by the parser if a parsing word is used in the same compilation unit as where it was defined; see " { $link "compilation-units" } "." }
 290 { $notes "One possible workaround is to use the " { $link POSTPONE: << } " word to execute code at parse time. However, executing words defined in the same source file at parse time is still prohibited." } ;
 291
 292 HELP: auto-use?
 293 { $var-description "If set to a true value, the behavior of the parser when encountering an unknown word name is changed. If only one loaded vocabulary has a word with this name, instead of throwing an error, the parser adds the vocabulary to the search path and prints a parse note. Off by default." }
 294 { $notes "This feature is intended to help during development. To generate a " { $link POSTPONE: USING: } " form automatically, enable " { $link auto-use? } ", load the source file, and copy and paste the " { $link POSTPONE: USING: } " form printed by the parser back into the file, then disable " { $link auto-use? } ". See " { $link "vocabulary-search-errors" } "." } ;