core/sequences/sequences.factor

   1 ! Copyright (C) 2005, 2011 Slava Pestov, Daniel Ehrenberg.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors kernel kernel.private math math.order
   4 math.private slots.private ;
   5 IN: sequences
   6
   7 MIXIN: sequence
   8
   9 GENERIC: length ( seq -- n ) flushable
  10 GENERIC: set-length ( n seq -- )
  11 GENERIC: nth ( n seq -- elt ) flushable
  12 GENERIC: set-nth ( elt n seq -- )
  13 GENERIC: new-sequence ( len seq -- newseq ) flushable
  14 GENERIC: new-resizable ( len seq -- newseq ) flushable
  15 GENERIC: like ( seq exemplar -- newseq ) flushable
  16 GENERIC: clone-like ( seq exemplar -- newseq ) flushable
  17
  18 : new-like ( len exemplar quot -- seq )
  19     over [ [ new-sequence ] dip call ] dip like ; inline
  20
  21 M: sequence like drop ; inline
  22
  23 GENERIC: lengthen ( n seq -- )
  24 GENERIC: shorten ( n seq -- )
  25
  26 M: sequence lengthen 2dup length > [ set-length ] [ 2drop ] if ; inline
  27 M: sequence shorten 2dup length < [ set-length ] [ 2drop ] if ; inline
  28
  29 : empty? ( seq -- ? ) length 0 = ; inline
  30
  31 : if-empty ( ..a seq quot1: ( ..a -- ..b ) quot2: ( ..a seq -- ..b ) -- ..b )
  32     [ dup empty? ] [ [ drop ] prepose ] [ ] tri* if ; inline
  33
  34 : when-empty ( ... seq quot: ( ... -- ... obj ) -- ... seq/obj ) [ ] if-empty ; inline
  35 : unless-empty ( ... seq quot: ( ... seq -- ... ) -- ... ) [ ] swap if-empty ; inline
  36
  37 : delete-all ( seq -- ) 0 swap set-length ;
  38
  39 : first ( seq -- first ) 0 swap nth ; inline
  40 : second ( seq -- second ) 1 swap nth ; inline
  41 : third ( seq -- third ) 2 swap nth ; inline
  42 : fourth ( seq -- fourth ) 3 swap nth ; inline
  43
  44 : set-first ( first seq -- ) 0 swap set-nth ; inline
  45 : set-second ( second seq -- ) 1 swap set-nth ; inline
  46 : set-third ( third seq -- ) 2 swap set-nth ; inline
  47 : set-fourth  ( fourth seq -- ) 3 swap set-nth ; inline
  48
  49 : push ( elt seq -- ) [ length ] [ set-nth ] bi ;
  50
  51 ERROR: bounds-error index seq ;
  52
  53 GENERIC#: bounds-check? 1 ( n seq -- ? )
  54
  55 M: integer bounds-check?
  56     dupd length < [ 0 >= ] [ drop f ] if ; inline
  57
  58 : bounds-check ( n seq -- n seq )
  59     2dup bounds-check? [ bounds-error ] unless ; inline
  60
  61 MIXIN: immutable-sequence
  62
  63 ERROR: immutable element index sequence ;
  64
  65 M: immutable-sequence set-nth immutable ;
  66
  67 INSTANCE: immutable-sequence sequence
  68
  69 <PRIVATE
  70
  71 : array-nth ( n array -- elt )
  72     swap 2 fixnum+fast slot ; inline
  73
  74 : set-array-nth ( elt n array -- )
  75     swap 2 fixnum+fast set-slot ; inline
  76
  77 : dispatch ( n array -- ) array-nth call ;
  78
  79 GENERIC: resize ( n seq -- newseq ) flushable
  80
  81 ! Unsafe sequence protocol for inner loops
  82 GENERIC: nth-unsafe ( n seq -- elt ) flushable
  83 GENERIC: set-nth-unsafe ( elt n seq -- )
  84
  85 M: sequence nth bounds-check nth-unsafe ; inline
  86 M: sequence set-nth bounds-check set-nth-unsafe ; inline
  87
  88 M: sequence nth-unsafe nth ; inline
  89 M: sequence set-nth-unsafe set-nth ; inline
  90
  91 : change-nth-unsafe ( i seq quot -- )
  92     [ [ nth-unsafe ] dip call ] 2keepd set-nth-unsafe ; inline
  93
  94 PRIVATE>
  95
  96 ! The f object supports the sequence protocol trivially
  97 M: f length drop 0 ; inline
  98 M: f nth-unsafe nip ; inline
  99 M: f like drop [ f ] when-empty ; inline
 100
 101 INSTANCE: f immutable-sequence
 102
 103 ! Integer sequences
 104 TUPLE: iota { n integer read-only } ;
 105
 106 ERROR: non-negative-integer-expected n ;
 107
 108 : <iota> ( n -- iota )
 109     dup 0 < [ non-negative-integer-expected ] when
 110     iota boa ; inline
 111
 112 M: iota length n>> ; inline
 113 M: iota nth-unsafe drop ; inline
 114
 115 INSTANCE: iota immutable-sequence
 116
 117 <PRIVATE
 118
 119 : first-unsafe ( seq -- first ) 0 swap nth-unsafe ; inline
 120 : second-unsafe ( seq -- second ) 1 swap nth-unsafe ; inline
 121 : third-unsafe ( seq -- third ) 2 swap nth-unsafe ; inline
 122 : fourth-unsafe ( seq -- fourth ) 3 swap nth-unsafe ; inline
 123
 124 : first2-unsafe ( seq -- first second )
 125     [ first-unsafe ] [ second-unsafe ] bi ; inline
 126
 127 : first3-unsafe ( seq -- first second third )
 128     [ first2-unsafe ] [ third-unsafe ] bi ; inline
 129
 130 : first4-unsafe ( seq -- first second third fourth )
 131     [ first3-unsafe ] [ fourth-unsafe ] bi ; inline
 132
 133 : exchange-unsafe ( m n seq -- )
 134     [ [ nth-unsafe ] curry bi@ ]
 135     [ [ set-nth-unsafe ] curry bi@ ] 3bi ; inline
 136
 137 : (1sequence) ( obj seq -- seq )
 138     [ 0 swap set-nth-unsafe ] keep ; inline
 139
 140 : (2sequence) ( obj1 obj2 seq -- seq )
 141     [ 1 swap set-nth-unsafe ] keep (1sequence) ; inline
 142
 143 : (3sequence) ( obj1 obj2 obj3 seq -- seq )
 144     [ 2 swap set-nth-unsafe ] keep (2sequence) ; inline
 145
 146 : (4sequence) ( obj1 obj2 obj3 obj4 seq -- seq )
 147     [ 3 swap set-nth-unsafe ] keep (3sequence) ; inline
 148
 149 PRIVATE>
 150
 151 : head-to-index ( seq to -- zero to seq ) [ 0 ] 2dip swap ; inline
 152
 153 : index-to-tail ( seq from -- from length seq ) swap [ length ] keep ; inline
 154
 155 : from-tail ( seq n -- seq n' ) [ dup length ] dip - ; inline
 156
 157 : 1sequence ( obj exemplar -- seq )
 158     1 swap [ (1sequence) ] new-like ; inline
 159
 160 : 2sequence ( obj1 obj2 exemplar -- seq )
 161     2 swap [ (2sequence) ] new-like ; inline
 162
 163 : 3sequence ( obj1 obj2 obj3 exemplar -- seq )
 164     3 swap [ (3sequence) ] new-like ; inline
 165
 166 : 4sequence ( obj1 obj2 obj3 obj4 exemplar -- seq )
 167     4 swap [ (4sequence) ] new-like ; inline
 168
 169 : first2 ( seq -- first second )
 170     1 swap bounds-check nip first2-unsafe ; inline
 171
 172 : first3 ( seq -- first second third )
 173     2 swap bounds-check nip first3-unsafe ; inline
 174
 175 : first4 ( seq -- first second third fourth )
 176     3 swap bounds-check nip first4-unsafe ; inline
 177
 178 : ?nth ( n seq -- elt/f )
 179     2dup bounds-check? [ nth-unsafe ] [ 2drop f ] if ; inline
 180
 181 : ?set-nth ( elt n seq -- )
 182     2dup bounds-check? [ set-nth-unsafe ] [ 3drop ] if ; inline
 183
 184 : index-or-length ( seq n -- seq n' ) over length min ; inline
 185
 186 : index-of-last ( seq -- n seq ) [ length 1 - ] keep ; inline
 187
 188 : ?first ( seq -- elt/f ) 0 swap ?nth ; inline
 189 : ?second ( seq -- elt/f ) 1 swap ?nth ; inline
 190 : ?last ( seq -- elt/f )
 191     index-of-last over 0 <
 192     [ 2drop f ] [ nth-unsafe ] if ; inline
 193
 194 MIXIN: virtual-sequence
 195 GENERIC: virtual-exemplar ( seq -- seq' )
 196 GENERIC: virtual@ ( n seq -- n' seq' )
 197
 198 M: virtual-sequence nth virtual@ nth ; inline
 199 M: virtual-sequence set-nth virtual@ set-nth ; inline
 200 M: virtual-sequence nth-unsafe virtual@ nth-unsafe ; inline
 201 M: virtual-sequence set-nth-unsafe virtual@ set-nth-unsafe ; inline
 202 M: virtual-sequence like virtual-exemplar like ; inline
 203 M: virtual-sequence new-sequence virtual-exemplar new-sequence ; inline
 204
 205 INSTANCE: virtual-sequence sequence
 206
 207 ! A reversal of an underlying sequence.
 208 TUPLE: reversed { seq read-only } ;
 209
 210 C: <reversed> reversed
 211
 212 M: reversed virtual-exemplar seq>> ; inline
 213 M: reversed virtual@ seq>> [ length swap - 1 - ] keep ; inline
 214 M: reversed length seq>> length ; inline
 215
 216 INSTANCE: reversed virtual-sequence
 217
 218 ! A slice of another sequence.
 219 TUPLE: slice
 220     { from integer read-only }
 221     { to integer read-only }
 222     { seq read-only } ;
 223
 224 : >slice< ( slice -- from to seq )
 225     [ from>> ] [ to>> ] [ seq>> ] tri ; inline
 226
 227 : collapse-slice ( m n slice -- m' n' seq )
 228     [ from>> ] [ seq>> ] bi [ [ + ] curry bi@ ] dip ; inline
 229
 230 ERROR: slice-error from to seq ;
 231
 232 : check-slice ( from to seq -- from to seq )
 233     pick 0 < [ slice-error ] when
 234     2dup length > [ slice-error ] when
 235     2over > [ slice-error ] when ; inline
 236
 237 <PRIVATE
 238
 239 : <slice-unsafe> ( from to seq -- slice )
 240     dup slice? [ collapse-slice ] when slice boa ; inline
 241
 242 PRIVATE>
 243
 244 : <slice> ( from to seq -- slice )
 245     check-slice <slice-unsafe> ; inline
 246
 247 M: slice virtual-exemplar seq>> ; inline
 248
 249 M: slice virtual@ [ from>> + ] [ seq>> ] bi ; inline
 250
 251 M: slice length [ to>> ] [ from>> ] bi - ; inline
 252
 253 : head-slice ( seq n -- slice ) head-to-index <slice> ; inline
 254
 255 : tail-slice ( seq n -- slice ) index-to-tail <slice> ; inline
 256
 257 : rest-slice ( seq -- slice ) 1 tail-slice ; inline
 258
 259 : head-slice* ( seq n -- slice ) from-tail head-slice ; inline
 260
 261 : tail-slice* ( seq n -- slice ) from-tail tail-slice ; inline
 262
 263 : but-last-slice ( seq -- slice ) 1 head-slice* ; inline
 264
 265 INSTANCE: slice virtual-sequence
 266
 267 ! One element repeated many times
 268 TUPLE: repetition
 269     { length integer read-only }
 270     { elt read-only } ;
 271
 272 : <repetition> ( len elt -- repetition )
 273     over 0 < [ non-negative-integer-expected ] when
 274     repetition boa ; inline
 275
 276 M: repetition length length>> ; inline
 277 M: repetition nth-unsafe nip elt>> ; inline
 278
 279 INSTANCE: repetition immutable-sequence
 280
 281 <PRIVATE
 282
 283 ERROR: integer-length-expected obj ;
 284
 285 ! The check-length call forces partial dispatch
 286 : check-length ( n -- n )
 287     dup integer? [ integer-length-expected ] unless ; inline
 288
 289 : >sequence< ( seq -- i n seq )
 290     [ drop 0 ] [ length check-length ] [ ] tri ; inline
 291
 292 : length-sequence ( seq -- n seq )
 293     [ length check-length ] [ ] bi ; inline
 294
 295 : >underlying< ( slice/seq -- i n slice/seq )
 296     dup slice? [ >slice< ] [ >sequence< ] if ; inline
 297
 298 TUPLE: copier
 299     { src-i integer read-only }
 300     { src read-only }
 301     { dst-i integer read-only }
 302     { dst read-only } ;
 303
 304 C: <copier> copier
 305
 306 : copy-nth-unsafe ( n copy -- )
 307     [ [ src-i>> + ] [ src>> ] bi nth-unsafe ]
 308     [ [ dst-i>> + ] [ dst>> ] bi set-nth-unsafe ] 2bi ; inline
 309
 310 : (copy) ( n copy -- dst )
 311     over 0 <= [ nip dst>> ] [
 312         [ 1 - ] dip [ copy-nth-unsafe ] [ (copy) ] 2bi
 313     ] if ; inline recursive
 314
 315 : subseq>copy ( from to seq -- n copy )
 316     [ over - check-length swap ] dip
 317     3dup nip new-sequence 0 swap <copier> ; inline
 318
 319 : bounds-check-head ( n seq -- n seq )
 320     over 0 < [ bounds-error ] when ; inline
 321
 322 : check-copy ( src n dst -- src n dst )
 323     3dup bounds-check-head
 324     [ swap length + ] dip lengthen ; inline
 325
 326 : copy-unsafe ( src i dst -- )
 327     [ [ length check-length 0 ] keep ] 2dip <copier> (copy) drop ; inline
 328
 329 : subseq-unsafe-as ( from to seq exemplar -- subseq )
 330     [ subseq>copy (copy) ] dip like ; inline
 331
 332 : subseq-unsafe ( from to seq -- subseq )
 333     dup subseq-unsafe-as ; inline
 334
 335 PRIVATE>
 336
 337 : subseq-as ( from to seq exemplar -- subseq )
 338     [ check-slice ] dip subseq-unsafe-as ;
 339
 340 : subseq ( from to seq -- subseq )
 341     dup subseq-as ;
 342
 343 : head ( seq n -- headseq ) head-to-index subseq ;
 344
 345 : tail ( seq n -- tailseq ) index-to-tail subseq ;
 346
 347 : rest ( seq -- tailseq ) 1 tail ;
 348
 349 : head* ( seq n -- headseq ) from-tail head ;
 350
 351 : tail* ( seq n -- tailseq ) from-tail tail ;
 352
 353 : but-last ( seq -- headseq ) 1 head* ;
 354
 355 : copy ( src i dst -- ) check-copy copy-unsafe ; inline
 356
 357 M: sequence clone-like
 358     [ dup length ] dip new-sequence [ 0 swap copy-unsafe ] keep ; inline
 359
 360 M: immutable-sequence clone-like like ; inline
 361
 362 : push-all ( src dst -- ) [ length ] [ copy ] bi ; inline
 363
 364 <PRIVATE
 365
 366 : (append) ( seq1 seq2 accum -- accum )
 367     [ [ over length ] dip copy-unsafe ]
 368     [ 0 swap copy-unsafe ]
 369     [ ] tri ; inline
 370
 371 PRIVATE>
 372
 373 : append-as ( seq1 seq2 exemplar -- newseq )
 374     [ 2dup [ length ] bi@ + ] dip
 375     [ (append) ] new-like ; inline
 376
 377 : append ( seq1 seq2 -- newseq ) over append-as ;
 378
 379 : prepend-as ( seq1 seq2 exemplar -- newseq ) swapd append-as ; inline
 380
 381 : prepend ( seq1 seq2 -- newseq ) over prepend-as ;
 382
 383 : 3append-as ( seq1 seq2 seq3 exemplar -- newseq )
 384     [ 3dup [ length ] tri@ + + ] dip [
 385         [ [ 2over [ length ] bi@ + ] dip copy-unsafe ]
 386         [ (append) ] bi
 387     ] new-like ; inline
 388
 389 : 3append ( seq1 seq2 seq3 -- newseq ) pick 3append-as ;
 390
 391 : surround-as ( seq1 seq2 seq3 exemplar -- newseq )
 392     [ swap ] 2dip 3append-as ; inline
 393
 394 : surround ( seq1 seq2 seq3 -- newseq ) over surround-as ; inline
 395
 396 : 1surround-as ( seq1 seq2 exemplar  -- newseq ) dupd surround-as ; inline
 397
 398 : 1surround ( seq1 seq2 -- newseq ) dup 1surround-as ; inline
 399
 400 : glue-as ( seq1 seq2 seq3 exemplar -- newseq ) swapd 3append-as ; inline
 401
 402 : glue ( seq1 seq2 seq3 -- newseq ) pick glue-as ; inline
 403
 404 : change-nth ( ..a i seq quot: ( ..a elt -- ..b newelt ) -- ..b )
 405     [ [ nth ] dip call ] 2keepd set-nth-unsafe ; inline
 406
 407 : min-length ( seq1 seq2 -- n ) [ length ] bi@ min ; inline
 408
 409 : max-length ( seq1 seq2 -- n ) [ length ] bi@ max ; inline
 410
 411 <PRIVATE
 412
 413 : sequence-operator ( seq quot -- i n quot' )
 414     [ >underlying< [ nth-unsafe ] curry ] dip compose ; inline
 415
 416 : length-iterator ( seq -- n quot' )
 417     length-sequence [ nth-unsafe ] curry ; inline
 418
 419 : length-operator ( seq quot -- n quot' )
 420     [ length-iterator ] dip compose ; inline
 421
 422 : collect-into ( quot into -- quot' )
 423     [ [ keep ] dip set-nth-unsafe ] 2curry ; inline
 424
 425 : collect-from ( i n quot into -- )
 426     collect-into each-integer-from ; inline
 427
 428 : collect ( n quot into -- )
 429     collect-into each-integer ; inline
 430
 431 : sequence-index-operator ( seq quot -- n quot' )
 432     [ length-iterator [ keep ] curry ] dip compose ; inline
 433
 434 : map-into ( seq quot into -- )
 435     [ length-operator ] dip collect ; inline
 436
 437 : 2nth-unsafe ( n seq1 seq2 -- elt1 elt2 )
 438     [ nth-unsafe ] bi-curry@ bi ; inline
 439
 440 : setup-2each ( seq1 seq2 -- n quot )
 441     [ min-length check-length ] 2keep [ 2nth-unsafe ] 2curry ; inline
 442
 443 : (2each) ( seq1 seq2 quot -- n quot' )
 444     [ setup-2each ] dip compose ; inline
 445
 446 : 3nth-unsafe ( n seq1 seq2 seq3 -- elt1 elt2 elt3 )
 447     [ nth-unsafe ] tri-curry@ tri ; inline
 448
 449 : setup-3each ( seq1 seq2 seq3 -- n quot )
 450     [ [ length ] tri@ min min check-length ]
 451     [ [ 3nth-unsafe ] 3curry ] 3bi ; inline
 452
 453 : (3each) ( seq1 seq2 seq3 quot -- n quot' )
 454     [ setup-3each ] dip compose ; inline
 455
 456 : element/index ( i/f seq -- elt/f i/f )
 457     '[ [ _ nth ] [ f ] if* ] keep ;
 458
 459 : index/element ( i/f seq -- i/f elt/f )
 460     dupd '[ _ nth ] [ f ] if* ;
 461
 462 : (accumulate) ( seq identity quot -- identity seq quot' )
 463     swapd [ keepd ] curry ; inline
 464
 465 : (accumulate*) ( seq identity quot -- identity seq quot' )
 466     swapd [ dup ] compose ; inline
 467
 468 PRIVATE>
 469
 470 : each ( ... seq quot: ( ... x -- ... ) -- ... )
 471     sequence-operator each-integer-from ; inline
 472
 473 : each-from ( ... seq quot: ( ... x -- ... ) i -- ... )
 474     -rot length-operator each-integer-from ; inline
 475
 476 : reduce ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... result )
 477     swapd each ; inline
 478
 479 : map-integers-from-as ( ... from len quot: ( ... i -- ... elt ) exemplar -- ... newseq )
 480     overd [ [ collect-from ] keep ] new-like ; inline
 481
 482 : map-integers-as ( ... len quot: ( ... i -- ... elt ) exemplar -- ... newseq )
 483     overd [ [ collect ] keep ] new-like ; inline
 484
 485 : map-integers ( ... len quot: ( ... i -- ... elt ) -- ... newseq )
 486     { } map-integers-as ; inline
 487
 488 : map-as ( ... seq quot: ( ... elt -- ... newelt ) exemplar -- ... newseq )
 489     [ length-operator ] dip map-integers-as ; inline
 490
 491 : map ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 492     over map-as ; inline
 493
 494 : replicate-as ( ... len quot: ( ... -- ... newelt ) exemplar -- ... newseq )
 495     [ [ drop ] prepose ] dip map-integers-as ; inline
 496
 497 : replicate ( ... len quot: ( ... -- ... newelt ) -- ... newseq )
 498     { } replicate-as ; inline
 499
 500 : map! ( ... seq quot: ( ... elt -- ... newelt ) -- ... seq )
 501     over [ map-into ] keep ; inline
 502
 503 : accumulate-as ( ... seq identity quot: ( ... prev elt -- ... next ) exemplar -- ... final newseq )
 504     [ (accumulate) ] dip map-as ; inline
 505
 506 : accumulate ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... final newseq )
 507     pick accumulate-as ; inline
 508
 509 : accumulate! ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... final seq )
 510     (accumulate) map! ; inline
 511
 512 : accumulate*-as ( ... seq identity quot: ( ... prev elt -- ... next ) exemplar -- ... newseq )
 513     [ (accumulate*) ] dip map-as nip ; inline
 514
 515 : accumulate* ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... newseq )
 516     pick accumulate*-as ; inline
 517
 518 : accumulate*! ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... seq )
 519     (accumulate*) map! nip ; inline
 520
 521 : 2each ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ) -- ... )
 522     (2each) each-integer ; inline
 523
 524 : 2each-from ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ) i -- ... )
 525     [ (2each) ] dip -rot each-integer-from ; inline
 526
 527 : 2reduce ( ... seq1 seq2 identity quot: ( ... prev elt1 elt2 -- ... next ) -- ... result )
 528     -rotd 2each ; inline
 529
 530 : 2map-as ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) exemplar -- ... newseq )
 531     [ (2each) ] dip map-integers-as ; inline
 532
 533 : 2map ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... newseq )
 534     pick 2map-as ; inline
 535
 536 : 2all? ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... ? )
 537     (2each) all-integers? ; inline
 538
 539 : 2any? ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... ? )
 540     negate 2all? not ; inline
 541
 542 : 3each ( ... seq1 seq2 seq3 quot: ( ... elt1 elt2 elt3 -- ... ) -- ... )
 543     (3each) each-integer ; inline
 544
 545 : 3map-as ( ... seq1 seq2 seq3 quot: ( ... elt1 elt2 elt3 -- ... newelt ) exemplar -- ... newseq )
 546     [ (3each) ] dip map-integers-as ; inline
 547
 548 : 3map ( ... seq1 seq2 seq3 quot: ( ... elt1 elt2 elt3 -- ... newelt ) -- ... newseq )
 549     pickd swap 3map-as ; inline
 550
 551 <PRIVATE
 552
 553 : bounds-check-call ( n seq quot -- elt i )
 554     2over bounds-check? [ call ] [ 3drop f f ] if ; inline
 555
 556 : find-from-unsafe ( ... n seq quot: ( ... elt -- ... ? ) -- ... i elt )
 557     [ length-operator find-integer-from ] keepd
 558     index/element ; inline
 559
 560 : find-last-from-unsafe ( ... n seq quot: ( ... elt -- ... ? ) -- ... i elt )
 561     [ length-operator nip find-last-integer ] keepd
 562     index/element ; inline
 563
 564 PRIVATE>
 565
 566 : find-from ( ... n seq quot: ( ... elt -- ... ? ) -- ... i elt )
 567     '[ _ find-from-unsafe ] bounds-check-call ; inline
 568
 569 : find ( ... seq quot: ( ... elt -- ... ? ) -- ... i elt )
 570     [ 0 ] 2dip find-from-unsafe ; inline
 571
 572 : find-last-from ( ... n seq quot: ( ... elt -- ... ? ) -- ... i elt )
 573     '[ _ find-last-from-unsafe ] bounds-check-call ; inline
 574
 575 : find-last ( ... seq quot: ( ... elt -- ... ? ) -- ... i elt )
 576     [ index-of-last ] dip find-last-from ; inline
 577
 578 : find-index-from ( ... n seq quot: ( ... elt i -- ... ? ) -- ... i elt )
 579     '[
 580         _ [ sequence-index-operator find-integer-from ] keepd
 581         index/element
 582     ] bounds-check-call ; inline
 583
 584 : find-index ( ... seq quot: ( ... elt i -- ... ? ) -- ... i elt )
 585     [ 0 ] 2dip find-index-from ; inline
 586
 587 : all? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 588     sequence-operator all-integers-from? ; inline
 589
 590 : push-if ( ..a elt quot: ( ..a elt -- ..b ? ) accum -- ..b )
 591     [ keep ] dip rot [ push ] [ 2drop ] if ; inline
 592
 593 <PRIVATE
 594
 595 : (selector-as) ( quot length exemplar -- selector accum )
 596     new-resizable [ [ push-if ] 2curry ] keep ; inline
 597
 598 PRIVATE>
 599
 600 : selector-as ( quot exemplar -- selector accum )
 601     [ length ] keep (selector-as) ; inline
 602
 603 : selector ( quot -- selector accum )
 604     V{ } selector-as ; inline
 605
 606 : filter-as ( ... seq quot: ( ... elt -- ... ? ) exemplar -- ... subseq )
 607     pick length over [ (selector-as) [ each ] dip ] 2curry dip like ; inline
 608
 609 : filter ( ... seq quot: ( ... elt -- ... ? ) -- ... subseq )
 610     over filter-as ; inline
 611
 612 : reject-as ( ... seq quot: ( ... elt -- ... ? ) exemplar -- ... subseq )
 613     [ negate ] [ filter-as ] bi* ; inline
 614
 615 : reject ( ... seq quot: ( ... elt -- ... ? ) -- ... subseq )
 616     over reject-as ; inline
 617
 618 : push-either ( ..a elt quot: ( ..a elt -- ..b ? ) accum1 accum2 -- ..b )
 619     [ keep swap ] 2dip ? push ; inline
 620
 621 : 2selector ( quot -- selector accum1 accum2 )
 622     V{ } clone V{ } clone [ [ push-either ] 3curry ] 2keep ; inline
 623
 624 : partition ( ... seq quot: ( ... elt -- ... ? ) -- ... trueseq falseseq )
 625     over [ 2selector [ each ] 2dip ] dip [ like ] curry bi@ ; inline
 626
 627 : collector-for-as ( seq quot exemplar -- seq quot' vec )
 628     [ over length ] dip new-resizable [ [ push ] curry compose ] keep ; inline
 629
 630 : collector-as ( quot exemplar -- quot' vec )
 631     [ length ] keep new-resizable [ [ push ] curry compose ] keep ; inline
 632
 633 : collector-for ( seq quot -- seq quot' vec )
 634     V{ } collector-for-as ; inline
 635
 636 : collector ( quot -- quot' vec )
 637     V{ } collector-as ; inline
 638
 639 : produce-as ( ..a pred: ( ..a -- ..b ? ) quot: ( ..b -- ..a obj ) exemplar -- ..b seq )
 640     dup [ collector-as [ while ] dip ] curry dip like ; inline
 641
 642 : produce ( ..a pred: ( ..a -- ..b ? ) quot: ( ..b -- ..a obj ) -- ..b seq )
 643     { } produce-as ; inline
 644
 645 : follow ( ... obj quot: ( ... prev -- ... result/f ) -- ... seq )
 646     [ dup ] swap [ keep ] curry produce nip ; inline
 647
 648 : each-index ( ... seq quot: ( ... elt index -- ... ) -- ... )
 649     sequence-index-operator each-integer ; inline
 650
 651 : map-index-as ( ... seq quot: ( ... elt index -- ... newelt ) exemplar -- ... newseq )
 652     [ dup length <iota> ] 2dip 2map-as ; inline
 653
 654 : map-index ( ... seq quot: ( ... elt index -- ... newelt ) -- ... newseq )
 655     over map-index-as ; inline
 656
 657 : interleave ( ... seq between quot: ( ... elt -- ... ) -- ... )
 658     pick empty? [ 3drop ] [
 659         [ [ drop first-unsafe ] dip call ]
 660         [ [ bi* ] 2curry 1 each-from ]
 661         3bi
 662     ] if ; inline
 663
 664 : reduce-index ( ... seq identity quot: ( ... prev elt index -- ... next ) -- ... result )
 665     swapd each-index ; inline
 666
 667 : index ( obj seq -- n )
 668     [ = ] with find drop ;
 669
 670 : index-from ( obj i seq -- n )
 671     rot [ = ] curry find-from drop ;
 672
 673 : last-index ( obj seq -- n )
 674     [ = ] with find-last drop ;
 675
 676 : last-index-from ( obj i seq -- n )
 677     rot [ = ] curry find-last-from drop ;
 678
 679 : indices ( obj seq -- indices )
 680     swap [ = ] curry [ swap ] prepose V{ } clone [
 681         [ push ] curry [ [ drop ] if ] curry compose each-index
 682     ] keep ;
 683
 684 <PRIVATE
 685
 686 : nths-unsafe ( indices seq -- seq' )
 687     [ [ nth-unsafe ] curry ] keep map-as ;
 688
 689 PRIVATE>
 690
 691 : nths ( indices seq -- seq' )
 692     [ [ nth ] curry ] keep map-as ;
 693
 694 : any? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 695     find drop >boolean ; inline
 696
 697 : none? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 698     any? not ; inline
 699
 700 : member? ( elt seq -- ? )
 701     [ = ] with any? ;
 702
 703 : member-eq? ( elt seq -- ? )
 704     [ eq? ] with any? ;
 705
 706 : remove ( elt seq -- newseq )
 707     [ = ] with reject ;
 708
 709 : remove-eq ( elt seq -- newseq )
 710     [ eq? ] with reject ;
 711
 712 : sift ( seq -- newseq )
 713     [ ] filter ;
 714
 715 : harvest ( seq -- newseq )
 716     [ empty? ] reject ;
 717
 718 <PRIVATE
 719
 720 : mismatch-unsafe ( n seq1 seq2 -- i )
 721     [ 2nth-unsafe = not ] 2curry find-integer ; inline
 722
 723 PRIVATE>
 724
 725 : mismatch ( seq1 seq2 -- i )
 726     [ min-length ] 2keep mismatch-unsafe ;
 727
 728 M: sequence <=>
 729     [ mismatch ] 2keep pick
 730     [ 2nth-unsafe <=> ] [ [ length ] compare nip ] if ;
 731
 732 : sequence= ( seq1 seq2 -- ? )
 733     2dup [ length ] bi@ dupd =
 734     [ -rot mismatch-unsafe not ] [ 3drop f ] if ; inline
 735
 736 ERROR: assert-sequence got expected ;
 737
 738 : assert-sequence= ( a b -- )
 739     2dup sequence= [ 2drop ] [ assert-sequence ] if ;
 740
 741 M: reversed equal? over reversed? [ sequence= ] [ 2drop f ] if ;
 742
 743 M: slice equal? over slice? [ sequence= ] [ 2drop f ] if ;
 744
 745 <PRIVATE
 746
 747 : sequence-hashcode-step ( oldhash newpart -- newhash )
 748     integer>fixnum swap [
 749         [ -2 fixnum-shift-fast ] [ 5 fixnum-shift-fast ] bi
 750         fixnum+fast fixnum+fast
 751     ] keep fixnum-bitxor ; inline
 752
 753 PRIVATE>
 754
 755 : sequence-hashcode ( n seq -- x )
 756     [ 0 ] 2dip [ hashcode* sequence-hashcode-step ] with each ; inline
 757
 758 M: sequence hashcode* [ sequence-hashcode ] recursive-hashcode ;
 759
 760 M: iota hashcode*
 761     over 0 <= [ 2drop 0 ] [
 762         nip length 0 swap [ sequence-hashcode-step ] each-integer
 763     ] if ;
 764
 765 M: reversed hashcode* [ sequence-hashcode ] recursive-hashcode ;
 766
 767 M: slice hashcode* [ sequence-hashcode ] recursive-hashcode ;
 768
 769 : move ( to from seq -- )
 770     2over =
 771     [ 3drop ] [ [ nth swap ] [ set-nth ] bi ] if ; inline
 772
 773 <PRIVATE
 774
 775 : move-unsafe* ( to from seq -- from-nth )
 776     2over =
 777     [ nth-unsafe nip ]
 778     [ [ nth-unsafe tuck swap ] [ set-nth-unsafe ] bi ] if ; inline
 779
 780 : filter-from! ( store from seq quot: ( ... elt -- ... ? ) -- seq )
 781     2over length < [
 782         [ [ move-unsafe* ] dip call ] 4keep
 783         [ swap [ 1 + ] when ] 3dip
 784         [ 1 + ] 2dip filter-from!
 785     ] [ drop [ nip set-length ] keep ] if ; inline recursive
 786
 787 : move-unsafe ( to from seq -- )
 788     2over =
 789     [ 3drop ] [ [ nth-unsafe swap ] [ set-nth-unsafe ] bi ] if ; inline
 790
 791 PRIVATE>
 792
 793 : filter! ( ... seq quot: ( ... elt -- ... ? ) -- ... seq )
 794     [ 0 0 ] 2dip filter-from! ; inline
 795
 796 : reject! ( ... seq quot: ( ... elt -- ... ? ) -- ... seq )
 797     negate filter! ; inline
 798
 799 : remove! ( elt seq -- seq )
 800     [ = ] with reject! ;
 801
 802 : remove-eq! ( elt seq -- seq )
 803     [ eq? ] with reject! ;
 804
 805 : prefix ( seq elt -- newseq )
 806     over [ over length 1 + ] dip [
 807         (1sequence) [ 1 swap copy-unsafe ] keep
 808     ] new-like ;
 809
 810 : suffix ( seq elt -- newseq )
 811     over [ over length 1 + ] dip [
 812         [ [ over length ] dip set-nth-unsafe ] keep
 813         [ 0 swap copy-unsafe ] keep
 814     ] new-like ;
 815
 816 : suffix! ( seq elt -- seq ) over push ; inline
 817
 818 : append! ( seq1 seq2 -- seq1 ) over push-all ; inline
 819
 820 : last ( seq -- elt )
 821     index-of-last
 822     over 0 < [ bounds-error ] [ nth-unsafe ] if ; inline
 823
 824 <PRIVATE
 825
 826 : last-unsafe ( seq -- elt )
 827     index-of-last nth-unsafe ; inline
 828
 829 PRIVATE>
 830
 831 : set-last ( elt seq -- )
 832     index-of-last
 833     over 0 < [ bounds-error ] [ set-nth-unsafe ] if ; inline
 834
 835 : pop* ( seq -- ) index-of-last shorten ;
 836
 837 <PRIVATE
 838
 839 : move-backward ( shift from to seq -- )
 840     2over = [
 841         4drop
 842     ] [
 843         [ [ 2over + pick ] dip move-unsafe [ 1 + ] dip ] keep
 844         move-backward
 845     ] if ;
 846
 847 : move-forward ( shift from to seq -- )
 848     2over = [
 849         4drop
 850     ] [
 851         [ [ [ ] [ nip + ] [ 2nip ] 3tri ] dip move-unsafe 1 - ] keep
 852         move-forward
 853     ] if ;
 854
 855 : (open-slice) ( shift from to seq ? -- )
 856     [
 857         [ [ 1 - ] bi@ ] dip move-forward
 858     ] [
 859         [ over - ] 2dip move-backward
 860     ] if ;
 861
 862 : open-slice ( shift from seq -- )
 863     pick 0 = [
 864         3drop
 865     ] [
 866         [ ] [ nip length + ] [ 2nip ] 3tri
 867         [ pick 0 > [ [ length ] keep ] dip (open-slice) ] 2dip
 868         set-length
 869     ] if ;
 870
 871 PRIVATE>
 872
 873 : delete-slice ( from to seq -- )
 874     check-slice [ over [ - ] dip ] dip open-slice ;
 875
 876 : remove-nth! ( n seq -- seq )
 877     [ [ dup 1 + ] dip delete-slice ] keep ;
 878
 879 : snip ( from to seq -- head tail )
 880     [ swap head ] [ swap tail ] bi-curry bi* ; inline
 881
 882 : snip-slice ( from to seq -- head tail )
 883     [ swap head-slice ] [ swap tail-slice ] bi-curry bi* ; inline
 884
 885 : replace-slice ( new from to seq -- seq' )
 886     snip-slice surround ;
 887
 888 : remove-nth ( n seq -- seq' )
 889     [ [ dup 1 + ] dip snip-slice ] keep append-as ;
 890
 891 : pop ( seq -- elt )
 892     index-of-last over 0 >=
 893     [ [ nth-unsafe ] [ shorten ] 2bi ]
 894     [ bounds-error ] if ;
 895
 896 : exchange ( m n seq -- )
 897     [ nip bounds-check 2drop ]
 898     [ bounds-check 3drop ]
 899     [ exchange-unsafe ]
 900     3tri ;
 901
 902 : midpoint@ ( seq -- n ) length 2/ ; inline
 903
 904 : reverse! ( seq -- seq )
 905     [
 906         [ midpoint@ ] [ length ] [ ] tri
 907         [ [ over - 1 - ] dip exchange-unsafe ] 2curry
 908         each-integer
 909     ] keep ;
 910
 911 : reverse ( seq -- newseq )
 912      [
 913         dup [ length ] keep new-sequence
 914         [ 0 swap copy-unsafe ] keep reverse!
 915     ] keep like ;
 916
 917 GENERIC: sum-lengths ( seq -- n )
 918
 919 M: object sum-lengths
 920     0 [ length + ] reduce ;
 921
 922 M: repetition sum-lengths
 923     [ length>> ] [ elt>> length ] bi * ;
 924
 925 : concat-as ( seq exemplar -- newseq )
 926     [
 927         [ dup sum-lengths ] dip new-resizable
 928         [ [ push-all ] curry each ] keep
 929     ] keep like ; inline
 930
 931 : concat ( seq -- newseq )
 932     [ { } ] [ dup first concat-as ] if-empty ;
 933
 934 <PRIVATE
 935
 936 : joined-length ( seq glue -- n )
 937     [ [ sum-lengths ] [ length 1 [-] ] bi ] dip length * + ;
 938
 939 PRIVATE>
 940
 941 : join-as ( seq glue exemplar -- newseq )
 942     over empty? [ nip concat-as ] [
 943         [
 944             2dup joined-length over new-resizable [
 945                 [ [ push-all ] 2curry ]
 946                 [ nip [ push-all ] curry ] 2bi
 947                 interleave
 948             ] keep
 949         ] dip like
 950     ] if ;
 951
 952 : join ( seq glue -- newseq )
 953     dup join-as ; inline
 954
 955 <PRIVATE
 956
 957 : padding ( ... seq n elt quot: ( ... seq1 seq2 -- ... newseq ) -- ... newseq )
 958     [
 959         [ over length [-] dup 0 = [ drop ] ] dip
 960         [ <repetition> ] curry
 961     ] dip compose if ; inline
 962
 963 PRIVATE>
 964
 965 : pad-head ( seq n elt -- padded )
 966     [ swap dup append-as ] padding ;
 967
 968 : pad-tail ( seq n elt -- padded )
 969     [ append ] padding ;
 970
 971 : shorter? ( seq1 seq2 -- ? ) [ length ] bi@ < ; inline
 972 : longer? ( seq1 seq2 -- ? ) [ length ] bi@ > ; inline
 973 : shorter ( seq1 seq2 -- seq ) [ [ length ] bi@ <= ] 2keep ? ; inline
 974 : longer ( seq1 seq2 -- seq ) [ [ length ] bi@ >= ] 2keep ? ; inline
 975
 976 : head? ( seq begin -- ? )
 977     2dup shorter? [
 978         2drop f
 979     ] [
 980         [ length [ head-slice ] keep swap ] keep
 981         mismatch-unsafe not
 982     ] if ;
 983
 984 : tail? ( seq end -- ? )
 985     2dup shorter? [
 986         2drop f
 987     ] [
 988         [ length [ tail-slice* ] keep swap ] keep
 989         mismatch-unsafe not
 990     ] if ;
 991
 992 : cut-slice ( seq n -- before-slice after-slice )
 993     [ head-slice ] [ tail-slice ] 2bi ; inline
 994
 995 : cut-slice* ( seq n -- before-slice after-slice )
 996     [ head-slice* ] [ tail-slice* ] 2bi ;
 997
 998 : insert-nth ( elt n seq -- seq' )
 999     swap cut-slice [ swap suffix ] dip append ;
1000
1001 : halves ( seq -- first-slice second-slice )
1002     dup midpoint@ cut-slice ; inline
1003
1004 <PRIVATE
1005
1006 : nth2-unsafe ( n seq -- a b )
1007     [ nth-unsafe ] [ [ 1 + ] dip nth-unsafe ] 2bi ; inline
1008
1009 : nth3-unsafe ( n seq -- a b c )
1010     [ nth2-unsafe ] [ [ 2 + ] dip nth-unsafe ] 2bi ; inline
1011
1012 : (binary-reduce) ( seq start quot: ( elt1 elt2 -- newelt ) from length -- value )
1013     ! We can't use case here since combinators depends on
1014     ! sequences
1015     dup 4 < [
1016         integer>fixnum {
1017             [ 2drop nip ]
1018             [ 2nip swap nth-unsafe ]
1019             [ -rot [ drop swap nth2-unsafe ] dip call ]
1020             [ -rot [ drop swap nth3-unsafe ] dip bi@ ]
1021         } dispatch
1022     ] [
1023         [ 2/ ] [ over - ] bi [ 2dup + ] dip
1024         [ (binary-reduce) ] [ 2curry ] curry 2bi@
1025         pick [ 3bi ] dip call
1026     ] if ; inline recursive
1027
1028 PRIVATE>
1029
1030 : binary-reduce ( seq start quot: ( elt1 elt2 -- newelt ) -- value )
1031     pick dup slice? [
1032         [ seq>> ] 3dip [ from>> 0 max ] [ to>> 0 max over - ] bi
1033     ] [
1034         length 0 max 0 swap
1035     ] if (binary-reduce) ; inline
1036
1037 : cut ( seq n -- before after )
1038     [ head ] [ tail ] 2bi ;
1039
1040 : cut* ( seq n -- before after )
1041     [ head* ] [ tail* ] 2bi ;
1042
1043 : subseq-starts-at? ( i seq subseq -- ? )
1044     [ length swap ] keep
1045     '[
1046         [ + _ nth-unsafe ] keep _ nth-unsafe =
1047     ] with all-integers? ; inline
1048
1049 : subseq-index-from ( n seq subseq -- i/f )
1050     [ [ length ] bi@ - 1 + ] 2keep
1051     '[ _ _ subseq-starts-at? ] find-integer-from ; inline
1052
1053 : subseq-index ( seq subseq -- i/f ) [ 0 ] 2dip subseq-index-from ; inline
1054
1055 : subseq-of? ( seq subseq -- ? ) subseq-index >boolean ; inline
1056
1057 : subseq-start-from ( subseq seq n -- i/f )
1058     spin subseq-index-from ; inline deprecated
1059
1060 : subseq-start ( subseq seq -- i/f ) swap subseq-index ; inline deprecated
1061
1062 : subseq? ( subseq seq -- ? ) subseq-start >boolean ; inline deprecated
1063
1064 : drop-prefix ( seq1 seq2 -- slice1 slice2 )
1065     2dup mismatch [ 2dup min-length ] unless*
1066     [ tail-slice ] curry bi@ ;
1067
1068 : unclip ( seq -- rest first )
1069     [ rest ] [ first-unsafe ] bi ;
1070
1071 : unclip-last ( seq -- butlast last )
1072     [ but-last ] [ last-unsafe ] bi ;
1073
1074 : unclip-slice ( seq -- rest-slice first )
1075     [ rest-slice ] [ first-unsafe ] bi ; inline
1076
1077 : map-reduce ( ..a seq map-quot: ( ..a elt -- ..a intermediate ) reduce-quot: ( ..a prev intermediate -- ..a next ) -- ..a result )
1078     [ [ [ first ] keep ] dip [ dip ] keep ] dip
1079     '[ swap _ dip swap @ ] 1 each-from ; inline
1080
1081 : 2map-reduce ( ..a seq1 seq2 map-quot: ( ..a elt1 elt2 -- ..a intermediate ) reduce-quot: ( ..a prev intermediate -- ..a next ) -- ..a result )
1082     [ [ [ [ first ] bi@ ] 2keep ] dip [ 2dip ] keep ] dip
1083     '[ rot _ dip swap @ ] 1 2each-from ; inline
1084
1085 <PRIVATE
1086
1087 : (map-find) ( seq quot find-quot -- result elt )
1088     [ [ f ] 2dip [ nip ] prepose [ dup ] compose ] dip call nip ; inline
1089
1090 PRIVATE>
1091
1092 : map-find ( ... seq quot: ( ... elt -- ... result/f ) -- ... result elt )
1093     [ find ] (map-find) ; inline
1094
1095 : map-find-last ( ... seq quot: ( ... elt -- ... result/f ) -- ... result elt )
1096     [ find-last ] (map-find) ; inline
1097
1098 : unclip-last-slice ( seq -- butlast-slice last )
1099     [ but-last-slice ] [ last-unsafe ] bi ; inline
1100
1101 <PRIVATE
1102
1103 : (trim-head) ( seq quot -- seq n )
1104     over [ negate find drop ] dip swap
1105     [ dup length ] unless* ; inline
1106
1107 : (trim-tail) ( seq quot -- seq n )
1108     over [ negate find-last drop ?1+ ] dip
1109     swap ; inline
1110
1111 PRIVATE>
1112
1113 : trim-head-slice ( ... seq quot: ( ... elt -- ... ? ) -- ... slice )
1114     (trim-head) tail-slice ; inline
1115
1116 : trim-head ( ... seq quot: ( ... elt -- ... ? ) -- ... newseq )
1117     (trim-head) tail ; inline
1118
1119 : trim-tail-slice ( ... seq quot: ( ... elt -- ... ? ) -- ... slice )
1120     (trim-tail) head-slice ; inline
1121
1122 : trim-tail ( ... seq quot: ( ... elt -- ... ? ) -- ... newseq )
1123     (trim-tail) head ; inline
1124
1125 : trim-slice ( ... seq quot: ( ... elt -- ... ? ) -- ... slice )
1126     [ trim-head-slice ] [ trim-tail-slice ] bi ; inline
1127
1128 : trim ( ... seq quot: ( ... elt -- ... ? ) -- ... newseq )
1129     [ trim-slice ] [ drop ] 2bi like ; inline
1130
1131 GENERIC: sum ( seq -- n )
1132 M: object sum 0 [ + ] binary-reduce ; inline
1133 M: iota sum length dup 1 - * 2/ ; inline
1134 M: repetition sum [ elt>> ] [ length>> ] bi * ; inline
1135
1136 : product ( seq -- n ) 1 [ * ] binary-reduce ;
1137
1138 : infimum ( seq -- elt ) [ ] [ min ] map-reduce ;
1139
1140 : supremum ( seq -- elt ) [ ] [ max ] map-reduce ;
1141
1142 : map-sum ( ... seq quot: ( ... elt -- ... n ) -- ... n )
1143     [ 0 ] 2dip [ dip + ] curry [ swap ] prepose each ; inline
1144
1145 : count ( ... seq quot: ( ... elt -- ... ? ) -- ... n )
1146     [ 1 0 ? ] compose map-sum ; inline
1147
1148 : cartesian-each ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ) -- ... )
1149     [ with each ] 2curry each ; inline
1150
1151 : cartesian-map ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... newseq )
1152     [ with { } map-as ] 2curry { } map-as ; inline
1153
1154 : cartesian-product-as ( seq1 seq2 exemplar -- newseq )
1155     [ 2sequence ] curry cartesian-map ; inline
1156
1157 : cartesian-product ( seq1 seq2 -- newseq )
1158     dup cartesian-product-as ; inline
1159
1160 : cartesian-find ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... elt1 elt2 )
1161     [ f ] 3dip [ with find swap ] 2curry [ nip ] prepose find nip swap ; inline
1162
1163 <PRIVATE
1164
1165 : select-by ( ... seq quot: ( ... elt -- ... x ) compare: ( obj1 obj2 -- ? ) -- ... elt )
1166     [
1167         [ keep swap ] curry [ [ first ] dip call ] 2keep
1168         [ curry 2dip pick over ] curry
1169     ] [
1170         [ [ 2drop ] [ 2nipd ] if ] compose
1171     ] bi* compose 1 each-from drop ; inline
1172
1173 PRIVATE>
1174
1175 : supremum-by ( ... seq quot: ( ... elt -- ... x ) -- ... elt )
1176     [ after? ] select-by ; inline
1177
1178 : infimum-by ( ... seq quot: ( ... elt -- ... x ) -- ... elt )
1179     [ before? ] select-by ; inline
1180
1181 : shortest ( seqs -- elt ) [ length ] infimum-by ;
1182
1183 : longest ( seqs -- elt ) [ length ] supremum-by ;
1184
1185 ! We hand-optimize flip to such a degree because type hints
1186 ! cannot express that an array is an array of arrays yet, and
1187 ! this word happens to be performance-critical since the compiler
1188 ! itself uses it. Optimizing it like this reduced compile time.
1189 <PRIVATE
1190
1191 : generic-flip ( matrix -- newmatrix )
1192     [ [ length ] [ min ] map-reduce ] keep
1193     '[ _ [ nth-unsafe ] with { } map-as ] map-integers ; inline
1194
1195 USE: arrays
1196
1197 : array-flip ( matrix -- newmatrix )
1198     { array } declare
1199     [ [ { array } declare length>> ] [ min ] map-reduce ] keep
1200     '[ _ [ { array } declare array-nth ] with { } map-as ] map-integers ;
1201
1202 PRIVATE>
1203
1204 : flip ( matrix -- newmatrix )
1205     dup empty? [
1206         dup array? [
1207             dup [ array? ] all?
1208             [ array-flip ] [ generic-flip ] if
1209         ] [ generic-flip ] if
1210     ] unless ;