core/sequences/sequences.factor

   1 ! Copyright (C) 2005, 2011 Slava Pestov, Daniel Ehrenberg.
   2 ! See https://factorcode.org/license.txt for BSD license.
   3 USING: accessors kernel kernel.private math math.order
   4 math.private slots.private ;
   5 IN: sequences
   6
   7 MIXIN: sequence
   8
   9 GENERIC: length ( seq -- n ) flushable
  10 GENERIC: set-length ( n seq -- )
  11 GENERIC: nth ( n seq -- elt ) flushable
  12 GENERIC: set-nth ( elt n seq -- )
  13 GENERIC: new-sequence ( len seq -- newseq ) flushable
  14 GENERIC: new-resizable ( len seq -- newseq ) flushable
  15 GENERIC: like ( seq exemplar -- newseq ) flushable
  16 GENERIC: clone-like ( seq exemplar -- newseq ) flushable
  17
  18 : lengthd ( seq obj -- n obj ) [ length ] dip ; inline
  19
  20 : new-sequence-like ( len-exemplar type-exemplar -- newseq )
  21     lengthd new-sequence ; inline
  22
  23 : new-resizable-like ( len-exemplar type-exemplar -- newseq )
  24     lengthd new-resizable ; inline
  25
  26 : new-like ( len exemplar quot -- seq )
  27     over [ [ new-sequence ] dip call ] dip like ; inline
  28
  29 M: sequence like drop ; inline
  30
  31 GENERIC: lengthen ( n seq -- )
  32 GENERIC: shorten ( n seq -- )
  33
  34 M: sequence lengthen 2dup length > [ set-length ] [ 2drop ] if ; inline
  35 M: sequence shorten 2dup length < [ set-length ] [ 2drop ] if ; inline
  36
  37 : 2length ( seq1 seq2 -- n1 n2 ) [ length ] bi@ ; inline
  38 : 3length ( seq1 seq2 seq3 -- n1 n2 n3 ) [ length ] tri@ ; inline
  39
  40 : empty? ( seq -- ? ) length 0 = ; inline
  41
  42 : if-empty ( ..a seq quot1: ( ..a -- ..b ) quot2: ( ..a seq -- ..b ) -- ..b )
  43     [ dup empty? ] [ [ drop ] prepose ] [ ] tri* if ; inline
  44
  45 : when-empty ( ... seq quot: ( ... -- ... obj ) -- ... seq/obj ) [ ] if-empty ; inline
  46 : unless-empty ( ... seq quot: ( ... seq -- ... ) -- ... ) [ ] swap if-empty ; inline
  47
  48 : delete-all ( seq -- ) 0 swap set-length ;
  49
  50 : first ( seq -- first ) 0 swap nth ; inline
  51 : second ( seq -- second ) 1 swap nth ; inline
  52 : third ( seq -- third ) 2 swap nth ; inline
  53 : fourth ( seq -- fourth ) 3 swap nth ; inline
  54
  55 : set-first ( first seq -- ) 0 swap set-nth ; inline
  56 : set-second ( second seq -- ) 1 swap set-nth ; inline
  57 : set-third ( third seq -- ) 2 swap set-nth ; inline
  58 : set-fourth  ( fourth seq -- ) 3 swap set-nth ; inline
  59
  60 : push ( elt seq -- ) [ length ] [ set-nth ] bi ;
  61
  62 ERROR: bounds-error index seq ;
  63
  64 GENERIC#: bounds-check? 1 ( n seq -- ? )
  65
  66 M: integer bounds-check?
  67     dupd length < [ 0 >= ] [ drop f ] if ; inline
  68
  69 : bounds-check ( n seq -- n seq )
  70     2dup bounds-check? [ bounds-error ] unless ; inline
  71
  72 MIXIN: immutable-sequence
  73
  74 ERROR: immutable element index sequence ;
  75
  76 M: immutable-sequence set-nth immutable ;
  77
  78 INSTANCE: immutable-sequence sequence
  79
  80 <PRIVATE
  81
  82 : array-nth ( n array -- elt )
  83     swap 2 fixnum+fast slot ; inline
  84
  85 : set-array-nth ( elt n array -- )
  86     swap 2 fixnum+fast set-slot ; inline
  87
  88 : dispatch ( n array -- ) array-nth call ;
  89
  90 GENERIC: resize ( n seq -- newseq ) flushable
  91
  92 ! Unsafe sequence protocol for inner loops
  93 GENERIC: nth-unsafe ( n seq -- elt ) flushable
  94 GENERIC: set-nth-unsafe ( elt n seq -- )
  95
  96 M: sequence nth bounds-check nth-unsafe ; inline
  97 M: sequence set-nth bounds-check set-nth-unsafe ; inline
  98
  99 M: sequence nth-unsafe nth ; inline
 100 M: sequence set-nth-unsafe set-nth ; inline
 101
 102 PRIVATE>
 103
 104 ! The f object supports the sequence protocol trivially
 105 M: f length drop 0 ; inline
 106 M: f nth-unsafe nip ; inline
 107 M: f like drop [ f ] when-empty ; inline
 108
 109 INSTANCE: f immutable-sequence
 110
 111 ! Integer sequences
 112 TUPLE: iota { n integer read-only } ;
 113
 114 : <iota> ( n -- iota )
 115     assert-non-negative iota boa ; inline
 116
 117 M: iota length n>> ; inline
 118 M: iota nth-unsafe drop ; inline
 119
 120 INSTANCE: iota immutable-sequence
 121
 122 <PRIVATE
 123
 124 : first-unsafe ( seq -- first ) 0 swap nth-unsafe ; inline
 125 : second-unsafe ( seq -- second ) 1 swap nth-unsafe ; inline
 126 : third-unsafe ( seq -- third ) 2 swap nth-unsafe ; inline
 127 : fourth-unsafe ( seq -- fourth ) 3 swap nth-unsafe ; inline
 128
 129 : first2-unsafe ( seq -- first second )
 130     [ first-unsafe ] [ second-unsafe ] bi ; inline
 131
 132 : first3-unsafe ( seq -- first second third )
 133     [ first2-unsafe ] [ third-unsafe ] bi ; inline
 134
 135 : first4-unsafe ( seq -- first second third fourth )
 136     [ first3-unsafe ] [ fourth-unsafe ] bi ; inline
 137
 138 : exchange-unsafe ( m n seq -- )
 139     [ [ nth-unsafe ] curry bi@ ]
 140     [ [ set-nth-unsafe ] curry bi@ ] 3bi ; inline
 141
 142 : (1sequence) ( obj seq -- seq )
 143     [ 0 swap set-nth-unsafe ] keep ; inline
 144
 145 : (2sequence) ( obj1 obj2 seq -- seq )
 146     [ 1 swap set-nth-unsafe ] keep (1sequence) ; inline
 147
 148 : (3sequence) ( obj1 obj2 obj3 seq -- seq )
 149     [ 2 swap set-nth-unsafe ] keep (2sequence) ; inline
 150
 151 : (4sequence) ( obj1 obj2 obj3 obj4 seq -- seq )
 152     [ 3 swap set-nth-unsafe ] keep (3sequence) ; inline
 153
 154 PRIVATE>
 155
 156 : head-to-index ( seq to -- zero to seq ) [ 0 ] 2dip swap ; inline
 157
 158 : index-to-tail ( seq from -- from length seq ) swap [ length ] keep ; inline
 159
 160 : from-tail ( seq n -- seq n' ) [ dup length ] dip - ; inline
 161
 162 : 1sequence ( obj exemplar -- seq )
 163     1 swap [ (1sequence) ] new-like ; inline
 164
 165 : 2sequence ( obj1 obj2 exemplar -- seq )
 166     2 swap [ (2sequence) ] new-like ; inline
 167
 168 : 3sequence ( obj1 obj2 obj3 exemplar -- seq )
 169     3 swap [ (3sequence) ] new-like ; inline
 170
 171 : 4sequence ( obj1 obj2 obj3 obj4 exemplar -- seq )
 172     4 swap [ (4sequence) ] new-like ; inline
 173
 174 : first2 ( seq -- first second )
 175     1 swap bounds-check nip first2-unsafe ; inline
 176
 177 : first3 ( seq -- first second third )
 178     2 swap bounds-check nip first3-unsafe ; inline
 179
 180 : first4 ( seq -- first second third fourth )
 181     3 swap bounds-check nip first4-unsafe ; inline
 182
 183 : ??nth ( n seq -- elt/f ? )
 184     2dup bounds-check? [ nth-unsafe t ] [ 2drop f f ] if ; inline
 185
 186 : ?nth ( n seq -- elt/f ) ??nth drop ; inline
 187
 188 : ?set-nth ( elt n seq -- )
 189     2dup bounds-check? [ set-nth-unsafe ] [ 3drop ] if ; inline
 190
 191 : index-or-length ( seq n -- seq n' ) over length min ; inline
 192
 193 : index-of-last ( seq -- n seq ) [ length 1 - ] keep ; inline
 194
 195 : ?first ( seq -- elt/f ) 0 swap ?nth ; inline
 196 : ?second ( seq -- elt/f ) 1 swap ?nth ; inline
 197 : ?last ( seq -- elt/f )
 198     index-of-last over 0 <
 199     [ 2drop f ] [ nth-unsafe ] if ; inline
 200
 201 MIXIN: virtual-sequence
 202 GENERIC: virtual-exemplar ( seq -- seq' )
 203 GENERIC: virtual@ ( n seq -- n' seq' )
 204
 205 M: virtual-sequence nth virtual@ nth ; inline
 206 M: virtual-sequence set-nth virtual@ set-nth ; inline
 207 M: virtual-sequence nth-unsafe virtual@ nth-unsafe ; inline
 208 M: virtual-sequence set-nth-unsafe virtual@ set-nth-unsafe ; inline
 209 M: virtual-sequence like virtual-exemplar like ; inline
 210 M: virtual-sequence new-sequence virtual-exemplar new-sequence ; inline
 211
 212 INSTANCE: virtual-sequence sequence
 213
 214 ! A reversal of an underlying sequence.
 215 TUPLE: reversed { seq read-only } ;
 216
 217 C: <reversed> reversed
 218
 219 M: reversed virtual-exemplar seq>> ; inline
 220 M: reversed virtual@ seq>> [ length swap - 1 - ] keep ; inline
 221 M: reversed length seq>> length ; inline
 222
 223 INSTANCE: reversed virtual-sequence
 224
 225 ! A slice of another sequence.
 226 TUPLE: slice
 227     { from integer read-only }
 228     { to integer read-only }
 229     { seq read-only } ;
 230
 231 : >slice< ( slice -- from to seq )
 232     [ from>> ] [ to>> ] [ seq>> ] tri ; inline
 233
 234 : collapse-slice ( m n slice -- m' n' seq )
 235     [ from>> ] [ seq>> ] bi [ [ + ] curry bi@ ] dip ; inline
 236
 237 ERROR: slice-error from to seq ;
 238
 239 : check-slice ( from to seq -- from to seq )
 240     pick 0 < [ slice-error ] when
 241     2dup length > [ slice-error ] when
 242     2over > [ slice-error ] when ; inline
 243
 244 <PRIVATE
 245
 246 : <slice-unsafe> ( from to seq -- slice )
 247     dup slice? [ collapse-slice ] when slice boa ; inline
 248
 249 PRIVATE>
 250
 251 : <slice> ( from to seq -- slice )
 252     check-slice <slice-unsafe> ; inline
 253
 254 M: slice virtual-exemplar seq>> ; inline
 255
 256 M: slice virtual@ [ from>> + ] [ seq>> ] bi ; inline
 257
 258 M: slice length [ to>> ] [ from>> ] bi - ; inline
 259
 260 : head-slice ( seq n -- slice ) head-to-index <slice> ; inline
 261
 262 : tail-slice ( seq n -- slice ) index-to-tail <slice> ; inline
 263
 264 : rest-slice ( seq -- slice ) 1 tail-slice ; inline
 265
 266 : head-slice* ( seq n -- slice ) from-tail head-slice ; inline
 267
 268 : tail-slice* ( seq n -- slice ) from-tail tail-slice ; inline
 269
 270 : but-last-slice ( seq -- slice ) 1 head-slice* ; inline
 271
 272 INSTANCE: slice virtual-sequence
 273
 274 ! One element repeated many times
 275 TUPLE: repetition
 276     { length integer read-only }
 277     { elt read-only } ;
 278
 279 : <repetition> ( len elt -- repetition )
 280     over 0 < [ non-negative-integer-expected ] when
 281     repetition boa ; inline
 282
 283 M: repetition length length>> ; inline
 284 M: repetition nth-unsafe nip elt>> ; inline
 285
 286 INSTANCE: repetition immutable-sequence
 287
 288 <PRIVATE
 289
 290 ERROR: integer-length-expected obj ;
 291
 292 ! The check-length call forces partial dispatch
 293 : check-length ( n -- n )
 294     dup integer? [ integer-length-expected ] unless ; inline
 295
 296 : >sequence< ( seq -- i n seq )
 297     [ drop 0 ] [ length check-length ] [ ] tri ; inline
 298
 299 : length-sequence ( seq -- n seq )
 300     [ length check-length ] [ ] bi ; inline
 301
 302 : >underlying< ( slice/seq -- from to slice/seq )
 303     dup slice? [ >slice< ] [ >sequence< ] if ; inline
 304
 305 TUPLE: copier
 306     { src-i integer read-only }
 307     { src read-only }
 308     { dst-i integer read-only }
 309     { dst read-only } ;
 310
 311 C: <copier> copier
 312
 313 : copy-nth-unsafe ( n copy -- )
 314     [ [ src-i>> + ] [ src>> ] bi nth-unsafe ]
 315     [ [ dst-i>> + ] [ dst>> ] bi set-nth-unsafe ] 2bi ; inline
 316
 317 : (copy) ( n copy -- dst )
 318     over 0 <= [ nip dst>> ] [
 319         [ 1 - ] dip [ copy-nth-unsafe ] [ (copy) ] 2bi
 320     ] if ; inline recursive
 321
 322 : subseq>copy ( from to seq -- n copy )
 323     [ over - check-length swap ] dip
 324     3dup nip new-sequence 0 swap <copier> ; inline
 325
 326 : bounds-check-head ( n seq -- n seq )
 327     over 0 < [ bounds-error ] when ; inline
 328
 329 : copy-unsafe ( src i dst -- )
 330     [ [ length check-length 0 ] keep ] 2dip <copier> (copy) drop ; inline
 331
 332 : subseq-unsafe-as ( from to seq exemplar -- subseq )
 333     [ subseq>copy (copy) ] dip like ; inline
 334
 335 : subseq-unsafe ( from to seq -- subseq )
 336     dup subseq-unsafe-as ; inline
 337
 338 : change-nth-unsafe ( i seq quot -- )
 339     [ [ nth-unsafe ] dip call ] 2keepd set-nth-unsafe ; inline
 340
 341 : nth-of-unsafe ( seq n -- elt ) swap nth-unsafe ; inline
 342
 343 : set-nth-of-unsafe ( seq n elt -- seq ) swap pick set-nth-unsafe ; inline
 344
 345 : copy-nth-of-unsafe ( dst dst-i src src-i -- )
 346     nth-of-unsafe set-nth-of-unsafe drop ; inline
 347
 348 : copy-loop ( dst dst-i src src-i src-stop -- dst )
 349     2dup >= [
 350         4drop
 351     ] [
 352         [
 353             [ copy-nth-of-unsafe ] 4keep
 354             [ 1 + ] 2dip 1 +
 355         ] dip copy-loop
 356     ] if ; inline recursive
 357
 358 PRIVATE>
 359
 360 : subseq-as ( from to seq exemplar -- subseq )
 361     [ check-slice ] dip subseq-unsafe-as ;
 362
 363 : subseq ( from to seq -- subseq )
 364     dup subseq-as ;
 365
 366 : head ( seq n -- headseq ) head-to-index subseq ;
 367
 368 : tail ( seq n -- tailseq ) index-to-tail subseq ;
 369
 370 : rest ( seq -- tailseq ) 1 tail ;
 371
 372 : head* ( seq n -- headseq ) from-tail head ;
 373
 374 : tail* ( seq n -- tailseq ) from-tail tail ;
 375
 376 : but-last ( seq -- headseq ) 1 head* ;
 377
 378 : copy ( src i dst -- )
 379     3dup bounds-check-head
 380     [ swap length + ] dip lengthen
 381     copy-unsafe ; inline
 382
 383 M: sequence clone-like
 384     dupd new-sequence-like [ 0 swap copy-unsafe ] keep ; inline
 385
 386 M: immutable-sequence clone-like like ; inline
 387
 388 : push-all ( src dst -- ) [ length ] [ copy ] bi ; inline
 389
 390 <PRIVATE
 391
 392 : (append) ( seq1 seq2 accum -- accum )
 393     [ [ over length ] dip copy-unsafe ]
 394     [ 0 swap copy-unsafe ]
 395     [ ] tri ; inline
 396
 397 PRIVATE>
 398
 399 : append-as ( seq1 seq2 exemplar -- newseq )
 400     [ 2dup 2length + ] dip
 401     [ (append) ] new-like ; inline
 402
 403 : append ( seq1 seq2 -- newseq ) over append-as ;
 404
 405 : prepend-as ( seq1 seq2 exemplar -- newseq ) swapd append-as ; inline
 406
 407 : prepend ( seq1 seq2 -- newseq ) over prepend-as ;
 408
 409 : 3append-as ( seq1 seq2 seq3 exemplar -- newseq )
 410     [ 3dup 3length + + ] dip [
 411         [ [ 2over 2length + ] dip copy-unsafe ]
 412         [ (append) ] bi
 413     ] new-like ; inline
 414
 415 : 3append ( seq1 seq2 seq3 -- newseq ) pick 3append-as ;
 416
 417 : surround-as ( seq1 seq2 seq3 exemplar -- newseq )
 418     [ swap ] 2dip 3append-as ; inline
 419
 420 : surround ( seq1 seq2 seq3 -- newseq ) over surround-as ; inline
 421
 422 : 1surround-as ( seq1 seq2 exemplar  -- newseq ) dupd surround-as ; inline
 423
 424 : 1surround ( seq1 seq2 -- newseq ) dup 1surround-as ; inline
 425
 426 : glue-as ( seq1 seq2 seq3 exemplar -- newseq ) swapd 3append-as ; inline
 427
 428 : glue ( seq1 seq2 seq3 -- newseq ) pick glue-as ; inline
 429
 430 : change-nth ( ..a i seq quot: ( ..a elt -- ..b newelt ) -- ..b )
 431     [ [ nth ] dip call ] 2keepd set-nth-unsafe ; inline
 432
 433 : min-length ( seq1 seq2 -- n ) 2length min ; inline
 434
 435 : max-length ( seq1 seq2 -- n ) 2length max ; inline
 436
 437 <PRIVATE
 438
 439 : sequence-operator ( seq quot -- i n quot' )
 440     [ >underlying< [ nth-unsafe ] curry ] dip compose ; inline
 441
 442 : length-iterator ( seq -- n quot' )
 443     length-sequence [ nth-unsafe ] curry ; inline
 444
 445 : length-operator ( seq quot -- n quot' )
 446     [ length-iterator ] dip compose ; inline
 447
 448 : collect-into ( quot into -- quot' )
 449     [ [ keep ] dip set-nth-unsafe ] 2curry ; inline
 450
 451 : collect-from ( i n quot into -- )
 452     collect-into each-integer-from ; inline
 453
 454 : collect ( n quot into -- )
 455     collect-into each-integer ; inline
 456
 457 : sequence-index-operator ( seq quot -- n quot' )
 458     [ length-iterator [ keep ] curry ] dip compose ; inline
 459
 460 : map-into ( seq quot into -- )
 461     [ length-operator ] dip collect ; inline
 462
 463 : 2nth-unsafe ( n seq1 seq2 -- elt1 elt2 )
 464     [ nth-unsafe ] bi-curry@ bi ; inline
 465
 466 : 2length-iterator ( seq1 seq2 -- n quot )
 467     [ min-length check-length ] 2keep [ 2nth-unsafe ] 2curry ; inline
 468
 469 : 2length-operator ( seq1 seq2 quot -- n quot' )
 470     [ 2length-iterator ] dip compose ; inline
 471
 472 : 3nth-unsafe ( n seq1 seq2 seq3 -- elt1 elt2 elt3 )
 473     [ nth-unsafe ] tri-curry@ tri ; inline
 474
 475 : 3length-iterator ( seq1 seq2 seq3 -- n quot )
 476     [ 3length min min check-length ]
 477     [ [ 3nth-unsafe ] 3curry ] 3bi ; inline
 478
 479 : 3length-operator ( seq1 seq2 seq3 quot -- n quot' )
 480     [ 3length-iterator ] dip compose ; inline
 481
 482 : element/index ( i/f seq -- elt/f i/f )
 483     '[ [ _ nth ] [ f ] if* ] keep ; inline
 484
 485 : index/element ( i/f seq -- i/f elt/f )
 486     dupd '[ _ nth ] [ f ] if* ; inline
 487
 488 : (accumulate) ( seq identity quot -- identity seq quot' )
 489     swapd [ keepd ] curry ; inline
 490
 491 : (accumulate*) ( seq identity quot -- identity seq quot' )
 492     swapd [ dup ] compose ; inline
 493
 494 PRIVATE>
 495
 496 : each ( ... seq quot: ( ... x -- ... ) -- ... )
 497     sequence-operator each-integer-from ; inline
 498
 499 : each-from ( ... seq quot: ( ... x -- ... ) i -- ... )
 500     -rot length-operator each-integer-from ; inline
 501
 502 : reduce ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... result )
 503     swapd each ; inline
 504
 505 : map-integers-from-as ( ... from len quot: ( ... i -- ... elt ) exemplar -- ... newseq )
 506     overd [ [ collect-from ] keep ] new-like ; inline
 507
 508 : map-integers-as ( ... len quot: ( ... i -- ... elt ) exemplar -- ... newseq )
 509     overd [ [ collect ] keep ] new-like ; inline
 510
 511 : map-integers ( ... len quot: ( ... i -- ... elt ) -- ... newseq )
 512     { } map-integers-as ; inline
 513
 514 : map-as ( ... seq quot: ( ... elt -- ... newelt ) exemplar -- ... newseq )
 515     [ length-operator ] dip map-integers-as ; inline
 516
 517 : map ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 518     over map-as ; inline
 519
 520 : replicate-as ( ... len quot: ( ... -- ... newelt ) exemplar -- ... newseq )
 521     [ [ drop ] prepose ] dip map-integers-as ; inline
 522
 523 : replicate ( ... len quot: ( ... -- ... newelt ) -- ... newseq )
 524     { } replicate-as ; inline
 525
 526 : map! ( ... seq quot: ( ... elt -- ... newelt ) -- ... seq )
 527     over [ map-into ] keep ; inline
 528
 529 : accumulate-as ( ... seq identity quot: ( ... prev elt -- ... next ) exemplar -- ... final newseq )
 530     [ (accumulate) ] dip map-as ; inline
 531
 532 : accumulate ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... final newseq )
 533     pick accumulate-as ; inline
 534
 535 : accumulate! ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... final seq )
 536     (accumulate) map! ; inline
 537
 538 : accumulate*-as ( ... seq identity quot: ( ... prev elt -- ... next ) exemplar -- ... newseq )
 539     [ (accumulate*) ] dip map-as nip ; inline
 540
 541 : accumulate* ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... newseq )
 542     pick accumulate*-as ; inline
 543
 544 : accumulate*! ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... seq )
 545     (accumulate*) map! nip ; inline
 546
 547 : 2each ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ) -- ... )
 548     2length-operator each-integer ; inline
 549
 550 : 2each-from ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ) from -- ... )
 551     -roll 2length-operator each-integer-from ; inline
 552
 553 : 2reduce ( ... seq1 seq2 identity quot: ( ... prev elt1 elt2 -- ... next ) -- ... result )
 554     -rotd 2each ; inline
 555
 556 : 2map-as ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) exemplar -- ... newseq )
 557     [ 2length-operator ] dip map-integers-as ; inline
 558
 559 : 2map ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... newseq )
 560     pick 2map-as ; inline
 561
 562 : 2all? ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... ? )
 563     2length-operator all-integers? ; inline
 564
 565 : 2any? ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... ? )
 566     negate 2all? not ; inline
 567
 568 : 3each ( ... seq1 seq2 seq3 quot: ( ... elt1 elt2 elt3 -- ... ) -- ... )
 569     3length-operator each-integer ; inline
 570
 571 : 3map-as ( ... seq1 seq2 seq3 quot: ( ... elt1 elt2 elt3 -- ... newelt ) exemplar -- ... newseq )
 572     [ 3length-operator ] dip map-integers-as ; inline
 573
 574 : 3map ( ... seq1 seq2 seq3 quot: ( ... elt1 elt2 elt3 -- ... newelt ) -- ... newseq )
 575     pickd swap 3map-as ; inline
 576
 577 <PRIVATE
 578
 579 : bounds-check-call ( n seq quot -- obj1 obj2 )
 580     2over bounds-check? [ call ] [ 3drop f f ] if ; inline
 581
 582 : do-find-from ( ... n seq quot: ( ... elt -- ... ? ) -- ... i/f seq )
 583     [ length-operator find-integer-from ] keepd ; inline
 584
 585 : find-last-from-unsafe ( ... n seq quot: ( ... elt -- ... ? ) -- ... i/f seq )
 586     [ length-operator nip find-last-integer ] keepd ; inline
 587
 588 PRIVATE>
 589
 590 : find-from ( ... n seq quot: ( ... elt -- ... ? ) -- ... i elt )
 591     '[ _ do-find-from index/element ] bounds-check-call ; inline
 592
 593 : find ( ... seq quot: ( ... elt -- ... ? ) -- ... i elt )
 594     [ 0 ] 2dip do-find-from index/element ; inline
 595
 596 : find-last-from ( ... n seq quot: ( ... elt -- ... ? ) -- ... i elt )
 597     '[ _ find-last-from-unsafe index/element ] bounds-check-call ; inline
 598
 599 : find-last ( ... seq quot: ( ... elt -- ... ? ) -- ... i elt )
 600     [ index-of-last ] dip find-last-from ; inline
 601
 602 : find-index-from ( ... n seq quot: ( ... elt i -- ... ? ) -- ... i elt )
 603     '[
 604         _ [ sequence-index-operator find-integer-from ] keepd
 605         index/element
 606     ] bounds-check-call ; inline
 607
 608 : find-index ( ... seq quot: ( ... elt i -- ... ? ) -- ... i elt )
 609     [ 0 ] 2dip find-index-from ; inline
 610
 611 : all? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 612     sequence-operator all-integers-from? ; inline
 613
 614 : push-when ( ..a elt quot: ( ..a elt -- ..b ? ) accum -- ..b )
 615     [ keep ] dip rot [ push ] [ 2drop ] if ; inline
 616
 617 <PRIVATE
 618
 619 : (selector-as) ( quot length exemplar -- selector accum )
 620     new-resizable [ [ push-when ] 2curry ] keep ; inline
 621
 622 PRIVATE>
 623
 624 : selector-as ( quot exemplar -- selector accum )
 625     [ length ] keep (selector-as) ; inline
 626
 627 : selector ( quot -- selector accum )
 628     V{ } selector-as ; inline
 629
 630 : filter-as ( ... seq quot: ( ... elt -- ... ? ) exemplar -- ... subseq )
 631     pick length over [ (selector-as) [ each ] dip ] 2curry dip like ; inline
 632
 633 : filter ( ... seq quot: ( ... elt -- ... ? ) -- ... subseq )
 634     over filter-as ; inline
 635
 636 : reject-as ( ... seq quot: ( ... elt -- ... ? ) exemplar -- ... subseq )
 637     [ negate ] [ filter-as ] bi* ; inline
 638
 639 : reject ( ... seq quot: ( ... elt -- ... ? ) -- ... subseq )
 640     over reject-as ; inline
 641
 642 : push-either ( ..a elt quot: ( ..a elt -- ..b ? ) accum1 accum2 -- ..b )
 643     [ keep swap ] 2dip ? push ; inline
 644
 645 : 2selector ( quot -- selector accum1 accum2 )
 646     V{ } clone V{ } clone [ [ push-either ] 3curry ] 2keep ; inline
 647
 648 : partition ( ... seq quot: ( ... elt -- ... ? ) -- ... trueseq falseseq )
 649     over [ 2selector [ each ] 2dip ] dip [ like ] curry bi@ ; inline
 650
 651 : collector-as ( quot exemplar -- quot' vec )
 652     dup new-resizable-like [ [ push ] curry compose ] keep ; inline
 653
 654 : collector ( quot -- quot' vec )
 655     V{ } collector-as ; inline
 656
 657 : produce-as ( ..a pred: ( ..a -- ..b ? ) quot: ( ..b -- ..a obj ) exemplar -- ..b seq )
 658     dup [ collector-as [ while ] dip ] curry dip like ; inline
 659
 660 : produce ( ..a pred: ( ..a -- ..b ? ) quot: ( ..b -- ..a obj ) -- ..b seq )
 661     { } produce-as ; inline
 662
 663 : follow ( ... obj quot: ( ... prev -- ... result/f ) -- ... seq )
 664     [ dup ] swap [ keep ] curry produce nip ; inline
 665
 666 : each-index ( ... seq quot: ( ... elt index -- ... ) -- ... )
 667     sequence-index-operator each-integer ; inline
 668
 669 : map-index-as ( ... seq quot: ( ... elt index -- ... newelt ) exemplar -- ... newseq )
 670     [ dup length <iota> ] 2dip 2map-as ; inline
 671
 672 : map-index ( ... seq quot: ( ... elt index -- ... newelt ) -- ... newseq )
 673     over map-index-as ; inline
 674
 675 : interleave ( ... seq between quot: ( ... elt -- ... ) -- ... )
 676     pick empty? [ 3drop ] [
 677         [ [ drop first-unsafe ] dip call ]
 678         [ [ bi* ] 2curry 1 each-from ]
 679         3bi
 680     ] if ; inline
 681
 682 : reduce-index ( ... seq identity quot: ( ... prev elt index -- ... next ) -- ... result )
 683     swapd each-index ; inline
 684
 685 : index ( obj seq -- n )
 686     [ = ] with find drop ;
 687
 688 : index-from ( obj i seq -- n )
 689     rot [ = ] curry find-from drop ;
 690
 691 : last-index ( obj seq -- n )
 692     [ = ] with find-last drop ;
 693
 694 : last-index-from ( obj i seq -- n )
 695     rot [ = ] curry find-last-from drop ;
 696
 697 : indices ( obj seq -- indices )
 698     swap [ = ] curry [ swap ] prepose V{ } clone [
 699         [ push ] curry [ [ drop ] if ] curry compose each-index
 700     ] keep ;
 701
 702 <PRIVATE
 703
 704 : nths-unsafe ( indices seq -- seq' )
 705     [ [ nth-unsafe ] curry ] keep map-as ;
 706
 707 PRIVATE>
 708
 709 : nths ( indices seq -- seq' )
 710     [ [ nth ] curry ] keep map-as ;
 711
 712 : nths-of ( seq indices -- seq' )
 713     swap nths ; inline
 714
 715 : any? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 716     find drop >boolean ; inline
 717
 718 : none? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 719     any? not ; inline
 720
 721 : member? ( elt seq -- ? )
 722     [ = ] with any? ;
 723
 724 : member-eq? ( elt seq -- ? )
 725     [ eq? ] with any? ;
 726
 727 : remove ( elt seq -- newseq )
 728     [ = ] with reject ;
 729
 730 : remove-eq ( elt seq -- newseq )
 731     [ eq? ] with reject ;
 732
 733 : sift ( seq -- newseq )
 734     [ ] filter ;
 735
 736 : harvest ( seq -- newseq )
 737     [ empty? ] reject ;
 738
 739 <PRIVATE
 740
 741 : mismatch-unsafe ( n seq1 seq2 -- i )
 742     [ 2nth-unsafe = not ] 2curry find-integer ; inline
 743
 744 PRIVATE>
 745
 746 : mismatch ( seq1 seq2 -- i )
 747     [ min-length ] 2keep mismatch-unsafe ;
 748
 749 M: sequence <=>
 750     [ mismatch ] 2keep pick
 751     [ 2nth-unsafe <=> ] [ [ length ] compare nip ] if ;
 752
 753 : sequence= ( seq1 seq2 -- ? )
 754     2dup 2length dupd =
 755     [ -rot mismatch-unsafe not ] [ 3drop f ] if ; inline
 756
 757 ERROR: assert-sequence got expected ;
 758
 759 : assert-sequence= ( a b -- )
 760     2dup sequence= [ 2drop ] [ assert-sequence ] if ;
 761
 762 M: reversed equal? over reversed? [ sequence= ] [ 2drop f ] if ;
 763
 764 M: slice equal? over slice? [ sequence= ] [ 2drop f ] if ;
 765
 766 <PRIVATE
 767
 768 : sequence-hashcode-step ( oldhash newpart -- newhash )
 769     integer>fixnum swap [
 770         [ -2 fixnum-shift-fast ] [ 5 fixnum-shift-fast ] bi
 771         fixnum+fast fixnum+fast
 772     ] keep fixnum-bitxor ; inline
 773
 774 PRIVATE>
 775
 776 : sequence-hashcode ( n seq -- x )
 777     [ 0 ] 2dip [ hashcode* sequence-hashcode-step ] with each ; inline
 778
 779 M: sequence hashcode* [ sequence-hashcode ] recursive-hashcode ;
 780
 781 M: iota hashcode*
 782     over 0 <= [ 2drop 0 ] [
 783         nip length 0 swap [ sequence-hashcode-step ] each-integer
 784     ] if ;
 785
 786 M: reversed hashcode* [ sequence-hashcode ] recursive-hashcode ;
 787
 788 M: slice hashcode* [ sequence-hashcode ] recursive-hashcode ;
 789
 790 : move ( to from seq -- )
 791     2over =
 792     [ 3drop ] [ [ nth swap ] [ set-nth ] bi ] if ; inline
 793
 794 <PRIVATE
 795
 796 : move-unsafe* ( to from seq -- from-nth )
 797     2over =
 798     [ nth-unsafe nip ]
 799     [ [ nth-unsafe tuck swap ] [ set-nth-unsafe ] bi ] if ; inline
 800
 801 : filter-from! ( store from seq quot: ( ... elt -- ... ? ) -- seq )
 802     2over length < [
 803         [ [ move-unsafe* ] dip call ] 4keep
 804         [ swap [ 1 + ] when ] 3dip
 805         [ 1 + ] 2dip filter-from!
 806     ] [ drop [ nip set-length ] keep ] if ; inline recursive
 807
 808 : move-unsafe ( to from seq -- )
 809     2over =
 810     [ 3drop ] [ [ nth-unsafe swap ] [ set-nth-unsafe ] bi ] if ; inline
 811
 812 PRIVATE>
 813
 814 : filter! ( ... seq quot: ( ... elt -- ... ? ) -- ... seq )
 815     [ 0 0 ] 2dip filter-from! ; inline
 816
 817 : reject! ( ... seq quot: ( ... elt -- ... ? ) -- ... seq )
 818     negate filter! ; inline
 819
 820 : remove! ( elt seq -- seq )
 821     [ = ] with reject! ;
 822
 823 : remove-eq! ( elt seq -- seq )
 824     [ eq? ] with reject! ;
 825
 826 : prefix ( seq elt -- newseq )
 827     over [ over length 1 + ] dip [
 828         (1sequence) [ 1 swap copy-unsafe ] keep
 829     ] new-like ;
 830
 831 : suffix ( seq elt -- newseq )
 832     over [ over length 1 + ] dip [
 833         [ [ over length ] dip set-nth-unsafe ] keep
 834         [ 0 swap copy-unsafe ] keep
 835     ] new-like ;
 836
 837 : suffix! ( seq elt -- seq ) over push ; inline
 838
 839 : append! ( seq1 seq2 -- seq1 ) over push-all ; inline
 840
 841 : last ( seq -- elt )
 842     index-of-last
 843     over 0 < [ bounds-error ] [ nth-unsafe ] if ; inline
 844
 845 <PRIVATE
 846
 847 : last-unsafe ( seq -- elt )
 848     index-of-last nth-unsafe ; inline
 849
 850 PRIVATE>
 851
 852 : set-last ( elt seq -- )
 853     index-of-last
 854     over 0 < [ bounds-error ] [ set-nth-unsafe ] if ; inline
 855
 856 : pop* ( seq -- ) index-of-last shorten ;
 857
 858 <PRIVATE
 859
 860 : move-backward ( shift from to seq -- )
 861     2over = [
 862         4drop
 863     ] [
 864         [ [ 2over + pick ] dip move-unsafe [ 1 + ] dip ] keep
 865         move-backward
 866     ] if ;
 867
 868 : open-slice ( shift from seq -- )
 869     pick 0 = [
 870         3drop
 871     ] [
 872         [ ] [ nip length + ] [ 2nip ] 3tri
 873         [ [ length ] keep [ over - ] 2dip move-backward ] 2dip
 874         set-length
 875     ] if ;
 876
 877 PRIVATE>
 878
 879 : delete-slice ( from to seq -- )
 880     check-slice [ over [ - ] dip ] dip open-slice ;
 881
 882 : remove-nth! ( n seq -- seq )
 883     [ [ dup 1 + ] dip delete-slice ] keep ;
 884
 885 : snip ( from to seq -- head tail )
 886     [ swap head ] [ swap tail ] bi-curry bi* ; inline
 887
 888 : snip-slice ( from to seq -- head tail )
 889     [ swap head-slice ] [ swap tail-slice ] bi-curry bi* ; inline
 890
 891 : replace-slice ( new from to seq -- seq' )
 892     snip-slice surround ;
 893
 894 : remove-nth ( n seq -- seq' )
 895     [ [ dup 1 + ] dip snip-slice ] keep append-as ;
 896
 897 : pop ( seq -- elt )
 898     index-of-last over 0 >=
 899     [ [ nth-unsafe ] [ shorten ] 2bi ]
 900     [ bounds-error ] if ;
 901
 902 : exchange ( m n seq -- )
 903     [ nip bounds-check 2drop ]
 904     [ bounds-check 3drop ]
 905     [ exchange-unsafe ]
 906     3tri ;
 907
 908 : midpoint@ ( seq -- n ) length 2/ ; inline
 909
 910 : reverse! ( seq -- seq )
 911     [
 912         [ midpoint@ ] [ length ] [ ] tri
 913         [ [ over - 1 - ] dip exchange-unsafe ] 2curry
 914         each-integer
 915     ] keep ;
 916
 917 : reverse ( seq -- newseq )
 918     [
 919         dup [ length ] keep new-sequence
 920         [ 0 swap copy-unsafe ] keep reverse!
 921     ] keep like ;
 922
 923 GENERIC: sum-lengths ( seq -- n )
 924
 925 M: object sum-lengths
 926     0 [ length + ] reduce ;
 927
 928 M: repetition sum-lengths
 929     [ length>> ] [ elt>> length ] bi * ;
 930
 931 : concat-as ( seq exemplar -- newseq )
 932     [
 933         [ dup sum-lengths ] dip new-resizable
 934         [ [ push-all ] curry each ] keep
 935     ] keep like ; inline
 936
 937 : concat ( seq -- newseq )
 938     [ { } ] [ dup first concat-as ] if-empty ;
 939
 940 <PRIVATE
 941
 942 : joined-length ( seq glue -- n )
 943     [ [ sum-lengths ] [ length 1 [-] ] bi ] dip length * + ;
 944
 945 PRIVATE>
 946
 947 : join-as ( seq glue exemplar -- newseq )
 948     over empty? [ nip concat-as ] [
 949         [
 950             2dup joined-length over new-resizable [
 951                 [ [ push-all ] 2curry ]
 952                 [ nip [ push-all ] curry ] 2bi
 953                 interleave
 954             ] keep
 955         ] dip like
 956     ] if ;
 957
 958 : join ( seq glue -- newseq )
 959     dup join-as ; inline
 960
 961 <PRIVATE
 962
 963 : padding ( ... seq n elt quot: ( ... seq1 seq2 -- ... newseq ) -- ... newseq )
 964     [
 965         [ over length [-] dup 0 = [ drop ] ] dip
 966         [ <repetition> ] curry
 967     ] dip compose if ; inline
 968
 969 PRIVATE>
 970
 971 : pad-head ( seq n elt -- padded )
 972     [ swap dup append-as ] padding ;
 973
 974 : pad-tail ( seq n elt -- padded )
 975     [ append ] padding ;
 976
 977 : shorter? ( seq1 seq2 -- ? ) 2length < ; inline
 978 : longer? ( seq1 seq2 -- ? ) 2length > ; inline
 979 : shorter ( seq1 seq2 -- seq ) [ 2length <= ] most ; inline
 980 : longer ( seq1 seq2 -- seq ) [ 2length >= ] most ; inline
 981
 982 : head? ( seq begin -- ? )
 983     2dup shorter? [
 984         2drop f
 985     ] [
 986         [ length [ head-slice ] keep swap ] keep
 987         mismatch-unsafe not
 988     ] if ;
 989
 990 : tail? ( seq end -- ? )
 991     2dup shorter? [
 992         2drop f
 993     ] [
 994         [ length [ tail-slice* ] keep swap ] keep
 995         mismatch-unsafe not
 996     ] if ;
 997
 998 : cut-slice ( seq n -- before-slice after-slice )
 999     [ head-slice ] [ tail-slice ] 2bi ; inline
1000
1001 : cut-slice* ( seq n -- before-slice after-slice )
1002     [ head-slice* ] [ tail-slice* ] 2bi ;
1003
1004 : insert-nth ( elt n seq -- seq' )
1005     swap cut-slice [ swap suffix ] dip append ;
1006
1007 : halves ( seq -- first-slice second-slice )
1008     dup midpoint@ cut-slice ; inline
1009
1010 <PRIVATE
1011
1012 : nth2-unsafe ( n seq -- a b )
1013     [ nth-unsafe ] [ [ 1 + ] dip nth-unsafe ] 2bi ; inline
1014
1015 : nth3-unsafe ( n seq -- a b c )
1016     [ nth2-unsafe ] [ [ 2 + ] dip nth-unsafe ] 2bi ; inline
1017
1018 : (binary-reduce) ( seq start quot: ( elt1 elt2 -- newelt ) from length -- value )
1019     ! We can't use case here since combinators depends on
1020     ! sequences
1021     dup 4 < [
1022         integer>fixnum {
1023             [ 2drop nip ]
1024             [ 2nip swap nth-unsafe ]
1025             [ -rot [ drop swap nth2-unsafe ] dip call ]
1026             [ -rot [ drop swap nth3-unsafe ] dip bi@ ]
1027         } dispatch
1028     ] [
1029         [ 2/ ] [ over - ] bi [ 2dup + ] dip
1030         [ (binary-reduce) ] [ 2curry ] curry 2bi@
1031         pick [ 3bi ] dip call
1032     ] if ; inline recursive
1033
1034 PRIVATE>
1035
1036 : binary-reduce ( seq start quot: ( elt1 elt2 -- newelt ) -- value )
1037     pick dup slice? [
1038         [ seq>> ] 3dip [ from>> 0 max ] [ to>> 0 max over - ] bi
1039     ] [
1040         length 0 max 0 swap
1041     ] if (binary-reduce) ; inline
1042
1043 : cut ( seq n -- before after )
1044     [ head ] [ tail ] 2bi ;
1045
1046 : cut* ( seq n -- before after )
1047     [ head* ] [ tail* ] 2bi ;
1048
1049 : subseq-starts-at? ( i seq subseq -- ? )
1050     [ length swap ] keep
1051     '[
1052         [ + _ nth-unsafe ] keep _ nth-unsafe =
1053     ] with all-integers? ; inline
1054
1055 : subseq-index-from ( n seq subseq -- i/f )
1056     [ 2length - 1 + ] 2keep
1057     '[ _ _ subseq-starts-at? ] find-integer-from ; inline
1058
1059 : subseq-index ( seq subseq -- i/f ) [ 0 ] 2dip subseq-index-from ; inline
1060
1061 : subseq-of? ( seq subseq -- ? ) subseq-index >boolean ; inline
1062
1063 : subseq-start-from ( subseq seq n -- i/f )
1064     spin subseq-index-from ; inline deprecated
1065
1066 : subseq-start ( subseq seq -- i/f ) swap subseq-index ; inline deprecated
1067
1068 : subseq? ( subseq seq -- ? ) subseq-start >boolean ; inline deprecated
1069
1070 : drop-prefix ( seq1 seq2 -- slice1 slice2 )
1071     2dup mismatch [ 2dup min-length ] unless*
1072     [ tail-slice ] curry bi@ ;
1073
1074 : unclip ( seq -- rest first )
1075     [ rest ] [ first-unsafe ] bi ;
1076
1077 : unclip-last ( seq -- butlast last )
1078     [ but-last ] [ last-unsafe ] bi ;
1079
1080 : unclip-slice ( seq -- rest-slice first )
1081     [ rest-slice ] [ first-unsafe ] bi ; inline
1082
1083 : map-reduce ( ..a seq map-quot: ( ..a elt -- ..a intermediate ) reduce-quot: ( ..a prev intermediate -- ..a next ) -- ..a result )
1084     [ [ [ first ] keep ] dip [ dip ] keep ] dip
1085     '[ swap _ dip swap @ ] 1 each-from ; inline
1086
1087 : 2map-reduce ( ..a seq1 seq2 map-quot: ( ..a elt1 elt2 -- ..a intermediate ) reduce-quot: ( ..a prev intermediate -- ..a next ) -- ..a result )
1088     [ [ [ [ first ] bi@ ] 2keep ] dip [ 2dip ] keep ] dip
1089     '[ rot _ dip swap @ ] 1 2each-from ; inline
1090
1091 <PRIVATE
1092
1093 : (map-find) ( seq quot find-quot -- result elt )
1094     [ [ f ] 2dip [ nip ] prepose [ dup ] compose ] dip call nip ; inline
1095
1096 PRIVATE>
1097
1098 : map-find ( ... seq quot: ( ... elt -- ... result/f ) -- ... result elt )
1099     [ find ] (map-find) ; inline
1100
1101 : map-find-last ( ... seq quot: ( ... elt -- ... result/f ) -- ... result elt )
1102     [ find-last ] (map-find) ; inline
1103
1104 : unclip-last-slice ( seq -- butlast-slice last )
1105     [ but-last-slice ] [ last-unsafe ] bi ; inline
1106
1107 <PRIVATE
1108
1109 : (trim-head) ( seq quot -- seq n )
1110     over [ negate find drop ] dip swap
1111     [ dup length ] unless* ; inline
1112
1113 : (trim-tail) ( seq quot -- seq n )
1114     over [ negate find-last drop ?1+ ] dip
1115     swap ; inline
1116
1117 PRIVATE>
1118
1119 : trim-head-slice ( ... seq quot: ( ... elt -- ... ? ) -- ... slice )
1120     (trim-head) tail-slice ; inline
1121
1122 : trim-head ( ... seq quot: ( ... elt -- ... ? ) -- ... newseq )
1123     (trim-head) tail ; inline
1124
1125 : trim-tail-slice ( ... seq quot: ( ... elt -- ... ? ) -- ... slice )
1126     (trim-tail) head-slice ; inline
1127
1128 : trim-tail ( ... seq quot: ( ... elt -- ... ? ) -- ... newseq )
1129     (trim-tail) head ; inline
1130
1131 : trim-slice ( ... seq quot: ( ... elt -- ... ? ) -- ... slice )
1132     [ trim-head-slice ] [ trim-tail-slice ] bi ; inline
1133
1134 : trim ( ... seq quot: ( ... elt -- ... ? ) -- ... newseq )
1135     [ trim-slice ] [ drop ] 2bi like ; inline
1136
1137 GENERIC: sum ( seq -- n )
1138 M: object sum 0 [ + ] binary-reduce ; inline
1139 M: iota sum length dup 1 - * 2/ ; inline
1140 M: repetition sum [ elt>> ] [ length>> ] bi * ; inline
1141
1142 : product ( seq -- n ) 1 [ * ] binary-reduce ;
1143
1144 : infimum ( seq -- elt ) [ ] [ min ] map-reduce ;
1145
1146 : supremum ( seq -- elt ) [ ] [ max ] map-reduce ;
1147
1148 : map-sum ( ... seq quot: ( ... elt -- ... n ) -- ... n )
1149     [ 0 ] 2dip [ dip + ] curry [ swap ] prepose each ; inline
1150
1151 : count ( ... seq quot: ( ... elt -- ... ? ) -- ... n )
1152     [ 1 0 ? ] compose map-sum ; inline
1153
1154 : cartesian-each ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ) -- ... )
1155     [ with each ] 2curry each ; inline
1156
1157 : cartesian-map ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... newseq )
1158     [ with { } map-as ] 2curry { } map-as ; inline
1159
1160 : cartesian-product-as ( seq1 seq2 exemplar -- newseq )
1161     [ 2sequence ] curry cartesian-map ; inline
1162
1163 : cartesian-product ( seq1 seq2 -- newseq )
1164     dup cartesian-product-as ; inline
1165
1166 : cartesian-find ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... elt1 elt2 )
1167     [ f ] 3dip [ with find swap ] 2curry [ nip ] prepose find nip swap ; inline
1168
1169 <PRIVATE
1170
1171 : select-by ( ... seq quot: ( ... elt -- ... x ) compare: ( obj1 obj2 -- ? ) -- ... elt )
1172     [
1173         [ keep swap ] curry [ [ first ] dip call ] 2keep
1174         [ curry 2dip pick over ] curry
1175     ] [
1176         [ [ 2drop ] [ 2nipd ] if ] compose
1177     ] bi* compose 1 each-from drop ; inline
1178
1179 PRIVATE>
1180
1181 : supremum-by ( ... seq quot: ( ... elt -- ... x ) -- ... elt )
1182     [ after? ] select-by ; inline
1183
1184 : infimum-by ( ... seq quot: ( ... elt -- ... x ) -- ... elt )
1185     [ before? ] select-by ; inline
1186
1187 : shortest ( seqs -- elt ) [ length ] infimum-by ;
1188
1189 : longest ( seqs -- elt ) [ length ] supremum-by ;
1190
1191 ! We hand-optimize flip to such a degree because type hints
1192 ! cannot express that an array is an array of arrays yet, and
1193 ! this word happens to be performance-critical since the compiler
1194 ! itself uses it. Optimizing it like this reduced compile time.
1195 <PRIVATE
1196
1197 : generic-flip ( matrix -- newmatrix )
1198     [ [ length ] [ min ] map-reduce ] keep
1199     '[ _ [ nth-unsafe ] with { } map-as ] map-integers ; inline
1200
1201 USE: arrays
1202
1203 : array-flip ( matrix -- newmatrix )
1204     { array } declare
1205     [ [ { array } declare length>> ] [ min ] map-reduce ] keep
1206     '[ _ [ { array } declare array-nth ] with { } map-as ] map-integers ;
1207
1208 PRIVATE>
1209
1210 : flip ( matrix -- newmatrix )
1211     dup empty? [
1212         dup array? [
1213             dup [ array? ] all?
1214             [ array-flip ] [ generic-flip ] if
1215         ] [ generic-flip ] if
1216     ] unless ;