core/sequences/sequences.factor

   1 ! Copyright (C) 2005, 2011 Slava Pestov, Daniel Ehrenberg.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors kernel kernel.private slots.private math
   4 math.private math.order ;
   5 IN: sequences
   6
   7 MIXIN: sequence
   8
   9 GENERIC: length ( seq -- n ) flushable
  10 GENERIC: set-length ( n seq -- )
  11 GENERIC: nth ( n seq -- elt ) flushable
  12 GENERIC: set-nth ( elt n seq -- )
  13 GENERIC: new-sequence ( len seq -- newseq ) flushable
  14 GENERIC: new-resizable ( len seq -- newseq ) flushable
  15 GENERIC: like ( seq exemplar -- newseq ) flushable
  16 GENERIC: clone-like ( seq exemplar -- newseq ) flushable
  17
  18 : new-like ( len exemplar quot -- seq )
  19     over [ [ new-sequence ] dip call ] dip like ; inline
  20
  21 M: sequence like drop ; inline
  22
  23 GENERIC: lengthen ( n seq -- )
  24 GENERIC: shorten ( n seq -- )
  25
  26 M: sequence lengthen 2dup length > [ set-length ] [ 2drop ] if ; inline
  27
  28 M: sequence shorten 2dup length < [ set-length ] [ 2drop ] if ; inline
  29
  30 : empty? ( seq -- ? ) length 0 = ; inline
  31
  32 : if-empty ( ..a seq quot1: ( ..a -- ..b ) quot2: ( ..a seq -- ..b ) -- ..b )
  33     [ dup empty? ] [ [ drop ] prepose ] [ ] tri* if ; inline
  34
  35 : when-empty ( seq quot -- ) [ ] if-empty ; inline
  36
  37 : unless-empty ( seq quot -- ) [ ] swap if-empty ; inline
  38
  39 : delete-all ( seq -- ) 0 swap set-length ;
  40
  41 : first ( seq -- first ) 0 swap nth ; inline
  42 : second ( seq -- second ) 1 swap nth ; inline
  43 : third ( seq -- third ) 2 swap nth ; inline
  44 : fourth ( seq -- fourth ) 3 swap nth ; inline
  45
  46 : set-first ( first seq -- ) 0 swap set-nth ; inline
  47 : set-second ( second seq -- ) 1 swap set-nth ; inline
  48 : set-third ( third seq -- ) 2 swap set-nth ; inline
  49 : set-fourth  ( fourth seq -- ) 3 swap set-nth ; inline
  50
  51 : push ( elt seq -- ) [ length ] [ set-nth ] bi ;
  52
  53 : bounds-check? ( n seq -- ? )
  54     dupd length < [ 0 >= ] [ drop f ] if ; inline
  55
  56 ERROR: bounds-error index seq ;
  57
  58 : bounds-check ( n seq -- n seq )
  59     2dup bounds-check? [ bounds-error ] unless ; inline
  60
  61 MIXIN: immutable-sequence
  62
  63 ERROR: immutable seq ;
  64
  65 M: immutable-sequence set-nth immutable ;
  66
  67 INSTANCE: immutable-sequence sequence
  68
  69 <PRIVATE
  70
  71 : array-nth ( n array -- elt )
  72     swap 2 fixnum+fast slot ; inline
  73
  74 : set-array-nth ( elt n array -- )
  75     swap 2 fixnum+fast set-slot ; inline
  76
  77 : dispatch ( n array -- ) array-nth call ;
  78
  79 GENERIC: resize ( n seq -- newseq ) flushable
  80
  81 ! Unsafe sequence protocol for inner loops
  82 GENERIC: nth-unsafe ( n seq -- elt ) flushable
  83 GENERIC: set-nth-unsafe ( elt n seq -- )
  84
  85 M: sequence nth bounds-check nth-unsafe ; inline
  86 M: sequence set-nth bounds-check set-nth-unsafe ; inline
  87
  88 M: sequence nth-unsafe nth ; inline
  89 M: sequence set-nth-unsafe set-nth ; inline
  90
  91 : change-nth-unsafe ( i seq quot -- )
  92     [ [ nth-unsafe ] dip call ] 3keep drop set-nth-unsafe ; inline
  93
  94 PRIVATE>
  95
  96 ! The f object supports the sequence protocol trivially
  97 M: f length drop 0 ; inline
  98 M: f nth-unsafe nip ; inline
  99 M: f like drop [ f ] when-empty ; inline
 100
 101 INSTANCE: f immutable-sequence
 102
 103 ! Integer sequences
 104 TUPLE: iota { n integer read-only } ;
 105
 106 : iota ( n -- iota ) \ iota boa ; inline
 107
 108 M: iota length n>> ; inline
 109 M: iota nth-unsafe drop ; inline
 110
 111 INSTANCE: iota immutable-sequence
 112
 113 <PRIVATE
 114
 115 : first-unsafe ( seq -- first )
 116     0 swap nth-unsafe ; inline
 117
 118 : first2-unsafe ( seq -- first second )
 119     [ first-unsafe ] [ 1 swap nth-unsafe ] bi ; inline
 120
 121 : first3-unsafe ( seq -- first second third )
 122     [ first2-unsafe ] [ 2 swap nth-unsafe ] bi ; inline
 123
 124 : first4-unsafe ( seq -- first second third fourth )
 125     [ first3-unsafe ] [ 3 swap nth-unsafe ] bi ; inline
 126
 127 : exchange-unsafe ( m n seq -- )
 128     [ [ nth-unsafe ] curry bi@ ]
 129     [ [ set-nth-unsafe ] curry bi@ ] 3bi ; inline
 130
 131 : (head) ( seq n -- from to seq ) [ 0 ] 2dip swap ; inline
 132
 133 : (tail) ( seq n -- from to seq ) swap [ length ] keep ; inline
 134
 135 : from-end ( seq n -- seq n' ) [ dup length ] dip - ; inline
 136
 137 : (1sequence) ( obj seq -- seq )
 138     [ 0 swap set-nth-unsafe ] keep ; inline
 139
 140 : (2sequence) ( obj1 obj2 seq -- seq )
 141     [ 1 swap set-nth-unsafe ] keep
 142     (1sequence) ; inline
 143
 144 : (3sequence) ( obj1 obj2 obj3 seq -- seq )
 145     [ 2 swap set-nth-unsafe ] keep
 146     (2sequence) ; inline
 147
 148 : (4sequence) ( obj1 obj2 obj3 obj4 seq -- seq )
 149     [ 3 swap set-nth-unsafe ] keep
 150     (3sequence) ; inline
 151
 152 PRIVATE>
 153
 154 : 1sequence ( obj exemplar -- seq )
 155     1 swap [ (1sequence) ] new-like ; inline
 156
 157 : 2sequence ( obj1 obj2 exemplar -- seq )
 158     2 swap [ (2sequence) ] new-like ; inline
 159
 160 : 3sequence ( obj1 obj2 obj3 exemplar -- seq )
 161     3 swap [ (3sequence) ] new-like ; inline
 162
 163 : 4sequence ( obj1 obj2 obj3 obj4 exemplar -- seq )
 164     4 swap [ (4sequence) ] new-like ; inline
 165
 166 : first2 ( seq -- first second )
 167     1 swap bounds-check nip first2-unsafe ; inline
 168
 169 : first3 ( seq -- first second third )
 170     2 swap bounds-check nip first3-unsafe ; inline
 171
 172 : first4 ( seq -- first second third fourth )
 173     3 swap bounds-check nip first4-unsafe ; inline
 174
 175 : ?nth ( n seq -- elt/f )
 176     2dup bounds-check? [ nth-unsafe ] [ 2drop f ] if ; inline
 177
 178 : ?first ( seq -- elt/f ) 0 swap ?nth ; inline
 179 : ?second ( seq -- elt/f ) 1 swap ?nth ; inline
 180
 181 MIXIN: virtual-sequence
 182 GENERIC: virtual-exemplar ( seq -- seq' )
 183 GENERIC: virtual@ ( n seq -- n' seq' )
 184
 185 M: virtual-sequence nth virtual@ nth ; inline
 186 M: virtual-sequence set-nth virtual@ set-nth ; inline
 187 M: virtual-sequence nth-unsafe virtual@ nth-unsafe ; inline
 188 M: virtual-sequence set-nth-unsafe virtual@ set-nth-unsafe ; inline
 189 M: virtual-sequence like virtual-exemplar like ; inline
 190 M: virtual-sequence new-sequence virtual-exemplar new-sequence ; inline
 191
 192 INSTANCE: virtual-sequence sequence
 193
 194 ! A reversal of an underlying sequence.
 195 TUPLE: reversed { seq read-only } ;
 196
 197 C: <reversed> reversed
 198
 199 M: reversed virtual-exemplar seq>> ; inline
 200 M: reversed virtual@ seq>> [ length swap - 1 - ] keep ; inline
 201 M: reversed length seq>> length ; inline
 202
 203 INSTANCE: reversed virtual-sequence
 204
 205 ! A slice of another sequence.
 206 TUPLE: slice
 207 { from read-only }
 208 { to read-only }
 209 { seq read-only } ;
 210
 211 : collapse-slice ( m n slice -- m' n' seq )
 212     [ from>> ] [ seq>> ] bi [ [ + ] curry bi@ ] dip ; inline
 213
 214 TUPLE: slice-error from to seq reason ;
 215
 216 : slice-error ( from to seq ? string -- from to seq )
 217     [ \ slice-error boa throw ] curry when ; inline
 218
 219 : check-slice ( from to seq -- from to seq )
 220     3dup
 221     [ 2drop 0 < "start < 0" slice-error ]
 222     [ [ drop ] 2dip length > "end > sequence" slice-error ]
 223     [ drop > "start > end" slice-error ]
 224     3tri ; inline
 225
 226 : <slice> ( from to seq -- slice )
 227     check-slice
 228     dup slice? [ collapse-slice ] when
 229     slice boa ; inline
 230
 231 M: slice virtual-exemplar seq>> ; inline
 232
 233 M: slice virtual@ [ from>> + ] [ seq>> ] bi ; inline
 234
 235 M: slice length [ to>> ] [ from>> ] bi - ; inline
 236
 237 : short ( seq n -- seq n' ) over length min ; inline
 238
 239 : head-slice ( seq n -- slice ) (head) <slice> ; inline
 240
 241 : tail-slice ( seq n -- slice ) (tail) <slice> ; inline
 242
 243 : rest-slice ( seq -- slice ) 1 tail-slice ; inline
 244
 245 : head-slice* ( seq n -- slice ) from-end head-slice ; inline
 246
 247 : tail-slice* ( seq n -- slice ) from-end tail-slice ; inline
 248
 249 : but-last-slice ( seq -- slice ) 1 head-slice* ; inline
 250
 251 INSTANCE: slice virtual-sequence
 252
 253 ! One element repeated many times
 254 TUPLE: repetition { len read-only } { elt read-only } ;
 255
 256 C: <repetition> repetition
 257
 258 M: repetition length len>> ; inline
 259 M: repetition nth-unsafe nip elt>> ; inline
 260
 261 INSTANCE: repetition immutable-sequence
 262
 263 <PRIVATE
 264
 265 ERROR: integer-length-expected obj ;
 266
 267 : check-length ( n -- n )
 268     dup integer? [ integer-length-expected ] unless ; inline
 269
 270 TUPLE: copy-state
 271     { src-i read-only }
 272     { src read-only }
 273     { dst-i read-only }
 274     { dst read-only } ;
 275
 276 C: <copy> copy-state
 277
 278 : ((copy)) ( n copy -- )
 279     [ [ src-i>> + ] [ src>> ] bi nth-unsafe ]
 280     [ [ dst-i>> + ] [ dst>> ] bi set-nth-unsafe ] 2bi ; inline
 281
 282 : (copy) ( n copy -- dst )
 283     over 0 <= [ nip dst>> ] [ [ 1 - ] dip [ ((copy)) ] [ (copy) ] 2bi ] if ;
 284     inline recursive
 285
 286 : subseq>copy ( from to seq -- n copy )
 287     [ over - check-length swap ] dip
 288     3dup nip new-sequence 0 swap <copy> ; inline
 289
 290 : check-copy ( src n dst -- src n dst )
 291     3dup over 0 < [ bounds-error ] when
 292     [ swap length + ] dip lengthen ; inline
 293
 294 PRIVATE>
 295
 296 : subseq ( from to seq -- subseq )
 297     [ check-slice subseq>copy (copy) ] keep like ;
 298
 299 : head ( seq n -- headseq ) (head) subseq ;
 300
 301 : tail ( seq n -- tailseq ) (tail) subseq ;
 302
 303 : rest ( seq -- tailseq ) 1 tail ;
 304
 305 : head* ( seq n -- headseq ) from-end head ;
 306
 307 : tail* ( seq n -- tailseq ) from-end tail ;
 308
 309 : but-last ( seq -- headseq ) 1 head* ;
 310
 311 : copy ( src i dst -- )
 312     #! The check-length call forces partial dispatch
 313     [ [ length check-length 0 ] keep ] 2dip
 314     check-copy <copy> (copy) drop ; inline
 315
 316 M: sequence clone-like
 317     [ dup length ] dip new-sequence [ 0 swap copy ] keep ; inline
 318
 319 M: immutable-sequence clone-like like ; inline
 320
 321 : push-all ( src dest -- ) [ length ] [ copy ] bi ;
 322
 323 <PRIVATE
 324
 325 : (append) ( seq1 seq2 accum -- accum )
 326     [ [ over length ] dip copy ]
 327     [ 0 swap copy ]
 328     [ ] tri ; inline
 329
 330 PRIVATE>
 331
 332 : append-as ( seq1 seq2 exemplar -- newseq )
 333     [ over length over length + ] dip
 334     [ (append) ] new-like ; inline
 335
 336 : 3append-as ( seq1 seq2 seq3 exemplar -- newseq )
 337     [ 3dup [ length ] tri@ + + ] dip [
 338         [ [ 2over [ length ] bi@ + ] dip copy ]
 339         [ (append) ] bi
 340     ] new-like ; inline
 341
 342 : append ( seq1 seq2 -- newseq ) over append-as ;
 343
 344 : prepend ( seq1 seq2 -- newseq ) swap append ; inline
 345
 346 : 3append ( seq1 seq2 seq3 -- newseq ) pick 3append-as ;
 347
 348 : surround ( seq1 seq2 seq3 -- newseq ) swapd 3append ; inline
 349
 350 : glue ( seq1 seq2 seq3 -- newseq ) swap 3append ; inline
 351
 352 : change-nth ( ..a i seq quot: ( ..a elt -- ..b newelt ) -- ..b )
 353     [ [ nth ] dip call ] 3keep drop set-nth ; inline
 354
 355 : min-length ( seq1 seq2 -- n ) [ length ] bi@ min ; inline
 356
 357 : max-length ( seq1 seq2 -- n ) [ length ] bi@ max ; inline
 358
 359 <PRIVATE
 360
 361 : ((each)) ( seq -- n quot )
 362     [ length ] keep [ nth-unsafe ] curry ; inline
 363
 364 : (each) ( seq quot -- n quot' )
 365     [ ((each)) ] dip compose ; inline
 366
 367 : (each-index) ( seq quot -- n quot' )
 368     [ ((each)) [ keep ] curry ] dip compose ; inline
 369
 370 : (collect) ( quot into -- quot' )
 371     [ [ keep ] dip set-nth-unsafe ] 2curry ; inline
 372
 373 : collect ( n quot into -- )
 374     (collect) each-integer ; inline
 375
 376 : map-into ( seq quot into -- )
 377     [ (each) ] dip collect ; inline
 378
 379 : 2nth-unsafe ( n seq1 seq2 -- elt1 elt2 )
 380     [ nth-unsafe ] bi-curry@ bi ; inline
 381
 382 : (2each) ( seq1 seq2 quot -- n quot' )
 383     [
 384         [ min-length ] 2keep
 385         [ 2nth-unsafe ] 2curry
 386     ] dip compose ; inline
 387
 388 : 3nth-unsafe ( n seq1 seq2 seq3 -- elt1 elt2 elt3 )
 389     [ nth-unsafe ] tri-curry@ tri ; inline
 390
 391 : (3each) ( seq1 seq2 seq3 quot -- n quot' )
 392     [
 393         [ [ length ] tri@ min min ]
 394         [ [ 3nth-unsafe ] 3curry ] 3bi
 395     ] dip compose ; inline
 396
 397 : finish-find ( i seq -- i elt )
 398     over [ dupd nth-unsafe ] [ drop f ] if ; inline
 399
 400 : (find) ( seq quot quot' -- i elt )
 401     pick [ [ (each) ] dip call ] dip finish-find ; inline
 402
 403 : (find-from) ( n seq quot quot' -- i elt )
 404     [ 2dup bounds-check? ] 2dip
 405     [ (find) ] 2curry
 406     [ 2drop f f ]
 407     if ; inline
 408
 409 : (find-index) ( seq quot quot' -- i elt )
 410     pick [ [ (each-index) ] dip call ] dip finish-find ; inline
 411
 412 : (accumulate) ( seq identity quot -- identity seq quot )
 413     [ swap ] dip [ curry keep ] curry ; inline
 414
 415 PRIVATE>
 416
 417 : each ( ... seq quot: ( ... x -- ... ) -- ... )
 418     (each) each-integer ; inline
 419
 420 : reduce ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... result )
 421     swapd each ; inline
 422
 423 : map-integers ( ... len quot: ( ... i -- ... elt ) exemplar -- ... newseq )
 424     [ over ] dip [ [ collect ] keep ] new-like ; inline
 425
 426 : map-as ( ... seq quot: ( ... elt -- ... newelt ) exemplar -- ... newseq )
 427     [ (each) ] dip map-integers ; inline
 428
 429 : map ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 430     over map-as ; inline
 431
 432 : replicate-as ( ... len quot: ( ... -- ... newelt ) exemplar -- ... newseq )
 433     [ [ drop ] prepose ] dip map-integers ; inline
 434
 435 : replicate ( ... len quot: ( ... -- ... newelt ) -- ... newseq )
 436     { } replicate-as ; inline
 437
 438 : map! ( ... seq quot: ( ... elt -- ... newelt ) -- ... seq )
 439     over [ map-into ] keep ; inline
 440
 441 : accumulate-as ( ... seq identity quot: ( ... prev elt -- ... next ) exemplar -- ... final newseq )
 442     [ (accumulate) ] dip map-as ; inline
 443
 444 : accumulate ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... final newseq )
 445     pick accumulate-as ; inline
 446
 447 : accumulate! ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... final seq )
 448     (accumulate) map! ; inline
 449
 450 : 2each ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ) -- ... )
 451     (2each) each-integer ; inline
 452
 453 : 2reduce ( ... seq1 seq2 identity quot: ( ... prev elt1 elt2 -- ... next ) -- ... result )
 454     [ -rot ] dip 2each ; inline
 455
 456 : 2map-as ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) exemplar -- ... newseq )
 457     [ (2each) ] dip map-integers ; inline
 458
 459 : 2map ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... newseq )
 460     pick 2map-as ; inline
 461
 462 : 2all? ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... ? )
 463     (2each) all-integers? ; inline
 464
 465 : 3each ( ... seq1 seq2 seq3 quot: ( ... elt1 elt2 elt3 -- ... ) -- ... )
 466     (3each) each-integer ; inline
 467
 468 : 3map-as ( ... seq1 seq2 seq3 quot: ( ... elt1 elt2 elt3 -- ... newelt ) exemplar -- ... newseq )
 469     [ (3each) ] dip map-integers ; inline
 470
 471 : 3map ( ... seq1 seq2 seq3 quot: ( ... elt1 elt2 elt3 -- ... newelt ) -- ... newseq )
 472     [ pick ] dip swap 3map-as ; inline
 473
 474 : find-from ( ... n seq quot: ( ... elt -- ... ? ) -- ... i elt )
 475     [ (find-integer) ] (find-from) ; inline
 476
 477 : find ( ... seq quot: ( ... elt -- ... ? ) -- ... i elt )
 478     [ find-integer ] (find) ; inline
 479
 480 : find-last-from ( ... n seq quot: ( ... elt -- ... ? ) -- ... i elt )
 481     [ nip find-last-integer ] (find-from) ; inline
 482
 483 : find-last ( ... seq quot: ( ... elt -- ... ? ) -- ... i elt )
 484     [ [ 1 - ] dip find-last-integer ] (find) ; inline
 485
 486 : find-index ( ... seq quot: ( ... elt i -- ... ? ) -- ... i elt )
 487     [ find-integer ] (find-index) ; inline
 488
 489 : all? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 490     (each) all-integers? ; inline
 491
 492 : push-if ( ..a elt quot: ( ..a elt -- ..b ? ) accum -- ..b )
 493     [ keep ] dip rot [ push ] [ 2drop ] if ; inline
 494
 495 : selector-for ( quot exemplar -- selector accum )
 496     [ length ] keep new-resizable [ [ push-if ] 2curry ] keep ; inline
 497
 498 : selector ( quot -- selector accum )
 499     V{ } selector-for ; inline
 500
 501 : filter-as ( ... seq quot: ( ... elt -- ... ? ) exemplar -- ... subseq )
 502     dup [ selector-for [ each ] dip ] curry dip like ; inline
 503
 504 : filter ( ... seq quot: ( ... elt -- ... ? ) -- ... subseq )
 505     over filter-as ; inline
 506
 507 : push-either ( ..a elt quot: ( ..a elt -- ..b ? ) accum1 accum2 -- ..b )
 508     [ keep swap ] 2dip ? push ; inline
 509
 510 : 2selector ( quot -- selector accum1 accum2 )
 511     V{ } clone V{ } clone [ [ push-either ] 3curry ] 2keep ; inline
 512
 513 : partition ( ... seq quot: ( ... elt -- ... ? ) -- ... trueseq falseseq )
 514     over [ 2selector [ each ] 2dip ] dip [ like ] curry bi@ ; inline
 515
 516 : collector-for ( quot exemplar -- quot' vec )
 517     [ length ] keep new-resizable [ [ push ] curry compose ] keep ; inline
 518
 519 : collector ( quot -- quot' vec )
 520     V{ } collector-for ; inline
 521
 522 : produce-as ( ..a pred: ( ..a -- ..b ? ) quot: ( ..b -- ..a obj ) exemplar -- ..b seq )
 523     dup [ collector-for [ while ] dip ] curry dip like ; inline
 524
 525 : produce ( ..a pred: ( ..a -- ..b ? ) quot: ( ..b -- ..a obj ) -- ..b seq )
 526     { } produce-as ; inline
 527
 528 : follow ( ... obj quot: ( ... prev -- ... result/f ) -- ... seq )
 529     [ dup ] swap [ keep ] curry produce nip ; inline
 530
 531 : each-index ( ... seq quot: ( ... elt index -- ... ) -- ... )
 532     (each-index) each-integer ; inline
 533
 534 : interleave ( ... seq between quot: ( ... elt -- ... ) -- ... )
 535     pick empty? [ 3drop ] [
 536         [ [ drop first-unsafe ] dip call ]
 537         [ [ rest-slice ] 2dip [ bi* ] 2curry each ]
 538         3bi
 539     ] if ; inline
 540
 541 : map-index ( ... seq quot: ( ... elt index -- ... newelt ) -- ... newseq )
 542     [ dup length iota ] dip 2map ; inline
 543
 544 : reduce-index ( ... seq identity quot: ( ... prev elt index -- ... next ) -- ... result )
 545     swapd each-index ; inline
 546
 547 : index ( obj seq -- n )
 548     [ = ] with find drop ;
 549
 550 : index-from ( obj i seq -- n )
 551     rot [ = ] curry find-from drop ;
 552
 553 : last-index ( obj seq -- n )
 554     [ = ] with find-last drop ;
 555
 556 : last-index-from ( obj i seq -- n )
 557     rot [ = ] curry find-last-from drop ;
 558
 559 <PRIVATE
 560
 561 : (indices) ( elt i obj accum -- )
 562     [ swap [ = ] dip ] dip [ push ] 2curry when ; inline
 563
 564 PRIVATE>
 565
 566 : indices ( obj seq -- indices )
 567     swap V{ } clone
 568     [ [ (indices) ] 2curry each-index ] keep ;
 569
 570 : nths ( indices seq -- seq' )
 571     [ [ nth ] curry ] keep map-as ;
 572
 573 : any? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 574     find drop >boolean ; inline
 575
 576 : member? ( elt seq -- ? )
 577     [ = ] with any? ;
 578
 579 : member-eq? ( elt seq -- ? )
 580     [ eq? ] with any? ;
 581
 582 : remove ( elt seq -- newseq )
 583     [ = not ] with filter ;
 584
 585 : remove-eq ( elt seq -- newseq )
 586     [ eq? not ] with filter ;
 587
 588 : sift ( seq -- newseq )
 589     [ ] filter ;
 590
 591 : harvest ( seq -- newseq )
 592     [ empty? not ] filter ;
 593
 594 : mismatch ( seq1 seq2 -- i )
 595     [ min-length ] 2keep
 596     [ 2nth-unsafe = not ] 2curry
 597     find-integer ; inline
 598
 599 M: sequence <=>
 600     [ mismatch ] 2keep pick
 601     [ 2nth-unsafe <=> ] [ [ length ] compare nip ] if ;
 602
 603 : sequence= ( seq1 seq2 -- ? )
 604     2dup [ length ] bi@ =
 605     [ mismatch not ] [ 2drop f ] if ; inline
 606
 607 ERROR: assert-sequence got expected ;
 608
 609 : assert-sequence= ( a b -- )
 610     2dup sequence= [ 2drop ] [ assert-sequence ] if ;
 611
 612 <PRIVATE
 613
 614 : sequence-hashcode-step ( oldhash newpart -- newhash )
 615     >fixnum swap [
 616         [ -2 fixnum-shift-fast ] [ 5 fixnum-shift-fast ] bi
 617         fixnum+fast fixnum+fast
 618     ] keep fixnum-bitxor ; inline
 619
 620 PRIVATE>
 621
 622 : sequence-hashcode ( n seq -- x )
 623     [ 0 ] 2dip [ hashcode* sequence-hashcode-step ] with each ; inline
 624
 625 M: reversed equal? over reversed? [ sequence= ] [ 2drop f ] if ;
 626
 627 M: slice equal? over slice? [ sequence= ] [ 2drop f ] if ;
 628
 629 : move ( to from seq -- )
 630     2over =
 631     [ 3drop ] [ [ nth swap ] [ set-nth ] bi ] if ; inline
 632
 633 <PRIVATE
 634
 635 : (filter!) ( ... quot: ( ... elt -- ... ? ) store scan seq -- ... )
 636     2dup length < [
 637         [ move ] 3keep
 638         [ nth-unsafe pick call [ 1 + ] when ] 2keep
 639         [ 1 + ] dip
 640         (filter!)
 641     ] [ nip set-length drop ] if ; inline recursive
 642
 643 PRIVATE>
 644
 645 : filter! ( ... seq quot: ( ... elt -- ... ? ) -- ... seq )
 646     swap [ [ 0 0 ] dip (filter!) ] keep ; inline
 647
 648 : remove! ( elt seq -- seq )
 649     [ = not ] with filter! ;
 650
 651 : remove-eq! ( elt seq -- seq )
 652     [ eq? not ] with filter! ;
 653
 654 : prefix ( seq elt -- newseq )
 655     over [ over length 1 + ] dip [
 656         [ 0 swap set-nth-unsafe ] keep
 657         [ 1 swap copy ] keep
 658     ] new-like ;
 659
 660 : suffix ( seq elt -- newseq )
 661     over [ over length 1 + ] dip [
 662         [ [ over length ] dip set-nth-unsafe ] keep
 663         [ 0 swap copy ] keep
 664     ] new-like ;
 665
 666 : suffix! ( seq elt -- seq ) over push ; inline
 667
 668 : append! ( seq1 seq2 -- seq1 ) over push-all ; inline
 669
 670 : last ( seq -- elt ) [ length 1 - ] [ nth ] bi ;
 671
 672 : set-last ( elt seq -- ) [ length 1 - ] keep set-nth ;
 673
 674 : pop* ( seq -- ) [ length 1 - ] [ shorten ] bi ;
 675
 676 <PRIVATE
 677
 678 : move-backward ( shift from to seq -- )
 679     2over = [
 680         2drop 2drop
 681     ] [
 682         [ [ 2over + pick ] dip move [ 1 + ] dip ] keep
 683         move-backward
 684     ] if ;
 685
 686 : move-forward ( shift from to seq -- )
 687     2over = [
 688         2drop 2drop
 689     ] [
 690         [ [ pick [ dup dup ] dip + swap ] dip move 1 - ] keep
 691         move-forward
 692     ] if ;
 693
 694 : (open-slice) ( shift from to seq ? -- )
 695     [
 696         [ [ 1 - ] bi@ ] dip move-forward
 697     ] [
 698         [ over - ] 2dip move-backward
 699     ] if ;
 700
 701 : open-slice ( shift from seq -- )
 702     pick 0 = [
 703         3drop
 704     ] [
 705         pick over length + over
 706         [ pick 0 > [ [ length ] keep ] dip (open-slice) ] 2dip
 707         set-length
 708     ] if ;
 709
 710 PRIVATE>
 711
 712 : delete-slice ( from to seq -- )
 713     check-slice [ over [ - ] dip ] dip open-slice ;
 714
 715 : remove-nth! ( n seq -- seq )
 716     [ [ dup 1 + ] dip delete-slice ] keep ;
 717
 718 : snip ( from to seq -- head tail )
 719     [ swap head ] [ swap tail ] bi-curry bi* ; inline
 720
 721 : snip-slice ( from to seq -- head tail )
 722     [ swap head-slice ] [ swap tail-slice ] bi-curry bi* ; inline
 723
 724 : replace-slice ( new from to seq -- seq' )
 725     snip-slice surround ;
 726
 727 : remove-nth ( n seq -- seq' )
 728     [ [ { } ] dip dup 1 + ] dip replace-slice ;
 729
 730 : pop ( seq -- elt )
 731     [ length 1 - ] [ [ nth ] [ shorten ] 2bi ] bi ;
 732
 733 : exchange ( m n seq -- )
 734     [ nip bounds-check 2drop ]
 735     [ bounds-check 3drop ]
 736     [ exchange-unsafe ]
 737     3tri ;
 738
 739 : reverse! ( seq -- seq )
 740     [
 741         [ length 2/ iota ] [ length ] [ ] tri
 742         [ [ over - 1 - ] dip exchange-unsafe ] 2curry each
 743     ] keep ;
 744
 745 : reverse ( seq -- newseq )
 746     [
 747         dup [ length ] keep new-sequence
 748         [ 0 swap copy ] keep reverse!
 749     ] keep like ;
 750
 751 : sum-lengths ( seq -- n )
 752     0 [ length + ] reduce ;
 753
 754 : concat-as ( seq exemplar -- newseq )
 755     swap [ { } ] [
 756         [ sum-lengths over new-resizable ] keep
 757         [ append! ] each
 758     ] if-empty swap like ;
 759
 760 : concat ( seq -- newseq )
 761     [ { } ] [ dup first concat-as ] if-empty ;
 762
 763 <PRIVATE
 764
 765 : joined-length ( seq glue -- n )
 766     [ [ sum-lengths ] [ length 1 [-] ] bi ] dip length * + ;
 767
 768 PRIVATE>
 769
 770 : join ( seq glue -- newseq )
 771     dup empty? [ concat-as ] [
 772         [
 773             2dup joined-length over new-resizable [
 774                 [ [ push-all ] 2curry ] [ [ nip push-all ] 2curry ] 2bi
 775                 interleave
 776             ] keep
 777         ] keep like
 778     ] if ;
 779
 780 : padding ( ... seq n elt quot: ( ... seq1 seq2 -- ... newseq ) -- ... newseq )
 781     [
 782         [ over length [-] dup 0 = [ drop ] ] dip
 783         [ <repetition> ] curry
 784     ] dip compose if ; inline
 785
 786 : pad-head ( seq n elt -- padded )
 787     [ swap dup append-as ] padding ;
 788
 789 : pad-tail ( seq n elt -- padded )
 790     [ append ] padding ;
 791
 792 : shorter? ( seq1 seq2 -- ? ) [ length ] bi@ < ;
 793
 794 : head? ( seq begin -- ? )
 795     2dup shorter? [
 796         2drop f
 797     ] [
 798         [ nip ] [ length head-slice ] 2bi sequence=
 799     ] if ;
 800
 801 : tail? ( seq end -- ? )
 802     2dup shorter? [
 803         2drop f
 804     ] [
 805         [ nip ] [ length tail-slice* ] 2bi sequence=
 806     ] if ;
 807
 808 : cut-slice ( seq n -- before-slice after-slice )
 809     [ head-slice ] [ tail-slice ] 2bi ;
 810
 811 : insert-nth ( elt n seq -- seq' )
 812     swap cut-slice [ swap suffix ] dip append ;
 813
 814 : midpoint@ ( seq -- n ) length 2/ ; inline
 815
 816 : halves ( seq -- first-slice second-slice )
 817     dup midpoint@ cut-slice ;
 818
 819 : binary-reduce ( ... seq start quot: ( ... elt1 elt2 -- ... newelt ) -- ... value )
 820     #! We can't use case here since combinators depends on
 821     #! sequences
 822     pick length dup 0 3 between? [
 823         >fixnum {
 824             [ drop nip ]
 825             [ 2drop first ]
 826             [ [ drop first2 ] dip call ]
 827             [ [ drop first3 ] dip bi@ ]
 828         } dispatch
 829     ] [
 830         drop
 831         [ halves ] 2dip
 832         [ [ binary-reduce ] 2curry bi@ ] keep
 833         call
 834     ] if ; inline recursive
 835
 836 : cut ( seq n -- before after )
 837     [ head ] [ tail ] 2bi ;
 838
 839 : cut* ( seq n -- before after )
 840     [ head* ] [ tail* ] 2bi ;
 841
 842 <PRIVATE
 843
 844 : (start) ( subseq seq n -- subseq seq ? )
 845     pick length iota [
 846         [ 3dup ] dip [ + swap nth-unsafe ] keep rot nth-unsafe =
 847     ] all? nip ; inline
 848
 849 : prepare-2map-reduce ( seq1 seq2 map-quot -- initial length seq1 seq2 )
 850     [ drop min-length dup 1 < [ "Empty sequence" throw ] when 1 - ]
 851     [ drop [ [ 1 + ] 2dip 2nth-unsafe ] 2curry ]
 852     [ [ [ first-unsafe ] bi@ ] dip call ]
 853     3tri -rot ; inline
 854
 855 PRIVATE>
 856
 857 : start* ( subseq seq n -- i )
 858     pick length pick length swap - 1 + iota
 859     [ (start) ] find-from
 860     swap [ 3drop ] dip ;
 861
 862 : start ( subseq seq -- i ) 0 start* ; inline
 863
 864 : subseq? ( subseq seq -- ? ) start >boolean ;
 865
 866 : drop-prefix ( seq1 seq2 -- slice1 slice2 )
 867     2dup mismatch [ 2dup min-length ] unless*
 868     [ tail-slice ] curry bi@ ;
 869
 870 : unclip ( seq -- rest first )
 871     [ rest ] [ first-unsafe ] bi ;
 872
 873 : unclip-last ( seq -- butlast last )
 874     [ but-last ] [ last ] bi ;
 875
 876 : unclip-slice ( seq -- rest-slice first )
 877     [ rest-slice ] [ first-unsafe ] bi ; inline
 878
 879 : map-reduce ( ..a seq map-quot: ( ..a x -- ..b elt ) reduce-quot: ( ..b prev elt -- ..a next ) -- ..a result )
 880     [ [ unclip-slice ] dip [ call ] keep ] dip
 881     compose reduce ; inline
 882
 883 : 2map-reduce ( ..a seq1 seq2 map-quot: ( ..a elt1 elt2 -- ..b intermediate ) reduce-quot: ( ..b prev intermediate -- ..a next ) -- ..a result )
 884     [ [ prepare-2map-reduce ] keep ] dip
 885     compose compose each-integer ; inline
 886
 887 <PRIVATE
 888
 889 : (map-find) ( seq quot find-quot -- result elt )
 890     [ [ f ] 2dip [ [ nip ] dip call dup ] curry ] dip call
 891     [ [ drop f ] unless ] dip ; inline
 892
 893 PRIVATE>
 894
 895 : map-find ( ... seq quot: ( ... elt -- ... result/f ) -- ... result elt )
 896     [ find ] (map-find) ; inline
 897
 898 : map-find-last ( ... seq quot: ( ... elt -- ... result/f ) -- ... result elt )
 899     [ find-last ] (map-find) ; inline
 900
 901 : unclip-last-slice ( seq -- butlast-slice last )
 902     [ but-last-slice ] [ last ] bi ; inline
 903
 904 <PRIVATE
 905
 906 : (trim-head) ( seq quot -- seq n )
 907     over [ [ not ] compose find drop ] dip
 908     [ length or ] keep swap ; inline
 909
 910 : (trim-tail) ( seq quot -- seq n )
 911     over [ [ not ] compose find-last drop ?1+ ] dip
 912     swap ; inline
 913
 914 PRIVATE>
 915
 916 : trim-head-slice ( ... seq quot: ( ... elt -- ... ? ) -- ... slice )
 917     (trim-head) tail-slice ; inline
 918
 919 : trim-head ( ... seq quot: ( ... elt -- ... ? ) -- ... newseq )
 920     (trim-head) tail ; inline
 921
 922 : trim-tail-slice ( ... seq quot: ( ... elt -- ... ? ) -- ... slice )
 923     (trim-tail) head-slice ; inline
 924
 925 : trim-tail ( ... seq quot: ( ... elt -- ... ? ) -- ... newseq )
 926     (trim-tail) head ; inline
 927
 928 : trim-slice ( ... seq quot: ( ... elt -- ... ? ) -- ... slice )
 929     [ trim-head-slice ] [ trim-tail-slice ] bi ; inline
 930
 931 : trim ( ... seq quot: ( ... elt -- ... ? ) -- ... newseq )
 932     [ trim-slice ] [ drop ] 2bi like ; inline
 933
 934 GENERIC: sum ( seq -- n )
 935 M: object sum 0 [ + ] binary-reduce ; inline
 936
 937 : product ( seq -- n ) 1 [ * ] binary-reduce ;
 938
 939 : infimum ( seq -- n ) [ ] [ min ] map-reduce ;
 940
 941 : supremum ( seq -- n ) [ ] [ max ] map-reduce ;
 942
 943 : map-sum ( ... seq quot: ( ... elt -- ... n ) -- ... n )
 944     [ 0 ] 2dip [ dip + ] curry [ swap ] prepose each ; inline
 945
 946 : count ( ... seq quot: ( ... elt -- ... ? ) -- ... n ) [ 1 0 ? ] compose map-sum ; inline
 947
 948 : cartesian-each ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ) -- ... )
 949     [ with each ] 2curry each ; inline
 950
 951 : cartesian-map ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... newseq )
 952     [ with map ] 2curry map ; inline
 953
 954 : cartesian-product ( seq1 seq2 -- newseq )
 955     [ { } 2sequence ] cartesian-map ;
 956
 957 ! We hand-optimize flip to such a degree because type hints
 958 ! cannot express that an array is an array of arrays yet, and
 959 ! this word happens to be performance-critical since the compiler
 960 ! itself uses it. Optimizing it like this reduced compile time.
 961 <PRIVATE
 962
 963 : generic-flip ( matrix -- newmatrix )
 964     [ dup first length [ length min ] reduce iota ] keep
 965     [ [ nth-unsafe ] with { } map-as ] curry { } map-as ; inline
 966
 967 USE: arrays
 968
 969 : array-length ( array -- len )
 970     { array } declare length>> ; inline
 971
 972 : array-flip ( matrix -- newmatrix )
 973     { array } declare
 974     [ dup first array-length [ array-length min ] reduce iota ] keep
 975     [ [ { array } declare array-nth ] with { } map-as ] curry { } map-as ;
 976
 977 PRIVATE>
 978
 979 : flip ( matrix -- newmatrix )
 980     dup empty? [
 981         dup array? [
 982             dup [ array? ] all?
 983             [ array-flip ] [ generic-flip ] if
 984         ] [ generic-flip ] if
 985     ] unless ;