core/sequences/sequences.factor

   1 ! Copyright (C) 2005, 2009 Slava Pestov, Daniel Ehrenberg.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors kernel kernel.private locals slots.private math
   4 math.private math.order ;
   5 IN: sequences
   6
   7 MIXIN: sequence
   8
   9 GENERIC: length ( seq -- n ) flushable
  10 GENERIC: set-length ( n seq -- )
  11 GENERIC: nth ( n seq -- elt ) flushable
  12 GENERIC: set-nth ( elt n seq -- )
  13 GENERIC: new-sequence ( len seq -- newseq ) flushable
  14 GENERIC: new-resizable ( len seq -- newseq ) flushable
  15 GENERIC: like ( seq exemplar -- newseq ) flushable
  16 GENERIC: clone-like ( seq exemplar -- newseq ) flushable
  17
  18 : new-like ( len exemplar quot -- seq )
  19     over [ [ new-sequence ] dip call ] dip like ; inline
  20
  21 M: sequence like drop ;
  22
  23 GENERIC: lengthen ( n seq -- )
  24 GENERIC: shorten ( n seq -- )
  25
  26 M: sequence lengthen 2dup length > [ set-length ] [ 2drop ] if ;
  27
  28 M: sequence shorten 2dup length < [ set-length ] [ 2drop ] if ;
  29
  30 : empty? ( seq -- ? ) length 0 = ; inline
  31
  32 : if-empty ( seq quot1 quot2 -- )
  33     [ dup empty? ] [ [ drop ] prepose ] [ ] tri* if ; inline
  34
  35 : when-empty ( seq quot -- ) [ ] if-empty ; inline
  36
  37 : unless-empty ( seq quot -- ) [ ] swap if-empty ; inline
  38
  39 : delete-all ( seq -- ) 0 swap set-length ;
  40
  41 : first ( seq -- first ) 0 swap nth ; inline
  42 : second ( seq -- second ) 1 swap nth ; inline
  43 : third ( seq -- third ) 2 swap nth ; inline
  44 : fourth ( seq -- fourth ) 3 swap nth ; inline
  45
  46 : set-first ( first seq -- ) 0 swap set-nth ; inline
  47 : set-second ( second seq -- ) 1 swap set-nth ; inline
  48 : set-third ( third seq -- ) 2 swap set-nth ; inline
  49 : set-fourth  ( fourth seq -- ) 3 swap set-nth ; inline
  50
  51 : push ( elt seq -- ) [ length ] [ set-nth ] bi ;
  52
  53 : bounds-check? ( n seq -- ? )
  54     dupd length < [ 0 >= ] [ drop f ] if ; inline
  55
  56 ERROR: bounds-error index seq ;
  57
  58 : bounds-check ( n seq -- n seq )
  59     2dup bounds-check? [ bounds-error ] unless ; inline
  60
  61 MIXIN: immutable-sequence
  62
  63 ERROR: immutable seq ;
  64
  65 M: immutable-sequence set-nth immutable ;
  66
  67 INSTANCE: immutable-sequence sequence
  68
  69 <PRIVATE
  70
  71 : array-nth ( n array -- elt )
  72     swap 2 fixnum+fast slot ; inline
  73
  74 : set-array-nth ( elt n array -- )
  75     swap 2 fixnum+fast set-slot ; inline
  76
  77 : dispatch ( n array -- ) array-nth call ;
  78
  79 GENERIC: resize ( n seq -- newseq ) flushable
  80
  81 ! Unsafe sequence protocol for inner loops
  82 GENERIC: nth-unsafe ( n seq -- elt ) flushable
  83 GENERIC: set-nth-unsafe ( elt n seq -- )
  84
  85 M: sequence nth bounds-check nth-unsafe ;
  86 M: sequence set-nth bounds-check set-nth-unsafe ;
  87
  88 M: sequence nth-unsafe nth ;
  89 M: sequence set-nth-unsafe set-nth ;
  90
  91 ! The f object supports the sequence protocol trivially
  92 M: f length drop 0 ;
  93 M: f nth-unsafe nip ;
  94 M: f like drop [ f ] when-empty ;
  95
  96 INSTANCE: f immutable-sequence
  97
  98 ! Integers support the sequence protocol
  99 M: integer length ;
 100 M: integer nth-unsafe drop ;
 101
 102 INSTANCE: integer immutable-sequence
 103
 104 PRIVATE>
 105
 106 ! In the future, this will replace integer sequences
 107 TUPLE: iota { n integer read-only } ;
 108
 109 : iota ( n -- iota ) \ iota boa ; inline
 110
 111 <PRIVATE
 112
 113 M: iota length n>> ;
 114 M: iota nth-unsafe drop ;
 115
 116 INSTANCE: iota immutable-sequence
 117
 118 : first-unsafe ( seq -- first )
 119     0 swap nth-unsafe ; inline
 120
 121 : first2-unsafe ( seq -- first second )
 122     [ first-unsafe ] [ 1 swap nth-unsafe ] bi ; inline
 123
 124 : first3-unsafe ( seq -- first second third )
 125     [ first2-unsafe ] [ 2 swap nth-unsafe ] bi ; inline
 126
 127 : first4-unsafe ( seq -- first second third fourth )
 128     [ first3-unsafe ] [ 3 swap nth-unsafe ] bi ; inline
 129
 130 : exchange-unsafe ( m n seq -- )
 131     [ [ nth-unsafe ] curry bi@ ]
 132     [ [ set-nth-unsafe ] curry bi@ ] 3bi ; inline
 133
 134 : (head) ( seq n -- from to seq ) [ 0 ] 2dip swap ; inline
 135
 136 : (tail) ( seq n -- from to seq ) swap [ length ] keep ; inline
 137
 138 : from-end ( seq n -- seq n' ) [ dup length ] dip - ; inline
 139
 140 : (1sequence) ( obj seq -- seq )
 141     [ 0 swap set-nth-unsafe ] keep ; inline
 142
 143 : (2sequence) ( obj1 obj2 seq -- seq )
 144     [ 1 swap set-nth-unsafe ] keep
 145     (1sequence) ; inline
 146
 147 : (3sequence) ( obj1 obj2 obj3 seq -- seq )
 148     [ 2 swap set-nth-unsafe ] keep
 149     (2sequence) ; inline
 150
 151 : (4sequence) ( obj1 obj2 obj3 obj4 seq -- seq )
 152     [ 3 swap set-nth-unsafe ] keep
 153     (3sequence) ; inline
 154
 155 PRIVATE>
 156
 157 : 1sequence ( obj exemplar -- seq )
 158     1 swap [ (1sequence) ] new-like ; inline
 159
 160 : 2sequence ( obj1 obj2 exemplar -- seq )
 161     2 swap [ (2sequence) ] new-like ; inline
 162
 163 : 3sequence ( obj1 obj2 obj3 exemplar -- seq )
 164     3 swap [ (3sequence) ] new-like ; inline
 165
 166 : 4sequence ( obj1 obj2 obj3 obj4 exemplar -- seq )
 167     4 swap [ (4sequence) ] new-like ; inline
 168
 169 : first2 ( seq -- first second )
 170     1 swap bounds-check nip first2-unsafe ; flushable
 171
 172 : first3 ( seq -- first second third )
 173     2 swap bounds-check nip first3-unsafe ; flushable
 174
 175 : first4 ( seq -- first second third fourth )
 176     3 swap bounds-check nip first4-unsafe ; flushable
 177
 178 : ?nth ( n seq -- elt/f )
 179     2dup bounds-check? [ nth-unsafe ] [ 2drop f ] if ; inline
 180
 181 MIXIN: virtual-sequence
 182 GENERIC: virtual-seq ( seq -- seq' )
 183 GENERIC: virtual@ ( n seq -- n' seq' )
 184
 185 M: virtual-sequence nth virtual@ nth ;
 186 M: virtual-sequence set-nth virtual@ set-nth ;
 187 M: virtual-sequence nth-unsafe virtual@ nth-unsafe ;
 188 M: virtual-sequence set-nth-unsafe virtual@ set-nth-unsafe ;
 189 M: virtual-sequence like virtual-seq like ;
 190 M: virtual-sequence new-sequence virtual-seq new-sequence ;
 191
 192 INSTANCE: virtual-sequence sequence
 193
 194 ! A reversal of an underlying sequence.
 195 TUPLE: reversed { seq read-only } ;
 196
 197 C: <reversed> reversed
 198
 199 M: reversed virtual-seq seq>> ;
 200
 201 M: reversed virtual@ seq>> [ length swap - 1 - ] keep ;
 202
 203 M: reversed length seq>> length ;
 204
 205 INSTANCE: reversed virtual-sequence
 206
 207 ! A slice of another sequence.
 208 TUPLE: slice
 209 { from read-only }
 210 { to read-only }
 211 { seq read-only } ;
 212
 213 : collapse-slice ( m n slice -- m' n' seq )
 214     [ from>> ] [ seq>> ] bi [ [ + ] curry bi@ ] dip ; inline
 215
 216 TUPLE: slice-error from to seq reason ;
 217
 218 : slice-error ( from to seq ? string -- from to seq )
 219     [ \ slice-error boa throw ] curry when ; inline
 220
 221 : check-slice ( from to seq -- from to seq )
 222     3dup
 223     [ 2drop 0 < "start < 0" slice-error ]
 224     [ [ drop ] 2dip length > "end > sequence" slice-error ]
 225     [ drop > "start > end" slice-error ]
 226     3tri ; inline
 227
 228 : <slice> ( from to seq -- slice )
 229     dup slice? [ collapse-slice ] when
 230     check-slice
 231     slice boa ; inline
 232
 233 M: slice virtual-seq seq>> ;
 234
 235 M: slice virtual@ [ from>> + ] [ seq>> ] bi ;
 236
 237 M: slice length [ to>> ] [ from>> ] bi - ;
 238
 239 : short ( seq n -- seq n' ) over length min ; inline
 240
 241 : head-slice ( seq n -- slice ) (head) <slice> ; inline
 242
 243 : tail-slice ( seq n -- slice ) (tail) <slice> ; inline
 244
 245 : rest-slice ( seq -- slice ) 1 tail-slice ; inline
 246
 247 : head-slice* ( seq n -- slice ) from-end head-slice ; inline
 248
 249 : tail-slice* ( seq n -- slice ) from-end tail-slice ; inline
 250
 251 : but-last-slice ( seq -- slice ) 1 head-slice* ; inline
 252
 253 INSTANCE: slice virtual-sequence
 254
 255 ! One element repeated many times
 256 TUPLE: repetition { len read-only } { elt read-only } ;
 257
 258 C: <repetition> repetition
 259
 260 M: repetition length len>> ;
 261 M: repetition nth-unsafe nip elt>> ;
 262
 263 INSTANCE: repetition immutable-sequence
 264
 265 <PRIVATE
 266
 267 : check-length ( n -- n )
 268     #! Ricing.
 269     dup integer? [ "length not an integer" throw ] unless ; inline
 270
 271 : ((copy)) ( dst i src j n -- dst i src j n )
 272     dup -roll [
 273         + swap nth-unsafe -roll [
 274             + swap set-nth-unsafe
 275         ] 3keep drop
 276     ] 3keep ; inline
 277
 278 : (copy) ( dst i src j n -- dst )
 279     dup 0 <= [ 2drop 2drop ] [ 1 - ((copy)) (copy) ] if ;
 280     inline recursive
 281
 282 : prepare-subseq ( from to seq -- dst i src j n )
 283     #! The check-length call forces partial dispatch
 284     [ [ swap - ] dip new-sequence dup 0 ] 3keep
 285     -rot drop roll length check-length ; inline
 286
 287 : check-copy ( src n dst -- )
 288     over 0 < [ bounds-error ] when
 289     [ swap length + ] dip lengthen ; inline
 290
 291 PRIVATE>
 292
 293 : subseq ( from to seq -- subseq )
 294     [ check-slice prepare-subseq (copy) ] keep like ;
 295
 296 : head ( seq n -- headseq ) (head) subseq ;
 297
 298 : tail ( seq n -- tailseq ) (tail) subseq ;
 299
 300 : rest ( seq -- tailseq ) 1 tail ;
 301
 302 : head* ( seq n -- headseq ) from-end head ;
 303
 304 : tail* ( seq n -- tailseq ) from-end tail ;
 305
 306 : but-last ( seq -- headseq ) 1 head* ;
 307
 308 : copy ( src i dst -- )
 309     #! The check-length call forces partial dispatch
 310     pick length check-length [ 3dup check-copy spin 0 ] dip
 311     (copy) drop ; inline
 312
 313 M: sequence clone-like
 314     [ dup length ] dip new-sequence [ 0 swap copy ] keep ;
 315
 316 M: immutable-sequence clone-like like ;
 317
 318 : push-all ( src dest -- ) [ length ] [ copy ] bi ;
 319
 320 <PRIVATE
 321
 322 : (append) ( seq1 seq2 accum -- accum )
 323     [ [ over length ] dip copy ]
 324     [ 0 swap copy ]
 325     [ ] tri ; inline
 326
 327 PRIVATE>
 328
 329 : append-as ( seq1 seq2 exemplar -- newseq )
 330     [ over length over length + ] dip
 331     [ (append) ] new-like ; inline
 332
 333 : 3append-as ( seq1 seq2 seq3 exemplar -- newseq )
 334     [ 3dup [ length ] tri@ + + ] dip [
 335         [ [ 2over [ length ] bi@ + ] dip copy ]
 336         [ (append) ] bi
 337     ] new-like ; inline
 338
 339 : append ( seq1 seq2 -- newseq ) over append-as ;
 340
 341 : prepend ( seq1 seq2 -- newseq ) swap append ; inline
 342
 343 : 3append ( seq1 seq2 seq3 -- newseq ) pick 3append-as ;
 344
 345 : surround ( seq1 seq2 seq3 -- newseq ) swapd 3append ; inline
 346
 347 : glue ( seq1 seq2 seq3 -- newseq ) swap 3append ; inline
 348
 349 : change-nth ( i seq quot -- )
 350     [ [ nth ] dip call ] 3keep drop set-nth ; inline
 351
 352 : min-length ( seq1 seq2 -- n ) [ length ] bi@ min ; inline
 353
 354 : max-length ( seq1 seq2 -- n ) [ length ] bi@ max ; inline
 355
 356 <PRIVATE
 357
 358 : (each) ( seq quot -- n quot' )
 359     [ [ length ] keep [ nth-unsafe ] curry ] dip compose ; inline
 360
 361 : (collect) ( quot into -- quot' )
 362     [ [ keep ] dip set-nth-unsafe ] 2curry ; inline
 363
 364 : collect ( n quot into -- )
 365     (collect) each-integer ; inline
 366
 367 : map-into ( seq quot into -- )
 368     [ (each) ] dip collect ; inline
 369
 370 : 2nth-unsafe ( n seq1 seq2 -- elt1 elt2 )
 371     [ nth-unsafe ] bi-curry@ bi ; inline
 372
 373 : (2each) ( seq1 seq2 quot -- n quot' )
 374     [
 375         [ min-length ] 2keep
 376         [ 2nth-unsafe ] 2curry
 377     ] dip compose ; inline
 378
 379 : 3nth-unsafe ( n seq1 seq2 seq3 -- elt1 elt2 elt3 )
 380     [ nth-unsafe ] tri-curry@ tri ; inline
 381
 382 : (3each) ( seq1 seq2 seq3 quot -- n quot' )
 383     [
 384         [ [ length ] tri@ min min ]
 385         [ [ 3nth-unsafe ] 3curry ] 3bi
 386     ] dip compose ; inline
 387
 388 : finish-find ( i seq -- i elt )
 389     over [ dupd nth-unsafe ] [ drop f ] if ; inline
 390
 391 : (find) ( seq quot quot' -- i elt )
 392     pick [ [ (each) ] dip call ] dip finish-find ; inline
 393
 394 : (find-from) ( n seq quot quot' -- i elt )
 395     [ 2dup bounds-check? ] 2dip
 396     [ (find) ] 2curry
 397     [ 2drop f f ]
 398     if ; inline
 399
 400 PRIVATE>
 401
 402 : each ( seq quot -- )
 403     (each) each-integer ; inline
 404
 405 : reduce ( seq identity quot -- result )
 406     swapd each ; inline
 407
 408 : map-as ( seq quot exemplar -- newseq )
 409     [ over length ] dip [ [ map-into ] keep ] new-like ; inline
 410
 411 : map ( seq quot -- newseq )
 412     over map-as ; inline
 413
 414 : replicate ( seq quot -- newseq )
 415     [ drop ] prepose map ; inline
 416
 417 : replicate-as ( seq quot exemplar -- newseq )
 418     [ [ drop ] prepose ] dip map-as ; inline
 419
 420 : change-each ( seq quot -- )
 421     over map-into ; inline
 422
 423 : accumulate ( seq identity quot -- final newseq )
 424     swapd [ [ call ] [ 2drop ] 3bi ] curry { } map-as ; inline
 425
 426 : 2each ( seq1 seq2 quot -- )
 427     (2each) each-integer ; inline
 428
 429 : 2reverse-each ( seq1 seq2 quot -- )
 430     [ [ <reversed> ] bi@ ] dip 2each ; inline
 431
 432 : 2reduce ( seq1 seq2 identity quot -- result )
 433     [ -rot ] dip 2each ; inline
 434
 435 : 2map-as ( seq1 seq2 quot exemplar -- newseq )
 436     [ (2each) ] dip map-as ; inline
 437
 438 : 2map ( seq1 seq2 quot -- newseq )
 439     pick 2map-as ; inline
 440
 441 : 2all? ( seq1 seq2 quot -- ? )
 442     (2each) all-integers? ; inline
 443
 444 : 3each ( seq1 seq2 seq3 quot -- )
 445     (3each) each ; inline
 446
 447 : 3map-as ( seq1 seq2 seq3 quot exemplar -- newseq )
 448     [ (3each) ] dip map-as ; inline
 449
 450 : 3map ( seq1 seq2 seq3 quot -- newseq )
 451     [ pick ] dip swap 3map-as ; inline
 452
 453 : find-from ( n seq quot -- i elt )
 454     [ (find-integer) ] (find-from) ; inline
 455
 456 : find ( seq quot -- i elt )
 457     [ find-integer ] (find) ; inline
 458
 459 : find-last-from ( n seq quot -- i elt )
 460     [ nip find-last-integer ] (find-from) ; inline
 461
 462 : find-last ( seq quot -- i elt )
 463     [ [ 1 - ] dip find-last-integer ] (find) ; inline
 464
 465 : all? ( seq quot -- ? )
 466     (each) all-integers? ; inline
 467
 468 : push-if ( elt quot accum -- )
 469     [ keep ] dip rot [ push ] [ 2drop ] if ; inline
 470
 471 : pusher ( quot -- quot accum )
 472     V{ } clone [ [ push-if ] 2curry ] keep ; inline
 473
 474 : filter ( seq quot -- subseq )
 475     over [ pusher [ each ] dip ] dip like ; inline
 476
 477 : push-either ( elt quot accum1 accum2 -- )
 478     [ keep swap ] 2dip ? push ; inline
 479
 480 : 2pusher ( quot -- quot accum1 accum2 )
 481     V{ } clone V{ } clone [ [ push-either ] 3curry ] 2keep ; inline
 482
 483 : partition ( seq quot -- trueseq falseseq )
 484     over [ 2pusher [ each ] 2dip ] dip [ like ] curry bi@ ; inline
 485
 486 : accumulator ( quot -- quot' vec )
 487     V{ } clone [ [ push ] curry compose ] keep ; inline
 488
 489 : produce-as ( pred quot exemplar -- seq )
 490     [ accumulator [ while ] dip ] dip like ; inline
 491
 492 : produce ( pred quot -- seq )
 493     { } produce-as ; inline
 494
 495 : follow ( obj quot -- seq )
 496     [ dup ] swap [ keep ] curry produce nip ; inline
 497
 498 : prepare-index ( seq quot -- seq n quot )
 499     [ dup length ] dip ; inline
 500
 501 : each-index ( seq quot -- )
 502     prepare-index 2each ; inline
 503
 504 : interleave ( seq between quot -- )
 505     swap [ drop ] [ [ 2dip call ] 2curry ] 2bi
 506     [ [ 0 = ] 2dip if ] 2curry
 507     each-index ; inline
 508
 509 : map-index ( seq quot -- newseq )
 510     prepare-index 2map ; inline
 511
 512 : reduce-index ( seq identity quot -- )
 513     swapd each-index ; inline
 514
 515 : index ( obj seq -- n )
 516     [ = ] with find drop ;
 517
 518 : index-from ( obj i seq -- n )
 519     rot [ = ] curry find-from drop ;
 520
 521 : last-index ( obj seq -- n )
 522     [ = ] with find-last drop ;
 523
 524 : last-index-from ( obj i seq -- n )
 525     rot [ = ] curry find-last-from drop ;
 526
 527 : (indices) ( elt i obj accum -- )
 528     [ swap [ = ] dip ] dip [ push ] 2curry when ; inline
 529
 530 : indices ( obj seq -- indices )
 531     swap V{ } clone
 532     [ [ (indices) ] 2curry each-index ] keep ;
 533
 534 : nths ( indices seq -- seq' )
 535     [ nth ] curry map ;
 536
 537 : any? ( seq quot -- ? )
 538     find drop >boolean ; inline
 539
 540 : member? ( elt seq -- ? )
 541     [ = ] with any? ;
 542
 543 : memq? ( elt seq -- ? )
 544     [ eq? ] with any? ;
 545
 546 : remove ( elt seq -- newseq )
 547     [ = not ] with filter ;
 548
 549 : remq ( elt seq -- newseq )
 550     [ eq? not ] with filter ;
 551
 552 : sift ( seq -- newseq )
 553     [ ] filter ;
 554
 555 : harvest ( seq -- newseq )
 556     [ empty? not ] filter ;
 557
 558 : mismatch ( seq1 seq2 -- i )
 559     [ min-length iota ] 2keep
 560     [ 2nth-unsafe = not ] 2curry
 561     find drop ; inline
 562
 563 M: sequence <=>
 564     2dup mismatch
 565     [ -rot 2nth-unsafe <=> ] [ [ length ] compare ] if* ;
 566
 567 : sequence= ( seq1 seq2 -- ? )
 568     2dup [ length ] bi@ =
 569     [ mismatch not ] [ 2drop f ] if ; inline
 570
 571 ERROR: assert-sequence got expected ;
 572
 573 : assert-sequence= ( a b -- )
 574     2dup sequence= [ 2drop ] [ assert-sequence ] if ;
 575
 576 : sequence-hashcode-step ( oldhash newpart -- newhash )
 577     >fixnum swap [
 578         [ -2 fixnum-shift-fast ] [ 5 fixnum-shift-fast ] bi
 579         fixnum+fast fixnum+fast
 580     ] keep fixnum-bitxor ; inline
 581
 582 : sequence-hashcode ( n seq -- x )
 583     [ 0 ] 2dip [ hashcode* sequence-hashcode-step ] with each ; inline
 584
 585 M: reversed equal? over reversed? [ sequence= ] [ 2drop f ] if ;
 586
 587 M: slice equal? over slice? [ sequence= ] [ 2drop f ] if ;
 588
 589 : move ( to from seq -- )
 590     2over =
 591     [ 3drop ] [ [ nth swap ] [ set-nth ] bi ] if ; inline
 592
 593 <PRIVATE
 594
 595 : (filter-here) ( quot: ( elt -- ? ) store scan seq -- )
 596     2dup length < [
 597         [ move ] 3keep
 598         [ nth-unsafe pick call [ 1 + ] when ] 2keep
 599         [ 1 + ] dip
 600         (filter-here)
 601     ] [ nip set-length drop ] if ; inline recursive
 602
 603 PRIVATE>
 604
 605 : filter-here ( seq quot -- )
 606     swap [ 0 0 ] dip (filter-here) ; inline
 607
 608 : delete ( elt seq -- )
 609     [ = not ] with filter-here ;
 610
 611 : delq ( elt seq -- )
 612     [ eq? not ] with filter-here ;
 613
 614 : prefix ( seq elt -- newseq )
 615     over [ over length 1 + ] dip [
 616         [ 0 swap set-nth-unsafe ] keep
 617         [ 1 swap copy ] keep
 618     ] new-like ;
 619
 620 : suffix ( seq elt -- newseq )
 621     over [ over length 1 + ] dip [
 622         [ [ over length ] dip set-nth-unsafe ] keep
 623         [ 0 swap copy ] keep
 624     ] new-like ;
 625
 626 : peek ( seq -- elt ) [ length 1 - ] [ nth ] bi ;
 627
 628 : pop* ( seq -- ) [ length 1 - ] [ shorten ] bi ;
 629
 630 <PRIVATE
 631
 632 : move-backward ( shift from to seq -- )
 633     2over = [
 634         2drop 2drop
 635     ] [
 636         [ [ 2over + pick ] dip move [ 1 + ] dip ] keep
 637         move-backward
 638     ] if ;
 639
 640 : move-forward ( shift from to seq -- )
 641     2over = [
 642         2drop 2drop
 643     ] [
 644         [ [ pick [ dup dup ] dip + swap ] dip move 1 - ] keep
 645         move-forward
 646     ] if ;
 647
 648 : (open-slice) ( shift from to seq ? -- )
 649     [
 650         [ [ 1 - ] bi@ ] dip move-forward
 651     ] [
 652         [ over - ] 2dip move-backward
 653     ] if ;
 654
 655 : open-slice ( shift from seq -- )
 656     pick 0 = [
 657         3drop
 658     ] [
 659         pick over length + over
 660         [ pick 0 > [ [ length ] keep ] dip (open-slice) ] 2dip
 661         set-length
 662     ] if ;
 663
 664 PRIVATE>
 665
 666 : delete-slice ( from to seq -- )
 667     check-slice [ over [ - ] dip ] dip open-slice ;
 668
 669 : delete-nth ( n seq -- )
 670     [ dup 1 + ] dip delete-slice ;
 671
 672 : snip ( from to seq -- head tail )
 673     [ swap head ] [ swap tail ] bi-curry bi* ; inline
 674
 675 : snip-slice ( from to seq -- head tail )
 676     [ swap head-slice ] [ swap tail-slice ] bi-curry bi* ; inline
 677
 678 : replace-slice ( new from to seq -- seq' )
 679     snip-slice surround ;
 680
 681 : remove-nth ( n seq -- seq' )
 682     [ [ { } ] dip dup 1 + ] dip replace-slice ;
 683
 684 : pop ( seq -- elt )
 685     [ length 1 - ] [ [ nth ] [ shorten ] 2bi ] bi ;
 686
 687 : exchange ( m n seq -- )
 688     [ nip bounds-check 2drop ]
 689     [ bounds-check 3drop ]
 690     [ exchange-unsafe ]
 691     3tri ;
 692
 693 : reverse-here ( seq -- )
 694     [ length 2/ ] [ length ] [ ] tri
 695     [ [ over - 1 - ] dip exchange-unsafe ] 2curry each ;
 696
 697 : reverse ( seq -- newseq )
 698     [
 699         dup [ length ] keep new-sequence
 700         [ 0 swap copy ] keep
 701         [ reverse-here ] keep
 702     ] keep like ;
 703
 704 : sum-lengths ( seq -- n )
 705     0 [ length + ] reduce ;
 706
 707 : concat-as ( seq exemplar -- newseq )
 708     swap [ { } ] [
 709         [ sum-lengths over new-resizable ] keep
 710         [ over push-all ] each
 711     ] if-empty swap like ;
 712
 713 : concat ( seq -- newseq )
 714     [ { } ] [ dup first concat-as ] if-empty ;
 715
 716 <PRIVATE
 717
 718 : joined-length ( seq glue -- n )
 719     [ [ sum-lengths ] [ length 1 [-] ] bi ] dip length * + ;
 720
 721 PRIVATE>
 722
 723 : join ( seq glue -- newseq )
 724     dup empty? [ concat-as ] [
 725         [
 726             2dup joined-length over new-resizable [
 727                 [ [ push-all ] 2curry ] [ [ nip push-all ] 2curry ] 2bi
 728                 interleave
 729             ] keep
 730         ] keep like
 731     ] if ;
 732
 733 : padding ( seq n elt quot -- newseq )
 734     [
 735         [ over length [-] dup 0 = [ drop ] ] dip
 736         [ <repetition> ] curry
 737     ] dip compose if ; inline
 738
 739 : pad-head ( seq n elt -- padded )
 740     [ swap dup append-as ] padding ;
 741
 742 : pad-tail ( seq n elt -- padded )
 743     [ append ] padding ;
 744
 745 : shorter? ( seq1 seq2 -- ? ) [ length ] bi@ < ;
 746
 747 : head? ( seq begin -- ? )
 748     2dup shorter? [
 749         2drop f
 750     ] [
 751         [ nip ] [ length head-slice ] 2bi sequence=
 752     ] if ;
 753
 754 : tail? ( seq end -- ? )
 755     2dup shorter? [
 756         2drop f
 757     ] [
 758         [ nip ] [ length tail-slice* ] 2bi sequence=
 759     ] if ;
 760
 761 : cut-slice ( seq n -- before-slice after-slice )
 762     [ head-slice ] [ tail-slice ] 2bi ;
 763
 764 : insert-nth ( elt n seq -- seq' )
 765     swap cut-slice [ swap suffix ] dip append ;
 766
 767 : midpoint@ ( seq -- n ) length 2/ ; inline
 768
 769 : halves ( seq -- first-slice second-slice )
 770     dup midpoint@ cut-slice ;
 771
 772 : binary-reduce ( seq start quot: ( elt1 elt2 -- newelt ) -- value )
 773     #! We can't use case here since combinators depends on
 774     #! sequences
 775     pick length dup 0 3 between? [
 776         >fixnum {
 777             [ drop nip ]
 778             [ 2drop first ]
 779             [ [ drop first2 ] dip call ]
 780             [ [ drop first3 ] dip bi@ ]
 781         } dispatch
 782     ] [
 783         drop
 784         [ halves ] 2dip
 785         [ [ binary-reduce ] 2curry bi@ ] keep
 786         call
 787     ] if ; inline recursive
 788
 789 : cut ( seq n -- before after )
 790     [ head ] [ tail ] 2bi ;
 791
 792 : cut* ( seq n -- before after )
 793     [ head* ] [ tail* ] 2bi ;
 794
 795 <PRIVATE
 796
 797 : (start) ( subseq seq n -- subseq seq ? )
 798     pick length [
 799         [ 3dup ] dip [ + swap nth-unsafe ] keep rot nth-unsafe =
 800     ] all? nip ; inline
 801
 802 PRIVATE>
 803
 804 : start* ( subseq seq n -- i )
 805     pick length pick length swap - 1 +
 806     [ (start) ] find-from
 807     swap [ 3drop ] dip ;
 808
 809 : start ( subseq seq -- i ) 0 start* ; inline
 810
 811 : subseq? ( subseq seq -- ? ) start >boolean ;
 812
 813 : drop-prefix ( seq1 seq2 -- slice1 slice2 )
 814     2dup mismatch [ 2dup min-length ] unless*
 815     [ tail-slice ] curry bi@ ;
 816
 817 : unclip ( seq -- rest first )
 818     [ rest ] [ first-unsafe ] bi ;
 819
 820 : unclip-last ( seq -- butlast last )
 821     [ but-last ] [ peek ] bi ;
 822
 823 : unclip-slice ( seq -- rest-slice first )
 824     [ rest-slice ] [ first-unsafe ] bi ; inline
 825
 826 : 2unclip-slice ( seq1 seq2 -- rest-slice1 rest-slice2 first1 first2 )
 827     [ unclip-slice ] bi@ swapd ; inline
 828
 829 : map-reduce ( seq map-quot reduce-quot -- result )
 830     [ [ unclip-slice ] dip [ call ] keep ] dip
 831     compose reduce ; inline
 832
 833 : 2map-reduce ( seq1 seq2 map-quot reduce-quot -- result )
 834     [ [ 2unclip-slice ] dip [ call ] keep ] dip
 835     compose 2reduce ; inline
 836
 837 : map-find ( seq quot -- result elt )
 838     [ f ] 2dip
 839     [ [ nip ] dip call dup ] curry find
 840     [ [ drop f ] unless ] dip ; inline
 841
 842 : unclip-last-slice ( seq -- butlast-slice last )
 843     [ but-last-slice ] [ peek ] bi ; inline
 844
 845 : <flat-slice> ( seq -- slice )
 846     dup slice? [ { } like ] when
 847     [ drop 0 ] [ length ] [ ] tri <slice> ;
 848     inline
 849
 850 <PRIVATE
 851
 852 : (trim-head) ( seq quot -- seq n )
 853     over [ [ not ] compose find drop ] dip
 854     [ length or ] keep swap ; inline
 855
 856 : (trim-tail) ( seq quot -- seq n )
 857     over [ [ not ] compose find-last drop ?1+ ] dip
 858     swap ; inline
 859
 860 PRIVATE>
 861
 862 : trim-head-slice ( seq quot -- slice )
 863     (trim-head) tail-slice ; inline
 864
 865 : trim-head ( seq quot -- newseq )
 866     (trim-head) tail ; inline
 867
 868 : trim-tail-slice ( seq quot -- slice )
 869     (trim-tail) head-slice ; inline
 870
 871 : trim-tail ( seq quot -- newseq )
 872     (trim-tail) head ; inline
 873
 874 : trim-slice ( seq quot -- slice )
 875     [ trim-head-slice ] [ trim-tail-slice ] bi ; inline
 876
 877 : trim ( seq quot -- newseq )
 878     [ trim-slice ] [ drop ] 2bi like ; inline
 879
 880 : sum ( seq -- n ) 0 [ + ] binary-reduce ;
 881
 882 : product ( seq -- n ) 1 [ * ] binary-reduce ;
 883
 884 : infimum ( seq -- n ) [ ] [ min ] map-reduce ;
 885
 886 : supremum ( seq -- n ) [ ] [ max ] map-reduce ;
 887
 888 : sigma ( seq quot -- n )
 889     [ 0 ] 2dip [ dip + ] curry [ swap ] prepose each ; inline
 890
 891 : count ( seq quot -- n ) [ 1 0 ? ] compose sigma ; inline
 892
 893 ! We hand-optimize flip to such a degree because type hints
 894 ! cannot express that an array is an array of arrays yet, and
 895 ! this word happens to be performance-critical since the compiler
 896 ! itself uses it. Optimizing it like this reduced compile time.
 897 <PRIVATE
 898
 899 : generic-flip ( matrix -- newmatrix )
 900     [ dup first length [ length min ] reduce ] keep
 901     [ [ nth-unsafe ] with { } map-as ] curry { } map-as ; inline
 902
 903 USE: arrays
 904
 905 : array-length ( array -- len )
 906     { array } declare length>> ; inline
 907
 908 : array-flip ( matrix -- newmatrix )
 909     { array } declare
 910     [ dup first array-length [ array-length min ] reduce ] keep
 911     [ [ array-nth ] with { } map-as ] curry { } map-as ;
 912
 913 PRIVATE>
 914
 915 : flip ( matrix -- newmatrix )
 916     dup empty? [
 917         dup array? [
 918             dup [ array? ] all?
 919             [ array-flip ] [ generic-flip ] if
 920         ] [ generic-flip ] if
 921     ] unless ;
 922
 923 : reduce1 ( seq quot -- result ) [ unclip ] dip reduce ; inline
 924
 925 :: reduce-r
 926     ( list identity quot: ( obj1 obj2 -- obj ) -- result )
 927     list empty?
 928     [ identity ]
 929     [ list rest identity quot reduce-r list first quot call ] if ;
 930     inline recursive