core/sequences/sequences.factor

   1 ! Copyright (C) 2005, 2008 Slava Pestov, Daniel Ehrenberg.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors kernel kernel.private slots.private math
   4 math.private math.order ;
   5 IN: sequences
   6
   7 MIXIN: sequence
   8
   9 GENERIC: length ( seq -- n ) flushable
  10 GENERIC: set-length ( n seq -- )
  11 GENERIC: nth ( n seq -- elt ) flushable
  12 GENERIC: set-nth ( elt n seq -- )
  13 GENERIC: new-sequence ( len seq -- newseq ) flushable
  14 GENERIC: new-resizable ( len seq -- newseq ) flushable
  15 GENERIC: like ( seq exemplar -- newseq ) flushable
  16 GENERIC: clone-like ( seq exemplar -- newseq ) flushable
  17
  18 : new-like ( len exemplar quot -- seq )
  19     over >r >r new-sequence r> call r> like ; inline
  20
  21 M: sequence like drop ;
  22
  23 GENERIC: lengthen ( n seq -- )
  24 GENERIC: shorten ( n seq -- )
  25
  26 M: sequence lengthen 2dup length > [ set-length ] [ 2drop ] if ;
  27
  28 M: sequence shorten 2dup length < [ set-length ] [ 2drop ] if ;
  29
  30 : empty? ( seq -- ? ) length 0 = ; inline
  31
  32 : if-empty ( seq quot1 quot2 -- )
  33     [ dup empty? ] [ [ drop ] prepose ] [ ] tri* if ; inline
  34
  35 : when-empty ( seq quot -- ) [ ] if-empty ; inline
  36
  37 : unless-empty ( seq quot -- ) [ ] swap if-empty ; inline
  38
  39 : delete-all ( seq -- ) 0 swap set-length ;
  40
  41 : first ( seq -- first ) 0 swap nth ; inline
  42 : second ( seq -- second ) 1 swap nth ; inline
  43 : third ( seq -- third ) 2 swap nth ; inline
  44 : fourth ( seq -- fourth ) 3 swap nth ; inline
  45
  46 : set-first ( first seq -- ) 0 swap set-nth ; inline
  47 : set-second ( second seq -- ) 1 swap set-nth ; inline
  48 : set-third ( third seq -- ) 2 swap set-nth ; inline
  49 : set-fourth  ( fourth seq -- ) 3 swap set-nth ; inline
  50
  51 : push ( elt seq -- ) [ length ] [ set-nth ] bi ;
  52
  53 : bounds-check? ( n seq -- ? )
  54     dupd length < [ 0 >= ] [ drop f ] if ; inline
  55
  56 ERROR: bounds-error index seq ;
  57
  58 : bounds-check ( n seq -- n seq )
  59     2dup bounds-check? [ bounds-error ] unless ; inline
  60
  61 MIXIN: immutable-sequence
  62
  63 ERROR: immutable seq ;
  64
  65 M: immutable-sequence set-nth immutable ;
  66
  67 INSTANCE: immutable-sequence sequence
  68
  69 <PRIVATE
  70
  71 : array-nth ( n array -- elt )
  72     swap 2 fixnum+fast slot ; inline
  73
  74 : set-array-nth ( elt n array -- )
  75     swap 2 fixnum+fast set-slot ; inline
  76
  77 : dispatch ( n array -- ) array-nth call ;
  78
  79 GENERIC: resize ( n seq -- newseq ) flushable
  80
  81 ! Unsafe sequence protocol for inner loops
  82 GENERIC: nth-unsafe ( n seq -- elt ) flushable
  83 GENERIC: set-nth-unsafe ( elt n seq -- )
  84
  85 M: sequence nth bounds-check nth-unsafe ;
  86 M: sequence set-nth bounds-check set-nth-unsafe ;
  87
  88 M: sequence nth-unsafe nth ;
  89 M: sequence set-nth-unsafe set-nth ;
  90
  91 ! The f object supports the sequence protocol trivially
  92 M: f length drop 0 ;
  93 M: f nth-unsafe nip ;
  94 M: f like drop [ f ] when-empty ;
  95
  96 INSTANCE: f immutable-sequence
  97
  98 ! Integers support the sequence protocol
  99 M: integer length ;
 100 M: integer nth-unsafe drop ;
 101
 102 INSTANCE: integer immutable-sequence
 103
 104 : first2-unsafe
 105     [ 0 swap nth-unsafe 1 ] [ nth-unsafe ] bi ; inline
 106
 107 : first3-unsafe
 108     [ first2-unsafe 2 ] [ nth-unsafe ] bi ; inline
 109
 110 : first4-unsafe
 111     [ first3-unsafe 3 ] [ nth-unsafe ] bi ; inline
 112
 113 : exchange-unsafe ( m n seq -- )
 114     [ tuck nth-unsafe >r nth-unsafe r> ] 3keep tuck
 115     >r >r set-nth-unsafe r> r> set-nth-unsafe ; inline
 116
 117 : (head) ( seq n -- from to seq ) 0 spin ; inline
 118
 119 : (tail) ( seq n -- from to seq ) over length rot ; inline
 120
 121 : from-end >r dup length r> - ; inline
 122
 123 : (2sequence)
 124     tuck 1 swap set-nth-unsafe
 125     tuck 0 swap set-nth-unsafe ; inline
 126
 127 : (3sequence)
 128     tuck 2 swap set-nth-unsafe
 129     (2sequence) ; inline
 130
 131 : (4sequence)
 132     tuck 3 swap set-nth-unsafe
 133     (3sequence) ; inline
 134
 135 PRIVATE>
 136
 137 : 2sequence ( obj1 obj2 exemplar -- seq )
 138     2 swap [ (2sequence) ] new-like ; inline
 139
 140 : 3sequence ( obj1 obj2 obj3 exemplar -- seq )
 141     3 swap [ (3sequence) ] new-like ; inline
 142
 143 : 4sequence ( obj1 obj2 obj3 obj4 exemplar -- seq )
 144     4 swap [ (4sequence) ] new-like ; inline
 145
 146 : first2 ( seq -- first second )
 147     1 swap bounds-check nip first2-unsafe ; flushable
 148
 149 : first3 ( seq -- first second third )
 150     2 swap bounds-check nip first3-unsafe ; flushable
 151
 152 : first4 ( seq -- first second third fourth )
 153     3 swap bounds-check nip first4-unsafe ; flushable
 154
 155 : ?nth ( n seq -- elt/f )
 156     2dup bounds-check? [ nth-unsafe ] [ 2drop f ] if ; flushable
 157
 158 MIXIN: virtual-sequence
 159 GENERIC: virtual-seq ( seq -- seq' )
 160 GENERIC: virtual@ ( n seq -- n' seq' )
 161
 162 M: virtual-sequence nth virtual@ nth ;
 163 M: virtual-sequence set-nth virtual@ set-nth ;
 164 M: virtual-sequence nth-unsafe virtual@ nth-unsafe ;
 165 M: virtual-sequence set-nth-unsafe virtual@ set-nth-unsafe ;
 166 M: virtual-sequence like virtual-seq like ;
 167 M: virtual-sequence new-sequence virtual-seq new-sequence ;
 168
 169 INSTANCE: virtual-sequence sequence
 170
 171 ! A reversal of an underlying sequence.
 172 TUPLE: reversed { seq read-only } ;
 173
 174 C: <reversed> reversed
 175
 176 M: reversed virtual-seq seq>> ;
 177
 178 M: reversed virtual@ seq>> [ length swap - 1- ] keep ;
 179
 180 M: reversed length seq>> length ;
 181
 182 INSTANCE: reversed virtual-sequence
 183
 184 ! A slice of another sequence.
 185 TUPLE: slice
 186 { from read-only }
 187 { to read-only }
 188 { seq read-only } ;
 189
 190 : collapse-slice ( m n slice -- m' n' seq )
 191     [ from>> ] [ seq>> ] bi >r tuck + >r + r> r> ; inline
 192
 193 ERROR: slice-error reason ;
 194
 195 : check-slice ( from to seq -- from to seq )
 196     pick 0 < [ "start < 0" slice-error ] when
 197     dup length pick < [ "end > sequence" slice-error ] when
 198     2over > [ "start > end" slice-error ] when ; inline
 199
 200 : <slice> ( from to seq -- slice )
 201     dup slice? [ collapse-slice ] when
 202     check-slice
 203     slice boa ; inline
 204
 205 M: slice virtual-seq seq>> ;
 206
 207 M: slice virtual@ [ from>> + ] [ seq>> ] bi ;
 208
 209 M: slice length [ to>> ] [ from>> ] bi - ;
 210
 211 : short ( seq n -- seq n' ) over length min ; inline
 212
 213 : head-slice ( seq n -- slice ) (head) <slice> ; inline
 214
 215 : tail-slice ( seq n -- slice ) (tail) <slice> ; inline
 216
 217 : rest-slice ( seq -- slice ) 1 tail-slice ; inline
 218
 219 : head-slice* ( seq n -- slice ) from-end head-slice ; inline
 220
 221 : tail-slice* ( seq n -- slice ) from-end tail-slice ; inline
 222
 223 : but-last-slice ( seq -- slice ) 1 head-slice* ; inline
 224
 225 INSTANCE: slice virtual-sequence
 226
 227 ! One element repeated many times
 228 TUPLE: repetition { len read-only } { elt read-only } ;
 229
 230 C: <repetition> repetition
 231
 232 M: repetition length len>> ;
 233 M: repetition nth-unsafe nip elt>> ;
 234
 235 INSTANCE: repetition immutable-sequence
 236
 237 <PRIVATE
 238
 239 : check-length ( n -- n )
 240     #! Ricing.
 241     dup integer? [ "length not an integer" throw ] unless ; inline
 242
 243 : ((copy)) ( dst i src j n -- dst i src j n )
 244     dup -roll [
 245         + swap nth-unsafe -roll [
 246             + swap set-nth-unsafe
 247         ] 3keep drop
 248     ] 3keep ; inline
 249
 250 : (copy) ( dst i src j n -- dst )
 251     dup 0 <= [ 2drop 2drop ] [ 1- ((copy)) (copy) ] if ;
 252     inline recursive
 253
 254 : prepare-subseq ( from to seq -- dst i src j n )
 255     #! The check-length call forces partial dispatch
 256     [ >r swap - r> new-sequence dup 0 ] 3keep
 257     -rot drop roll length check-length ; inline
 258
 259 : check-copy ( src n dst -- )
 260     over 0 < [ bounds-error ] when
 261     >r swap length + r> lengthen ; inline
 262
 263 PRIVATE>
 264
 265 : subseq ( from to seq -- subseq )
 266     [ check-slice prepare-subseq (copy) ] [ like ] bi ;
 267
 268 : head ( seq n -- headseq ) (head) subseq ;
 269
 270 : tail ( seq n -- tailseq ) (tail) subseq ;
 271
 272 : rest ( seq -- tailseq ) 1 tail ;
 273
 274 : head* ( seq n -- headseq ) from-end head ;
 275
 276 : tail* ( seq n -- tailseq ) from-end tail ;
 277
 278 : but-last ( seq -- headseq ) 1 head* ;
 279
 280 : copy ( src i dst -- )
 281     #! The check-length call forces partial dispatch
 282     pick length check-length >r 3dup check-copy spin 0 r>
 283     (copy) drop ; inline
 284
 285 M: sequence clone-like
 286     >r dup length r> new-sequence [ 0 swap copy ] keep ;
 287
 288 M: immutable-sequence clone-like like ;
 289
 290 : push-all ( src dest -- ) [ length ] [ copy ] bi ;
 291
 292 <PRIVATE
 293
 294 : ((append)) ( seq1 seq2 accum -- accum )
 295     [ >r over length r> copy ]
 296     [ 0 swap copy ]
 297     [ ] tri ; inline
 298
 299 : (append) ( seq1 seq2 exemplar -- newseq )
 300     >r over length over length + r>
 301     [ ((append)) ] new-like ; inline
 302
 303 : (3append) ( seq1 seq2 seq3 exemplar -- newseq )
 304     >r pick length pick length pick length + + r> [
 305         [ >r pick length pick length + r> copy ]
 306         [ ((append)) ] bi
 307     ] new-like ; inline
 308
 309 PRIVATE>
 310
 311 : append ( seq1 seq2 -- newseq ) over (append) ;
 312
 313 : prepend ( seq1 seq2 -- newseq ) swap append ; inline
 314
 315 : 3append ( seq1 seq2 seq3 -- newseq ) pick (3append) ;
 316
 317 : change-nth ( i seq quot -- )
 318     [ >r nth r> call ] 3keep drop set-nth ; inline
 319
 320 : min-length ( seq1 seq2 -- n ) [ length ] bi@ min ; inline
 321
 322 : max-length ( seq1 seq2 -- n ) [ length ] bi@ max ; inline
 323
 324 <PRIVATE
 325
 326 : (each) ( seq quot -- n quot' )
 327     >r dup length swap [ nth-unsafe ] curry r> compose ; inline
 328
 329 : (collect) ( quot into -- quot' )
 330     [ >r keep r> set-nth-unsafe ] 2curry ; inline
 331
 332 : collect ( n quot into -- )
 333     (collect) each-integer ; inline
 334
 335 : map-into ( seq quot into -- )
 336     >r (each) r> collect ; inline
 337
 338 : 2nth-unsafe ( n seq1 seq2 -- elt1 elt2 )
 339     >r over r> nth-unsafe >r nth-unsafe r> ; inline
 340
 341 : (2each) ( seq1 seq2 quot -- n quot' )
 342     >r [ min-length ] 2keep r>
 343     [ >r 2nth-unsafe r> call ] 3curry ; inline
 344
 345 : 2map-into ( seq1 seq2 quot into -- newseq )
 346     >r (2each) r> collect ; inline
 347
 348 : finish-find ( i seq -- i elt )
 349     over [ dupd nth-unsafe ] [ drop f ] if ; inline
 350
 351 : (find) ( seq quot quot' -- i elt )
 352     pick >r >r (each) r> call r> finish-find ; inline
 353
 354 : (find-from) ( n seq quot quot' -- i elt )
 355     [ 2dup bounds-check? ] 2dip
 356     [ (find) ] 2curry
 357     [ 2drop f f ]
 358     if ; inline
 359
 360 : (monotonic) ( seq quot -- ? )
 361     [ 2dup nth-unsafe rot 1+ rot nth-unsafe ]
 362     prepose curry ; inline
 363
 364 : (interleave) ( n elt between quot -- )
 365     roll 0 = [ nip ] [ swapd 2slip ] if call ; inline
 366
 367 PRIVATE>
 368
 369 : each ( seq quot -- )
 370     (each) each-integer ; inline
 371
 372 : reduce ( seq identity quot -- result )
 373     swapd each ; inline
 374
 375 : map-as ( seq quot exemplar -- newseq )
 376     >r over length r> [ [ map-into ] keep ] new-like ; inline
 377
 378 : map ( seq quot -- newseq )
 379     over map-as ; inline
 380
 381 : replicate ( seq quot -- newseq )
 382     [ drop ] prepose map ; inline
 383
 384 : replicate-as ( seq quot exemplar -- newseq )
 385     >r [ drop ] prepose r> map-as ; inline
 386
 387 : change-each ( seq quot -- )
 388     over map-into ; inline
 389
 390 : accumulate ( seq identity quot -- final newseq )
 391     swapd [ pick slip ] curry map ; inline
 392
 393 : 2each ( seq1 seq2 quot -- )
 394     (2each) each-integer ; inline
 395
 396 : 2reverse-each ( seq1 seq2 quot -- )
 397     >r [ <reversed> ] bi@ r> 2each ; inline
 398
 399 : 2reduce ( seq1 seq2 identity quot -- result )
 400     >r -rot r> 2each ; inline
 401
 402 : 2map-as ( seq1 seq2 quot exemplar -- newseq )
 403     >r 2over min-length r>
 404     [ [ 2map-into ] keep ] new-like ; inline
 405
 406 : 2map ( seq1 seq2 quot -- newseq )
 407     pick 2map-as ; inline
 408
 409 : 2change-each ( seq1 seq2 quot -- )
 410     pick 2map-into ; inline
 411
 412 : 2all? ( seq1 seq2 quot -- ? )
 413     (2each) all-integers? ; inline
 414
 415 : find-from ( n seq quot -- i elt )
 416     [ (find-integer) ] (find-from) ; inline
 417
 418 : find ( seq quot -- i elt )
 419     [ find-integer ] (find) ; inline
 420
 421 : find-last-from ( n seq quot -- i elt )
 422     [ nip find-last-integer ] (find-from) ; inline
 423
 424 : find-last ( seq quot -- i elt )
 425     [ >r 1- r> find-last-integer ] (find) ; inline
 426
 427 : all? ( seq quot -- ? )
 428     (each) all-integers? ; inline
 429
 430 : push-if ( elt quot accum -- )
 431     >r keep r> rot [ push ] [ 2drop ] if  ; inline
 432
 433 : pusher ( quot -- quot accum )
 434     V{ } clone [ [ push-if ] 2curry ] keep ; inline
 435
 436 : filter ( seq quot -- subseq )
 437     over >r pusher >r each r> r> like ; inline
 438
 439 : push-either ( elt quot accum1 accum2 -- )
 440     >r >r keep swap r> r> ? push ; inline
 441
 442 : 2pusher ( quot -- quot accum1 accum2 )
 443     V{ } clone V{ } clone [ [ push-either ] 3curry ] 2keep ; inline
 444
 445 : partition ( seq quot -- trueseq falseseq )
 446     over >r 2pusher >r >r each r> r> r> tuck [ like ] 2bi@ ; inline
 447
 448 : monotonic? ( seq quot -- ? )
 449     >r dup length 1- swap r> (monotonic) all? ; inline
 450
 451 : interleave ( seq between quot -- )
 452     [ (interleave) ] 2curry >r dup length swap r> 2each ; inline
 453
 454 : accumulator ( quot -- quot' vec )
 455     V{ } clone [ [ push ] curry compose ] keep ; inline
 456
 457 : produce-as ( pred quot tail exemplar -- seq )
 458     >r swap accumulator >r swap while r> r> like ; inline
 459
 460 : produce ( pred quot tail -- seq )
 461     { } produce-as ; inline
 462
 463 : follow ( obj quot -- seq )
 464     >r [ dup ] r> [ keep ] curry [ ] produce nip ; inline
 465
 466 : prepare-index ( seq quot -- seq n quot )
 467     >r dup length r> ; inline
 468
 469 : each-index ( seq quot -- )
 470     prepare-index 2each ; inline
 471
 472 : map-index ( seq quot -- )
 473     prepare-index 2map ; inline
 474
 475 : reduce-index ( seq identity quot -- )
 476     swapd each-index ; inline
 477
 478 : index ( obj seq -- n )
 479     [ = ] with find drop ;
 480
 481 : index-from ( obj i seq -- n )
 482     rot [ = ] curry find-from drop ;
 483
 484 : last-index ( obj seq -- n )
 485     [ = ] with find-last drop ;
 486
 487 : last-index-from ( obj i seq -- n )
 488     rot [ = ] curry find-last-from drop ;
 489
 490 : indices ( obj seq -- indices )
 491     V{ } clone spin
 492     [ rot = [ over push ] [ drop ] if ]
 493     curry each-index ;
 494
 495 : nths ( indices seq -- seq' )
 496     [ nth ] curry map ;
 497
 498 : contains? ( seq quot -- ? )
 499     find drop >boolean ; inline
 500
 501 : member? ( obj seq -- ? )
 502     [ = ] with contains? ;
 503
 504 : memq? ( obj seq -- ? )
 505     [ eq? ] with contains? ;
 506
 507 : remove ( obj seq -- newseq )
 508     [ = not ] with filter ;
 509
 510 : sift ( seq -- newseq )
 511     [ ] filter ;
 512
 513 : harvest ( seq -- newseq )
 514     [ empty? not ] filter ;
 515
 516 : cache-nth ( i seq quot -- elt )
 517     2over ?nth dup [
 518         >r 3drop r>
 519     ] [
 520         drop swap >r over >r call dup r> r> set-nth
 521     ] if ; inline
 522
 523 : mismatch ( seq1 seq2 -- i )
 524     [ min-length ] 2keep
 525     [ 2nth-unsafe = not ] 2curry
 526     find drop ; inline
 527
 528 M: sequence <=>
 529     2dup mismatch
 530     [ -rot 2nth-unsafe <=> ] [ [ length ] compare ] if* ;
 531
 532 : sequence= ( seq1 seq2 -- ? )
 533     2dup [ length ] bi@ =
 534     [ mismatch not ] [ 2drop f ] if ; inline
 535
 536 : sequence-hashcode-step ( oldhash newpart -- newhash )
 537     >fixnum swap [
 538         dup -2 fixnum-shift-fast swap 5 fixnum-shift-fast
 539         fixnum+fast fixnum+fast
 540     ] keep fixnum-bitxor ; inline
 541
 542 : sequence-hashcode ( n seq -- x )
 543     0 -rot [ hashcode* sequence-hashcode-step ] with each ; inline
 544
 545 M: reversed equal? over reversed? [ sequence= ] [ 2drop f ] if ;
 546
 547 M: slice equal? over slice? [ sequence= ] [ 2drop f ] if ;
 548
 549 : move ( to from seq -- )
 550     2over =
 551     [ 3drop ] [ [ nth swap ] [ set-nth ] bi ] if ; inline
 552
 553 <PRIVATE
 554
 555 : (delete) ( elt store scan seq -- elt store scan seq )
 556     2dup length < [
 557         3dup move
 558         [ nth pick = ] 2keep rot
 559         [ >r >r 1+ r> r> ] unless >r 1+ r> (delete)
 560     ] when ;
 561
 562 PRIVATE>
 563
 564 : delete ( elt seq -- ) 0 0 rot (delete) nip set-length drop ;
 565
 566 : prefix ( seq elt -- newseq )
 567     over >r over length 1+ r> [
 568         [ 0 swap set-nth-unsafe ] keep
 569         [ 1 swap copy ] keep
 570     ] new-like ;
 571
 572 : suffix ( seq elt -- newseq )
 573     over >r over length 1+ r> [
 574         [ >r over length r> set-nth-unsafe ] keep
 575         [ 0 swap copy ] keep
 576     ] new-like ;
 577
 578 : peek ( seq -- elt ) [ length 1- ] [ nth ] bi ;
 579
 580 : pop* ( seq -- ) [ length 1- ] [ shorten ] bi ;
 581
 582 <PRIVATE
 583
 584 : move-backward ( shift from to seq -- )
 585     2over = [
 586         2drop 2drop
 587     ] [
 588         [ >r 2over + pick r> move >r 1+ r> ] keep
 589         move-backward
 590     ] if ;
 591
 592 : move-forward ( shift from to seq -- )
 593     2over = [
 594         2drop 2drop
 595     ] [
 596         [ >r pick >r dup dup r> + swap r> move 1- ] keep
 597         move-forward
 598     ] if ;
 599
 600 : (open-slice) ( shift from to seq ? -- )
 601     [
 602         >r [ 1- ] bi@ r> move-forward
 603     ] [
 604         >r >r over - r> r> move-backward
 605     ] if ;
 606
 607 PRIVATE>
 608
 609 : open-slice ( shift from seq -- )
 610     pick 0 = [
 611         3drop
 612     ] [
 613         pick over length + over >r >r
 614         pick 0 > >r [ length ] keep r> (open-slice)
 615         r> r> set-length
 616     ] if ;
 617
 618 : delete-slice ( from to seq -- )
 619     check-slice >r over >r - r> r> open-slice ;
 620
 621 : delete-nth ( n seq -- )
 622     >r dup 1+ r> delete-slice ;
 623
 624 : replace-slice ( new from to seq -- )
 625     [ >r >r dup pick length + r> - over r> open-slice ] keep
 626     copy ;
 627
 628 : remove-nth ( n seq -- seq' )
 629     [ swap head-slice ] [ swap 1+ tail-slice ] 2bi append ;
 630
 631 : pop ( seq -- elt )
 632     [ length 1- ] [ [ nth ] [ shorten ] 2bi ] bi ;
 633
 634 : all-equal? ( seq -- ? ) [ = ] monotonic? ;
 635
 636 : all-eq? ( seq -- ? ) [ eq? ] monotonic? ;
 637
 638 : exchange ( m n seq -- )
 639     pick over bounds-check 2drop 2dup bounds-check 2drop
 640     exchange-unsafe ;
 641
 642 : reverse-here ( seq -- )
 643     dup length dup 2/ [
 644         >r 2dup r>
 645         tuck - 1- rot exchange-unsafe
 646     ] each 2drop ;
 647
 648 : reverse ( seq -- newseq )
 649     [
 650         dup [ length ] keep new-sequence
 651         [ 0 swap copy ] keep
 652         [ reverse-here ] keep
 653     ] keep like ;
 654
 655 : sum-lengths ( seq -- n )
 656     0 [ length + ] reduce ;
 657
 658 : concat ( seq -- newseq )
 659     [
 660         { }
 661     ] [
 662         [ sum-lengths ] keep
 663         [ first new-resizable ] keep
 664         [ [ over push-all ] each ] keep
 665         first like
 666     ] if-empty ;
 667
 668 <PRIVATE
 669
 670 : joined-length ( seq glue -- n )
 671     >r dup sum-lengths swap length 1 [-] r> length * + ;
 672
 673 PRIVATE>
 674
 675 : join ( seq glue -- newseq )
 676     [
 677         2dup joined-length over new-resizable spin
 678         [ dup pick push-all ] [ pick push-all ] interleave drop
 679     ] keep like ;
 680
 681 : padding ( seq n elt quot -- newseq )
 682     [
 683         [ over length [-] dup 0 = [ drop ] ] dip
 684         [ <repetition> ] curry
 685     ] dip compose if ; inline
 686
 687 : pad-left ( seq n elt -- padded )
 688     [ swap dup (append) ] padding ;
 689
 690 : pad-right ( seq n elt -- padded )
 691     [ append ] padding ;
 692
 693 : shorter? ( seq1 seq2 -- ? ) [ length ] bi@ < ;
 694
 695 : head? ( seq begin -- ? )
 696     2dup shorter? [
 697         2drop f
 698     ] [
 699         tuck length head-slice sequence=
 700     ] if ;
 701
 702 : tail? ( seq end -- ? )
 703     2dup shorter? [
 704         2drop f
 705     ] [
 706         tuck length tail-slice* sequence=
 707     ] if ;
 708
 709 : cut-slice ( seq n -- before-slice after-slice )
 710     [ head-slice ] [ tail-slice ] 2bi ;
 711
 712 : insert-nth ( elt n seq -- seq' )
 713     swap cut-slice [ swap suffix ] dip append ;
 714
 715 : midpoint@ ( seq -- n ) length 2/ ; inline
 716
 717 : halves ( seq -- first-slice second-slice )
 718     dup midpoint@ cut-slice ;
 719
 720 : binary-reduce ( seq start quot: ( elt1 elt2 -- newelt ) -- value )
 721     #! We can't use case here since combinators depends on
 722     #! sequences
 723     pick length dup 0 3 between? [
 724         >fixnum {
 725             [ drop nip ]
 726             [ 2drop first ]
 727             [ >r drop first2 r> call ]
 728             [ >r drop first3 r> bi@ ]
 729         } dispatch
 730     ] [
 731         drop
 732         >r >r halves r> r>
 733         [ [ binary-reduce ] 2curry bi@ ] keep
 734         call
 735     ] if ; inline recursive
 736
 737 : cut ( seq n -- before after )
 738     [ head ] [ tail ] 2bi ;
 739
 740 : cut* ( seq n -- before after )
 741     [ head* ] [ tail* ] 2bi ;
 742
 743 <PRIVATE
 744
 745 : (start) ( subseq seq n -- subseq seq ? )
 746     pick length [
 747         >r 3dup r> [ + swap nth-unsafe ] keep rot nth-unsafe =
 748     ] all? nip ; inline
 749
 750 PRIVATE>
 751
 752 : start* ( subseq seq n -- i )
 753     pick length pick length swap - 1+
 754     [ (start) ] find-from
 755     swap >r 3drop r> ;
 756
 757 : start ( subseq seq -- i ) 0 start* ; inline
 758
 759 : subseq? ( subseq seq -- ? ) start >boolean ;
 760
 761 : drop-prefix ( seq1 seq2 -- slice1 slice2 )
 762     2dup mismatch [ 2dup min-length ] unless*
 763     tuck tail-slice >r tail-slice r> ;
 764
 765 : unclip ( seq -- rest first )
 766     [ rest ] [ first ] bi ;
 767
 768 : unclip-last ( seq -- butlast last )
 769     [ but-last ] [ peek ] bi ;
 770
 771 : unclip-slice ( seq -- rest-slice first )
 772     [ rest-slice ] [ first ] bi ; inline
 773
 774 : 2unclip-slice ( seq1 seq2 -- rest-slice1 rest-slice2 first1 first2 )
 775     [ unclip-slice ] bi@ swapd ; inline
 776
 777 : map-reduce ( seq map-quot reduce-quot -- result )
 778     [ [ unclip-slice ] dip [ call ] keep ] dip
 779     compose reduce ; inline
 780
 781 : 2map-reduce ( seq1 seq2 map-quot reduce-quot -- result )
 782     [ [ 2unclip-slice ] dip [ call ] keep ] dip
 783     compose 2reduce ; inline
 784
 785 : unclip-last-slice ( seq -- butlast-slice last )
 786     [ but-last-slice ] [ peek ] bi ; inline
 787
 788 : <flat-slice> ( seq -- slice )
 789     dup slice? [ { } like ] when 0 over length rot <slice> ;
 790     inline
 791
 792 : trim-left-slice ( seq quot -- slice )
 793     over >r [ not ] compose find drop r> swap
 794     [ tail-slice ] [ dup length tail-slice ] if* ; inline
 795
 796 : trim-left ( seq quot -- newseq )
 797     over [ trim-left-slice ] dip like ; inline
 798
 799 : trim-right-slice ( seq quot -- slice )
 800     over >r [ not ] compose find-last drop r> swap
 801     [ 1+ head-slice ] [ 0 head-slice ] if* ; inline
 802
 803 : trim-right ( seq quot -- newseq )
 804     over [ trim-right-slice ] dip like ; inline
 805
 806 : trim-slice ( seq quot -- slice )
 807     [ trim-left-slice ] [ trim-right-slice ] bi ; inline
 808
 809 : trim ( seq quot -- newseq )
 810     over [ trim-slice ] dip like ; inline
 811
 812 : sum ( seq -- n ) 0 [ + ] binary-reduce ;
 813
 814 : product ( seq -- n ) 1 [ * ] binary-reduce ;
 815
 816 : infimum ( seq -- n ) dup first [ min ] reduce ;
 817
 818 : supremum ( seq -- n ) dup first [ max ] reduce ;
 819
 820 : flip ( matrix -- newmatrix )
 821     dup empty? [
 822         dup [ length ] map infimum
 823         swap [ [ nth-unsafe ] with { } map-as ] curry { } map-as
 824     ] unless ;
 825
 826 : sigma ( seq quot -- n ) [ + ] compose 0 swap reduce ; inline
 827
 828 : count ( seq quot -- n ) [ 1 0 ? ] compose sigma ; inline