core/sequences/sequences.factor

   1 ! Copyright (C) 2005, 2011 Slava Pestov, Daniel Ehrenberg.
   2 ! See https://factorcode.org/license.txt for BSD license.
   3 USING: accessors kernel kernel.private math math.order
   4 math.private slots.private ;
   5 IN: sequences
   6
   7 MIXIN: sequence
   8
   9 GENERIC: length ( seq -- n ) flushable
  10 GENERIC: set-length ( n seq -- )
  11 GENERIC: nth ( n seq -- elt ) flushable
  12 GENERIC: set-nth ( elt n seq -- )
  13 GENERIC: new-sequence ( len seq -- newseq ) flushable
  14 GENERIC: new-resizable ( len seq -- newseq ) flushable
  15 GENERIC: like ( seq exemplar -- newseq ) flushable
  16 GENERIC: clone-like ( seq exemplar -- newseq ) flushable
  17
  18 : lengthd ( seq obj -- n obj ) [ length ] dip ; inline
  19
  20 : new-sequence-like ( len-exemplar type-exemplar -- newseq )
  21     lengthd new-sequence ; inline
  22
  23 : new-resizable-like ( len-exemplar type-exemplar -- newseq )
  24     lengthd new-resizable ; inline
  25
  26 : new-like ( len exemplar quot -- seq )
  27     over [ [ new-sequence ] dip call ] dip like ; inline
  28
  29 M: sequence like drop ; inline
  30
  31 GENERIC: lengthen ( n seq -- )
  32 GENERIC: shorten ( n seq -- )
  33
  34 M: sequence lengthen 2dup length > [ set-length ] [ 2drop ] if ; inline
  35 M: sequence shorten 2dup length < [ set-length ] [ 2drop ] if ; inline
  36
  37 : nth-of ( seq n -- elt ) swap nth ; inline
  38 : set-nth-of ( seq n elt -- seq ) spin [ set-nth ] keep ; inline
  39
  40 : 2length ( seq1 seq2 -- n1 n2 ) [ length ] bi@ ; inline
  41 : 3length ( seq1 seq2 seq3 -- n1 n2 n3 ) [ length ] tri@ ; inline
  42
  43 : empty? ( seq -- ? ) length 0 = ; inline
  44
  45 : if-empty ( ..a seq quot1: ( ..a -- ..b ) quot2: ( ..a seq -- ..b ) -- ..b )
  46     [ dup empty? ] [ [ drop ] prepose ] [ ] tri* if ; inline
  47
  48 : when-empty ( ... seq quot: ( ... -- ... obj ) -- ... seq/obj ) [ ] if-empty ; inline
  49 : unless-empty ( ... seq quot: ( ... seq -- ... ) -- ... ) [ ] swap if-empty ; inline
  50
  51 : delete-all ( seq -- ) 0 swap set-length ;
  52
  53 : first ( seq -- first ) 0 swap nth ; inline
  54 : second ( seq -- second ) 1 swap nth ; inline
  55 : third ( seq -- third ) 2 swap nth ; inline
  56 : fourth ( seq -- fourth ) 3 swap nth ; inline
  57
  58 : set-first ( first seq -- ) 0 swap set-nth ; inline
  59 : set-second ( second seq -- ) 1 swap set-nth ; inline
  60 : set-third ( third seq -- ) 2 swap set-nth ; inline
  61 : set-fourth  ( fourth seq -- ) 3 swap set-nth ; inline
  62
  63 : push ( elt seq -- ) [ length ] [ set-nth ] bi ;
  64
  65 ERROR: bounds-error index seq ;
  66
  67 GENERIC#: bounds-check? 1 ( n seq -- ? )
  68
  69 M: integer bounds-check?
  70     dupd length < [ 0 >= ] [ drop f ] if ; inline
  71
  72 : bounds-check ( n seq -- n seq )
  73     2dup bounds-check? [ bounds-error ] unless ; inline
  74
  75 MIXIN: immutable-sequence
  76
  77 ERROR: immutable element index sequence ;
  78
  79 M: immutable-sequence set-nth immutable ;
  80
  81 INSTANCE: immutable-sequence sequence
  82
  83 <PRIVATE
  84
  85 : array-nth ( n array -- elt )
  86     swap 2 fixnum+fast slot ; inline
  87
  88 : set-array-nth ( elt n array -- )
  89     swap 2 fixnum+fast set-slot ; inline
  90
  91 : dispatch ( n array -- ) array-nth call ;
  92
  93 GENERIC: resize ( n seq -- newseq ) flushable
  94
  95 ! Unsafe sequence protocol for inner loops
  96 GENERIC: nth-unsafe ( n seq -- elt ) flushable
  97 GENERIC: set-nth-unsafe ( elt n seq -- )
  98
  99 M: sequence nth bounds-check nth-unsafe ; inline
 100 M: sequence set-nth bounds-check set-nth-unsafe ; inline
 101
 102 M: sequence nth-unsafe nth ; inline
 103 M: sequence set-nth-unsafe set-nth ; inline
 104
 105 : nth-of-unsafe ( seq n -- elt ) swap nth-unsafe ; inline
 106
 107 : set-nth-of-unsafe ( seq n elt -- seq ) swap pick set-nth-unsafe ; inline
 108
 109 : change-nth-unsafe ( i seq quot -- )
 110     [ [ nth-unsafe ] dip call ] 2keepd set-nth-unsafe ; inline
 111
 112 : change-nth-of-unsafe ( seq i quot -- seq )
 113     [ [ nth-of-unsafe ] dip call ] 2keepd rot set-nth-of-unsafe ; inline
 114
 115 PRIVATE>
 116
 117 ! The f object supports the sequence protocol trivially
 118 M: f length drop 0 ; inline
 119 M: f nth-unsafe nip ; inline
 120 M: f like drop [ f ] when-empty ; inline
 121
 122 INSTANCE: f immutable-sequence
 123
 124 ! Integer sequences
 125 TUPLE: iota { n integer read-only } ;
 126
 127 ERROR: non-negative-integer-expected n ;
 128
 129 : ensure-non-negative ( n -- n )
 130     dup 0 < [ non-negative-integer-expected ] when ; inline
 131
 132 : <iota> ( n -- iota )
 133     ensure-non-negative iota boa ; inline
 134
 135 M: iota length n>> ; inline
 136 M: iota nth-unsafe drop ; inline
 137
 138 INSTANCE: iota immutable-sequence
 139
 140 <PRIVATE
 141
 142 : first-unsafe ( seq -- first ) 0 swap nth-unsafe ; inline
 143 : second-unsafe ( seq -- second ) 1 swap nth-unsafe ; inline
 144 : third-unsafe ( seq -- third ) 2 swap nth-unsafe ; inline
 145 : fourth-unsafe ( seq -- fourth ) 3 swap nth-unsafe ; inline
 146
 147 : first2-unsafe ( seq -- first second )
 148     [ first-unsafe ] [ second-unsafe ] bi ; inline
 149
 150 : first3-unsafe ( seq -- first second third )
 151     [ first2-unsafe ] [ third-unsafe ] bi ; inline
 152
 153 : first4-unsafe ( seq -- first second third fourth )
 154     [ first3-unsafe ] [ fourth-unsafe ] bi ; inline
 155
 156 : exchange-unsafe ( m n seq -- )
 157     [ [ nth-unsafe ] curry bi@ ]
 158     [ [ set-nth-unsafe ] curry bi@ ] 3bi ; inline
 159
 160 : (1sequence) ( obj seq -- seq )
 161     [ 0 swap set-nth-unsafe ] keep ; inline
 162
 163 : (2sequence) ( obj1 obj2 seq -- seq )
 164     [ 1 swap set-nth-unsafe ] keep (1sequence) ; inline
 165
 166 : (3sequence) ( obj1 obj2 obj3 seq -- seq )
 167     [ 2 swap set-nth-unsafe ] keep (2sequence) ; inline
 168
 169 : (4sequence) ( obj1 obj2 obj3 obj4 seq -- seq )
 170     [ 3 swap set-nth-unsafe ] keep (3sequence) ; inline
 171
 172 PRIVATE>
 173
 174 : head-to-index ( seq to -- zero to seq ) [ 0 ] 2dip swap ; inline
 175
 176 : index-to-tail ( seq from -- from length seq ) swap [ length ] keep ; inline
 177
 178 : from-tail ( seq n -- seq n' ) [ dup length ] dip - ; inline
 179
 180 : 1sequence ( obj exemplar -- seq )
 181     1 swap [ (1sequence) ] new-like ; inline
 182
 183 : 2sequence ( obj1 obj2 exemplar -- seq )
 184     2 swap [ (2sequence) ] new-like ; inline
 185
 186 : 3sequence ( obj1 obj2 obj3 exemplar -- seq )
 187     3 swap [ (3sequence) ] new-like ; inline
 188
 189 : 4sequence ( obj1 obj2 obj3 obj4 exemplar -- seq )
 190     4 swap [ (4sequence) ] new-like ; inline
 191
 192 : first2 ( seq -- first second )
 193     1 swap bounds-check nip first2-unsafe ; inline
 194
 195 : first3 ( seq -- first second third )
 196     2 swap bounds-check nip first3-unsafe ; inline
 197
 198 : first4 ( seq -- first second third fourth )
 199     3 swap bounds-check nip first4-unsafe ; inline
 200
 201 : ??nth ( n seq -- elt/f ? )
 202     2dup bounds-check? [ nth-unsafe t ] [ 2drop f f ] if ; inline
 203
 204 : ?nth ( n seq -- elt/f )
 205     ??nth drop ; inline
 206
 207 : ?set-nth ( elt n seq -- )
 208     2dup bounds-check? [ set-nth-unsafe ] [ 3drop ] if ; inline
 209
 210 : ?nth-of ( seq n -- elt/f ) swap ?nth ; inline
 211
 212 : ??nth-of ( seq n -- elt/f ? ) swap ??nth ; inline
 213
 214 : index-or-length ( seq n -- seq n' ) over length min ; inline
 215
 216 : index-of-last ( seq -- n seq ) [ length 1 - ] keep ; inline
 217
 218 : ?first ( seq -- elt/f ) 0 swap ?nth ; inline
 219 : ?second ( seq -- elt/f ) 1 swap ?nth ; inline
 220 : ?last ( seq -- elt/f )
 221     index-of-last over 0 <
 222     [ 2drop f ] [ nth-unsafe ] if ; inline
 223
 224 MIXIN: virtual-sequence
 225 GENERIC: virtual-exemplar ( seq -- seq' )
 226 GENERIC: virtual@ ( n seq -- n' seq' )
 227
 228 M: virtual-sequence nth virtual@ nth ; inline
 229 M: virtual-sequence set-nth virtual@ set-nth ; inline
 230 M: virtual-sequence nth-unsafe virtual@ nth-unsafe ; inline
 231 M: virtual-sequence set-nth-unsafe virtual@ set-nth-unsafe ; inline
 232 M: virtual-sequence like virtual-exemplar like ; inline
 233 M: virtual-sequence new-sequence virtual-exemplar new-sequence ; inline
 234
 235 INSTANCE: virtual-sequence sequence
 236
 237 ! A reversal of an underlying sequence.
 238 TUPLE: reversed { seq read-only } ;
 239
 240 C: <reversed> reversed
 241
 242 M: reversed virtual-exemplar seq>> ; inline
 243 M: reversed virtual@ seq>> [ length swap - 1 - ] keep ; inline
 244 M: reversed length seq>> length ; inline
 245
 246 INSTANCE: reversed virtual-sequence
 247
 248 ! A slice of another sequence.
 249 TUPLE: slice
 250     { from integer read-only }
 251     { to integer read-only }
 252     { seq read-only } ;
 253
 254 : >slice< ( slice -- from to seq )
 255     [ from>> ] [ to>> ] [ seq>> ] tri ; inline
 256
 257 : collapse-slice ( m n slice -- m' n' seq )
 258     [ from>> ] [ seq>> ] bi [ [ + ] curry bi@ ] dip ; inline
 259
 260 ERROR: slice-error from to seq ;
 261
 262 : check-slice ( from to seq -- from to seq )
 263     pick 0 < [ slice-error ] when
 264     2dup length > [ slice-error ] when
 265     2over > [ slice-error ] when ; inline
 266
 267 <PRIVATE
 268
 269 : <slice-unsafe> ( from to seq -- slice )
 270     dup slice? [ collapse-slice ] when slice boa ; inline
 271
 272 PRIVATE>
 273
 274 : <slice> ( from to seq -- slice )
 275     check-slice <slice-unsafe> ; inline
 276
 277 M: slice virtual-exemplar seq>> ; inline
 278
 279 M: slice virtual@ [ from>> + ] [ seq>> ] bi ; inline
 280
 281 M: slice length [ to>> ] [ from>> ] bi - ; inline
 282
 283 : head-slice ( seq n -- slice ) head-to-index <slice> ; inline
 284
 285 : tail-slice ( seq n -- slice ) index-to-tail <slice> ; inline
 286
 287 : rest-slice ( seq -- slice ) 1 tail-slice ; inline
 288
 289 : head-slice* ( seq n -- slice ) from-tail head-slice ; inline
 290
 291 : tail-slice* ( seq n -- slice ) from-tail tail-slice ; inline
 292
 293 : but-last-slice ( seq -- slice ) 1 head-slice* ; inline
 294
 295 INSTANCE: slice virtual-sequence
 296
 297 ! One element repeated many times
 298 TUPLE: repetition
 299     { length integer read-only }
 300     { elt read-only } ;
 301
 302 : <repetition> ( len elt -- repetition )
 303     over 0 < [ non-negative-integer-expected ] when
 304     repetition boa ; inline
 305
 306 M: repetition length length>> ; inline
 307 M: repetition nth-unsafe nip elt>> ; inline
 308
 309 INSTANCE: repetition immutable-sequence
 310
 311 <PRIVATE
 312
 313 ERROR: integer-length-expected obj ;
 314
 315 ! The check-length call forces partial dispatch
 316 : check-length ( n -- n )
 317     dup integer? [ integer-length-expected ] unless ; inline
 318
 319 : >sequence< ( seq -- i n seq )
 320     [ drop 0 ] [ length check-length ] [ ] tri ; inline
 321
 322 : length-sequence ( seq -- n seq )
 323     [ length check-length ] [ ] bi ; inline
 324
 325 : >underlying< ( slice/seq -- from to slice/seq )
 326     dup slice? [ >slice< ] [ >sequence< ] if ; inline
 327
 328 TUPLE: copier
 329     { src-i integer read-only }
 330     { src read-only }
 331     { dst-i integer read-only }
 332     { dst read-only } ;
 333
 334 C: <copier> copier
 335
 336 : copy-nth-unsafe ( n copy -- )
 337     [ [ src-i>> + ] [ src>> ] bi nth-unsafe ]
 338     [ [ dst-i>> + ] [ dst>> ] bi set-nth-unsafe ] 2bi ; inline
 339
 340 : copy-nth-of-unsafe ( dst dst-i src src-i -- )
 341     nth-of-unsafe set-nth-of-unsafe drop ; inline
 342
 343 : (copy) ( n copy -- dst )
 344     over 0 <= [ nip dst>> ] [
 345         [ 1 - ] dip [ copy-nth-unsafe ] [ (copy) ] 2bi
 346     ] if ; inline recursive
 347
 348 : subseq>copy ( from to seq -- n copy )
 349     [ over - check-length swap ] dip
 350     3dup nip new-sequence 0 swap <copier> ; inline
 351
 352 : bounds-check-head ( n seq -- n seq )
 353     over 0 < [ bounds-error ] when ; inline
 354
 355 : check-grow-copy ( dst n src -- dst src n )
 356     over [ lengthd + lengthen ] 2keep ; inline
 357
 358 : copy-unsafe ( src i dst -- )
 359     [ [ length check-length 0 ] keep ] 2dip <copier> (copy) drop ; inline
 360
 361 : subseq-unsafe-as ( from to seq exemplar -- subseq )
 362     [ subseq>copy (copy) ] dip like ; inline
 363
 364 : subseq-unsafe ( from to seq -- subseq )
 365     dup subseq-unsafe-as ; inline
 366
 367 : copy-loop ( dst dst-i src src-i src-stop -- dst )
 368     2dup >= [
 369         4drop
 370     ] [
 371         [
 372             [ copy-nth-of-unsafe ] 4keep
 373             [ 1 + ] 2dip 1 +
 374         ] dip copy-loop
 375     ] if ; inline recursive
 376
 377 PRIVATE>
 378
 379 : subseq-as ( from to seq exemplar -- subseq )
 380     [ check-slice ] dip subseq-unsafe-as ;
 381
 382 : subseq ( from to seq -- subseq )
 383     dup subseq-as ;
 384
 385 : head ( seq n -- headseq ) head-to-index subseq ;
 386
 387 : tail ( seq n -- tailseq ) index-to-tail subseq ;
 388
 389 : rest ( seq -- tailseq ) 1 tail ;
 390
 391 : head* ( seq n -- headseq ) from-tail head ;
 392
 393 : tail* ( seq n -- tailseq ) from-tail tail ;
 394
 395 : but-last ( seq -- headseq ) 1 head* ;
 396
 397 : copy ( src i dst -- )
 398     3dup bounds-check-head
 399     [ swap length + ] dip lengthen
 400     copy-unsafe ; inline
 401
 402 M: sequence clone-like
 403     dupd new-sequence-like [ 0 swap copy-unsafe ] keep ; inline
 404
 405 M: immutable-sequence clone-like like ; inline
 406
 407 : push-all ( src dst -- ) [ length ] [ copy ] bi ; inline
 408
 409 <PRIVATE
 410
 411 : (append) ( seq1 seq2 accum -- accum )
 412     [ [ over length ] dip copy-unsafe ]
 413     [ 0 swap copy-unsafe ]
 414     [ ] tri ; inline
 415
 416 PRIVATE>
 417
 418 : append-as ( seq1 seq2 exemplar -- newseq )
 419     [ 2dup 2length + ] dip
 420     [ (append) ] new-like ; inline
 421
 422 : append ( seq1 seq2 -- newseq ) over append-as ;
 423
 424 : prepend-as ( seq1 seq2 exemplar -- newseq ) swapd append-as ; inline
 425
 426 : prepend ( seq1 seq2 -- newseq ) over prepend-as ;
 427
 428 : 3append-as ( seq1 seq2 seq3 exemplar -- newseq )
 429     [ 3dup 3length + + ] dip [
 430         [ [ 2over 2length + ] dip copy-unsafe ]
 431         [ (append) ] bi
 432     ] new-like ; inline
 433
 434 : 3append ( seq1 seq2 seq3 -- newseq ) pick 3append-as ;
 435
 436 : surround-as ( seq1 seq2 seq3 exemplar -- newseq )
 437     [ swap ] 2dip 3append-as ; inline
 438
 439 : surround ( seq1 seq2 seq3 -- newseq ) over surround-as ; inline
 440
 441 : 1surround-as ( seq1 seq2 exemplar  -- newseq ) dupd surround-as ; inline
 442
 443 : 1surround ( seq1 seq2 -- newseq ) dup 1surround-as ; inline
 444
 445 : glue-as ( seq1 seq2 seq3 exemplar -- newseq ) swapd 3append-as ; inline
 446
 447 : glue ( seq1 seq2 seq3 -- newseq ) pick glue-as ; inline
 448
 449 : change-nth ( ..a i seq quot: ( ..a elt -- ..b newelt ) -- ..b )
 450     [ [ nth ] dip call ] 2keepd set-nth-unsafe ; inline
 451
 452 : min-length ( seq1 seq2 -- n ) 2length min ; inline
 453
 454 : max-length ( seq1 seq2 -- n ) 2length max ; inline
 455
 456 <PRIVATE
 457
 458 : sequence-operator ( seq quot -- i n quot' )
 459     [ >underlying< [ nth-unsafe ] curry ] dip compose ; inline
 460
 461 : length-iterator ( seq -- n quot' )
 462     length-sequence [ nth-unsafe ] curry ; inline
 463
 464 : length-operator ( seq quot -- n quot' )
 465     [ length-iterator ] dip compose ; inline
 466
 467 : collect-into ( quot into -- quot' )
 468     [ [ keep ] dip set-nth-unsafe ] 2curry ; inline
 469
 470 : collect-from ( i n quot into -- )
 471     collect-into each-integer-from ; inline
 472
 473 : collect ( n quot into -- )
 474     collect-into each-integer ; inline
 475
 476 : sequence-index-operator ( seq quot -- n quot' )
 477     [ length-iterator [ keep ] curry ] dip compose ; inline
 478
 479 : map-into ( seq quot into -- )
 480     [ length-operator ] dip collect ; inline
 481
 482 : 2nth-unsafe ( n seq1 seq2 -- elt1 elt2 )
 483     [ nth-unsafe ] bi-curry@ bi ; inline
 484
 485 : 2length-iterator ( seq1 seq2 -- n quot )
 486     [ min-length check-length ] 2keep [ 2nth-unsafe ] 2curry ; inline
 487
 488 : 2length-operator ( seq1 seq2 quot -- n quot' )
 489     [ 2length-iterator ] dip compose ; inline
 490
 491 : 3nth-unsafe ( n seq1 seq2 seq3 -- elt1 elt2 elt3 )
 492     [ nth-unsafe ] tri-curry@ tri ; inline
 493
 494 : 3length-iterator ( seq1 seq2 seq3 -- n quot )
 495     [ 3length min min check-length ]
 496     [ [ 3nth-unsafe ] 3curry ] 3bi ; inline
 497
 498 : 3length-operator ( seq1 seq2 seq3 quot -- n quot' )
 499     [ 3length-iterator ] dip compose ; inline
 500
 501 : element/index ( i/f seq -- elt/f i/f )
 502     '[ [ _ nth ] [ f ] if* ] keep ; inline
 503
 504 : index/element ( i/f seq -- i/f elt/f )
 505     dupd '[ _ nth ] [ f ] if* ; inline
 506
 507 : (accumulate) ( seq identity quot -- identity seq quot' )
 508     swapd [ keepd ] curry ; inline
 509
 510 : (accumulate*) ( seq identity quot -- identity seq quot' )
 511     swapd [ dup ] compose ; inline
 512
 513 PRIVATE>
 514
 515 : each ( ... seq quot: ( ... x -- ... ) -- ... )
 516     sequence-operator each-integer-from ; inline
 517
 518 : each-from ( ... seq quot: ( ... x -- ... ) i -- ... )
 519     -rot length-operator each-integer-from ; inline
 520
 521 : reduce ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... result )
 522     swapd each ; inline
 523
 524 : map-integers-from-as ( ... from len quot: ( ... i -- ... elt ) exemplar -- ... newseq )
 525     overd [ [ collect-from ] keep ] new-like ; inline
 526
 527 : map-integers-as ( ... len quot: ( ... i -- ... elt ) exemplar -- ... newseq )
 528     overd [ [ collect ] keep ] new-like ; inline
 529
 530 : map-integers ( ... len quot: ( ... i -- ... elt ) -- ... newseq )
 531     { } map-integers-as ; inline
 532
 533 : map-as ( ... seq quot: ( ... elt -- ... newelt ) exemplar -- ... newseq )
 534     [ length-operator ] dip map-integers-as ; inline
 535
 536 : map ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 537     over map-as ; inline
 538
 539 : replicate-as ( ... len quot: ( ... -- ... newelt ) exemplar -- ... newseq )
 540     [ [ drop ] prepose ] dip map-integers-as ; inline
 541
 542 : replicate ( ... len quot: ( ... -- ... newelt ) -- ... newseq )
 543     { } replicate-as ; inline
 544
 545 : map! ( ... seq quot: ( ... elt -- ... newelt ) -- ... seq )
 546     over [ map-into ] keep ; inline
 547
 548 : accumulate-as ( ... seq identity quot: ( ... prev elt -- ... next ) exemplar -- ... final newseq )
 549     [ (accumulate) ] dip map-as ; inline
 550
 551 : accumulate ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... final newseq )
 552     pick accumulate-as ; inline
 553
 554 : accumulate! ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... final seq )
 555     (accumulate) map! ; inline
 556
 557 : accumulate*-as ( ... seq identity quot: ( ... prev elt -- ... next ) exemplar -- ... newseq )
 558     [ (accumulate*) ] dip map-as nip ; inline
 559
 560 : accumulate* ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... newseq )
 561     pick accumulate*-as ; inline
 562
 563 : accumulate*! ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... seq )
 564     (accumulate*) map! nip ; inline
 565
 566 : 2each ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ) -- ... )
 567     2length-operator each-integer ; inline
 568
 569 : 2each-from ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ) from -- ... )
 570     -roll 2length-operator each-integer-from ; inline
 571
 572 : 2reduce ( ... seq1 seq2 identity quot: ( ... prev elt1 elt2 -- ... next ) -- ... result )
 573     -rotd 2each ; inline
 574
 575 : 2map-as ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) exemplar -- ... newseq )
 576     [ 2length-operator ] dip map-integers-as ; inline
 577
 578 : 2map ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... newseq )
 579     pick 2map-as ; inline
 580
 581 : 2all? ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... ? )
 582     2length-operator all-integers? ; inline
 583
 584 : 2any? ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... ? )
 585     negate 2all? not ; inline
 586
 587 : 3each ( ... seq1 seq2 seq3 quot: ( ... elt1 elt2 elt3 -- ... ) -- ... )
 588     3length-operator each-integer ; inline
 589
 590 : 3map-as ( ... seq1 seq2 seq3 quot: ( ... elt1 elt2 elt3 -- ... newelt ) exemplar -- ... newseq )
 591     [ 3length-operator ] dip map-integers-as ; inline
 592
 593 : 3map ( ... seq1 seq2 seq3 quot: ( ... elt1 elt2 elt3 -- ... newelt ) -- ... newseq )
 594     pickd swap 3map-as ; inline
 595
 596 <PRIVATE
 597
 598 : bounds-check-call ( n seq quot -- elt i )
 599     2over bounds-check? [ call ] [ 3drop f f ] if ; inline
 600
 601 : find-from-unsafe ( ... n seq quot: ( ... elt -- ... ? ) -- ... i elt )
 602     [ length-operator find-integer-from ] keepd
 603     index/element ; inline
 604
 605 : find-last-from-unsafe ( ... n seq quot: ( ... elt -- ... ? ) -- ... i elt )
 606     [ length-operator nip find-last-integer ] keepd
 607     index/element ; inline
 608
 609 PRIVATE>
 610
 611 : find-from ( ... n seq quot: ( ... elt -- ... ? ) -- ... i elt )
 612     '[ _ find-from-unsafe ] bounds-check-call ; inline
 613
 614 : find ( ... seq quot: ( ... elt -- ... ? ) -- ... i elt )
 615     [ 0 ] 2dip find-from-unsafe ; inline
 616
 617 : find-last-from ( ... n seq quot: ( ... elt -- ... ? ) -- ... i elt )
 618     '[ _ find-last-from-unsafe ] bounds-check-call ; inline
 619
 620 : find-last ( ... seq quot: ( ... elt -- ... ? ) -- ... i elt )
 621     [ index-of-last ] dip find-last-from ; inline
 622
 623 : find-index-from ( ... n seq quot: ( ... elt i -- ... ? ) -- ... i elt )
 624     '[
 625         _ [ sequence-index-operator find-integer-from ] keepd
 626         index/element
 627     ] bounds-check-call ; inline
 628
 629 : find-index ( ... seq quot: ( ... elt i -- ... ? ) -- ... i elt )
 630     [ 0 ] 2dip find-index-from ; inline
 631
 632 : all? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 633     sequence-operator all-integers-from? ; inline
 634
 635 : push-when ( ..a elt quot: ( ..a elt -- ..b ? ) accum -- ..b )
 636     [ keep ] dip rot [ push ] [ 2drop ] if ; inline
 637
 638 : 2push-when ( ..a elt1 elt2 quot: ( ..a elt1 elt2 -- ..b ? ) accum -- ..b )
 639     [ keepd ] dip rot [ push ] [ 2drop ] if ; inline
 640
 641 : call-push-when ( ..a elt quot: ( ..a elt -- ..b elt' ? ) accum -- ..b )
 642     [ call ] dip swap [ push ] [ 2drop ] if ; inline
 643
 644 <PRIVATE
 645
 646 : (selector-as) ( quot length exemplar -- selector accum )
 647     new-resizable [ [ push-when ] 2curry ] keep ; inline
 648
 649 : (2selector-as) ( quot length exemplar -- selector accum )
 650     new-resizable [ [ 2push-when ] 2curry ] keep ; inline
 651
 652 PRIVATE>
 653
 654 : selector-as ( quot exemplar -- selector accum )
 655     [ length ] keep (selector-as) ; inline
 656
 657 : selector ( quot -- selector accum )
 658     V{ } selector-as ; inline
 659
 660 : filter-as ( ... seq quot: ( ... elt -- ... ? ) exemplar -- ... subseq )
 661     pick length over [ (selector-as) [ each ] dip ] 2curry dip like ; inline
 662
 663 : filter ( ... seq quot: ( ... elt -- ... ? ) -- ... subseq )
 664     over filter-as ; inline
 665
 666 : reject-as ( ... seq quot: ( ... elt -- ... ? ) exemplar -- ... subseq )
 667     [ negate ] [ filter-as ] bi* ; inline
 668
 669 : reject ( ... seq quot: ( ... elt -- ... ? ) -- ... subseq )
 670     over reject-as ; inline
 671
 672 : push-either ( ..a elt quot: ( ..a elt -- ..b ? ) accum1 accum2 -- ..b )
 673     [ keep swap ] 2dip ? push ; inline
 674
 675 : 2selector ( quot -- selector accum1 accum2 )
 676     V{ } clone V{ } clone [ [ push-either ] 3curry ] 2keep ; inline
 677
 678 : partition ( ... seq quot: ( ... elt -- ... ? ) -- ... trueseq falseseq )
 679     over [ 2selector [ each ] 2dip ] dip [ like ] curry bi@ ; inline
 680
 681 : collector-as ( quot exemplar -- quot' vec )
 682     dup new-resizable-like [ [ push ] curry compose ] keep ; inline
 683
 684 : collector ( quot -- quot' vec )
 685     V{ } collector-as ; inline
 686
 687 : produce-as ( ..a pred: ( ..a -- ..b ? ) quot: ( ..b -- ..a obj ) exemplar -- ..b seq )
 688     dup [ collector-as [ while ] dip ] curry dip like ; inline
 689
 690 : produce ( ..a pred: ( ..a -- ..b ? ) quot: ( ..b -- ..a obj ) -- ..b seq )
 691     { } produce-as ; inline
 692
 693 : follow ( ... obj quot: ( ... prev -- ... result/f ) -- ... seq )
 694     [ dup ] swap [ keep ] curry produce nip ; inline
 695
 696 : each-index ( ... seq quot: ( ... elt index -- ... ) -- ... )
 697     sequence-index-operator each-integer ; inline
 698
 699 : map-index-as ( ... seq quot: ( ... elt index -- ... newelt ) exemplar -- ... newseq )
 700     [ dup length <iota> ] 2dip 2map-as ; inline
 701
 702 : map-index ( ... seq quot: ( ... elt index -- ... newelt ) -- ... newseq )
 703     over map-index-as ; inline
 704
 705 : interleave ( ... seq between quot: ( ... elt -- ... ) -- ... )
 706     pick empty? [ 3drop ] [
 707         [ [ drop first-unsafe ] dip call ]
 708         [ [ bi* ] 2curry 1 each-from ]
 709         3bi
 710     ] if ; inline
 711
 712 : reduce-index ( ... seq identity quot: ( ... prev elt index -- ... next ) -- ... result )
 713     swapd each-index ; inline
 714
 715 : index ( obj seq -- n )
 716     [ = ] with find drop ;
 717
 718 : index-from ( obj i seq -- n )
 719     rot [ = ] curry find-from drop ;
 720
 721 : last-index ( obj seq -- n )
 722     [ = ] with find-last drop ;
 723
 724 : last-index-from ( obj i seq -- n )
 725     rot [ = ] curry find-last-from drop ;
 726
 727 : indices ( obj seq -- indices )
 728     swap [ = ] curry [ swap ] prepose V{ } clone [
 729         [ push ] curry [ [ drop ] if ] curry compose each-index
 730     ] keep ;
 731
 732 <PRIVATE
 733
 734 : nths-unsafe ( indices seq -- seq' )
 735     [ [ nth-unsafe ] curry ] keep map-as ;
 736
 737 PRIVATE>
 738
 739 : nths ( indices seq -- seq' )
 740     [ [ nth ] curry ] keep map-as ;
 741
 742 : nths-of ( seq indices -- seq' )
 743     swap nths ; inline
 744
 745 : any? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 746     find drop >boolean ; inline
 747
 748 : none? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 749     any? not ; inline
 750
 751 : member? ( elt seq -- ? )
 752     [ = ] with any? ;
 753
 754 : member-eq? ( elt seq -- ? )
 755     [ eq? ] with any? ;
 756
 757 : remove ( elt seq -- newseq )
 758     [ = ] with reject ;
 759
 760 : remove-eq ( elt seq -- newseq )
 761     [ eq? ] with reject ;
 762
 763 : sift ( seq -- newseq )
 764     [ ] filter ;
 765
 766 : harvest ( seq -- newseq )
 767     [ empty? ] reject ;
 768
 769 <PRIVATE
 770
 771 : mismatch-unsafe ( n seq1 seq2 -- i )
 772     [ 2nth-unsafe = not ] 2curry find-integer ; inline
 773
 774 PRIVATE>
 775
 776 : mismatch ( seq1 seq2 -- i )
 777     [ min-length ] 2keep mismatch-unsafe ;
 778
 779 M: sequence <=>
 780     [ mismatch ] 2keep pick
 781     [ 2nth-unsafe <=> ] [ [ length ] compare nip ] if ;
 782
 783 : sequence= ( seq1 seq2 -- ? )
 784     2dup 2length dupd =
 785     [ -rot mismatch-unsafe not ] [ 3drop f ] if ; inline
 786
 787 ERROR: assert-sequence got expected ;
 788
 789 : assert-sequence= ( a b -- )
 790     2dup sequence= [ 2drop ] [ assert-sequence ] if ;
 791
 792 M: reversed equal? over reversed? [ sequence= ] [ 2drop f ] if ;
 793
 794 M: slice equal? over slice? [ sequence= ] [ 2drop f ] if ;
 795
 796 <PRIVATE
 797
 798 : sequence-hashcode-step ( oldhash newpart -- newhash )
 799     integer>fixnum swap [
 800         [ -2 fixnum-shift-fast ] [ 5 fixnum-shift-fast ] bi
 801         fixnum+fast fixnum+fast
 802     ] keep fixnum-bitxor ; inline
 803
 804 PRIVATE>
 805
 806 : sequence-hashcode ( n seq -- x )
 807     [ 0 ] 2dip [ hashcode* sequence-hashcode-step ] with each ; inline
 808
 809 M: sequence hashcode* [ sequence-hashcode ] recursive-hashcode ;
 810
 811 M: iota hashcode*
 812     over 0 <= [ 2drop 0 ] [
 813         nip length 0 swap [ sequence-hashcode-step ] each-integer
 814     ] if ;
 815
 816 M: reversed hashcode* [ sequence-hashcode ] recursive-hashcode ;
 817
 818 M: slice hashcode* [ sequence-hashcode ] recursive-hashcode ;
 819
 820 : move ( to from seq -- )
 821     2over =
 822     [ 3drop ] [ [ nth swap ] [ set-nth ] bi ] if ; inline
 823
 824 <PRIVATE
 825
 826 : move-unsafe* ( to from seq -- from-nth )
 827     2over =
 828     [ nth-unsafe nip ]
 829     [ [ nth-unsafe tuck swap ] [ set-nth-unsafe ] bi ] if ; inline
 830
 831 : filter-from! ( store from seq quot: ( ... elt -- ... ? ) -- seq )
 832     2over length < [
 833         [ [ move-unsafe* ] dip call ] 4keep
 834         [ swap [ 1 + ] when ] 3dip
 835         [ 1 + ] 2dip filter-from!
 836     ] [ drop [ nip set-length ] keep ] if ; inline recursive
 837
 838 : move-unsafe ( to from seq -- )
 839     2over =
 840     [ 3drop ] [ [ nth-unsafe swap ] [ set-nth-unsafe ] bi ] if ; inline
 841
 842 PRIVATE>
 843
 844 : filter! ( ... seq quot: ( ... elt -- ... ? ) -- ... seq )
 845     [ 0 0 ] 2dip filter-from! ; inline
 846
 847 : reject! ( ... seq quot: ( ... elt -- ... ? ) -- ... seq )
 848     negate filter! ; inline
 849
 850 : remove! ( elt seq -- seq )
 851     [ = ] with reject! ;
 852
 853 : remove-eq! ( elt seq -- seq )
 854     [ eq? ] with reject! ;
 855
 856 : prefix ( seq elt -- newseq )
 857     over [ over length 1 + ] dip [
 858         (1sequence) [ 1 swap copy-unsafe ] keep
 859     ] new-like ;
 860
 861 : suffix ( seq elt -- newseq )
 862     over [ over length 1 + ] dip [
 863         [ [ over length ] dip set-nth-unsafe ] keep
 864         [ 0 swap copy-unsafe ] keep
 865     ] new-like ;
 866
 867 : suffix! ( seq elt -- seq ) over push ; inline
 868
 869 : append! ( seq1 seq2 -- seq1 ) over push-all ; inline
 870
 871 : last ( seq -- elt )
 872     index-of-last
 873     over 0 < [ bounds-error ] [ nth-unsafe ] if ; inline
 874
 875 <PRIVATE
 876
 877 : last-unsafe ( seq -- elt )
 878     index-of-last nth-unsafe ; inline
 879
 880 PRIVATE>
 881
 882 : set-last ( elt seq -- )
 883     index-of-last
 884     over 0 < [ bounds-error ] [ set-nth-unsafe ] if ; inline
 885
 886 : pop* ( seq -- ) index-of-last shorten ;
 887
 888 <PRIVATE
 889
 890 : move-backward ( shift from to seq -- )
 891     2over = [
 892         4drop
 893     ] [
 894         [ [ 2over + pick ] dip move-unsafe [ 1 + ] dip ] keep
 895         move-backward
 896     ] if ;
 897
 898 : open-slice ( shift from seq -- )
 899     pick 0 = [
 900         3drop
 901     ] [
 902         [ ] [ nip length + ] [ 2nip ] 3tri
 903         [ [ length ] keep [ over - ] 2dip move-backward ] 2dip
 904         set-length
 905     ] if ;
 906
 907 PRIVATE>
 908
 909 : delete-slice ( from to seq -- )
 910     check-slice [ over [ - ] dip ] dip open-slice ;
 911
 912 : remove-nth! ( n seq -- seq )
 913     [ [ dup 1 + ] dip delete-slice ] keep ;
 914
 915 : snip ( from to seq -- head tail )
 916     [ swap head ] [ swap tail ] bi-curry bi* ; inline
 917
 918 : snip-slice ( from to seq -- head tail )
 919     [ swap head-slice ] [ swap tail-slice ] bi-curry bi* ; inline
 920
 921 : replace-slice ( new from to seq -- seq' )
 922     snip-slice surround ;
 923
 924 : remove-nth ( n seq -- seq' )
 925     [ [ dup 1 + ] dip snip-slice ] keep append-as ;
 926
 927 : pop ( seq -- elt )
 928     index-of-last over 0 >=
 929     [ [ nth-unsafe ] [ shorten ] 2bi ]
 930     [ bounds-error ] if ;
 931
 932 : exchange ( m n seq -- )
 933     [ nip bounds-check 2drop ]
 934     [ bounds-check 3drop ]
 935     [ exchange-unsafe ]
 936     3tri ;
 937
 938 : midpoint@ ( seq -- n ) length 2/ ; inline
 939
 940 : reverse! ( seq -- seq )
 941     [
 942         [ midpoint@ ] [ length ] [ ] tri
 943         [ [ over - 1 - ] dip exchange-unsafe ] 2curry
 944         each-integer
 945     ] keep ;
 946
 947 : reverse ( seq -- newseq )
 948     [
 949         dup [ length ] keep new-sequence
 950         [ 0 swap copy-unsafe ] keep reverse!
 951     ] keep like ;
 952
 953 GENERIC: sum-lengths ( seq -- n )
 954
 955 M: object sum-lengths
 956     0 [ length + ] reduce ;
 957
 958 M: repetition sum-lengths
 959     [ length>> ] [ elt>> length ] bi * ;
 960
 961 : concat-as ( seq exemplar -- newseq )
 962     [
 963         [ dup sum-lengths ] dip new-resizable
 964         [ [ push-all ] curry each ] keep
 965     ] keep like ; inline
 966
 967 : concat ( seq -- newseq )
 968     [ { } ] [ dup first concat-as ] if-empty ;
 969
 970 <PRIVATE
 971
 972 : joined-length ( seq glue -- n )
 973     [ [ sum-lengths ] [ length 1 [-] ] bi ] dip length * + ;
 974
 975 PRIVATE>
 976
 977 : join-as ( seq glue exemplar -- newseq )
 978     over empty? [ nip concat-as ] [
 979         [
 980             2dup joined-length over new-resizable [
 981                 [ [ push-all ] 2curry ]
 982                 [ nip [ push-all ] curry ] 2bi
 983                 interleave
 984             ] keep
 985         ] dip like
 986     ] if ;
 987
 988 : join ( seq glue -- newseq )
 989     dup join-as ; inline
 990
 991 <PRIVATE
 992
 993 : padding ( ... seq n elt quot: ( ... seq1 seq2 -- ... newseq ) -- ... newseq )
 994     [
 995         [ over length [-] dup 0 = [ drop ] ] dip
 996         [ <repetition> ] curry
 997     ] dip compose if ; inline
 998
 999 PRIVATE>
1000
1001 : pad-head ( seq n elt -- padded )
1002     [ swap dup append-as ] padding ;
1003
1004 : pad-tail ( seq n elt -- padded )
1005     [ append ] padding ;
1006
1007 : shorter? ( seq1 seq2 -- ? ) 2length < ; inline
1008 : longer? ( seq1 seq2 -- ? ) 2length > ; inline
1009 : shorter ( seq1 seq2 -- seq ) [ 2length <= ] most ; inline
1010 : longer ( seq1 seq2 -- seq ) [ 2length >= ] most ; inline
1011
1012 : head? ( seq begin -- ? )
1013     2dup shorter? [
1014         2drop f
1015     ] [
1016         [ length [ head-slice ] keep swap ] keep
1017         mismatch-unsafe not
1018     ] if ;
1019
1020 : tail? ( seq end -- ? )
1021     2dup shorter? [
1022         2drop f
1023     ] [
1024         [ length [ tail-slice* ] keep swap ] keep
1025         mismatch-unsafe not
1026     ] if ;
1027
1028 : cut-slice ( seq n -- before-slice after-slice )
1029     [ head-slice ] [ tail-slice ] 2bi ; inline
1030
1031 : cut-slice* ( seq n -- before-slice after-slice )
1032     [ head-slice* ] [ tail-slice* ] 2bi ;
1033
1034 : insert-nth ( elt n seq -- seq' )
1035     swap cut-slice [ swap suffix ] dip append ;
1036
1037 : halves ( seq -- first-slice second-slice )
1038     dup midpoint@ cut-slice ; inline
1039
1040 <PRIVATE
1041
1042 : nth2-unsafe ( n seq -- a b )
1043     [ nth-unsafe ] [ [ 1 + ] dip nth-unsafe ] 2bi ; inline
1044
1045 : nth3-unsafe ( n seq -- a b c )
1046     [ nth2-unsafe ] [ [ 2 + ] dip nth-unsafe ] 2bi ; inline
1047
1048 : (binary-reduce) ( seq start quot: ( elt1 elt2 -- newelt ) from length -- value )
1049     ! We can't use case here since combinators depends on
1050     ! sequences
1051     dup 4 < [
1052         integer>fixnum {
1053             [ 2drop nip ]
1054             [ 2nip swap nth-unsafe ]
1055             [ -rot [ drop swap nth2-unsafe ] dip call ]
1056             [ -rot [ drop swap nth3-unsafe ] dip bi@ ]
1057         } dispatch
1058     ] [
1059         [ 2/ ] [ over - ] bi [ 2dup + ] dip
1060         [ (binary-reduce) ] [ 2curry ] curry 2bi@
1061         pick [ 3bi ] dip call
1062     ] if ; inline recursive
1063
1064 PRIVATE>
1065
1066 : binary-reduce ( seq start quot: ( elt1 elt2 -- newelt ) -- value )
1067     pick dup slice? [
1068         [ seq>> ] 3dip [ from>> 0 max ] [ to>> 0 max over - ] bi
1069     ] [
1070         length 0 max 0 swap
1071     ] if (binary-reduce) ; inline
1072
1073 : cut ( seq n -- before after )
1074     [ head ] [ tail ] 2bi ;
1075
1076 : cut* ( seq n -- before after )
1077     [ head* ] [ tail* ] 2bi ;
1078
1079 : subseq-starts-at? ( i seq subseq -- ? )
1080     [ length swap ] keep
1081     '[
1082         [ + _ nth-unsafe ] keep _ nth-unsafe =
1083     ] with all-integers? ; inline
1084
1085 : subseq-index-from ( n seq subseq -- i/f )
1086     [ 2length - 1 + ] 2keep
1087     '[ _ _ subseq-starts-at? ] find-integer-from ; inline
1088
1089 : subseq-index ( seq subseq -- i/f ) [ 0 ] 2dip subseq-index-from ; inline
1090
1091 : subseq-of? ( seq subseq -- ? ) subseq-index >boolean ; inline
1092
1093 : subseq-start-from ( subseq seq n -- i/f )
1094     spin subseq-index-from ; inline deprecated
1095
1096 : subseq-start ( subseq seq -- i/f ) swap subseq-index ; inline deprecated
1097
1098 : subseq? ( subseq seq -- ? ) subseq-start >boolean ; inline deprecated
1099
1100 : drop-prefix ( seq1 seq2 -- slice1 slice2 )
1101     2dup mismatch [ 2dup min-length ] unless*
1102     [ tail-slice ] curry bi@ ;
1103
1104 : unclip ( seq -- rest first )
1105     [ rest ] [ first-unsafe ] bi ;
1106
1107 : unclip-last ( seq -- butlast last )
1108     [ but-last ] [ last-unsafe ] bi ;
1109
1110 : unclip-slice ( seq -- rest-slice first )
1111     [ rest-slice ] [ first-unsafe ] bi ; inline
1112
1113 : map-reduce ( ..a seq map-quot: ( ..a elt -- ..a intermediate ) reduce-quot: ( ..a prev intermediate -- ..a next ) -- ..a result )
1114     [ [ [ first ] keep ] dip [ dip ] keep ] dip
1115     '[ swap _ dip swap @ ] 1 each-from ; inline
1116
1117 : 2map-reduce ( ..a seq1 seq2 map-quot: ( ..a elt1 elt2 -- ..a intermediate ) reduce-quot: ( ..a prev intermediate -- ..a next ) -- ..a result )
1118     [ [ [ [ first ] bi@ ] 2keep ] dip [ 2dip ] keep ] dip
1119     '[ rot _ dip swap @ ] 1 2each-from ; inline
1120
1121 <PRIVATE
1122
1123 : (map-find) ( seq quot find-quot -- result elt )
1124     [ [ f ] 2dip [ nip ] prepose [ dup ] compose ] dip call nip ; inline
1125
1126 PRIVATE>
1127
1128 : map-find ( ... seq quot: ( ... elt -- ... result/f ) -- ... result elt )
1129     [ find ] (map-find) ; inline
1130
1131 : map-find-last ( ... seq quot: ( ... elt -- ... result/f ) -- ... result elt )
1132     [ find-last ] (map-find) ; inline
1133
1134 : unclip-last-slice ( seq -- butlast-slice last )
1135     [ but-last-slice ] [ last-unsafe ] bi ; inline
1136
1137 <PRIVATE
1138
1139 : (trim-head) ( seq quot -- seq n )
1140     over [ negate find drop ] dip swap
1141     [ dup length ] unless* ; inline
1142
1143 : (trim-tail) ( seq quot -- seq n )
1144     over [ negate find-last drop ?1+ ] dip
1145     swap ; inline
1146
1147 PRIVATE>
1148
1149 : trim-head-slice ( ... seq quot: ( ... elt -- ... ? ) -- ... slice )
1150     (trim-head) tail-slice ; inline
1151
1152 : trim-head ( ... seq quot: ( ... elt -- ... ? ) -- ... newseq )
1153     (trim-head) tail ; inline
1154
1155 : trim-tail-slice ( ... seq quot: ( ... elt -- ... ? ) -- ... slice )
1156     (trim-tail) head-slice ; inline
1157
1158 : trim-tail ( ... seq quot: ( ... elt -- ... ? ) -- ... newseq )
1159     (trim-tail) head ; inline
1160
1161 : trim-slice ( ... seq quot: ( ... elt -- ... ? ) -- ... slice )
1162     [ trim-head-slice ] [ trim-tail-slice ] bi ; inline
1163
1164 : trim ( ... seq quot: ( ... elt -- ... ? ) -- ... newseq )
1165     [ trim-slice ] [ drop ] 2bi like ; inline
1166
1167 GENERIC: sum ( seq -- n )
1168 M: object sum 0 [ + ] binary-reduce ; inline
1169 M: iota sum length dup 1 - * 2/ ; inline
1170 M: repetition sum [ elt>> ] [ length>> ] bi * ; inline
1171
1172 : product ( seq -- n ) 1 [ * ] binary-reduce ;
1173
1174 : infimum ( seq -- elt ) [ ] [ min ] map-reduce ;
1175
1176 : supremum ( seq -- elt ) [ ] [ max ] map-reduce ;
1177
1178 : map-sum ( ... seq quot: ( ... elt -- ... n ) -- ... n )
1179     [ 0 ] 2dip [ dip + ] curry [ swap ] prepose each ; inline
1180
1181 : count ( ... seq quot: ( ... elt -- ... ? ) -- ... n )
1182     [ 1 0 ? ] compose map-sum ; inline
1183
1184 : cartesian-each ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ) -- ... )
1185     [ with each ] 2curry each ; inline
1186
1187 : cartesian-map ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... newseq )
1188     [ with { } map-as ] 2curry { } map-as ; inline
1189
1190 : cartesian-product-as ( seq1 seq2 exemplar -- newseq )
1191     [ 2sequence ] curry cartesian-map ; inline
1192
1193 : cartesian-product ( seq1 seq2 -- newseq )
1194     dup cartesian-product-as ; inline
1195
1196 : cartesian-find ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... elt1 elt2 )
1197     [ f ] 3dip [ with find swap ] 2curry [ nip ] prepose find nip swap ; inline
1198
1199 <PRIVATE
1200
1201 : select-by ( ... seq quot: ( ... elt -- ... x ) compare: ( obj1 obj2 -- ? ) -- ... elt )
1202     [
1203         [ keep swap ] curry [ [ first ] dip call ] 2keep
1204         [ curry 2dip pick over ] curry
1205     ] [
1206         [ [ 2drop ] [ 2nipd ] if ] compose
1207     ] bi* compose 1 each-from drop ; inline
1208
1209 PRIVATE>
1210
1211 : supremum-by ( ... seq quot: ( ... elt -- ... x ) -- ... elt )
1212     [ after? ] select-by ; inline
1213
1214 : infimum-by ( ... seq quot: ( ... elt -- ... x ) -- ... elt )
1215     [ before? ] select-by ; inline
1216
1217 : shortest ( seqs -- elt ) [ length ] infimum-by ;
1218
1219 : longest ( seqs -- elt ) [ length ] supremum-by ;
1220
1221 ! We hand-optimize flip to such a degree because type hints
1222 ! cannot express that an array is an array of arrays yet, and
1223 ! this word happens to be performance-critical since the compiler
1224 ! itself uses it. Optimizing it like this reduced compile time.
1225 <PRIVATE
1226
1227 : generic-flip ( matrix -- newmatrix )
1228     [ [ length ] [ min ] map-reduce ] keep
1229     '[ _ [ nth-unsafe ] with { } map-as ] map-integers ; inline
1230
1231 USE: arrays
1232
1233 : array-flip ( matrix -- newmatrix )
1234     { array } declare
1235     [ [ { array } declare length>> ] [ min ] map-reduce ] keep
1236     '[ _ [ { array } declare array-nth ] with { } map-as ] map-integers ;
1237
1238 PRIVATE>
1239
1240 : flip ( matrix -- newmatrix )
1241     dup empty? [
1242         dup array? [
1243             dup [ array? ] all?
1244             [ array-flip ] [ generic-flip ] if
1245         ] [ generic-flip ] if
1246     ] unless ;