core/sequences/sequences.factor

   1 ! Copyright (C) 2005, 2008 Slava Pestov, Daniel Ehrenberg.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors kernel kernel.private slots.private math
   4 math.private math.order ;
   5 IN: sequences
   6
   7 MIXIN: sequence
   8
   9 GENERIC: length ( seq -- n ) flushable
  10 GENERIC: set-length ( n seq -- )
  11 GENERIC: nth ( n seq -- elt ) flushable
  12 GENERIC: set-nth ( elt n seq -- )
  13 GENERIC: new-sequence ( len seq -- newseq ) flushable
  14 GENERIC: new-resizable ( len seq -- newseq ) flushable
  15 GENERIC: like ( seq exemplar -- newseq ) flushable
  16 GENERIC: clone-like ( seq exemplar -- newseq ) flushable
  17
  18 : new-like ( len exemplar quot -- seq )
  19     over >r >r new-sequence r> call r> like ; inline
  20
  21 M: sequence like drop ;
  22
  23 GENERIC: lengthen ( n seq -- )
  24 GENERIC: shorten ( n seq -- )
  25
  26 M: sequence lengthen 2dup length > [ set-length ] [ 2drop ] if ;
  27
  28 M: sequence shorten 2dup length < [ set-length ] [ 2drop ] if ;
  29
  30 : empty? ( seq -- ? ) length zero? ; inline
  31 : delete-all ( seq -- ) 0 swap set-length ;
  32
  33 : first ( seq -- first ) 0 swap nth ; inline
  34 : second ( seq -- second ) 1 swap nth ; inline
  35 : third ( seq -- third ) 2 swap nth ; inline
  36 : fourth ( seq -- fourth ) 3 swap nth ; inline
  37
  38 : set-first ( first seq -- ) 0 swap set-nth ; inline
  39 : set-second ( second seq -- ) 1 swap set-nth ; inline
  40 : set-third ( third seq -- ) 2 swap set-nth ; inline
  41 : set-fourth  ( fourth seq -- ) 3 swap set-nth ; inline
  42
  43 : push ( elt seq -- ) [ length ] [ set-nth ] bi ;
  44
  45 : bounds-check? ( n seq -- ? )
  46     length 1- 0 swap between? ; inline
  47
  48 ERROR: bounds-error index seq ;
  49
  50 : bounds-check ( n seq -- n seq )
  51     2dup bounds-check? [ bounds-error ] unless ; inline
  52
  53 MIXIN: immutable-sequence
  54
  55 ERROR: immutable seq ;
  56
  57 M: immutable-sequence set-nth immutable ;
  58
  59 INSTANCE: immutable-sequence sequence
  60
  61 <PRIVATE
  62
  63 : array-nth ( n array -- elt )
  64     swap 2 fixnum+fast slot ; inline
  65
  66 : set-array-nth ( elt n array -- )
  67     swap 2 fixnum+fast set-slot ; inline
  68
  69 : dispatch ( n array -- ) array-nth (call) ;
  70
  71 GENERIC: resize ( n seq -- newseq ) flushable
  72
  73 ! Unsafe sequence protocol for inner loops
  74 GENERIC: nth-unsafe ( n seq -- elt ) flushable
  75 GENERIC: set-nth-unsafe ( elt n seq -- )
  76
  77 M: sequence nth bounds-check nth-unsafe ;
  78 M: sequence set-nth bounds-check set-nth-unsafe ;
  79
  80 M: sequence nth-unsafe nth ;
  81 M: sequence set-nth-unsafe set-nth ;
  82
  83 ! The f object supports the sequence protocol trivially
  84 M: f length drop 0 ;
  85 M: f nth-unsafe nip ;
  86 M: f like drop dup empty? [ drop f ] when ;
  87
  88 INSTANCE: f immutable-sequence
  89
  90 ! Integers support the sequence protocol
  91 M: integer length ;
  92 M: integer nth-unsafe drop ;
  93
  94 INSTANCE: integer immutable-sequence
  95
  96 : first2-unsafe
  97     [ 0 swap nth-unsafe 1 ] [ nth-unsafe ] bi ; inline
  98
  99 : first3-unsafe
 100     [ first2-unsafe 2 ] [ nth-unsafe ] bi ; inline
 101
 102 : first4-unsafe
 103     [ first3-unsafe 3 ] [ nth-unsafe ] bi ; inline
 104
 105 : exchange-unsafe ( m n seq -- )
 106     [ tuck nth-unsafe >r nth-unsafe r> ] 3keep tuck
 107     >r >r set-nth-unsafe r> r> set-nth-unsafe ; inline
 108
 109 : (head) ( seq n -- from to seq ) 0 spin ; inline
 110
 111 : (tail) ( seq n -- from to seq ) over length rot ; inline
 112
 113 : from-end >r dup length r> - ; inline
 114
 115 : (2sequence)
 116     tuck 1 swap set-nth-unsafe
 117     tuck 0 swap set-nth-unsafe ; inline
 118
 119 : (3sequence)
 120     tuck 2 swap set-nth-unsafe
 121     (2sequence) ; inline
 122
 123 : (4sequence)
 124     tuck 3 swap set-nth-unsafe
 125     (3sequence) ; inline
 126
 127 PRIVATE>
 128
 129 : 2sequence ( obj1 obj2 exemplar -- seq )
 130     2 swap [ (2sequence) ] new-like ; inline
 131
 132 : 3sequence ( obj1 obj2 obj3 exemplar -- seq )
 133     3 swap [ (3sequence) ] new-like ; inline
 134
 135 : 4sequence ( obj1 obj2 obj3 obj4 exemplar -- seq )
 136     4 swap [ (4sequence) ] new-like ; inline
 137
 138 : first2 ( seq -- first second )
 139     1 swap bounds-check nip first2-unsafe ; flushable
 140
 141 : first3 ( seq -- first second third )
 142     2 swap bounds-check nip first3-unsafe ; flushable
 143
 144 : first4 ( seq -- first second third fourth )
 145     3 swap bounds-check nip first4-unsafe ; flushable
 146
 147 : ?nth ( n seq -- elt/f )
 148     2dup bounds-check? [ nth-unsafe ] [ 2drop f ] if ; flushable
 149
 150 MIXIN: virtual-sequence
 151 GENERIC: virtual-seq ( seq -- seq' )
 152 GENERIC: virtual@ ( n seq -- n' seq' )
 153
 154 M: virtual-sequence nth virtual@ nth ;
 155 M: virtual-sequence set-nth virtual@ set-nth ;
 156 M: virtual-sequence nth-unsafe virtual@ nth-unsafe ;
 157 M: virtual-sequence set-nth-unsafe virtual@ set-nth-unsafe ;
 158 M: virtual-sequence like virtual-seq like ;
 159 M: virtual-sequence new-sequence virtual-seq new-sequence ;
 160
 161 INSTANCE: virtual-sequence sequence
 162
 163 ! A reversal of an underlying sequence.
 164 TUPLE: reversed { seq read-only } ;
 165
 166 C: <reversed> reversed
 167
 168 M: reversed virtual-seq seq>> ;
 169
 170 M: reversed virtual@ seq>> [ length swap - 1- ] keep ;
 171
 172 M: reversed length seq>> length ;
 173
 174 INSTANCE: reversed virtual-sequence
 175
 176 ! A slice of another sequence.
 177 TUPLE: slice
 178 { from read-only }
 179 { to read-only }
 180 { seq read-only } ;
 181
 182 : collapse-slice ( m n slice -- m' n' seq )
 183     [ from>> ] [ seq>> ] bi >r tuck + >r + r> r> ; inline
 184
 185 ERROR: slice-error reason ;
 186
 187 : check-slice ( from to seq -- from to seq )
 188     pick 0 < [ "start < 0" slice-error ] when
 189     dup length pick < [ "end > sequence" slice-error ] when
 190     2over > [ "start > end" slice-error ] when ; inline
 191
 192 : <slice> ( from to seq -- slice )
 193     dup slice? [ collapse-slice ] when
 194     check-slice
 195     slice boa ; inline
 196
 197 M: slice virtual-seq seq>> ;
 198
 199 M: slice virtual@ [ from>> + ] [ seq>> ] bi ;
 200
 201 M: slice length [ to>> ] [ from>> ] bi - ;
 202
 203 : short ( seq n -- seq n' ) over length min ; inline
 204
 205 : head-slice ( seq n -- slice ) (head) <slice> ; inline
 206
 207 : tail-slice ( seq n -- slice ) (tail) <slice> ; inline
 208
 209 : rest-slice ( seq -- slice ) 1 tail-slice ; inline
 210
 211 : head-slice* ( seq n -- slice ) from-end head-slice ; inline
 212
 213 : tail-slice* ( seq n -- slice ) from-end tail-slice ; inline
 214
 215 : but-last-slice ( seq -- slice ) 1 head-slice* ; inline
 216
 217 INSTANCE: slice virtual-sequence
 218
 219 ! One element repeated many times
 220 TUPLE: repetition { len read-only } { elt read-only } ;
 221
 222 C: <repetition> repetition
 223
 224 M: repetition length len>> ;
 225 M: repetition nth-unsafe nip elt>> ;
 226
 227 INSTANCE: repetition immutable-sequence
 228
 229 <PRIVATE
 230
 231 : ((copy)) ( dst i src j n -- dst i src j n )
 232     dup -roll [
 233         + swap nth-unsafe -roll [
 234             + swap set-nth-unsafe
 235         ] 3keep drop
 236     ] 3keep ; inline
 237
 238 : (copy) ( dst i src j n -- dst )
 239     dup 0 <= [ 2drop 2drop ] [ 1- ((copy)) (copy) ] if ;
 240     inline recursive
 241
 242 : prepare-subseq ( from to seq -- dst i src j n )
 243     [ >r swap - r> new-sequence dup 0 ] 3keep
 244     -rot drop roll length ; inline
 245
 246 : check-copy ( src n dst -- )
 247     over 0 < [ bounds-error ] when
 248     >r swap length + r> lengthen ; inline
 249
 250 PRIVATE>
 251
 252 : subseq ( from to seq -- subseq )
 253     [ check-slice prepare-subseq (copy) ] [ like ] bi ;
 254
 255 : head ( seq n -- headseq ) (head) subseq ;
 256
 257 : tail ( seq n -- tailseq ) (tail) subseq ;
 258
 259 : rest ( seq -- tailseq ) 1 tail ;
 260
 261 : head* ( seq n -- headseq ) from-end head ;
 262
 263 : tail* ( seq n -- tailseq ) from-end tail ;
 264
 265 : but-last ( seq -- headseq ) 1 head* ;
 266
 267 : copy ( src i dst -- )
 268     pick length >r 3dup check-copy spin 0 r>
 269     (copy) drop ; inline
 270
 271 M: sequence clone-like
 272     >r dup length r> new-sequence [ 0 swap copy ] keep ;
 273
 274 M: immutable-sequence clone-like like ;
 275
 276 : push-all ( src dest -- ) [ length ] [ copy ] bi ;
 277
 278 : ((append)) ( seq1 seq2 accum -- accum )
 279     [ >r over length r> copy ]
 280     [ 0 swap copy ]
 281     [ ] tri ; inline
 282
 283 : (append) ( seq1 seq2 exemplar -- newseq )
 284     >r over length over length + r>
 285     [ ((append)) ] new-like ; inline
 286
 287 : (3append) ( seq1 seq2 seq3 exemplar -- newseq )
 288     >r pick length pick length pick length + + r> [
 289         [ >r pick length pick length + r> copy ]
 290         [ ((append)) ] bi
 291     ] new-like ; inline
 292
 293 : append ( seq1 seq2 -- newseq ) over (append) ;
 294
 295 : prepend ( seq1 seq2 -- newseq ) swap append ; inline
 296
 297 : 3append ( seq1 seq2 seq3 -- newseq ) pick (3append) ;
 298
 299 : change-nth ( i seq quot -- )
 300     [ >r nth r> call ] 3keep drop set-nth ; inline
 301
 302 : min-length ( seq1 seq2 -- n ) [ length ] bi@ min ; inline
 303
 304 : max-length ( seq1 seq2 -- n ) [ length ] bi@ max ; inline
 305
 306 <PRIVATE
 307
 308 : (each) ( seq quot -- n quot' )
 309     >r dup length swap [ nth-unsafe ] curry r> compose ; inline
 310
 311 : (collect) ( quot into -- quot' )
 312     [ >r keep r> set-nth-unsafe ] 2curry ; inline
 313
 314 : collect ( n quot into -- )
 315     (collect) each-integer ; inline
 316
 317 : map-into ( seq quot into -- )
 318     >r (each) r> collect ; inline
 319
 320 : 2nth-unsafe ( n seq1 seq2 -- elt1 elt2 )
 321     >r over r> nth-unsafe >r nth-unsafe r> ; inline
 322
 323 : (2each) ( seq1 seq2 quot -- n quot' )
 324     >r [ min-length ] 2keep r>
 325     [ >r 2nth-unsafe r> call ] 3curry ; inline
 326
 327 : 2map-into ( seq1 seq2 quot into -- newseq )
 328     >r (2each) r> collect ; inline
 329
 330 : finish-find ( i seq -- i elt )
 331     over [ dupd nth-unsafe ] [ drop f ] if ; inline
 332
 333 : (find) ( seq quot quot' -- i elt )
 334     pick >r >r (each) r> call r> finish-find ; inline
 335
 336 : (find-from) ( n seq quot quot' -- i elt )
 337     [ 2dup bounds-check? ] 2dip
 338     [ (find) ] 2curry
 339     [ 2drop f f ]
 340     if ; inline
 341
 342 : (monotonic) ( seq quot -- ? )
 343     [ 2dup nth-unsafe rot 1+ rot nth-unsafe ]
 344     prepose curry ; inline
 345
 346 : (interleave) ( n elt between quot -- )
 347     roll zero? [ nip ] [ swapd 2slip ] if call ; inline
 348
 349 PRIVATE>
 350
 351 : each ( seq quot -- )
 352     (each) each-integer ; inline
 353
 354 : reduce ( seq identity quot -- result )
 355     swapd each ; inline
 356
 357 : map-as ( seq quot exemplar -- newseq )
 358     >r over length r> [ [ map-into ] keep ] new-like ; inline
 359
 360 : map ( seq quot -- newseq )
 361     over map-as ; inline
 362
 363 : replicate ( seq quot -- newseq )
 364     [ drop ] prepose map ; inline
 365
 366 : replicate-as ( seq quot exemplar -- newseq )
 367     >r [ drop ] prepose r> map-as ; inline
 368
 369 : change-each ( seq quot -- )
 370     over map-into ; inline
 371
 372 : accumulate ( seq identity quot -- final newseq )
 373     swapd [ pick slip ] curry map ; inline
 374
 375 : 2each ( seq1 seq2 quot -- )
 376     (2each) each-integer ; inline
 377
 378 : 2reverse-each ( seq1 seq2 quot -- )
 379     >r [ <reversed> ] bi@ r> 2each ; inline
 380
 381 : 2reduce ( seq1 seq2 identity quot -- result )
 382     >r -rot r> 2each ; inline
 383
 384 : 2map-as ( seq1 seq2 quot exemplar -- newseq )
 385     >r 2over min-length r>
 386     [ [ 2map-into ] keep ] new-like ; inline
 387
 388 : 2map ( seq1 seq2 quot -- newseq )
 389     pick 2map-as ; inline
 390
 391 : 2change-each ( seq1 seq2 quot -- newseq )
 392     pick 2map-into ; inline
 393
 394 : 2all? ( seq1 seq2 quot -- ? )
 395     (2each) all-integers? ; inline
 396
 397 : find-from ( n seq quot -- i elt )
 398     [ (find-integer) ] (find-from) ; inline
 399
 400 : find ( seq quot -- i elt )
 401     [ find-integer ] (find) ; inline
 402
 403 : find-last-from ( n seq quot -- i elt )
 404     [ nip find-last-integer ] (find-from) ; inline
 405
 406 : find-last ( seq quot -- i elt )
 407     [ >r 1- r> find-last-integer ] (find) ; inline
 408
 409 : all? ( seq quot -- ? )
 410     (each) all-integers? ; inline
 411
 412 : push-if ( elt quot accum -- )
 413     >r keep r> rot [ push ] [ 2drop ] if  ; inline
 414
 415 : pusher ( quot -- quot accum )
 416     V{ } clone [ [ push-if ] 2curry ] keep ; inline
 417
 418 : filter ( seq quot -- subseq )
 419     over >r pusher >r each r> r> like ; inline
 420
 421 : monotonic? ( seq quot -- ? )
 422     >r dup length 1- swap r> (monotonic) all? ; inline
 423
 424 : interleave ( seq between quot -- )
 425     [ (interleave) ] 2curry >r dup length swap r> 2each ; inline
 426
 427 : accumulator ( quot -- quot' vec )
 428     V{ } clone [ [ push ] curry compose ] keep ; inline
 429
 430 : produce ( pred quot tail -- seq )
 431     swap accumulator >r swap while r> { } like ; inline
 432
 433 : follow ( obj quot -- seq )
 434     >r [ dup ] r> [ keep ] curry [ ] produce nip ; inline
 435
 436 : prepare-index ( seq quot -- seq n quot )
 437     >r dup length r> ; inline
 438
 439 : each-index ( seq quot -- )
 440     prepare-index 2each ; inline
 441
 442 : map-index ( seq quot -- )
 443     prepare-index 2map ; inline
 444
 445 : reduce-index ( seq identity quot -- )
 446     swapd each-index ; inline
 447
 448 : index ( obj seq -- n )
 449     [ = ] with find drop ;
 450
 451 : index-from ( obj i seq -- n )
 452     rot [ = ] curry find-from drop ;
 453
 454 : last-index ( obj seq -- n )
 455     [ = ] with find-last drop ;
 456
 457 : last-index-from ( obj i seq -- n )
 458     rot [ = ] curry find-last-from drop ;
 459
 460 : nths ( seq indices -- seq' )
 461     swap [ nth ] curry map ;
 462
 463 : contains? ( seq quot -- ? )
 464     find drop >boolean ; inline
 465
 466 : member? ( obj seq -- ? )
 467     [ = ] with contains? ;
 468
 469 : memq? ( obj seq -- ? )
 470     [ eq? ] with contains? ;
 471
 472 : remove ( obj seq -- newseq )
 473     [ = not ] with filter ;
 474
 475 : sift ( seq -- newseq )
 476     [ ] filter ;
 477
 478 : harvest ( seq -- newseq )
 479     [ empty? not ] filter ;
 480
 481 : cache-nth ( i seq quot -- elt )
 482     2over ?nth dup [
 483         >r 3drop r>
 484     ] [
 485         drop swap >r over >r call dup r> r> set-nth
 486     ] if ; inline
 487
 488 : mismatch ( seq1 seq2 -- i )
 489     [ min-length ] 2keep
 490     [ 2nth-unsafe = not ] 2curry
 491     find drop ; inline
 492
 493 M: sequence <=>
 494     2dup mismatch
 495     [ -rot 2nth-unsafe <=> ] [ [ length ] compare ] if* ;
 496
 497 : sequence= ( seq1 seq2 -- ? )
 498     2dup [ length ] bi@ number=
 499     [ mismatch not ] [ 2drop f ] if ; inline
 500
 501 : sequence-hashcode-step ( oldhash newpart -- newhash )
 502     >fixnum swap [
 503         dup -2 fixnum-shift-fast swap 5 fixnum-shift-fast
 504         fixnum+fast fixnum+fast
 505     ] keep fixnum-bitxor ; inline
 506
 507 : sequence-hashcode ( n seq -- x )
 508     0 -rot [ hashcode* sequence-hashcode-step ] with each ; inline
 509
 510 M: reversed equal? over reversed? [ sequence= ] [ 2drop f ] if ;
 511
 512 M: slice equal? over slice? [ sequence= ] [ 2drop f ] if ;
 513
 514 : move ( to from seq -- )
 515     2over number=
 516     [ 3drop ] [ [ nth swap ] [ set-nth ] bi ] if ; inline
 517
 518 : (delete) ( elt store scan seq -- elt store scan seq )
 519     2dup length < [
 520         3dup move
 521         [ nth pick = ] 2keep rot
 522         [ >r >r 1+ r> r> ] unless >r 1+ r> (delete)
 523     ] when ;
 524
 525 : delete ( elt seq -- ) 0 0 rot (delete) nip set-length drop ;
 526
 527 : prefix ( seq elt -- newseq )
 528     over >r over length 1+ r> [
 529         [ 0 swap set-nth-unsafe ] keep
 530         [ 1 swap copy ] keep
 531     ] new-like ;
 532
 533 : suffix ( seq elt -- newseq )
 534     over >r over length 1+ r> [
 535         [ >r over length r> set-nth-unsafe ] keep
 536         [ 0 swap copy ] keep
 537     ] new-like ;
 538
 539 : peek ( seq -- elt ) [ length 1- ] [ nth ] bi ;
 540
 541 : pop* ( seq -- ) [ length 1- ] [ shorten ] bi ;
 542
 543 : move-backward ( shift from to seq -- )
 544     2over number= [
 545         2drop 2drop
 546     ] [
 547         [ >r 2over + pick r> move >r 1+ r> ] keep
 548         move-backward
 549     ] if ;
 550
 551 : move-forward ( shift from to seq -- )
 552     2over number= [
 553         2drop 2drop
 554     ] [
 555         [ >r pick >r dup dup r> + swap r> move 1- ] keep
 556         move-forward
 557     ] if ;
 558
 559 : (open-slice) ( shift from to seq ? -- )
 560     [
 561         >r [ 1- ] bi@ r> move-forward
 562     ] [
 563         >r >r over - r> r> move-backward
 564     ] if ;
 565
 566 : open-slice ( shift from seq -- )
 567     pick zero? [
 568         3drop
 569     ] [
 570         pick over length + over >r >r
 571         pick 0 > >r [ length ] keep r> (open-slice)
 572         r> r> set-length
 573     ] if ;
 574
 575 : delete-slice ( from to seq -- )
 576     check-slice >r over >r - r> r> open-slice ;
 577
 578 : delete-nth ( n seq -- )
 579     >r dup 1+ r> delete-slice ;
 580
 581 : replace-slice ( new from to seq -- )
 582     [ >r >r dup pick length + r> - over r> open-slice ] keep
 583     copy ;
 584
 585 : pop ( seq -- elt )
 586     [ length 1- ] [ [ nth ] [ shorten ] 2bi ] bi ;
 587
 588 : all-equal? ( seq -- ? ) [ = ] monotonic? ;
 589
 590 : all-eq? ( seq -- ? ) [ eq? ] monotonic? ;
 591
 592 : exchange ( m n seq -- )
 593     pick over bounds-check 2drop 2dup bounds-check 2drop
 594     exchange-unsafe ;
 595
 596 : reverse-here ( seq -- )
 597     dup length dup 2/ [
 598         >r 2dup r>
 599         tuck - 1- rot exchange-unsafe
 600     ] each 2drop ;
 601
 602 : reverse ( seq -- newseq )
 603     [
 604         dup [ length ] keep new-sequence
 605         [ 0 swap copy ] keep
 606         [ reverse-here ] keep
 607     ] keep like ;
 608
 609 : sum-lengths ( seq -- n )
 610     0 [ length + ] reduce ;
 611
 612 : concat ( seq -- newseq )
 613     dup empty? [
 614         drop { }
 615     ] [
 616         [ sum-lengths ] keep
 617         [ first new-resizable ] keep
 618         [ [ over push-all ] each ] keep
 619         first like
 620     ] if ;
 621
 622 : joined-length ( seq glue -- n )
 623     >r dup sum-lengths swap length 1 [-] r> length * + ;
 624
 625 : join ( seq glue -- newseq )
 626     [
 627         2dup joined-length over new-resizable spin
 628         [ dup pick push-all ] [ pick push-all ] interleave drop
 629     ] keep like ;
 630
 631 : padding ( seq n elt quot -- newseq )
 632     [
 633         [ over length [-] dup zero? [ drop ] ] dip
 634         [ <repetition> ] curry
 635     ] dip compose if ; inline
 636
 637 : pad-left ( seq n elt -- padded )
 638     [ swap dup (append) ] padding ;
 639
 640 : pad-right ( seq n elt -- padded )
 641     [ append ] padding ;
 642
 643 : shorter? ( seq1 seq2 -- ? ) >r length r> length < ;
 644
 645 : head? ( seq begin -- ? )
 646     2dup shorter? [
 647         2drop f
 648     ] [
 649         tuck length head-slice sequence=
 650     ] if ;
 651
 652 : tail? ( seq end -- ? )
 653     2dup shorter? [
 654         2drop f
 655     ] [
 656         tuck length tail-slice* sequence=
 657     ] if ;
 658
 659 : cut-slice ( seq n -- before after )
 660     [ head-slice ] [ tail-slice ] 2bi ;
 661
 662 : midpoint@ ( seq -- n ) length 2/ ; inline
 663
 664 : halves ( seq -- first second )
 665     dup midpoint@ cut-slice ;
 666
 667 : binary-reduce ( seq start quot: ( elt1 elt2 -- newelt ) -- value )
 668     #! We can't use case here since combinators depends on
 669     #! sequences
 670     pick length dup 0 3 between? [
 671         >fixnum {
 672             [ drop nip ]
 673             [ 2drop first ]
 674             [ >r drop first2 r> call ]
 675             [ >r drop first3 r> bi@ ]
 676         } dispatch
 677     ] [
 678         drop
 679         >r >r halves r> r>
 680         [ [ binary-reduce ] 2curry bi@ ] keep
 681         call
 682     ] if ; inline recursive
 683
 684 : cut ( seq n -- before after )
 685     [ head ] [ tail ] 2bi ;
 686
 687 : cut* ( seq n -- before after )
 688     [ head* ] [ tail* ] 2bi ;
 689
 690 <PRIVATE
 691
 692 : (start) ( subseq seq n -- subseq seq ? )
 693     pick length [
 694         >r 3dup r> [ + swap nth-unsafe ] keep rot nth-unsafe =
 695     ] all? nip ; inline
 696
 697 PRIVATE>
 698
 699 : start* ( subseq seq n -- i )
 700     pick length pick length swap - 1+
 701     [ (start) ] find-from
 702     swap >r 3drop r> ;
 703
 704 : start ( subseq seq -- i ) 0 start* ; inline
 705
 706 : subseq? ( subseq seq -- ? ) start >boolean ;
 707
 708 : drop-prefix ( seq1 seq2 -- slice1 slice2 )
 709     2dup mismatch [ 2dup min-length ] unless*
 710     tuck tail-slice >r tail-slice r> ;
 711
 712 : unclip ( seq -- rest first )
 713     [ rest ] [ first ] bi ;
 714
 715 : unclip-last ( seq -- butlast last )
 716     [ but-last ] [ peek ] bi ;
 717
 718 : unclip-slice ( seq -- rest first )
 719     [ rest-slice ] [ first ] bi ;
 720
 721 : unclip-last-slice ( seq -- butfirst last )
 722     [ but-last-slice ] [ peek ] bi ;
 723
 724 : <flat-slice> ( seq -- slice )
 725     dup slice? [ { } like ] when 0 over length rot <slice> ;
 726     inline
 727
 728 : left-trim ( seq quot -- newseq )
 729     over >r [ not ] compose find drop r> swap
 730     [ tail ] [ dup length tail ] if* ; inline
 731
 732 : right-trim ( seq quot -- newseq )
 733     over >r [ not ] compose find-last drop r> swap
 734     [ 1+ head ] [ 0 head ] if* ; inline
 735
 736 : trim ( seq quot -- newseq )
 737     [ left-trim ] [ right-trim ] bi ; inline
 738
 739 : sum ( seq -- n ) 0 [ + ] binary-reduce ;
 740
 741 : product ( seq -- n ) 1 [ * ] binary-reduce ;
 742
 743 : infimum ( seq -- n ) dup first [ min ] reduce ;
 744
 745 : supremum ( seq -- n ) dup first [ max ] reduce ;
 746
 747 : flip ( matrix -- newmatrix )
 748     dup empty? [
 749         dup [ length ] map infimum
 750         swap [ [ nth-unsafe ] with { } map-as ] curry { } map-as
 751     ] unless ;
 752
 753 : sigma ( seq quot -- n ) [ + ] compose 0 swap reduce ; inline
 754
 755 : count ( seq quot -- n ) [ 1 0 ? ] compose sigma ; inline