core/parser/parser-docs.factor

   1 USING: help.markup help.syntax kernel sequences words
   2 math strings vectors quotations generic effects classes
   3 vocabs.loader definitions io vocabs source-files
   4 namespaces compiler.units assocs lexer
   5 words.symbol words.alias words.constant vocabs.parser ;
   6 IN: parser
   7
   8 ARTICLE: "reading-ahead" "Reading ahead"
   9 "Parsing words can consume input:"
  10 { $subsection scan }
  11 { $subsection scan-word }
  12 "For example, the " { $link POSTPONE: HEX: } " word uses this feature to read hexadecimal literals:"
  13 { $see POSTPONE: HEX: }
  14 "It is defined in terms of a lower-level word that takes the numerical base on the data stack, but reads the number from the parser and then adds it to the parse tree:"
  15 { $see parse-base }
  16 "Another simple example is the " { $link POSTPONE: \ } " word:"
  17 { $see POSTPONE: \ } ;
  18
  19 ARTICLE: "parsing-word-nest" "Nested structure"
  20 "Recall that the parser loop calls parsing words with an accumulator vector on the stack. The parser loop can be invoked recursively with a new, empty accumulator; the result can then be added to the original accumulator. This is how parsing words for object literals are implemented; object literals can nest arbitrarily deep."
  21 $nl
  22 "A simple example is the parsing word that reads a quotation:"
  23 { $see POSTPONE: [ }
  24 "This word uses a utility word which recursively invokes the parser, reading objects into a new accumulator until an occurrence of " { $link POSTPONE: ] } ":"
  25 { $subsection parse-literal }
  26 "There is another, lower-level word for reading nested structure, which is also useful when called directly:"
  27 { $subsection parse-until }
  28 "Words such as " { $link POSTPONE: ] } " use a declaration which causes them to throw an error when an unpaired occurrence is encountered:"
  29 { $subsection POSTPONE: delimiter }
  30 { $see-also POSTPONE: { POSTPONE: H{ POSTPONE: V{ POSTPONE: W{ POSTPONE: T{ POSTPONE: } } ;
  31
  32 ARTICLE: "defining-words" "Defining words"
  33 "Defining words add definitions to the dictionary without modifying the parse tree. The simplest example is the " { $link POSTPONE: SYMBOL: } " word."
  34 { $see POSTPONE: SYMBOL: }
  35 "The key factor in the definition of " { $link POSTPONE: SYMBOL: } " is " { $link CREATE } ", which reads a token from the input and creates a word with that name. This word is then passed to " { $link define-symbol } "."
  36 { $subsection CREATE }
  37 { $subsection CREATE-WORD }
  38 "Colon definitions are defined in a more elaborate way:"
  39 { $subsection POSTPONE: : }
  40 "The " { $link POSTPONE: : } " word first calls " { $link CREATE } ", and then reads input until reaching " { $link POSTPONE: ; } " using a utility word:"
  41 { $subsection parse-definition }
  42 "The " { $link POSTPONE: ; } " word is just a delimiter; an unpaired occurrence throws a parse error:"
  43 { $see POSTPONE: ; }
  44 "There are additional parsing words whose syntax is delimited by " { $link POSTPONE: ; } ", and they are all implemented by calling " { $link parse-definition } "." ;
  45
  46 ARTICLE: "parsing-tokens" "Parsing raw tokens"
  47 "So far we have seen how to read individual tokens, or read a sequence of parsed objects until a delimiter. It is also possible to read raw tokens from the input and perform custom processing."
  48 $nl
  49 "One example is the " { $link POSTPONE: USING: } " parsing word."
  50 { $see POSTPONE: USING: }
  51 "It reads a list of vocabularies terminated by " { $link POSTPONE: ; } ". However, the vocabulary names do not name words, except by coincidence; so " { $link parse-until } " cannot be used here. Instead, a lower-level word is called:"
  52 { $subsection parse-tokens } ;
  53
  54 ARTICLE: "parsing-words" "Parsing words"
  55 "The Factor parser follows a simple recursive-descent design. The parser reads successive tokens from the input; if the token identifies a number or an ordinary word, it is added to an accumulator vector. Otherwise if the token identifies a parsing word, the parsing word is executed immediately."
  56 $nl
  57 "Parsing words are defined using the a defining word:"
  58 { $subsection POSTPONE: SYNTAX: }
  59 "Parsing words have uppercase names by convention. Here is the simplest possible parsing word; it prints a greeting at parse time:"
  60 { $code "SYNTAX: HELLO \"Hello world\" print ;" }
  61 "Parsing words must not pop or push items from the stack; however, they are permitted to access the accumulator vector supplied by the parser at the top of the stack. That is, parsing words must have stack effect " { $snippet "( accum -- accum )" } ", where " { $snippet "accum" } " is the accumulator vector supplied by the parser."
  62 $nl
  63 "Parsing words can read input, add word definitions to the dictionary, and do anything an ordinary word can."
  64 $nl
  65 "Because of the stack restriction, parsing words cannot pass data to other words by leaving values on the stack; instead, use " { $link parsed } " to add the data to the parse tree so that it can be evaluated later."
  66 $nl
  67 "Parsing words cannot be called from the same source file where they are defined, because new definitions are only compiled at the end of the source file. An attempt to use a parsing word in its own source file raises an error:"
  68 { $subsection staging-violation }
  69 "Tools for implementing parsing words:"
  70 { $subsection "reading-ahead" }
  71 { $subsection "parsing-word-nest" }
  72 { $subsection "defining-words" }
  73 { $subsection "parsing-tokens" }
  74 { $subsection "word-search-parsing" } ;
  75
  76 ARTICLE: "parser-files" "Parsing source files"
  77 "The parser can run source files:"
  78 { $subsection run-file }
  79 { $subsection parse-file }
  80 "The parser cross-references source files and definitions. This allows it to keep track of removed definitions, and prevent forward references and accidental redefinitions."
  81 $nl
  82 "While the above words are useful for one-off experiments, real programs should be written to use the vocabulary system instead; see " { $link "vocabs.loader" } "."
  83 { $see-also "source-files" } ;
  84
  85 ARTICLE: "top-level-forms" "Top level forms"
  86 "Any code outside of a definition is known as a " { $emphasis "top-level form" } "; top-level forms are run after the entire source file has been parsed, regardless of their position in the file."
  87 $nl
  88 "Top-level forms cannot access the parse-time manifest (" { $link "word-search-parsing" } "), nor do they run inside " { $link with-compilation-unit } "; as a result, meta-programming might require extra work in a top-level form compared with a parsing word."
  89 $nl
  90 "Also, top-level forms run in a new dynamic scope, so using " { $link set } " to store values is almost always wrong, since the values will be lost after the top-level form completes. To save values computed by a top-level form, either use " { $link set-global } " or define a new word with the value." ;
  91
  92 ARTICLE: "parser" "The parser"
  93 "This parser is a general facility for reading textual representations of objects and definitions. The parser is implemented in the " { $vocab-link "parser" } " and " { $vocab-link "syntax" } " vocabularies."
  94 $nl
  95 "This section concerns itself with usage and extension of the parser. Standard syntax is described in " { $link "syntax" } "."
  96 { $subsection "parser-files" }
  97 "The parser can be extended."
  98 { $subsection "parser-lexer" }
  99 "The parser can be invoked reflectively;"
 100 { $subsection parse-stream }
 101 { $see-also "parsing-words" "definitions" "definition-checking" } ;
 102
 103 ABOUT: "parser"
 104
 105 HELP: location
 106 { $values { "loc" "a " { $snippet "{ path line# }" } " pair" } }
 107 { $description "Outputs the current parser location. This value can be passed to " { $link set-where } " or " { $link remember-definition } "." } ;
 108
 109 HELP: save-location
 110 { $values { "definition" "a definition specifier" } }
 111 { $description "Saves the location of a definition and associates this definition with the current source file." } ;
 112
 113 HELP: parser-notes
 114 { $var-description "A boolean controlling whether the parser will print various notes. Switched on by default. If a source file is being run for its effect on " { $link output-stream } ", this variable should be switched off, to prevent parser notes from polluting the output." } ;
 115
 116 HELP: parser-notes?
 117 { $values { "?" "a boolean" } }
 118 { $description "Tests if the parser will print various notes and warnings. To disable parser notes, either set " { $link parser-notes } " to " { $link f } ", or pass the " { $snippet "-quiet" } " command line switch." } ;
 119
 120 HELP: bad-number
 121 { $error-description "Indicates the parser encountered an invalid numeric literal." } ;
 122
 123 HELP: create-in
 124 { $values { "str" "a word name" } { "word" "a new word" } }
 125 { $description "Creates a word in the current vocabulary. Until re-defined, the word throws an error when invoked." }
 126 $parsing-note ;
 127
 128 HELP: CREATE
 129 { $values { "word" word } }
 130 { $description "Reads the next token from the line currently being parsed, and creates a word with that name in the current vocabulary." }
 131 { $errors "Throws an error if the end of the line is reached." }
 132 $parsing-note ;
 133
 134 HELP: no-word-error
 135 { $error-description "Thrown if the parser encounters a token which does not name a word in the current vocabulary search path. If any words with this name exist in vocabularies not part of the search path, a number of restarts will offer to add those vocabularies to the search path and use the chosen word." }
 136 { $notes "Apart from a missing " { $link POSTPONE: USE: } ", this error can also indicate an ordering issue. In Factor, words must be defined before they can be called. Mutual recursion can be implemented via " { $link POSTPONE: DEFER: } "." } ;
 137
 138 HELP: no-word
 139 { $values { "name" string } { "newword" word } }
 140 { $description "Throws a " { $link no-word-error } "." } ;
 141
 142 HELP: scan-word
 143 { $values { "word/number/f" "a word, number or " { $link f } } }
 144 { $description "Reads the next token from parser input. If the token is a valid number literal, it is converted to a number, otherwise the dictionary is searched for a word named by the token. Outputs " { $link f } " if the end of the input has been reached." }
 145 { $errors "Throws an error if the token does not name a word, and does not parse as a number." }
 146 $parsing-note ;
 147
 148 HELP: parse-step
 149 { $values { "accum" vector } { "end" word } { "?" "a boolean" } }
 150 { $description "Parses a token. If the token is a number or an ordinary word, it is added to the accumulator. If it is a parsing word, calls the parsing word with the accumulator on the stack. Outputs " { $link f } " if " { $snippet "end" } " is encountered, " { $link t } " otherwise." }
 151 $parsing-note ;
 152
 153 HELP: (parse-until)
 154 { $values { "accum" vector } { "end" word } }
 155 { $description "Parses objects from parser input until " { $snippet "end" } " is encountered, adding them to the accumulator." }
 156 $parsing-note ;
 157
 158 HELP: parse-until
 159 { $values { "end" word } { "vec" "a new vector" } }
 160 { $description "Parses objects from parser input until " { $snippet "end" } ". Outputs a new vector with the results." }
 161 { $examples "This word is used to implement " { $link POSTPONE: ARTICLE: } "." }
 162 $parsing-note ;
 163
 164 { parse-tokens (parse-until) parse-until } related-words
 165
 166 HELP: parsed
 167 { $values { "accum" vector } { "obj" object } }
 168 { $description "Convenience word for parsing words. It behaves exactly the same as " { $link push } ", except the accumulator remains on the stack." }
 169 $parsing-note ;
 170
 171 HELP: (parse-lines)
 172 { $values { "lexer" lexer } { "quot" "a new " { $link quotation } } }
 173 { $description "Parses Factor source code using a custom lexer. The vocabulary search path is taken from the current scope." }
 174 { $errors "Throws a " { $link lexer-error } " if the input is malformed." } ;
 175
 176 HELP: parse-lines
 177 { $values { "lines" "a sequence of strings" } { "quot" "a new " { $link quotation } } }
 178 { $description "Parses Factor source code which has been tokenized into lines. The vocabulary search path is taken from the current scope." }
 179 { $errors "Throws a " { $link lexer-error } " if the input is malformed." } ;
 180
 181 HELP: parse-base
 182 { $values { "base" "an integer between 2 and 36" } { "parsed" integer } }
 183 { $description "Reads an integer in a specific numerical base from the parser input." }
 184 $parsing-note ;
 185
 186 HELP: parse-literal
 187 { $values { "accum" vector } { "end" word } { "quot" { $quotation "( seq -- obj )" } } }
 188 { $description "Parses objects from parser input until " { $snippet "end" } ", applies the quotation to the resulting sequence, and adds the output value to the accumulator." }
 189 { $examples "This word is used to implement " { $link POSTPONE: [ } "." }
 190 $parsing-note ;
 191
 192 HELP: parse-definition
 193 { $values { "quot" "a new " { $link quotation } } }
 194 { $description "Parses objects from parser input until " { $link POSTPONE: ; } " and outputs a quotation with the results." }
 195 { $examples "This word is used to implement " { $link POSTPONE: : } "." }
 196 $parsing-note ;
 197
 198 HELP: bootstrap-syntax
 199 { $var-description "Only set during bootstrap. Stores a copy of the " { $link vocab-words } " of the host's syntax vocabulary; this allows the host's parsing words to be used during bootstrap source parsing, not the target's." } ;
 200
 201 HELP: with-file-vocabs
 202 { $values { "quot" quotation } }
 203 { $description "Calls the quotation in a scope with the initial the vocabulary search path for parsing a file. This consists of just the " { $snippet "syntax" } " vocabulary." } ;
 204
 205 HELP: parse-fresh
 206 { $values { "lines" "a sequence of strings" } { "quot" quotation } }
 207 { $description "Parses Factor source code in a sequence of lines. The initial vocabulary search path is used (see " { $link with-file-vocabs } ")." }
 208 { $errors "Throws a parse error if the input is malformed." } ;
 209
 210 HELP: filter-moved
 211 { $values { "assoc1" assoc } { "assoc2" assoc } { "seq" "an seqence of definitions" } }
 212 { $description "Removes all definitions from " { $snippet "assoc2" } " which are in " { $snippet "assoc1" } " or are are no longer present in the current " { $link file } "." } ;
 213
 214 HELP: forget-smudged
 215 { $description "Forgets removed definitions and prints a warning message if any of them are still referenced from other source files." } ;
 216
 217 HELP: finish-parsing
 218 { $values { "lines" "the lines of text just parsed" } { "quot" "the quotation just parsed" } }
 219 { $description "Records information to the current " { $link file } "." }
 220 { $notes "This is one of the factors of " { $link parse-stream } "." } ;
 221
 222 HELP: parse-stream
 223 { $values { "stream" "an input stream" } { "name" "a file name for error reporting and cross-referencing" } { "quot" quotation } }
 224 { $description "Parses Factor source code read from the stream. The initial vocabulary search path is used." }
 225 { $errors "Throws an I/O error if there was an error reading from the stream. Throws a parse error if the input is malformed." } ;
 226
 227 HELP: parse-file
 228 { $values { "file" "a pathname string" } { "quot" quotation } }
 229 { $description "Parses the Factor source code stored in a file. The initial vocabulary search path is used." }
 230 { $errors "Throws an I/O error if there was an error reading from the file. Throws a parse error if the input is malformed." } ;
 231
 232 HELP: run-file
 233 { $values { "file" "a pathname string" } }
 234 { $description "Parses the Factor source code stored in a file and runs it. The initial vocabulary search path is used." }
 235 { $errors "Throws an error if loading the file fails, there input is malformed, or if a runtime error occurs while calling the parsed quotation." }  ;
 236
 237 HELP: ?run-file
 238 { $values { "path" "a pathname string" } }
 239 { $description "If the file exists, runs it with " { $link run-file } ", otherwise does nothing." } ;
 240
 241 HELP: staging-violation
 242 { $values { "word" word } }
 243 { $description "Throws a " { $link staging-violation } " error." }
 244 { $error-description "Thrown by the parser if a parsing word is used in the same compilation unit as where it was defined; see " { $link "compilation-units" } "." }
 245 { $notes "One possible workaround is to use the " { $link POSTPONE: << } " word to execute code at parse time. However, executing words defined in the same source file at parse time is still prohibited." } ;
 246
 247 HELP: auto-use?
 248 { $var-description "If set to a true value, the behavior of the parser when encountering an unknown word name is changed. If only one loaded vocabulary has a word with this name, instead of throwing an error, the parser adds the vocabulary to the search path and prints a parse note. Off by default." }
 249 { $notes "This feature is intended to help during development. To generate a " { $link POSTPONE: USING: } " form automatically, enable " { $link auto-use? } ", load the source file, and copy and paste the " { $link POSTPONE: USING: } " form printed by the parser back into the file, then disable " { $link auto-use? } ". See " { $link "word-search-errors" } "." } ;