core/sequences/sequences.factor

   1 ! Copyright (C) 2005, 2009 Slava Pestov, Daniel Ehrenberg.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors kernel kernel.private slots.private math
   4 math.private math.order ;
   5 IN: sequences
   6
   7 MIXIN: sequence
   8
   9 GENERIC: length ( seq -- n ) flushable
  10 GENERIC: set-length ( n seq -- )
  11 GENERIC: nth ( n seq -- elt ) flushable
  12 GENERIC: set-nth ( elt n seq -- )
  13 GENERIC: new-sequence ( len seq -- newseq ) flushable
  14 GENERIC: new-resizable ( len seq -- newseq ) flushable
  15 GENERIC: like ( seq exemplar -- newseq ) flushable
  16 GENERIC: clone-like ( seq exemplar -- newseq ) flushable
  17
  18 : new-like ( len exemplar quot -- seq )
  19     over [ [ new-sequence ] dip call ] dip like ; inline
  20
  21 M: sequence like drop ;
  22
  23 GENERIC: lengthen ( n seq -- )
  24 GENERIC: shorten ( n seq -- )
  25
  26 M: sequence lengthen 2dup length > [ set-length ] [ 2drop ] if ;
  27
  28 M: sequence shorten 2dup length < [ set-length ] [ 2drop ] if ;
  29
  30 : empty? ( seq -- ? ) length 0 = ; inline
  31
  32 <PRIVATE
  33
  34 : (if-empty) ( seq quot1 quot2 quot3 -- )
  35     [ [ drop ] prepose ] [ ] tri* if ; inline
  36
  37 PRIVATE>
  38
  39 : if-empty ( seq quot1 quot2 -- )
  40     [ dup empty? ] (if-empty) ; inline
  41
  42 : when-empty ( seq quot -- ) [ ] if-empty ; inline
  43
  44 : unless-empty ( seq quot -- ) [ ] swap if-empty ; inline
  45
  46 : if-zero ( n quot1 quot2 -- )
  47     [ dup zero? ] (if-empty) ; inline
  48
  49 : when-zero ( n quot -- ) [ ] if-zero ; inline
  50
  51 : unless-zero ( n quot -- ) [ ] swap if-zero ; inline
  52
  53 : delete-all ( seq -- ) 0 swap set-length ;
  54
  55 : first ( seq -- first ) 0 swap nth ; inline
  56 : second ( seq -- second ) 1 swap nth ; inline
  57 : third ( seq -- third ) 2 swap nth ; inline
  58 : fourth ( seq -- fourth ) 3 swap nth ; inline
  59
  60 : set-first ( first seq -- ) 0 swap set-nth ; inline
  61 : set-second ( second seq -- ) 1 swap set-nth ; inline
  62 : set-third ( third seq -- ) 2 swap set-nth ; inline
  63 : set-fourth  ( fourth seq -- ) 3 swap set-nth ; inline
  64
  65 : push ( elt seq -- ) [ length ] [ set-nth ] bi ;
  66
  67 : bounds-check? ( n seq -- ? )
  68     dupd length < [ 0 >= ] [ drop f ] if ; inline
  69
  70 ERROR: bounds-error index seq ;
  71
  72 : bounds-check ( n seq -- n seq )
  73     2dup bounds-check? [ bounds-error ] unless ; inline
  74
  75 MIXIN: immutable-sequence
  76
  77 ERROR: immutable seq ;
  78
  79 M: immutable-sequence set-nth immutable ;
  80
  81 INSTANCE: immutable-sequence sequence
  82
  83 <PRIVATE
  84
  85 : array-nth ( n array -- elt )
  86     swap 2 fixnum+fast slot ; inline
  87
  88 : set-array-nth ( elt n array -- )
  89     swap 2 fixnum+fast set-slot ; inline
  90
  91 : dispatch ( n array -- ) array-nth call ;
  92
  93 GENERIC: resize ( n seq -- newseq ) flushable
  94
  95 ! Unsafe sequence protocol for inner loops
  96 GENERIC: nth-unsafe ( n seq -- elt ) flushable
  97 GENERIC: set-nth-unsafe ( elt n seq -- )
  98
  99 M: sequence nth bounds-check nth-unsafe ;
 100 M: sequence set-nth bounds-check set-nth-unsafe ;
 101
 102 M: sequence nth-unsafe nth ;
 103 M: sequence set-nth-unsafe set-nth ;
 104
 105 : change-nth-unsafe ( i seq quot -- )
 106     [ [ nth-unsafe ] dip call ] 3keep drop set-nth-unsafe ; inline
 107
 108 ! The f object supports the sequence protocol trivially
 109 M: f length drop 0 ;
 110 M: f nth-unsafe nip ;
 111 M: f like drop [ f ] when-empty ;
 112
 113 INSTANCE: f immutable-sequence
 114
 115 ! Integers support the sequence protocol
 116 M: integer length ;
 117 M: integer nth-unsafe drop ;
 118
 119 INSTANCE: integer immutable-sequence
 120
 121 PRIVATE>
 122
 123 ! In the future, this will replace integer sequences
 124 TUPLE: iota { n integer read-only } ;
 125
 126 : iota ( n -- iota ) \ iota boa ; inline
 127
 128 <PRIVATE
 129
 130 M: iota length n>> ;
 131 M: iota nth-unsafe drop ;
 132
 133 INSTANCE: iota immutable-sequence
 134
 135 : first-unsafe ( seq -- first )
 136     0 swap nth-unsafe ; inline
 137
 138 : first2-unsafe ( seq -- first second )
 139     [ first-unsafe ] [ 1 swap nth-unsafe ] bi ; inline
 140
 141 : first3-unsafe ( seq -- first second third )
 142     [ first2-unsafe ] [ 2 swap nth-unsafe ] bi ; inline
 143
 144 : first4-unsafe ( seq -- first second third fourth )
 145     [ first3-unsafe ] [ 3 swap nth-unsafe ] bi ; inline
 146
 147 : exchange-unsafe ( m n seq -- )
 148     [ [ nth-unsafe ] curry bi@ ]
 149     [ [ set-nth-unsafe ] curry bi@ ] 3bi ; inline
 150
 151 : (head) ( seq n -- from to seq ) [ 0 ] 2dip swap ; inline
 152
 153 : (tail) ( seq n -- from to seq ) swap [ length ] keep ; inline
 154
 155 : from-end ( seq n -- seq n' ) [ dup length ] dip - ; inline
 156
 157 : (1sequence) ( obj seq -- seq )
 158     [ 0 swap set-nth-unsafe ] keep ; inline
 159
 160 : (2sequence) ( obj1 obj2 seq -- seq )
 161     [ 1 swap set-nth-unsafe ] keep
 162     (1sequence) ; inline
 163
 164 : (3sequence) ( obj1 obj2 obj3 seq -- seq )
 165     [ 2 swap set-nth-unsafe ] keep
 166     (2sequence) ; inline
 167
 168 : (4sequence) ( obj1 obj2 obj3 obj4 seq -- seq )
 169     [ 3 swap set-nth-unsafe ] keep
 170     (3sequence) ; inline
 171
 172 PRIVATE>
 173
 174 : 1sequence ( obj exemplar -- seq )
 175     1 swap [ (1sequence) ] new-like ; inline
 176
 177 : 2sequence ( obj1 obj2 exemplar -- seq )
 178     2 swap [ (2sequence) ] new-like ; inline
 179
 180 : 3sequence ( obj1 obj2 obj3 exemplar -- seq )
 181     3 swap [ (3sequence) ] new-like ; inline
 182
 183 : 4sequence ( obj1 obj2 obj3 obj4 exemplar -- seq )
 184     4 swap [ (4sequence) ] new-like ; inline
 185
 186 : first2 ( seq -- first second )
 187     1 swap bounds-check nip first2-unsafe ; flushable
 188
 189 : first3 ( seq -- first second third )
 190     2 swap bounds-check nip first3-unsafe ; flushable
 191
 192 : first4 ( seq -- first second third fourth )
 193     3 swap bounds-check nip first4-unsafe ; flushable
 194
 195 : ?nth ( n seq -- elt/f )
 196     2dup bounds-check? [ nth-unsafe ] [ 2drop f ] if ; inline
 197
 198 MIXIN: virtual-sequence
 199 GENERIC: virtual-seq ( seq -- seq' )
 200 GENERIC: virtual@ ( n seq -- n' seq' )
 201
 202 M: virtual-sequence nth virtual@ nth ;
 203 M: virtual-sequence set-nth virtual@ set-nth ;
 204 M: virtual-sequence nth-unsafe virtual@ nth-unsafe ;
 205 M: virtual-sequence set-nth-unsafe virtual@ set-nth-unsafe ;
 206 M: virtual-sequence like virtual-seq like ;
 207 M: virtual-sequence new-sequence virtual-seq new-sequence ;
 208
 209 INSTANCE: virtual-sequence sequence
 210
 211 ! A reversal of an underlying sequence.
 212 TUPLE: reversed { seq read-only } ;
 213
 214 C: <reversed> reversed
 215
 216 M: reversed virtual-seq seq>> ;
 217
 218 M: reversed virtual@ seq>> [ length swap - 1 - ] keep ;
 219
 220 M: reversed length seq>> length ;
 221
 222 INSTANCE: reversed virtual-sequence
 223
 224 ! A slice of another sequence.
 225 TUPLE: slice
 226 { from read-only }
 227 { to read-only }
 228 { seq read-only } ;
 229
 230 : collapse-slice ( m n slice -- m' n' seq )
 231     [ from>> ] [ seq>> ] bi [ [ + ] curry bi@ ] dip ; inline
 232
 233 TUPLE: slice-error from to seq reason ;
 234
 235 : slice-error ( from to seq ? string -- from to seq )
 236     [ \ slice-error boa throw ] curry when ; inline
 237
 238 : check-slice ( from to seq -- from to seq )
 239     3dup
 240     [ 2drop 0 < "start < 0" slice-error ]
 241     [ [ drop ] 2dip length > "end > sequence" slice-error ]
 242     [ drop > "start > end" slice-error ]
 243     3tri ; inline
 244
 245 : <slice> ( from to seq -- slice )
 246     dup slice? [ collapse-slice ] when
 247     check-slice
 248     slice boa ; inline
 249
 250 M: slice virtual-seq seq>> ;
 251
 252 M: slice virtual@ [ from>> + ] [ seq>> ] bi ;
 253
 254 M: slice length [ to>> ] [ from>> ] bi - ;
 255
 256 : short ( seq n -- seq n' ) over length min ; inline
 257
 258 : head-slice ( seq n -- slice ) (head) <slice> ; inline
 259
 260 : tail-slice ( seq n -- slice ) (tail) <slice> ; inline
 261
 262 : rest-slice ( seq -- slice ) 1 tail-slice ; inline
 263
 264 : head-slice* ( seq n -- slice ) from-end head-slice ; inline
 265
 266 : tail-slice* ( seq n -- slice ) from-end tail-slice ; inline
 267
 268 : but-last-slice ( seq -- slice ) 1 head-slice* ; inline
 269
 270 INSTANCE: slice virtual-sequence
 271
 272 ! One element repeated many times
 273 TUPLE: repetition { len read-only } { elt read-only } ;
 274
 275 C: <repetition> repetition
 276
 277 M: repetition length len>> ;
 278 M: repetition nth-unsafe nip elt>> ;
 279
 280 INSTANCE: repetition immutable-sequence
 281
 282 <PRIVATE
 283
 284 ERROR: integer-length-expected obj ;
 285
 286 : check-length ( n -- n )
 287     #! Ricing.
 288     dup integer? [ integer-length-expected ] unless ; inline
 289
 290 : ((copy)) ( dst i src j n -- dst i src j n )
 291     dup -roll [
 292         + swap nth-unsafe -roll [
 293             + swap set-nth-unsafe
 294         ] 3keep drop
 295     ] 3keep ; inline
 296
 297 : (copy) ( dst i src j n -- dst )
 298     dup 0 <= [ 2drop 2drop ] [ 1 - ((copy)) (copy) ] if ;
 299     inline recursive
 300
 301 : prepare-subseq ( from to seq -- dst i src j n )
 302     #! The check-length call forces partial dispatch
 303     [ [ swap - ] dip new-sequence dup 0 ] 3keep
 304     -rot drop roll length check-length ; inline
 305
 306 : check-copy ( src n dst -- )
 307     over 0 < [ bounds-error ] when
 308     [ swap length + ] dip lengthen ; inline
 309
 310 PRIVATE>
 311
 312 : subseq ( from to seq -- subseq )
 313     [ check-slice prepare-subseq (copy) ] keep like ;
 314
 315 : head ( seq n -- headseq ) (head) subseq ;
 316
 317 : tail ( seq n -- tailseq ) (tail) subseq ;
 318
 319 : rest ( seq -- tailseq ) 1 tail ;
 320
 321 : head* ( seq n -- headseq ) from-end head ;
 322
 323 : tail* ( seq n -- tailseq ) from-end tail ;
 324
 325 : but-last ( seq -- headseq ) 1 head* ;
 326
 327 : copy ( src i dst -- )
 328     #! The check-length call forces partial dispatch
 329     pick length check-length [ 3dup check-copy spin 0 ] dip
 330     (copy) drop ; inline
 331
 332 M: sequence clone-like
 333     [ dup length ] dip new-sequence [ 0 swap copy ] keep ;
 334
 335 M: immutable-sequence clone-like like ;
 336
 337 : push-all ( src dest -- ) [ length ] [ copy ] bi ;
 338
 339 <PRIVATE
 340
 341 : (append) ( seq1 seq2 accum -- accum )
 342     [ [ over length ] dip copy ]
 343     [ 0 swap copy ]
 344     [ ] tri ; inline
 345
 346 PRIVATE>
 347
 348 : append-as ( seq1 seq2 exemplar -- newseq )
 349     [ over length over length + ] dip
 350     [ (append) ] new-like ; inline
 351
 352 : 3append-as ( seq1 seq2 seq3 exemplar -- newseq )
 353     [ 3dup [ length ] tri@ + + ] dip [
 354         [ [ 2over [ length ] bi@ + ] dip copy ]
 355         [ (append) ] bi
 356     ] new-like ; inline
 357
 358 : append ( seq1 seq2 -- newseq ) over append-as ;
 359
 360 : prepend ( seq1 seq2 -- newseq ) swap append ; inline
 361
 362 : 3append ( seq1 seq2 seq3 -- newseq ) pick 3append-as ;
 363
 364 : surround ( seq1 seq2 seq3 -- newseq ) swapd 3append ; inline
 365
 366 : glue ( seq1 seq2 seq3 -- newseq ) swap 3append ; inline
 367
 368 : change-nth ( i seq quot -- )
 369     [ [ nth ] dip call ] 3keep drop set-nth ; inline
 370
 371 : min-length ( seq1 seq2 -- n ) [ length ] bi@ min ; inline
 372
 373 : max-length ( seq1 seq2 -- n ) [ length ] bi@ max ; inline
 374
 375 <PRIVATE
 376
 377 : ((each)) ( seq -- n quot )
 378     [ length ] keep [ nth-unsafe ] curry ; inline
 379
 380 : (each) ( seq quot -- n quot' )
 381     [ ((each)) ] dip compose ; inline
 382
 383 : (each-index) ( seq quot -- n quot' )
 384     [ ((each)) [ keep ] curry ] dip compose ; inline
 385
 386 : (collect) ( quot into -- quot' )
 387     [ [ keep ] dip set-nth-unsafe ] 2curry ; inline
 388
 389 : collect ( n quot into -- )
 390     (collect) each-integer ; inline
 391
 392 : map-into ( seq quot into -- )
 393     [ (each) ] dip collect ; inline
 394
 395 : 2nth-unsafe ( n seq1 seq2 -- elt1 elt2 )
 396     [ nth-unsafe ] bi-curry@ bi ; inline
 397
 398 : (2each) ( seq1 seq2 quot -- n quot' )
 399     [
 400         [ min-length ] 2keep
 401         [ 2nth-unsafe ] 2curry
 402     ] dip compose ; inline
 403
 404 : 3nth-unsafe ( n seq1 seq2 seq3 -- elt1 elt2 elt3 )
 405     [ nth-unsafe ] tri-curry@ tri ; inline
 406
 407 : (3each) ( seq1 seq2 seq3 quot -- n quot' )
 408     [
 409         [ [ length ] tri@ min min ]
 410         [ [ 3nth-unsafe ] 3curry ] 3bi
 411     ] dip compose ; inline
 412
 413 : finish-find ( i seq -- i elt )
 414     over [ dupd nth-unsafe ] [ drop f ] if ; inline
 415
 416 : (find) ( seq quot quot' -- i elt )
 417     pick [ [ (each) ] dip call ] dip finish-find ; inline
 418
 419 : (find-from) ( n seq quot quot' -- i elt )
 420     [ 2dup bounds-check? ] 2dip
 421     [ (find) ] 2curry
 422     [ 2drop f f ]
 423     if ; inline
 424
 425 PRIVATE>
 426
 427 : each ( seq quot -- )
 428     (each) each-integer ; inline
 429
 430 : reduce ( seq identity quot -- result )
 431     swapd each ; inline
 432
 433 : map-integers ( len quot exemplar -- newseq )
 434     [ over ] dip [ [ collect ] keep ] new-like ; inline
 435
 436 : map-as ( seq quot exemplar -- newseq )
 437     [ (each) ] dip map-integers ; inline
 438
 439 : map ( seq quot -- newseq )
 440     over map-as ; inline
 441
 442 : replicate ( seq quot -- newseq )
 443     [ drop ] prepose map ; inline
 444
 445 : replicate-as ( seq quot exemplar -- newseq )
 446     [ [ drop ] prepose ] dip map-as ; inline
 447
 448 : change-each ( seq quot -- )
 449     over map-into ; inline
 450
 451 : accumulate ( seq identity quot -- final newseq )
 452     swapd [ [ call ] [ 2drop ] 3bi ] curry { } map-as ; inline
 453
 454 : 2each ( seq1 seq2 quot -- )
 455     (2each) each-integer ; inline
 456
 457 : 2reverse-each ( seq1 seq2 quot -- )
 458     [ [ <reversed> ] bi@ ] dip 2each ; inline
 459
 460 : 2reduce ( seq1 seq2 identity quot -- result )
 461     [ -rot ] dip 2each ; inline
 462
 463 : 2map-as ( seq1 seq2 quot exemplar -- newseq )
 464     [ (2each) ] dip map-integers ; inline
 465
 466 : 2map ( seq1 seq2 quot -- newseq )
 467     pick 2map-as ; inline
 468
 469 : 2all? ( seq1 seq2 quot -- ? )
 470     (2each) all-integers? ; inline
 471
 472 : 3each ( seq1 seq2 seq3 quot -- )
 473     (3each) each ; inline
 474
 475 : 3map-as ( seq1 seq2 seq3 quot exemplar -- newseq )
 476     [ (3each) ] dip map-integers ; inline
 477
 478 : 3map ( seq1 seq2 seq3 quot -- newseq )
 479     [ pick ] dip swap 3map-as ; inline
 480
 481 : find-from ( n seq quot -- i elt )
 482     [ (find-integer) ] (find-from) ; inline
 483
 484 : find ( seq quot -- i elt )
 485     [ find-integer ] (find) ; inline
 486
 487 : find-last-from ( n seq quot -- i elt )
 488     [ nip find-last-integer ] (find-from) ; inline
 489
 490 : find-last ( seq quot -- i elt )
 491     [ [ 1 - ] dip find-last-integer ] (find) ; inline
 492
 493 : all? ( seq quot -- ? )
 494     (each) all-integers? ; inline
 495
 496 : push-if ( elt quot accum -- )
 497     [ keep ] dip rot [ push ] [ 2drop ] if ; inline
 498
 499 : pusher ( quot -- quot accum )
 500     V{ } clone [ [ push-if ] 2curry ] keep ; inline
 501
 502 : filter ( seq quot -- subseq )
 503     over [ pusher [ each ] dip ] dip like ; inline
 504
 505 : push-either ( elt quot accum1 accum2 -- )
 506     [ keep swap ] 2dip ? push ; inline
 507
 508 : 2pusher ( quot -- quot accum1 accum2 )
 509     V{ } clone V{ } clone [ [ push-either ] 3curry ] 2keep ; inline
 510
 511 : partition ( seq quot -- trueseq falseseq )
 512     over [ 2pusher [ each ] 2dip ] dip [ like ] curry bi@ ; inline
 513
 514 : accumulator ( quot -- quot' vec )
 515     V{ } clone [ [ push ] curry compose ] keep ; inline
 516
 517 : produce-as ( pred quot exemplar -- seq )
 518     [ accumulator [ while ] dip ] dip like ; inline
 519
 520 : produce ( pred quot -- seq )
 521     { } produce-as ; inline
 522
 523 : follow ( obj quot -- seq )
 524     [ dup ] swap [ keep ] curry produce nip ; inline
 525
 526 : each-index ( seq quot -- )
 527     (each-index) each-integer ; inline
 528
 529 : interleave ( seq between quot -- )
 530     pick empty? [ 3drop ] [
 531         [ [ drop first-unsafe ] dip call ]
 532         [ [ rest-slice ] 2dip [ bi* ] 2curry each ]
 533         3bi
 534     ] if ; inline
 535
 536 : map-index ( seq quot -- newseq )
 537     [ dup length iota ] dip 2map ; inline
 538
 539 : reduce-index ( seq identity quot -- )
 540     swapd each-index ; inline
 541
 542 : index ( obj seq -- n )
 543     [ = ] with find drop ;
 544
 545 : index-from ( obj i seq -- n )
 546     rot [ = ] curry find-from drop ;
 547
 548 : last-index ( obj seq -- n )
 549     [ = ] with find-last drop ;
 550
 551 : last-index-from ( obj i seq -- n )
 552     rot [ = ] curry find-last-from drop ;
 553
 554 : (indices) ( elt i obj accum -- )
 555     [ swap [ = ] dip ] dip [ push ] 2curry when ; inline
 556
 557 : indices ( obj seq -- indices )
 558     swap V{ } clone
 559     [ [ (indices) ] 2curry each-index ] keep ;
 560
 561 : nths ( indices seq -- seq' )
 562     [ nth ] curry map ;
 563
 564 : any? ( seq quot -- ? )
 565     find drop >boolean ; inline
 566
 567 : member? ( elt seq -- ? )
 568     [ = ] with any? ;
 569
 570 : memq? ( elt seq -- ? )
 571     [ eq? ] with any? ;
 572
 573 : remove ( elt seq -- newseq )
 574     [ = not ] with filter ;
 575
 576 : remq ( elt seq -- newseq )
 577     [ eq? not ] with filter ;
 578
 579 : sift ( seq -- newseq )
 580     [ ] filter ;
 581
 582 : harvest ( seq -- newseq )
 583     [ empty? not ] filter ;
 584
 585 : mismatch ( seq1 seq2 -- i )
 586     [ min-length iota ] 2keep
 587     [ 2nth-unsafe = not ] 2curry
 588     find drop ; inline
 589
 590 M: sequence <=>
 591     2dup mismatch
 592     [ -rot 2nth-unsafe <=> ] [ [ length ] compare ] if* ;
 593
 594 : sequence= ( seq1 seq2 -- ? )
 595     2dup [ length ] bi@ =
 596     [ mismatch not ] [ 2drop f ] if ; inline
 597
 598 ERROR: assert-sequence got expected ;
 599
 600 : assert-sequence= ( a b -- )
 601     2dup sequence= [ 2drop ] [ assert-sequence ] if ;
 602
 603 : sequence-hashcode-step ( oldhash newpart -- newhash )
 604     >fixnum swap [
 605         [ -2 fixnum-shift-fast ] [ 5 fixnum-shift-fast ] bi
 606         fixnum+fast fixnum+fast
 607     ] keep fixnum-bitxor ; inline
 608
 609 : sequence-hashcode ( n seq -- x )
 610     [ 0 ] 2dip [ hashcode* sequence-hashcode-step ] with each ; inline
 611
 612 M: reversed equal? over reversed? [ sequence= ] [ 2drop f ] if ;
 613
 614 M: slice equal? over slice? [ sequence= ] [ 2drop f ] if ;
 615
 616 : move ( to from seq -- )
 617     2over =
 618     [ 3drop ] [ [ nth swap ] [ set-nth ] bi ] if ; inline
 619
 620 <PRIVATE
 621
 622 : (filter-here) ( quot: ( elt -- ? ) store scan seq -- )
 623     2dup length < [
 624         [ move ] 3keep
 625         [ nth-unsafe pick call [ 1 + ] when ] 2keep
 626         [ 1 + ] dip
 627         (filter-here)
 628     ] [ nip set-length drop ] if ; inline recursive
 629
 630 PRIVATE>
 631
 632 : filter-here ( seq quot -- )
 633     swap [ 0 0 ] dip (filter-here) ; inline
 634
 635 : delete ( elt seq -- )
 636     [ = not ] with filter-here ;
 637
 638 : delq ( elt seq -- )
 639     [ eq? not ] with filter-here ;
 640
 641 : prefix ( seq elt -- newseq )
 642     over [ over length 1 + ] dip [
 643         [ 0 swap set-nth-unsafe ] keep
 644         [ 1 swap copy ] keep
 645     ] new-like ;
 646
 647 : suffix ( seq elt -- newseq )
 648     over [ over length 1 + ] dip [
 649         [ [ over length ] dip set-nth-unsafe ] keep
 650         [ 0 swap copy ] keep
 651     ] new-like ;
 652
 653 : last ( seq -- elt ) [ length 1 - ] [ nth ] bi ;
 654
 655 : set-last ( elt seq -- ) [ length 1 - ] keep set-nth ;
 656
 657 : pop* ( seq -- ) [ length 1 - ] [ shorten ] bi ;
 658
 659 <PRIVATE
 660
 661 : move-backward ( shift from to seq -- )
 662     2over = [
 663         2drop 2drop
 664     ] [
 665         [ [ 2over + pick ] dip move [ 1 + ] dip ] keep
 666         move-backward
 667     ] if ;
 668
 669 : move-forward ( shift from to seq -- )
 670     2over = [
 671         2drop 2drop
 672     ] [
 673         [ [ pick [ dup dup ] dip + swap ] dip move 1 - ] keep
 674         move-forward
 675     ] if ;
 676
 677 : (open-slice) ( shift from to seq ? -- )
 678     [
 679         [ [ 1 - ] bi@ ] dip move-forward
 680     ] [
 681         [ over - ] 2dip move-backward
 682     ] if ;
 683
 684 : open-slice ( shift from seq -- )
 685     pick 0 = [
 686         3drop
 687     ] [
 688         pick over length + over
 689         [ pick 0 > [ [ length ] keep ] dip (open-slice) ] 2dip
 690         set-length
 691     ] if ;
 692
 693 PRIVATE>
 694
 695 : delete-slice ( from to seq -- )
 696     check-slice [ over [ - ] dip ] dip open-slice ;
 697
 698 : delete-nth ( n seq -- )
 699     [ dup 1 + ] dip delete-slice ;
 700
 701 : snip ( from to seq -- head tail )
 702     [ swap head ] [ swap tail ] bi-curry bi* ; inline
 703
 704 : snip-slice ( from to seq -- head tail )
 705     [ swap head-slice ] [ swap tail-slice ] bi-curry bi* ; inline
 706
 707 : replace-slice ( new from to seq -- seq' )
 708     snip-slice surround ;
 709
 710 : remove-nth ( n seq -- seq' )
 711     [ [ { } ] dip dup 1 + ] dip replace-slice ;
 712
 713 : pop ( seq -- elt )
 714     [ length 1 - ] [ [ nth ] [ shorten ] 2bi ] bi ;
 715
 716 : exchange ( m n seq -- )
 717     [ nip bounds-check 2drop ]
 718     [ bounds-check 3drop ]
 719     [ exchange-unsafe ]
 720     3tri ;
 721
 722 : reverse-here ( seq -- )
 723     [ length 2/ iota ] [ length ] [ ] tri
 724     [ [ over - 1 - ] dip exchange-unsafe ] 2curry each ;
 725
 726 : reverse ( seq -- newseq )
 727     [
 728         dup [ length ] keep new-sequence
 729         [ 0 swap copy ] keep
 730         [ reverse-here ] keep
 731     ] keep like ;
 732
 733 : sum-lengths ( seq -- n )
 734     0 [ length + ] reduce ;
 735
 736 : concat-as ( seq exemplar -- newseq )
 737     swap [ { } ] [
 738         [ sum-lengths over new-resizable ] keep
 739         [ over push-all ] each
 740     ] if-empty swap like ;
 741
 742 : concat ( seq -- newseq )
 743     [ { } ] [ dup first concat-as ] if-empty ;
 744
 745 <PRIVATE
 746
 747 : joined-length ( seq glue -- n )
 748     [ [ sum-lengths ] [ length 1 [-] ] bi ] dip length * + ;
 749
 750 PRIVATE>
 751
 752 : join ( seq glue -- newseq )
 753     dup empty? [ concat-as ] [
 754         [
 755             2dup joined-length over new-resizable [
 756                 [ [ push-all ] 2curry ] [ [ nip push-all ] 2curry ] 2bi
 757                 interleave
 758             ] keep
 759         ] keep like
 760     ] if ;
 761
 762 : padding ( seq n elt quot -- newseq )
 763     [
 764         [ over length [-] dup 0 = [ drop ] ] dip
 765         [ <repetition> ] curry
 766     ] dip compose if ; inline
 767
 768 : pad-head ( seq n elt -- padded )
 769     [ swap dup append-as ] padding ;
 770
 771 : pad-tail ( seq n elt -- padded )
 772     [ append ] padding ;
 773
 774 : shorter? ( seq1 seq2 -- ? ) [ length ] bi@ < ;
 775
 776 : head? ( seq begin -- ? )
 777     2dup shorter? [
 778         2drop f
 779     ] [
 780         [ nip ] [ length head-slice ] 2bi sequence=
 781     ] if ;
 782
 783 : tail? ( seq end -- ? )
 784     2dup shorter? [
 785         2drop f
 786     ] [
 787         [ nip ] [ length tail-slice* ] 2bi sequence=
 788     ] if ;
 789
 790 : cut-slice ( seq n -- before-slice after-slice )
 791     [ head-slice ] [ tail-slice ] 2bi ;
 792
 793 : insert-nth ( elt n seq -- seq' )
 794     swap cut-slice [ swap suffix ] dip append ;
 795
 796 : midpoint@ ( seq -- n ) length 2/ ; inline
 797
 798 : halves ( seq -- first-slice second-slice )
 799     dup midpoint@ cut-slice ;
 800
 801 : binary-reduce ( seq start quot: ( elt1 elt2 -- newelt ) -- value )
 802     #! We can't use case here since combinators depends on
 803     #! sequences
 804     pick length dup 0 3 between? [
 805         >fixnum {
 806             [ drop nip ]
 807             [ 2drop first ]
 808             [ [ drop first2 ] dip call ]
 809             [ [ drop first3 ] dip bi@ ]
 810         } dispatch
 811     ] [
 812         drop
 813         [ halves ] 2dip
 814         [ [ binary-reduce ] 2curry bi@ ] keep
 815         call
 816     ] if ; inline recursive
 817
 818 : cut ( seq n -- before after )
 819     [ head ] [ tail ] 2bi ;
 820
 821 : cut* ( seq n -- before after )
 822     [ head* ] [ tail* ] 2bi ;
 823
 824 <PRIVATE
 825
 826 : (start) ( subseq seq n -- subseq seq ? )
 827     pick length iota [
 828         [ 3dup ] dip [ + swap nth-unsafe ] keep rot nth-unsafe =
 829     ] all? nip ; inline
 830
 831 PRIVATE>
 832
 833 : start* ( subseq seq n -- i )
 834     pick length pick length swap - 1 + iota
 835     [ (start) ] find-from
 836     swap [ 3drop ] dip ;
 837
 838 : start ( subseq seq -- i ) 0 start* ; inline
 839
 840 : subseq? ( subseq seq -- ? ) start >boolean ;
 841
 842 : drop-prefix ( seq1 seq2 -- slice1 slice2 )
 843     2dup mismatch [ 2dup min-length ] unless*
 844     [ tail-slice ] curry bi@ ;
 845
 846 : unclip ( seq -- rest first )
 847     [ rest ] [ first-unsafe ] bi ;
 848
 849 : unclip-last ( seq -- butlast last )
 850     [ but-last ] [ last ] bi ;
 851
 852 : unclip-slice ( seq -- rest-slice first )
 853     [ rest-slice ] [ first-unsafe ] bi ; inline
 854
 855 : 2unclip-slice ( seq1 seq2 -- rest-slice1 rest-slice2 first1 first2 )
 856     [ unclip-slice ] bi@ swapd ; inline
 857
 858 : map-reduce ( seq map-quot reduce-quot -- result )
 859     [ [ unclip-slice ] dip [ call ] keep ] dip
 860     compose reduce ; inline
 861
 862 : 2map-reduce ( seq1 seq2 map-quot reduce-quot -- result )
 863     [ [ 2unclip-slice ] dip [ call ] keep ] dip
 864     compose 2reduce ; inline
 865
 866 <PRIVATE
 867
 868 : (map-find) ( seq quot find-quot -- result elt )
 869     [ [ f ] 2dip [ [ nip ] dip call dup ] curry ] dip call
 870     [ [ drop f ] unless ] dip ; inline
 871
 872 PRIVATE>
 873
 874 : map-find ( seq quot -- result elt )
 875     [ find ] (map-find) ; inline
 876
 877 : map-find-last ( seq quot -- result elt )
 878     [ find-last ] (map-find) ; inline
 879
 880 : unclip-last-slice ( seq -- butlast-slice last )
 881     [ but-last-slice ] [ last ] bi ; inline
 882
 883 : <flat-slice> ( seq -- slice )
 884     dup slice? [ { } like ] when
 885     [ drop 0 ] [ length ] [ ] tri <slice> ;
 886     inline
 887
 888 <PRIVATE
 889
 890 : (trim-head) ( seq quot -- seq n )
 891     over [ [ not ] compose find drop ] dip
 892     [ length or ] keep swap ; inline
 893
 894 : (trim-tail) ( seq quot -- seq n )
 895     over [ [ not ] compose find-last drop ?1+ ] dip
 896     swap ; inline
 897
 898 PRIVATE>
 899
 900 : trim-head-slice ( seq quot -- slice )
 901     (trim-head) tail-slice ; inline
 902
 903 : trim-head ( seq quot -- newseq )
 904     (trim-head) tail ; inline
 905
 906 : trim-tail-slice ( seq quot -- slice )
 907     (trim-tail) head-slice ; inline
 908
 909 : trim-tail ( seq quot -- newseq )
 910     (trim-tail) head ; inline
 911
 912 : trim-slice ( seq quot -- slice )
 913     [ trim-head-slice ] [ trim-tail-slice ] bi ; inline
 914
 915 : trim ( seq quot -- newseq )
 916     [ trim-slice ] [ drop ] 2bi like ; inline
 917
 918 : sum ( seq -- n ) 0 [ + ] binary-reduce ;
 919
 920 : product ( seq -- n ) 1 [ * ] binary-reduce ;
 921
 922 : infimum ( seq -- n ) [ ] [ min ] map-reduce ;
 923
 924 : supremum ( seq -- n ) [ ] [ max ] map-reduce ;
 925
 926 : sigma ( seq quot -- n )
 927     [ 0 ] 2dip [ dip + ] curry [ swap ] prepose each ; inline
 928
 929 : count ( seq quot -- n ) [ 1 0 ? ] compose sigma ; inline
 930
 931 ! We hand-optimize flip to such a degree because type hints
 932 ! cannot express that an array is an array of arrays yet, and
 933 ! this word happens to be performance-critical since the compiler
 934 ! itself uses it. Optimizing it like this reduced compile time.
 935 <PRIVATE
 936
 937 : generic-flip ( matrix -- newmatrix )
 938     [ dup first length [ length min ] reduce ] keep
 939     [ [ nth-unsafe ] with { } map-as ] curry { } map-as ; inline
 940
 941 USE: arrays
 942
 943 : array-length ( array -- len )
 944     { array } declare length>> ; inline
 945
 946 : array-flip ( matrix -- newmatrix )
 947     { array } declare
 948     [ dup first array-length [ array-length min ] reduce ] keep
 949     [ [ { array } declare array-nth ] with { } map-as ] curry { } map-as ;
 950
 951 PRIVATE>
 952
 953 : flip ( matrix -- newmatrix )
 954     dup empty? [
 955         dup array? [
 956             dup [ array? ] all?
 957             [ array-flip ] [ generic-flip ] if
 958         ] [ generic-flip ] if
 959     ] unless ;