core/sequences/sequences.factor

   1 ! Copyright (C) 2005, 2011 Slava Pestov, Daniel Ehrenberg.
   2 ! See https://factorcode.org/license.txt for BSD license.
   3 USING: accessors kernel kernel.private math math.order
   4 math.private slots.private ;
   5 IN: sequences
   6
   7 MIXIN: sequence
   8
   9 GENERIC: length ( seq -- n ) flushable
  10 GENERIC: set-length ( n seq -- )
  11 GENERIC: nth ( n seq -- elt ) flushable
  12 GENERIC: set-nth ( elt n seq -- )
  13 GENERIC: new-sequence ( len seq -- newseq ) flushable
  14 GENERIC: new-resizable ( len seq -- newseq ) flushable
  15 GENERIC: like ( seq exemplar -- newseq ) flushable
  16 GENERIC: clone-like ( seq exemplar -- newseq ) flushable
  17
  18 : lengthd ( seq obj -- n obj ) [ length ] dip ; inline
  19
  20 : new-sequence-like ( len-exemplar type-exemplar -- newseq )
  21     lengthd new-sequence ; inline
  22
  23 : new-resizable-like ( len-exemplar type-exemplar -- newseq )
  24     lengthd new-resizable ; inline
  25
  26 : new-like ( len exemplar quot -- seq )
  27     over [ [ new-sequence ] dip call ] dip like ; inline
  28
  29 M: sequence like drop ; inline
  30
  31 GENERIC: lengthen ( n seq -- )
  32 GENERIC: shorten ( n seq -- )
  33
  34 M: sequence lengthen 2dup length > [ set-length ] [ 2drop ] if ; inline
  35 M: sequence shorten 2dup length < [ set-length ] [ 2drop ] if ; inline
  36
  37 : nth-of ( seq n -- elt ) swap nth ; inline
  38 : set-nth-of ( seq n elt -- seq ) spin [ set-nth ] keep ; inline
  39
  40 : 2length ( seq1 seq2 -- n1 n2 ) [ length ] bi@ ; inline
  41 : 3length ( seq1 seq2 seq3 -- n1 n2 n3 ) [ length ] tri@ ; inline
  42
  43 : empty? ( seq -- ? ) length 0 = ; inline
  44
  45 : if-empty ( ..a seq quot1: ( ..a -- ..b ) quot2: ( ..a seq -- ..b ) -- ..b )
  46     [ dup empty? ] [ [ drop ] prepose ] [ ] tri* if ; inline
  47
  48 : when-empty ( ... seq quot: ( ... -- ... obj ) -- ... seq/obj ) [ ] if-empty ; inline
  49 : unless-empty ( ... seq quot: ( ... seq -- ... ) -- ... ) [ ] swap if-empty ; inline
  50
  51 : delete-all ( seq -- ) 0 swap set-length ;
  52
  53 : first ( seq -- first ) 0 swap nth ; inline
  54 : second ( seq -- second ) 1 swap nth ; inline
  55 : third ( seq -- third ) 2 swap nth ; inline
  56 : fourth ( seq -- fourth ) 3 swap nth ; inline
  57
  58 : set-first ( first seq -- ) 0 swap set-nth ; inline
  59 : set-second ( second seq -- ) 1 swap set-nth ; inline
  60 : set-third ( third seq -- ) 2 swap set-nth ; inline
  61 : set-fourth  ( fourth seq -- ) 3 swap set-nth ; inline
  62
  63 : push ( elt seq -- ) [ length ] [ set-nth ] bi ;
  64
  65 ERROR: bounds-error index seq ;
  66
  67 GENERIC#: bounds-check? 1 ( n seq -- ? )
  68
  69 M: integer bounds-check?
  70     dupd length < [ 0 >= ] [ drop f ] if ; inline
  71
  72 : bounds-check ( n seq -- n seq )
  73     2dup bounds-check? [ bounds-error ] unless ; inline
  74
  75 MIXIN: immutable-sequence
  76
  77 ERROR: immutable element index sequence ;
  78
  79 M: immutable-sequence set-nth immutable ;
  80
  81 INSTANCE: immutable-sequence sequence
  82
  83 <PRIVATE
  84
  85 : array-nth ( n array -- elt )
  86     swap 2 fixnum+fast slot ; inline
  87
  88 : set-array-nth ( elt n array -- )
  89     swap 2 fixnum+fast set-slot ; inline
  90
  91 : dispatch ( n array -- ) array-nth call ;
  92
  93 GENERIC: resize ( n seq -- newseq ) flushable
  94
  95 ! Unsafe sequence protocol for inner loops
  96 GENERIC: nth-unsafe ( n seq -- elt ) flushable
  97 GENERIC: set-nth-unsafe ( elt n seq -- )
  98
  99 M: sequence nth bounds-check nth-unsafe ; inline
 100 M: sequence set-nth bounds-check set-nth-unsafe ; inline
 101
 102 M: sequence nth-unsafe nth ; inline
 103 M: sequence set-nth-unsafe set-nth ; inline
 104
 105 : nth-of-unsafe ( seq n -- elt ) swap nth-unsafe ; inline
 106
 107 : set-nth-of-unsafe ( seq n elt -- seq ) swap pick set-nth-unsafe ; inline
 108
 109 : change-nth-unsafe ( i seq quot -- )
 110     [ [ nth-unsafe ] dip call ] 2keepd set-nth-unsafe ; inline
 111
 112 : change-nth-of-unsafe ( seq i quot -- seq )
 113     [ [ nth-of-unsafe ] dip call ] 2keepd rot set-nth-of-unsafe ; inline
 114
 115 PRIVATE>
 116
 117 ! The f object supports the sequence protocol trivially
 118 M: f length drop 0 ; inline
 119 M: f nth-unsafe nip ; inline
 120 M: f like drop [ f ] when-empty ; inline
 121
 122 INSTANCE: f immutable-sequence
 123
 124 ! Integer sequences
 125 TUPLE: iota { n integer read-only } ;
 126
 127 ERROR: non-negative-integer-expected n ;
 128
 129 : ensure-non-negative ( n -- n )
 130     dup 0 < [ non-negative-integer-expected ] when ; inline
 131
 132 : <iota> ( n -- iota )
 133     ensure-non-negative iota boa ; inline
 134
 135 M: iota length n>> ; inline
 136 M: iota nth-unsafe drop ; inline
 137
 138 INSTANCE: iota immutable-sequence
 139
 140 <PRIVATE
 141
 142 : first-unsafe ( seq -- first ) 0 swap nth-unsafe ; inline
 143 : second-unsafe ( seq -- second ) 1 swap nth-unsafe ; inline
 144 : third-unsafe ( seq -- third ) 2 swap nth-unsafe ; inline
 145 : fourth-unsafe ( seq -- fourth ) 3 swap nth-unsafe ; inline
 146
 147 : first2-unsafe ( seq -- first second )
 148     [ first-unsafe ] [ second-unsafe ] bi ; inline
 149
 150 : first3-unsafe ( seq -- first second third )
 151     [ first2-unsafe ] [ third-unsafe ] bi ; inline
 152
 153 : first4-unsafe ( seq -- first second third fourth )
 154     [ first3-unsafe ] [ fourth-unsafe ] bi ; inline
 155
 156 : exchange-unsafe ( m n seq -- )
 157     [ [ nth-unsafe ] curry bi@ ]
 158     [ [ set-nth-unsafe ] curry bi@ ] 3bi ; inline
 159
 160 : (1sequence) ( obj seq -- seq )
 161     [ 0 swap set-nth-unsafe ] keep ; inline
 162
 163 : (2sequence) ( obj1 obj2 seq -- seq )
 164     [ 1 swap set-nth-unsafe ] keep (1sequence) ; inline
 165
 166 : (3sequence) ( obj1 obj2 obj3 seq -- seq )
 167     [ 2 swap set-nth-unsafe ] keep (2sequence) ; inline
 168
 169 : (4sequence) ( obj1 obj2 obj3 obj4 seq -- seq )
 170     [ 3 swap set-nth-unsafe ] keep (3sequence) ; inline
 171
 172 PRIVATE>
 173
 174 : head-to-index ( seq to -- zero to seq ) [ 0 ] 2dip swap ; inline
 175
 176 : index-to-tail ( seq from -- from length seq ) swap [ length ] keep ; inline
 177
 178 : from-tail ( seq n -- seq n' ) [ dup length ] dip - ; inline
 179
 180 : 1sequence ( obj exemplar -- seq )
 181     1 swap [ (1sequence) ] new-like ; inline
 182
 183 : 2sequence ( obj1 obj2 exemplar -- seq )
 184     2 swap [ (2sequence) ] new-like ; inline
 185
 186 : 3sequence ( obj1 obj2 obj3 exemplar -- seq )
 187     3 swap [ (3sequence) ] new-like ; inline
 188
 189 : 4sequence ( obj1 obj2 obj3 obj4 exemplar -- seq )
 190     4 swap [ (4sequence) ] new-like ; inline
 191
 192 : first2 ( seq -- first second )
 193     1 swap bounds-check nip first2-unsafe ; inline
 194
 195 : first3 ( seq -- first second third )
 196     2 swap bounds-check nip first3-unsafe ; inline
 197
 198 : first4 ( seq -- first second third fourth )
 199     3 swap bounds-check nip first4-unsafe ; inline
 200
 201 : ??nth ( n seq -- elt/f ? )
 202     2dup bounds-check? [ nth-unsafe t ] [ 2drop f f ] if ; inline
 203
 204 : ?nth ( n seq -- elt/f )
 205     ??nth drop ; inline
 206
 207 : ?set-nth ( elt n seq -- )
 208     2dup bounds-check? [ set-nth-unsafe ] [ 3drop ] if ; inline
 209
 210 : ?nth-of ( seq n -- elt/f ) swap ?nth ; inline
 211
 212 : ??nth-of ( seq n -- elt/f ? ) swap ??nth ; inline
 213
 214 : index-or-length ( seq n -- seq n' ) over length min ; inline
 215
 216 : index-of-last ( seq -- n seq ) [ length 1 - ] keep ; inline
 217
 218 : ?first ( seq -- elt/f ) 0 swap ?nth ; inline
 219 : ?second ( seq -- elt/f ) 1 swap ?nth ; inline
 220 : ?last ( seq -- elt/f )
 221     index-of-last over 0 <
 222     [ 2drop f ] [ nth-unsafe ] if ; inline
 223
 224 MIXIN: virtual-sequence
 225 GENERIC: virtual-exemplar ( seq -- seq' )
 226 GENERIC: virtual@ ( n seq -- n' seq' )
 227
 228 M: virtual-sequence nth virtual@ nth ; inline
 229 M: virtual-sequence set-nth virtual@ set-nth ; inline
 230 M: virtual-sequence nth-unsafe virtual@ nth-unsafe ; inline
 231 M: virtual-sequence set-nth-unsafe virtual@ set-nth-unsafe ; inline
 232 M: virtual-sequence like virtual-exemplar like ; inline
 233 M: virtual-sequence new-sequence virtual-exemplar new-sequence ; inline
 234
 235 INSTANCE: virtual-sequence sequence
 236
 237 ! A reversal of an underlying sequence.
 238 TUPLE: reversed { seq read-only } ;
 239
 240 C: <reversed> reversed
 241
 242 M: reversed virtual-exemplar seq>> ; inline
 243 M: reversed virtual@ seq>> [ length swap - 1 - ] keep ; inline
 244 M: reversed length seq>> length ; inline
 245
 246 INSTANCE: reversed virtual-sequence
 247
 248 ! A slice of another sequence.
 249 TUPLE: slice
 250     { from integer read-only }
 251     { to integer read-only }
 252     { seq read-only } ;
 253
 254 : >slice< ( slice -- from to seq )
 255     [ from>> ] [ to>> ] [ seq>> ] tri ; inline
 256
 257 : collapse-slice ( m n slice -- m' n' seq )
 258     [ from>> ] [ seq>> ] bi [ [ + ] curry bi@ ] dip ; inline
 259
 260 ERROR: slice-error from to seq ;
 261
 262 : check-slice ( from to seq -- from to seq )
 263     pick 0 < [ slice-error ] when
 264     2dup length > [ slice-error ] when
 265     2over > [ slice-error ] when ; inline
 266
 267 <PRIVATE
 268
 269 : <slice-unsafe> ( from to seq -- slice )
 270     dup slice? [ collapse-slice ] when slice boa ; inline
 271
 272 PRIVATE>
 273
 274 : <slice> ( from to seq -- slice )
 275     check-slice <slice-unsafe> ; inline
 276
 277 M: slice virtual-exemplar seq>> ; inline
 278
 279 M: slice virtual@ [ from>> + ] [ seq>> ] bi ; inline
 280
 281 M: slice length [ to>> ] [ from>> ] bi - ; inline
 282
 283 : head-slice ( seq n -- slice ) head-to-index <slice> ; inline
 284
 285 : tail-slice ( seq n -- slice ) index-to-tail <slice> ; inline
 286
 287 : rest-slice ( seq -- slice ) 1 tail-slice ; inline
 288
 289 : head-slice* ( seq n -- slice ) from-tail head-slice ; inline
 290
 291 : tail-slice* ( seq n -- slice ) from-tail tail-slice ; inline
 292
 293 : but-last-slice ( seq -- slice ) 1 head-slice* ; inline
 294
 295 INSTANCE: slice virtual-sequence
 296
 297 ! One element repeated many times
 298 TUPLE: repetition
 299     { length integer read-only }
 300     { elt read-only } ;
 301
 302 : <repetition> ( len elt -- repetition )
 303     over 0 < [ non-negative-integer-expected ] when
 304     repetition boa ; inline
 305
 306 M: repetition length length>> ; inline
 307 M: repetition nth-unsafe nip elt>> ; inline
 308
 309 INSTANCE: repetition immutable-sequence
 310
 311 <PRIVATE
 312
 313 ERROR: integer-length-expected obj ;
 314
 315 ! The check-length call forces partial dispatch
 316 : check-length ( n -- n )
 317     dup integer? [ integer-length-expected ] unless ; inline
 318
 319 : >sequence< ( seq -- i n seq )
 320     [ drop 0 ] [ length check-length ] [ ] tri ; inline
 321
 322 : length-sequence ( seq -- n seq )
 323     [ length check-length ] [ ] bi ; inline
 324
 325 : >underlying< ( slice/seq -- from to slice/seq )
 326     dup slice? [ >slice< ] [ >sequence< ] if ; inline
 327
 328 TUPLE: copier
 329     { src-i integer read-only }
 330     { src read-only }
 331     { dst-i integer read-only }
 332     { dst read-only } ;
 333
 334 C: <copier> copier
 335
 336 : copy-nth-unsafe ( n copy -- )
 337     [ [ src-i>> + ] [ src>> ] bi nth-unsafe ]
 338     [ [ dst-i>> + ] [ dst>> ] bi set-nth-unsafe ] 2bi ; inline
 339
 340 : copy-nth-of-unsafe ( dst dst-i src src-i -- )
 341     nth-of-unsafe set-nth-of-unsafe drop ; inline
 342
 343 : (copy) ( n copy -- dst )
 344     over 0 <= [ nip dst>> ] [
 345         [ 1 - ] dip [ copy-nth-unsafe ] [ (copy) ] 2bi
 346     ] if ; inline recursive
 347
 348 : subseq>copy ( from to seq -- n copy )
 349     [ over - check-length swap ] dip
 350     3dup nip new-sequence 0 swap <copier> ; inline
 351
 352 : bounds-check-head ( n seq -- n seq )
 353     over 0 < [ bounds-error ] when ; inline
 354
 355 : check-grow-copy ( dst n src -- dst src n )
 356     over [ lengthd + lengthen ] 2keep ; inline
 357
 358 : copy-unsafe ( src i dst -- )
 359     [ [ length check-length 0 ] keep ] 2dip <copier> (copy) drop ; inline
 360
 361 : subseq-unsafe-as ( from to seq exemplar -- subseq )
 362     [ subseq>copy (copy) ] dip like ; inline
 363
 364 : subseq-unsafe ( from to seq -- subseq )
 365     dup subseq-unsafe-as ; inline
 366
 367 : copy-loop ( dst dst-i src src-i src-stop -- dst )
 368     2dup >= [
 369         4drop
 370     ] [
 371         [
 372             [ copy-nth-of-unsafe ] 4keep
 373             [ 1 + ] 2dip 1 +
 374         ] dip copy-loop
 375     ] if ; inline recursive
 376
 377 PRIVATE>
 378
 379 : subseq-as ( from to seq exemplar -- subseq )
 380     [ check-slice ] dip subseq-unsafe-as ;
 381
 382 : subseq ( from to seq -- subseq )
 383     dup subseq-as ;
 384
 385 : head ( seq n -- headseq ) head-to-index subseq ;
 386
 387 : tail ( seq n -- tailseq ) index-to-tail subseq ;
 388
 389 : rest ( seq -- tailseq ) 1 tail ;
 390
 391 : head* ( seq n -- headseq ) from-tail head ;
 392
 393 : tail* ( seq n -- tailseq ) from-tail tail ;
 394
 395 : but-last ( seq -- headseq ) 1 head* ;
 396
 397 : copy ( src i dst -- )
 398     3dup bounds-check-head
 399     [ swap length + ] dip lengthen
 400     copy-unsafe ; inline
 401
 402 M: sequence clone-like
 403     dupd new-sequence-like [ 0 swap copy-unsafe ] keep ; inline
 404
 405 M: immutable-sequence clone-like like ; inline
 406
 407 : push-all ( src dst -- ) [ length ] [ copy ] bi ; inline
 408
 409 <PRIVATE
 410
 411 : (append) ( seq1 seq2 accum -- accum )
 412     [ [ over length ] dip copy-unsafe ]
 413     [ 0 swap copy-unsafe ]
 414     [ ] tri ; inline
 415
 416 PRIVATE>
 417
 418 : append-as ( seq1 seq2 exemplar -- newseq )
 419     [ 2dup 2length + ] dip
 420     [ (append) ] new-like ; inline
 421
 422 : append ( seq1 seq2 -- newseq ) over append-as ;
 423
 424 : prepend-as ( seq1 seq2 exemplar -- newseq ) swapd append-as ; inline
 425
 426 : prepend ( seq1 seq2 -- newseq ) over prepend-as ;
 427
 428 : 3append-as ( seq1 seq2 seq3 exemplar -- newseq )
 429     [ 3dup 3length + + ] dip [
 430         [ [ 2over 2length + ] dip copy-unsafe ]
 431         [ (append) ] bi
 432     ] new-like ; inline
 433
 434 : 3append ( seq1 seq2 seq3 -- newseq ) pick 3append-as ;
 435
 436 : surround-as ( seq1 seq2 seq3 exemplar -- newseq )
 437     [ swap ] 2dip 3append-as ; inline
 438
 439 : surround ( seq1 seq2 seq3 -- newseq ) over surround-as ; inline
 440
 441 : 1surround-as ( seq1 seq2 exemplar  -- newseq ) dupd surround-as ; inline
 442
 443 : 1surround ( seq1 seq2 -- newseq ) dup 1surround-as ; inline
 444
 445 : glue-as ( seq1 seq2 seq3 exemplar -- newseq ) swapd 3append-as ; inline
 446
 447 : glue ( seq1 seq2 seq3 -- newseq ) pick glue-as ; inline
 448
 449 : change-nth ( ..a i seq quot: ( ..a elt -- ..b newelt ) -- ..b )
 450     [ [ nth ] dip call ] 2keepd set-nth-unsafe ; inline
 451
 452 : min-length ( seq1 seq2 -- n ) 2length min ; inline
 453
 454 : max-length ( seq1 seq2 -- n ) 2length max ; inline
 455
 456 <PRIVATE
 457
 458 : sequence-operator ( seq quot -- i n quot' )
 459     [ >underlying< [ nth-unsafe ] curry ] dip compose ; inline
 460
 461 : length-iterator ( seq -- n quot' )
 462     length-sequence [ nth-unsafe ] curry ; inline
 463
 464 : length-operator ( seq quot -- n quot' )
 465     [ length-iterator ] dip compose ; inline
 466
 467 : collect-into ( quot into -- quot' )
 468     [ [ keep ] dip set-nth-unsafe ] 2curry ; inline
 469
 470 : collect-from ( i n quot into -- )
 471     collect-into each-integer-from ; inline
 472
 473 : collect ( n quot into -- )
 474     collect-into each-integer ; inline
 475
 476 : sequence-index-operator ( seq quot -- n quot' )
 477     [ length-iterator [ keep ] curry ] dip compose ; inline
 478
 479 : map-into ( seq quot into -- )
 480     [ length-operator ] dip collect ; inline
 481
 482 : 2nth-unsafe ( n seq1 seq2 -- elt1 elt2 )
 483     [ nth-unsafe ] bi-curry@ bi ; inline
 484
 485 : 2length-iterator ( seq1 seq2 -- n quot )
 486     [ min-length check-length ] 2keep [ 2nth-unsafe ] 2curry ; inline
 487
 488 : 2length-operator ( seq1 seq2 quot -- n quot' )
 489     [ 2length-iterator ] dip compose ; inline
 490
 491 : 3nth-unsafe ( n seq1 seq2 seq3 -- elt1 elt2 elt3 )
 492     [ nth-unsafe ] tri-curry@ tri ; inline
 493
 494 : 3length-iterator ( seq1 seq2 seq3 -- n quot )
 495     [ 3length min min check-length ]
 496     [ [ 3nth-unsafe ] 3curry ] 3bi ; inline
 497
 498 : 3length-operator ( seq1 seq2 seq3 quot -- n quot' )
 499     [ 3length-iterator ] dip compose ; inline
 500
 501 : element/index ( i/f seq -- elt/f i/f )
 502     '[ [ _ nth ] [ f ] if* ] keep ; inline
 503
 504 : index/element ( i/f seq -- i/f elt/f )
 505     dupd '[ _ nth ] [ f ] if* ; inline
 506
 507 : (accumulate) ( seq identity quot -- identity seq quot' )
 508     swapd [ keepd ] curry ; inline
 509
 510 : (accumulate*) ( seq identity quot -- identity seq quot' )
 511     swapd [ dup ] compose ; inline
 512
 513 PRIVATE>
 514
 515 : each ( ... seq quot: ( ... x -- ... ) -- ... )
 516     sequence-operator each-integer-from ; inline
 517
 518 : each-from ( ... seq quot: ( ... x -- ... ) i -- ... )
 519     -rot length-operator each-integer-from ; inline
 520
 521 : reduce ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... result )
 522     swapd each ; inline
 523
 524 : map-integers-from-as ( ... from len quot: ( ... i -- ... elt ) exemplar -- ... newseq )
 525     overd [ [ collect-from ] keep ] new-like ; inline
 526
 527 : map-integers-as ( ... len quot: ( ... i -- ... elt ) exemplar -- ... newseq )
 528     overd [ [ collect ] keep ] new-like ; inline
 529
 530 : map-integers ( ... len quot: ( ... i -- ... elt ) -- ... newseq )
 531     { } map-integers-as ; inline
 532
 533 : map-as ( ... seq quot: ( ... elt -- ... newelt ) exemplar -- ... newseq )
 534     [ length-operator ] dip map-integers-as ; inline
 535
 536 : map ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 537     over map-as ; inline
 538
 539 : replicate-as ( ... len quot: ( ... -- ... newelt ) exemplar -- ... newseq )
 540     [ [ drop ] prepose ] dip map-integers-as ; inline
 541
 542 : replicate ( ... len quot: ( ... -- ... newelt ) -- ... newseq )
 543     { } replicate-as ; inline
 544
 545 : map! ( ... seq quot: ( ... elt -- ... newelt ) -- ... seq )
 546     over [ map-into ] keep ; inline
 547
 548 : accumulate-as ( ... seq identity quot: ( ... prev elt -- ... next ) exemplar -- ... final newseq )
 549     [ (accumulate) ] dip map-as ; inline
 550
 551 : accumulate ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... final newseq )
 552     pick accumulate-as ; inline
 553
 554 : accumulate! ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... final seq )
 555     (accumulate) map! ; inline
 556
 557 : accumulate*-as ( ... seq identity quot: ( ... prev elt -- ... next ) exemplar -- ... newseq )
 558     [ (accumulate*) ] dip map-as nip ; inline
 559
 560 : accumulate* ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... newseq )
 561     pick accumulate*-as ; inline
 562
 563 : accumulate*! ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... seq )
 564     (accumulate*) map! nip ; inline
 565
 566 : 2each ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ) -- ... )
 567     2length-operator each-integer ; inline
 568
 569 : 2each-from ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ) from -- ... )
 570     -roll 2length-operator each-integer-from ; inline
 571
 572 : 2reduce ( ... seq1 seq2 identity quot: ( ... prev elt1 elt2 -- ... next ) -- ... result )
 573     -rotd 2each ; inline
 574
 575 : 2map-as ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) exemplar -- ... newseq )
 576     [ 2length-operator ] dip map-integers-as ; inline
 577
 578 : 2map ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... newseq )
 579     pick 2map-as ; inline
 580
 581 : 2all? ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... ? )
 582     2length-operator all-integers? ; inline
 583
 584 : 2any? ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... ? )
 585     negate 2all? not ; inline
 586
 587 : 3each ( ... seq1 seq2 seq3 quot: ( ... elt1 elt2 elt3 -- ... ) -- ... )
 588     3length-operator each-integer ; inline
 589
 590 : 3map-as ( ... seq1 seq2 seq3 quot: ( ... elt1 elt2 elt3 -- ... newelt ) exemplar -- ... newseq )
 591     [ 3length-operator ] dip map-integers-as ; inline
 592
 593 : 3map ( ... seq1 seq2 seq3 quot: ( ... elt1 elt2 elt3 -- ... newelt ) -- ... newseq )
 594     pickd swap 3map-as ; inline
 595
 596 <PRIVATE
 597
 598 : bounds-check-call ( n seq quot -- obj1 obj2 )
 599     2over bounds-check? [ call ] [ 3drop f f ] if ; inline
 600
 601 : find-from-unsafe ( ... n seq quot: ( ... elt -- ... ? ) -- ... i/f seq )
 602     [ length-operator find-integer-from ] keepd ; inline
 603
 604 : find-last-from-unsafe ( ... n seq quot: ( ... elt -- ... ? ) -- ... i/f seq )
 605     [ length-operator nip find-last-integer ] keepd ; inline
 606
 607 PRIVATE>
 608
 609 : find-from ( ... n seq quot: ( ... elt -- ... ? ) -- ... i elt )
 610     '[ _ find-from-unsafe index/element ] bounds-check-call ; inline
 611
 612 : find ( ... seq quot: ( ... elt -- ... ? ) -- ... i elt )
 613     [ 0 ] 2dip find-from-unsafe index/element ; inline
 614
 615 : find-last-from ( ... n seq quot: ( ... elt -- ... ? ) -- ... i elt )
 616     '[ _ find-last-from-unsafe index/element ] bounds-check-call ; inline
 617
 618 : find-last ( ... seq quot: ( ... elt -- ... ? ) -- ... i elt )
 619     [ index-of-last ] dip find-last-from ; inline
 620
 621 : find-index-from ( ... n seq quot: ( ... elt i -- ... ? ) -- ... i elt )
 622     '[
 623         _ [ sequence-index-operator find-integer-from ] keepd
 624         index/element
 625     ] bounds-check-call ; inline
 626
 627 : find-index ( ... seq quot: ( ... elt i -- ... ? ) -- ... i elt )
 628     [ 0 ] 2dip find-index-from ; inline
 629
 630 : find-from* ( ... n seq quot: ( ... elt -- ... ? ) -- ... elt i/f )
 631     '[ _ find-from-unsafe element/index ] bounds-check-call ; inline
 632
 633 : find* ( ... seq quot: ( ... elt -- ... ? ) -- ... elt i/f )
 634     [ 0 ] 2dip find-from-unsafe element/index ; inline
 635
 636 : find-last-from* ( ... n seq quot: ( ... elt -- ... ? ) -- ... elt i/f )
 637     '[ _ find-last-from-unsafe element/index ] bounds-check-call ; inline
 638
 639 : find-last* ( ... seq quot: ( ... elt -- ... ? ) -- ... elt i/f )
 640     [ index-of-last ] dip find-last-from* ; inline
 641
 642 : find-index-from* ( ... n seq quot: ( ... elt i -- ... ? ) -- ... elt i/f )
 643     '[
 644         _ [ sequence-index-operator find-integer-from ] keepd
 645         element/index
 646     ] bounds-check-call ; inline
 647
 648 : find-index* ( ... seq quot: ( ... elt i -- ... ? ) -- ... elt i/f )
 649     [ 0 ] 2dip find-index-from* ; inline
 650
 651 : all? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 652     sequence-operator all-integers-from? ; inline
 653
 654 : push-when ( ..a elt quot: ( ..a elt -- ..b ? ) accum -- ..b )
 655     [ keep ] dip rot [ push ] [ 2drop ] if ; inline
 656
 657 <PRIVATE
 658
 659 : (selector-as) ( quot length exemplar -- selector accum )
 660     new-resizable [ [ push-when ] 2curry ] keep ; inline
 661
 662 PRIVATE>
 663
 664 : selector-as ( quot exemplar -- selector accum )
 665     [ length ] keep (selector-as) ; inline
 666
 667 : selector ( quot -- selector accum )
 668     V{ } selector-as ; inline
 669
 670 : filter-as ( ... seq quot: ( ... elt -- ... ? ) exemplar -- ... subseq )
 671     pick length over [ (selector-as) [ each ] dip ] 2curry dip like ; inline
 672
 673 : filter ( ... seq quot: ( ... elt -- ... ? ) -- ... subseq )
 674     over filter-as ; inline
 675
 676 : reject-as ( ... seq quot: ( ... elt -- ... ? ) exemplar -- ... subseq )
 677     [ negate ] [ filter-as ] bi* ; inline
 678
 679 : reject ( ... seq quot: ( ... elt -- ... ? ) -- ... subseq )
 680     over reject-as ; inline
 681
 682 : push-either ( ..a elt quot: ( ..a elt -- ..b ? ) accum1 accum2 -- ..b )
 683     [ keep swap ] 2dip ? push ; inline
 684
 685 : 2selector ( quot -- selector accum1 accum2 )
 686     V{ } clone V{ } clone [ [ push-either ] 3curry ] 2keep ; inline
 687
 688 : partition ( ... seq quot: ( ... elt -- ... ? ) -- ... trueseq falseseq )
 689     over [ 2selector [ each ] 2dip ] dip [ like ] curry bi@ ; inline
 690
 691 : collector-as ( quot exemplar -- quot' vec )
 692     dup new-resizable-like [ [ push ] curry compose ] keep ; inline
 693
 694 : collector ( quot -- quot' vec )
 695     V{ } collector-as ; inline
 696
 697 : produce-as ( ..a pred: ( ..a -- ..b ? ) quot: ( ..b -- ..a obj ) exemplar -- ..b seq )
 698     dup [ collector-as [ while ] dip ] curry dip like ; inline
 699
 700 : produce ( ..a pred: ( ..a -- ..b ? ) quot: ( ..b -- ..a obj ) -- ..b seq )
 701     { } produce-as ; inline
 702
 703 : follow ( ... obj quot: ( ... prev -- ... result/f ) -- ... seq )
 704     [ dup ] swap [ keep ] curry produce nip ; inline
 705
 706 : each-index ( ... seq quot: ( ... elt index -- ... ) -- ... )
 707     sequence-index-operator each-integer ; inline
 708
 709 : map-index-as ( ... seq quot: ( ... elt index -- ... newelt ) exemplar -- ... newseq )
 710     [ dup length <iota> ] 2dip 2map-as ; inline
 711
 712 : map-index ( ... seq quot: ( ... elt index -- ... newelt ) -- ... newseq )
 713     over map-index-as ; inline
 714
 715 : interleave ( ... seq between quot: ( ... elt -- ... ) -- ... )
 716     pick empty? [ 3drop ] [
 717         [ [ drop first-unsafe ] dip call ]
 718         [ [ bi* ] 2curry 1 each-from ]
 719         3bi
 720     ] if ; inline
 721
 722 : reduce-index ( ... seq identity quot: ( ... prev elt index -- ... next ) -- ... result )
 723     swapd each-index ; inline
 724
 725 : index ( obj seq -- n )
 726     [ = ] with find drop ;
 727
 728 : index-from ( obj i seq -- n )
 729     rot [ = ] curry find-from drop ;
 730
 731 : last-index ( obj seq -- n )
 732     [ = ] with find-last drop ;
 733
 734 : last-index-from ( obj i seq -- n )
 735     rot [ = ] curry find-last-from drop ;
 736
 737 : indices ( obj seq -- indices )
 738     swap [ = ] curry [ swap ] prepose V{ } clone [
 739         [ push ] curry [ [ drop ] if ] curry compose each-index
 740     ] keep ;
 741
 742 <PRIVATE
 743
 744 : nths-unsafe ( indices seq -- seq' )
 745     [ [ nth-unsafe ] curry ] keep map-as ;
 746
 747 PRIVATE>
 748
 749 : nths ( indices seq -- seq' )
 750     [ [ nth ] curry ] keep map-as ;
 751
 752 : nths-of ( seq indices -- seq' )
 753     swap nths ; inline
 754
 755 : any? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 756     find drop >boolean ; inline
 757
 758 : none? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 759     any? not ; inline
 760
 761 : member? ( elt seq -- ? )
 762     [ = ] with any? ;
 763
 764 : member-eq? ( elt seq -- ? )
 765     [ eq? ] with any? ;
 766
 767 : remove ( elt seq -- newseq )
 768     [ = ] with reject ;
 769
 770 : remove-eq ( elt seq -- newseq )
 771     [ eq? ] with reject ;
 772
 773 : sift ( seq -- newseq )
 774     [ ] filter ;
 775
 776 : harvest ( seq -- newseq )
 777     [ empty? ] reject ;
 778
 779 <PRIVATE
 780
 781 : mismatch-unsafe ( n seq1 seq2 -- i )
 782     [ 2nth-unsafe = not ] 2curry find-integer ; inline
 783
 784 PRIVATE>
 785
 786 : mismatch ( seq1 seq2 -- i )
 787     [ min-length ] 2keep mismatch-unsafe ;
 788
 789 M: sequence <=>
 790     [ mismatch ] 2keep pick
 791     [ 2nth-unsafe <=> ] [ [ length ] compare nip ] if ;
 792
 793 : sequence= ( seq1 seq2 -- ? )
 794     2dup 2length dupd =
 795     [ -rot mismatch-unsafe not ] [ 3drop f ] if ; inline
 796
 797 ERROR: assert-sequence got expected ;
 798
 799 : assert-sequence= ( a b -- )
 800     2dup sequence= [ 2drop ] [ assert-sequence ] if ;
 801
 802 M: reversed equal? over reversed? [ sequence= ] [ 2drop f ] if ;
 803
 804 M: slice equal? over slice? [ sequence= ] [ 2drop f ] if ;
 805
 806 <PRIVATE
 807
 808 : sequence-hashcode-step ( oldhash newpart -- newhash )
 809     integer>fixnum swap [
 810         [ -2 fixnum-shift-fast ] [ 5 fixnum-shift-fast ] bi
 811         fixnum+fast fixnum+fast
 812     ] keep fixnum-bitxor ; inline
 813
 814 PRIVATE>
 815
 816 : sequence-hashcode ( n seq -- x )
 817     [ 0 ] 2dip [ hashcode* sequence-hashcode-step ] with each ; inline
 818
 819 M: sequence hashcode* [ sequence-hashcode ] recursive-hashcode ;
 820
 821 M: iota hashcode*
 822     over 0 <= [ 2drop 0 ] [
 823         nip length 0 swap [ sequence-hashcode-step ] each-integer
 824     ] if ;
 825
 826 M: reversed hashcode* [ sequence-hashcode ] recursive-hashcode ;
 827
 828 M: slice hashcode* [ sequence-hashcode ] recursive-hashcode ;
 829
 830 : move ( to from seq -- )
 831     2over =
 832     [ 3drop ] [ [ nth swap ] [ set-nth ] bi ] if ; inline
 833
 834 <PRIVATE
 835
 836 : move-unsafe* ( to from seq -- from-nth )
 837     2over =
 838     [ nth-unsafe nip ]
 839     [ [ nth-unsafe tuck swap ] [ set-nth-unsafe ] bi ] if ; inline
 840
 841 : filter-from! ( store from seq quot: ( ... elt -- ... ? ) -- seq )
 842     2over length < [
 843         [ [ move-unsafe* ] dip call ] 4keep
 844         [ swap [ 1 + ] when ] 3dip
 845         [ 1 + ] 2dip filter-from!
 846     ] [ drop [ nip set-length ] keep ] if ; inline recursive
 847
 848 : move-unsafe ( to from seq -- )
 849     2over =
 850     [ 3drop ] [ [ nth-unsafe swap ] [ set-nth-unsafe ] bi ] if ; inline
 851
 852 PRIVATE>
 853
 854 : filter! ( ... seq quot: ( ... elt -- ... ? ) -- ... seq )
 855     [ 0 0 ] 2dip filter-from! ; inline
 856
 857 : reject! ( ... seq quot: ( ... elt -- ... ? ) -- ... seq )
 858     negate filter! ; inline
 859
 860 : remove! ( elt seq -- seq )
 861     [ = ] with reject! ;
 862
 863 : remove-eq! ( elt seq -- seq )
 864     [ eq? ] with reject! ;
 865
 866 : prefix ( seq elt -- newseq )
 867     over [ over length 1 + ] dip [
 868         (1sequence) [ 1 swap copy-unsafe ] keep
 869     ] new-like ;
 870
 871 : suffix ( seq elt -- newseq )
 872     over [ over length 1 + ] dip [
 873         [ [ over length ] dip set-nth-unsafe ] keep
 874         [ 0 swap copy-unsafe ] keep
 875     ] new-like ;
 876
 877 : suffix! ( seq elt -- seq ) over push ; inline
 878
 879 : append! ( seq1 seq2 -- seq1 ) over push-all ; inline
 880
 881 : last ( seq -- elt )
 882     index-of-last
 883     over 0 < [ bounds-error ] [ nth-unsafe ] if ; inline
 884
 885 <PRIVATE
 886
 887 : last-unsafe ( seq -- elt )
 888     index-of-last nth-unsafe ; inline
 889
 890 PRIVATE>
 891
 892 : set-last ( elt seq -- )
 893     index-of-last
 894     over 0 < [ bounds-error ] [ set-nth-unsafe ] if ; inline
 895
 896 : pop* ( seq -- ) index-of-last shorten ;
 897
 898 <PRIVATE
 899
 900 : move-backward ( shift from to seq -- )
 901     2over = [
 902         4drop
 903     ] [
 904         [ [ 2over + pick ] dip move-unsafe [ 1 + ] dip ] keep
 905         move-backward
 906     ] if ;
 907
 908 : open-slice ( shift from seq -- )
 909     pick 0 = [
 910         3drop
 911     ] [
 912         [ ] [ nip length + ] [ 2nip ] 3tri
 913         [ [ length ] keep [ over - ] 2dip move-backward ] 2dip
 914         set-length
 915     ] if ;
 916
 917 PRIVATE>
 918
 919 : delete-slice ( from to seq -- )
 920     check-slice [ over [ - ] dip ] dip open-slice ;
 921
 922 : remove-nth! ( n seq -- seq )
 923     [ [ dup 1 + ] dip delete-slice ] keep ;
 924
 925 : snip ( from to seq -- head tail )
 926     [ swap head ] [ swap tail ] bi-curry bi* ; inline
 927
 928 : snip-slice ( from to seq -- head tail )
 929     [ swap head-slice ] [ swap tail-slice ] bi-curry bi* ; inline
 930
 931 : replace-slice ( new from to seq -- seq' )
 932     snip-slice surround ;
 933
 934 : remove-nth ( n seq -- seq' )
 935     [ [ dup 1 + ] dip snip-slice ] keep append-as ;
 936
 937 : pop ( seq -- elt )
 938     index-of-last over 0 >=
 939     [ [ nth-unsafe ] [ shorten ] 2bi ]
 940     [ bounds-error ] if ;
 941
 942 : exchange ( m n seq -- )
 943     [ nip bounds-check 2drop ]
 944     [ bounds-check 3drop ]
 945     [ exchange-unsafe ]
 946     3tri ;
 947
 948 : midpoint@ ( seq -- n ) length 2/ ; inline
 949
 950 : reverse! ( seq -- seq )
 951     [
 952         [ midpoint@ ] [ length ] [ ] tri
 953         [ [ over - 1 - ] dip exchange-unsafe ] 2curry
 954         each-integer
 955     ] keep ;
 956
 957 : reverse ( seq -- newseq )
 958     [
 959         dup [ length ] keep new-sequence
 960         [ 0 swap copy-unsafe ] keep reverse!
 961     ] keep like ;
 962
 963 GENERIC: sum-lengths ( seq -- n )
 964
 965 M: object sum-lengths
 966     0 [ length + ] reduce ;
 967
 968 M: repetition sum-lengths
 969     [ length>> ] [ elt>> length ] bi * ;
 970
 971 : concat-as ( seq exemplar -- newseq )
 972     [
 973         [ dup sum-lengths ] dip new-resizable
 974         [ [ push-all ] curry each ] keep
 975     ] keep like ; inline
 976
 977 : concat ( seq -- newseq )
 978     [ { } ] [ dup first concat-as ] if-empty ;
 979
 980 <PRIVATE
 981
 982 : joined-length ( seq glue -- n )
 983     [ [ sum-lengths ] [ length 1 [-] ] bi ] dip length * + ;
 984
 985 PRIVATE>
 986
 987 : join-as ( seq glue exemplar -- newseq )
 988     over empty? [ nip concat-as ] [
 989         [
 990             2dup joined-length over new-resizable [
 991                 [ [ push-all ] 2curry ]
 992                 [ nip [ push-all ] curry ] 2bi
 993                 interleave
 994             ] keep
 995         ] dip like
 996     ] if ;
 997
 998 : join ( seq glue -- newseq )
 999     dup join-as ; inline
1000
1001 <PRIVATE
1002
1003 : padding ( ... seq n elt quot: ( ... seq1 seq2 -- ... newseq ) -- ... newseq )
1004     [
1005         [ over length [-] dup 0 = [ drop ] ] dip
1006         [ <repetition> ] curry
1007     ] dip compose if ; inline
1008
1009 PRIVATE>
1010
1011 : pad-head ( seq n elt -- padded )
1012     [ swap dup append-as ] padding ;
1013
1014 : pad-tail ( seq n elt -- padded )
1015     [ append ] padding ;
1016
1017 : shorter? ( seq1 seq2 -- ? ) 2length < ; inline
1018 : longer? ( seq1 seq2 -- ? ) 2length > ; inline
1019 : shorter ( seq1 seq2 -- seq ) [ 2length <= ] most ; inline
1020 : longer ( seq1 seq2 -- seq ) [ 2length >= ] most ; inline
1021
1022 : head? ( seq begin -- ? )
1023     2dup shorter? [
1024         2drop f
1025     ] [
1026         [ length [ head-slice ] keep swap ] keep
1027         mismatch-unsafe not
1028     ] if ;
1029
1030 : tail? ( seq end -- ? )
1031     2dup shorter? [
1032         2drop f
1033     ] [
1034         [ length [ tail-slice* ] keep swap ] keep
1035         mismatch-unsafe not
1036     ] if ;
1037
1038 : cut-slice ( seq n -- before-slice after-slice )
1039     [ head-slice ] [ tail-slice ] 2bi ; inline
1040
1041 : cut-slice* ( seq n -- before-slice after-slice )
1042     [ head-slice* ] [ tail-slice* ] 2bi ;
1043
1044 : insert-nth ( elt n seq -- seq' )
1045     swap cut-slice [ swap suffix ] dip append ;
1046
1047 : halves ( seq -- first-slice second-slice )
1048     dup midpoint@ cut-slice ; inline
1049
1050 <PRIVATE
1051
1052 : nth2-unsafe ( n seq -- a b )
1053     [ nth-unsafe ] [ [ 1 + ] dip nth-unsafe ] 2bi ; inline
1054
1055 : nth3-unsafe ( n seq -- a b c )
1056     [ nth2-unsafe ] [ [ 2 + ] dip nth-unsafe ] 2bi ; inline
1057
1058 : (binary-reduce) ( seq start quot: ( elt1 elt2 -- newelt ) from length -- value )
1059     ! We can't use case here since combinators depends on
1060     ! sequences
1061     dup 4 < [
1062         integer>fixnum {
1063             [ 2drop nip ]
1064             [ 2nip swap nth-unsafe ]
1065             [ -rot [ drop swap nth2-unsafe ] dip call ]
1066             [ -rot [ drop swap nth3-unsafe ] dip bi@ ]
1067         } dispatch
1068     ] [
1069         [ 2/ ] [ over - ] bi [ 2dup + ] dip
1070         [ (binary-reduce) ] [ 2curry ] curry 2bi@
1071         pick [ 3bi ] dip call
1072     ] if ; inline recursive
1073
1074 PRIVATE>
1075
1076 : binary-reduce ( seq start quot: ( elt1 elt2 -- newelt ) -- value )
1077     pick dup slice? [
1078         [ seq>> ] 3dip [ from>> 0 max ] [ to>> 0 max over - ] bi
1079     ] [
1080         length 0 max 0 swap
1081     ] if (binary-reduce) ; inline
1082
1083 : cut ( seq n -- before after )
1084     [ head ] [ tail ] 2bi ;
1085
1086 : cut* ( seq n -- before after )
1087     [ head* ] [ tail* ] 2bi ;
1088
1089 : subseq-starts-at? ( i seq subseq -- ? )
1090     [ length swap ] keep
1091     '[
1092         [ + _ nth-unsafe ] keep _ nth-unsafe =
1093     ] with all-integers? ; inline
1094
1095 : subseq-index-from ( n seq subseq -- i/f )
1096     [ 2length - 1 + ] 2keep
1097     '[ _ _ subseq-starts-at? ] find-integer-from ; inline
1098
1099 : subseq-index ( seq subseq -- i/f ) [ 0 ] 2dip subseq-index-from ; inline
1100
1101 : subseq-of? ( seq subseq -- ? ) subseq-index >boolean ; inline
1102
1103 : subseq-start-from ( subseq seq n -- i/f )
1104     spin subseq-index-from ; inline deprecated
1105
1106 : subseq-start ( subseq seq -- i/f ) swap subseq-index ; inline deprecated
1107
1108 : subseq? ( subseq seq -- ? ) subseq-start >boolean ; inline deprecated
1109
1110 : drop-prefix ( seq1 seq2 -- slice1 slice2 )
1111     2dup mismatch [ 2dup min-length ] unless*
1112     [ tail-slice ] curry bi@ ;
1113
1114 : unclip ( seq -- rest first )
1115     [ rest ] [ first-unsafe ] bi ;
1116
1117 : unclip-last ( seq -- butlast last )
1118     [ but-last ] [ last-unsafe ] bi ;
1119
1120 : unclip-slice ( seq -- rest-slice first )
1121     [ rest-slice ] [ first-unsafe ] bi ; inline
1122
1123 : map-reduce ( ..a seq map-quot: ( ..a elt -- ..a intermediate ) reduce-quot: ( ..a prev intermediate -- ..a next ) -- ..a result )
1124     [ [ [ first ] keep ] dip [ dip ] keep ] dip
1125     '[ swap _ dip swap @ ] 1 each-from ; inline
1126
1127 : 2map-reduce ( ..a seq1 seq2 map-quot: ( ..a elt1 elt2 -- ..a intermediate ) reduce-quot: ( ..a prev intermediate -- ..a next ) -- ..a result )
1128     [ [ [ [ first ] bi@ ] 2keep ] dip [ 2dip ] keep ] dip
1129     '[ rot _ dip swap @ ] 1 2each-from ; inline
1130
1131 <PRIVATE
1132
1133 : (map-find) ( seq quot find-quot -- result elt )
1134     [ [ f ] 2dip [ nip ] prepose [ dup ] compose ] dip call nip ; inline
1135
1136 PRIVATE>
1137
1138 : map-find ( ... seq quot: ( ... elt -- ... result/f ) -- ... result elt )
1139     [ find ] (map-find) ; inline
1140
1141 : map-find-last ( ... seq quot: ( ... elt -- ... result/f ) -- ... result elt )
1142     [ find-last ] (map-find) ; inline
1143
1144 : unclip-last-slice ( seq -- butlast-slice last )
1145     [ but-last-slice ] [ last-unsafe ] bi ; inline
1146
1147 <PRIVATE
1148
1149 : (trim-head) ( seq quot -- seq n )
1150     over [ negate find drop ] dip swap
1151     [ dup length ] unless* ; inline
1152
1153 : (trim-tail) ( seq quot -- seq n )
1154     over [ negate find-last drop ?1+ ] dip
1155     swap ; inline
1156
1157 PRIVATE>
1158
1159 : trim-head-slice ( ... seq quot: ( ... elt -- ... ? ) -- ... slice )
1160     (trim-head) tail-slice ; inline
1161
1162 : trim-head ( ... seq quot: ( ... elt -- ... ? ) -- ... newseq )
1163     (trim-head) tail ; inline
1164
1165 : trim-tail-slice ( ... seq quot: ( ... elt -- ... ? ) -- ... slice )
1166     (trim-tail) head-slice ; inline
1167
1168 : trim-tail ( ... seq quot: ( ... elt -- ... ? ) -- ... newseq )
1169     (trim-tail) head ; inline
1170
1171 : trim-slice ( ... seq quot: ( ... elt -- ... ? ) -- ... slice )
1172     [ trim-head-slice ] [ trim-tail-slice ] bi ; inline
1173
1174 : trim ( ... seq quot: ( ... elt -- ... ? ) -- ... newseq )
1175     [ trim-slice ] [ drop ] 2bi like ; inline
1176
1177 GENERIC: sum ( seq -- n )
1178 M: object sum 0 [ + ] binary-reduce ; inline
1179 M: iota sum length dup 1 - * 2/ ; inline
1180 M: repetition sum [ elt>> ] [ length>> ] bi * ; inline
1181
1182 : product ( seq -- n ) 1 [ * ] binary-reduce ;
1183
1184 : infimum ( seq -- elt ) [ ] [ min ] map-reduce ;
1185
1186 : supremum ( seq -- elt ) [ ] [ max ] map-reduce ;
1187
1188 : map-sum ( ... seq quot: ( ... elt -- ... n ) -- ... n )
1189     [ 0 ] 2dip [ dip + ] curry [ swap ] prepose each ; inline
1190
1191 : count ( ... seq quot: ( ... elt -- ... ? ) -- ... n )
1192     [ 1 0 ? ] compose map-sum ; inline
1193
1194 : cartesian-each ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ) -- ... )
1195     [ with each ] 2curry each ; inline
1196
1197 : cartesian-map ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... newseq )
1198     [ with { } map-as ] 2curry { } map-as ; inline
1199
1200 : cartesian-product-as ( seq1 seq2 exemplar -- newseq )
1201     [ 2sequence ] curry cartesian-map ; inline
1202
1203 : cartesian-product ( seq1 seq2 -- newseq )
1204     dup cartesian-product-as ; inline
1205
1206 : cartesian-find ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... elt1 elt2 )
1207     [ f ] 3dip [ with find swap ] 2curry [ nip ] prepose find nip swap ; inline
1208
1209 <PRIVATE
1210
1211 : select-by ( ... seq quot: ( ... elt -- ... x ) compare: ( obj1 obj2 -- ? ) -- ... elt )
1212     [
1213         [ keep swap ] curry [ [ first ] dip call ] 2keep
1214         [ curry 2dip pick over ] curry
1215     ] [
1216         [ [ 2drop ] [ 2nipd ] if ] compose
1217     ] bi* compose 1 each-from drop ; inline
1218
1219 PRIVATE>
1220
1221 : supremum-by ( ... seq quot: ( ... elt -- ... x ) -- ... elt )
1222     [ after? ] select-by ; inline
1223
1224 : infimum-by ( ... seq quot: ( ... elt -- ... x ) -- ... elt )
1225     [ before? ] select-by ; inline
1226
1227 : shortest ( seqs -- elt ) [ length ] infimum-by ;
1228
1229 : longest ( seqs -- elt ) [ length ] supremum-by ;
1230
1231 ! We hand-optimize flip to such a degree because type hints
1232 ! cannot express that an array is an array of arrays yet, and
1233 ! this word happens to be performance-critical since the compiler
1234 ! itself uses it. Optimizing it like this reduced compile time.
1235 <PRIVATE
1236
1237 : generic-flip ( matrix -- newmatrix )
1238     [ [ length ] [ min ] map-reduce ] keep
1239     '[ _ [ nth-unsafe ] with { } map-as ] map-integers ; inline
1240
1241 USE: arrays
1242
1243 : array-flip ( matrix -- newmatrix )
1244     { array } declare
1245     [ [ { array } declare length>> ] [ min ] map-reduce ] keep
1246     '[ _ [ { array } declare array-nth ] with { } map-as ] map-integers ;
1247
1248 PRIVATE>
1249
1250 : flip ( matrix -- newmatrix )
1251     dup empty? [
1252         dup array? [
1253             dup [ array? ] all?
1254             [ array-flip ] [ generic-flip ] if
1255         ] [ generic-flip ] if
1256     ] unless ;