core/sequences/sequences.factor

   1 ! Copyright (C) 2005, 2011 Slava Pestov, Daniel Ehrenberg.
   2 ! See https://factorcode.org/license.txt for BSD license.
   3 USING: accessors kernel kernel.private math math.order
   4 math.private slots.private ;
   5 IN: sequences
   6
   7 MIXIN: sequence
   8
   9 GENERIC: length ( seq -- n ) flushable
  10 GENERIC: set-length ( n seq -- )
  11 GENERIC: nth ( n seq -- elt ) flushable
  12 GENERIC: set-nth ( elt n seq -- )
  13 GENERIC: new-sequence ( len seq -- newseq ) flushable
  14 GENERIC: new-resizable ( len seq -- newseq ) flushable
  15 GENERIC: like ( seq exemplar -- newseq ) flushable
  16 GENERIC: clone-like ( seq exemplar -- newseq ) flushable
  17
  18 : lengthd ( seq obj -- n obj ) [ length ] dip ; inline
  19
  20 : new-sequence-like ( len-exemplar type-exemplar -- newseq )
  21     lengthd new-sequence ; inline
  22
  23 : new-resizable-like ( len-exemplar type-exemplar -- newseq )
  24     lengthd new-resizable ; inline
  25
  26 : new-like ( len exemplar quot -- seq )
  27     over [ [ new-sequence ] dip call ] dip like ; inline
  28
  29 M: sequence like drop ; inline
  30
  31 GENERIC: lengthen ( n seq -- )
  32 GENERIC: shorten ( n seq -- )
  33
  34 M: sequence lengthen 2dup length > [ set-length ] [ 2drop ] if ; inline
  35 M: sequence shorten 2dup length < [ set-length ] [ 2drop ] if ; inline
  36
  37 : 2length ( seq1 seq2 -- n1 n2 ) [ length ] bi@ ; inline
  38 : 3length ( seq1 seq2 seq3 -- n1 n2 n3 ) [ length ] tri@ ; inline
  39
  40 : empty? ( seq -- ? ) length 0 = ; inline
  41
  42 : if-empty ( ..a seq quot1: ( ..a -- ..b ) quot2: ( ..a seq -- ..b ) -- ..b )
  43     [ dup empty? ] [ [ drop ] prepose ] [ ] tri* if ; inline
  44
  45 : when-empty ( ... seq quot: ( ... -- ... obj ) -- ... seq/obj ) [ ] if-empty ; inline
  46 : unless-empty ( ... seq quot: ( ... seq -- ... ) -- ... ) [ ] swap if-empty ; inline
  47
  48 : delete-all ( seq -- ) 0 swap set-length ;
  49
  50 : first ( seq -- first ) 0 swap nth ; inline
  51 : second ( seq -- second ) 1 swap nth ; inline
  52 : third ( seq -- third ) 2 swap nth ; inline
  53 : fourth ( seq -- fourth ) 3 swap nth ; inline
  54
  55 : set-first ( first seq -- ) 0 swap set-nth ; inline
  56 : set-second ( second seq -- ) 1 swap set-nth ; inline
  57 : set-third ( third seq -- ) 2 swap set-nth ; inline
  58 : set-fourth  ( fourth seq -- ) 3 swap set-nth ; inline
  59
  60 : push ( elt seq -- ) [ length ] [ set-nth ] bi ;
  61
  62 ERROR: bounds-error index seq ;
  63
  64 GENERIC#: bounds-check? 1 ( n seq -- ? )
  65
  66 M: integer bounds-check?
  67     dupd length < [ 0 >= ] [ drop f ] if ; inline
  68
  69 : bounds-check ( n seq -- n seq )
  70     2dup bounds-check? [ bounds-error ] unless ; inline
  71
  72 MIXIN: immutable-sequence
  73
  74 ERROR: immutable element index sequence ;
  75
  76 M: immutable-sequence set-nth immutable ;
  77
  78 INSTANCE: immutable-sequence sequence
  79
  80 <PRIVATE
  81
  82 : array-nth ( n array -- elt )
  83     swap 2 fixnum+fast slot ; inline
  84
  85 : set-array-nth ( elt n array -- )
  86     swap 2 fixnum+fast set-slot ; inline
  87
  88 : dispatch ( n array -- ) array-nth call ;
  89
  90 GENERIC: resize ( n seq -- newseq ) flushable
  91
  92 ! Unsafe sequence protocol for inner loops
  93 GENERIC: nth-unsafe ( n seq -- elt ) flushable
  94 GENERIC: set-nth-unsafe ( elt n seq -- )
  95
  96 M: sequence nth bounds-check nth-unsafe ; inline
  97 M: sequence set-nth bounds-check set-nth-unsafe ; inline
  98
  99 M: sequence nth-unsafe nth ; inline
 100 M: sequence set-nth-unsafe set-nth ; inline
 101
 102 PRIVATE>
 103
 104 ! The f object supports the sequence protocol trivially
 105 M: f length drop 0 ; inline
 106 M: f nth-unsafe nip ; inline
 107 M: f like drop [ f ] when-empty ; inline
 108
 109 INSTANCE: f immutable-sequence
 110
 111 ! Integer sequences
 112 TUPLE: iota { n integer read-only } ;
 113
 114 : <iota> ( n -- iota )
 115     assert-non-negative iota boa ; inline
 116
 117 M: iota length n>> ; inline
 118 M: iota nth-unsafe drop ; inline
 119
 120 INSTANCE: iota immutable-sequence
 121
 122 <PRIVATE
 123
 124 : first-unsafe ( seq -- first ) 0 swap nth-unsafe ; inline
 125 : second-unsafe ( seq -- second ) 1 swap nth-unsafe ; inline
 126 : third-unsafe ( seq -- third ) 2 swap nth-unsafe ; inline
 127 : fourth-unsafe ( seq -- fourth ) 3 swap nth-unsafe ; inline
 128
 129 : first2-unsafe ( seq -- first second )
 130     [ first-unsafe ] [ second-unsafe ] bi ; inline
 131
 132 : first3-unsafe ( seq -- first second third )
 133     [ first2-unsafe ] [ third-unsafe ] bi ; inline
 134
 135 : first4-unsafe ( seq -- first second third fourth )
 136     [ first3-unsafe ] [ fourth-unsafe ] bi ; inline
 137
 138 : exchange-unsafe ( m n seq -- )
 139     [ [ nth-unsafe ] curry bi@ ]
 140     [ [ set-nth-unsafe ] curry bi@ ] 3bi ; inline
 141
 142 : (1sequence) ( obj seq -- seq )
 143     [ 0 swap set-nth-unsafe ] keep ; inline
 144
 145 : (2sequence) ( obj1 obj2 seq -- seq )
 146     [ 1 swap set-nth-unsafe ] keep (1sequence) ; inline
 147
 148 : (3sequence) ( obj1 obj2 obj3 seq -- seq )
 149     [ 2 swap set-nth-unsafe ] keep (2sequence) ; inline
 150
 151 : (4sequence) ( obj1 obj2 obj3 obj4 seq -- seq )
 152     [ 3 swap set-nth-unsafe ] keep (3sequence) ; inline
 153
 154 : head-to-index ( seq to -- zero to seq ) [ 0 ] 2dip swap ; inline
 155
 156 : index-to-tail ( seq from -- from length seq ) swap [ length ] keep ; inline
 157
 158 PRIVATE>
 159
 160 : from-tail ( seq n -- seq n' ) [ dup length ] dip - ; inline
 161
 162 : 1sequence ( obj exemplar -- seq )
 163     1 swap [ (1sequence) ] new-like ; inline
 164
 165 : 2sequence ( obj1 obj2 exemplar -- seq )
 166     2 swap [ (2sequence) ] new-like ; inline
 167
 168 : 3sequence ( obj1 obj2 obj3 exemplar -- seq )
 169     3 swap [ (3sequence) ] new-like ; inline
 170
 171 : 4sequence ( obj1 obj2 obj3 obj4 exemplar -- seq )
 172     4 swap [ (4sequence) ] new-like ; inline
 173
 174 : first2 ( seq -- first second )
 175     1 swap bounds-check nip first2-unsafe ; inline
 176
 177 : first3 ( seq -- first second third )
 178     2 swap bounds-check nip first3-unsafe ; inline
 179
 180 : first4 ( seq -- first second third fourth )
 181     3 swap bounds-check nip first4-unsafe ; inline
 182
 183 : ?nth ( n seq -- elt/f )
 184     2dup bounds-check? [ nth-unsafe ] [ 2drop f ] if ; inline
 185
 186 : ?set-nth ( elt n seq -- )
 187     2dup bounds-check? [ set-nth-unsafe ] [ 3drop ] if ; inline
 188
 189 : index-or-length ( seq n -- seq n' ) over length min ; inline
 190
 191 : index-of-last ( seq -- n seq ) [ length 1 - ] keep ; inline
 192
 193 : ?first ( seq -- elt/f ) 0 swap ?nth ; inline
 194 : ?second ( seq -- elt/f ) 1 swap ?nth ; inline
 195 : ?last ( seq -- elt/f )
 196     index-of-last over 0 <
 197     [ 2drop f ] [ nth-unsafe ] if ; inline
 198
 199 MIXIN: virtual-sequence
 200 GENERIC: virtual-exemplar ( seq -- seq' )
 201 GENERIC: virtual@ ( n seq -- n' seq' )
 202
 203 M: virtual-sequence nth virtual@ nth ; inline
 204 M: virtual-sequence set-nth virtual@ set-nth ; inline
 205 M: virtual-sequence nth-unsafe virtual@ nth-unsafe ; inline
 206 M: virtual-sequence set-nth-unsafe virtual@ set-nth-unsafe ; inline
 207 M: virtual-sequence like virtual-exemplar like ; inline
 208 M: virtual-sequence new-sequence virtual-exemplar new-sequence ; inline
 209
 210 INSTANCE: virtual-sequence sequence
 211
 212 ! all wrapped-sequence instances need to define a slot `seq` that is a sequence
 213 MIXIN: wrapped-sequence
 214 M: wrapped-sequence virtual-exemplar seq>> ; inline
 215 M: wrapped-sequence virtual@ seq>> ; inline
 216 M: wrapped-sequence length seq>> length ; inline
 217 INSTANCE: wrapped-sequence virtual-sequence
 218
 219 TUPLE: sequence-view { seq sequence read-only } ;
 220 INSTANCE: sequence-view wrapped-sequence
 221
 222 ! A reversal of an underlying sequence.
 223 TUPLE: reversed < sequence-view ;
 224
 225 C: <reversed> reversed
 226
 227 M: reversed virtual@ seq>> [ length swap - 1 - ] keep ; inline
 228
 229 ! A slice of another sequence.
 230 TUPLE: slice
 231     { from integer read-only }
 232     { to integer read-only }
 233     { seq read-only } ;
 234
 235 : >slice< ( slice -- from to seq )
 236     [ from>> ] [ to>> ] [ seq>> ] tri ; inline
 237
 238 : collapse-slice ( m n slice -- m' n' seq )
 239     [ from>> ] [ seq>> ] bi [ [ + ] curry bi@ ] dip ; inline
 240
 241 ERROR: slice-error from to seq ;
 242
 243 : check-slice ( from to seq -- from to seq )
 244     pick 0 < [ slice-error ] when
 245     2dup length > [ slice-error ] when
 246     2over > [ slice-error ] when ; inline
 247
 248 <PRIVATE
 249
 250 : <slice-unsafe> ( from to seq -- slice )
 251     dup slice? [ collapse-slice ] when slice boa ; inline
 252
 253 PRIVATE>
 254
 255 : <slice> ( from to seq -- slice )
 256     check-slice <slice-unsafe> ; inline
 257
 258 M: slice virtual@ [ from>> + ] [ seq>> ] bi ; inline
 259
 260 M: slice length [ to>> ] [ from>> ] bi - ; inline
 261
 262 : head-slice ( seq n -- slice ) head-to-index <slice> ; inline
 263
 264 : tail-slice ( seq n -- slice ) index-to-tail <slice> ; inline
 265
 266 : rest-slice ( seq -- slice ) 1 tail-slice ; inline
 267
 268 : head-slice* ( seq n -- slice ) from-tail head-slice ; inline
 269
 270 : tail-slice* ( seq n -- slice ) from-tail tail-slice ; inline
 271
 272 : but-last-slice ( seq -- slice ) 1 head-slice* ; inline
 273
 274 INSTANCE: slice wrapped-sequence
 275
 276 ! One element repeated many times
 277 TUPLE: repetition
 278     { length integer read-only }
 279     { elt read-only } ;
 280
 281 : <repetition> ( len elt -- repetition )
 282     [ assert-non-negative ] dip repetition boa ; inline
 283
 284 M: repetition length length>> ; inline
 285 M: repetition nth-unsafe nip elt>> ; inline
 286
 287 INSTANCE: repetition immutable-sequence
 288
 289 <PRIVATE
 290
 291 ERROR: integer-length-expected obj ;
 292
 293 ! The check-length call forces partial dispatch
 294 : check-length ( n -- n )
 295     dup integer? [ integer-length-expected ] unless ; inline
 296
 297 : >sequence< ( seq -- i n seq )
 298     [ drop 0 ] [ length check-length ] [ ] tri ; inline
 299
 300 : length-sequence ( seq -- n seq )
 301     [ length check-length ] [ ] bi ; inline
 302
 303 : >underlying< ( slice/seq -- from to slice/seq )
 304     dup slice? [ >slice< ] [ >sequence< ] if ; inline
 305
 306 TUPLE: copier
 307     { src-i integer read-only }
 308     { src read-only }
 309     { dst-i integer read-only }
 310     { dst read-only } ;
 311
 312 C: <copier> copier
 313
 314 : copy-nth-unsafe ( n copy -- )
 315     [ [ src-i>> + ] [ src>> ] bi nth-unsafe ]
 316     [ [ dst-i>> + ] [ dst>> ] bi set-nth-unsafe ] 2bi ; inline
 317
 318 : (copy) ( n copy -- dst )
 319     over 0 <= [ nip dst>> ] [
 320         [ 1 - ] dip [ copy-nth-unsafe ] [ (copy) ] 2bi
 321     ] if ; inline recursive
 322
 323 : subseq>copy ( from to seq -- n copy )
 324     [ over - check-length swap ] dip
 325     3dup nip new-sequence 0 swap <copier> ; inline
 326
 327 : bounds-check-head ( n seq -- n seq )
 328     over 0 < [ bounds-error ] when ; inline
 329
 330 : copy-unsafe ( src i dst -- )
 331     [ [ length check-length 0 ] keep ] 2dip <copier> (copy) drop ; inline
 332
 333 : subseq-unsafe-as ( from to seq exemplar -- subseq )
 334     [ subseq>copy (copy) ] dip like ; inline
 335
 336 : subseq-unsafe ( from to seq -- subseq )
 337     dup subseq-unsafe-as ; inline
 338
 339 : change-nth-unsafe ( i seq quot -- )
 340     [ [ nth-unsafe ] dip call ] 2keepd set-nth-unsafe ; inline
 341
 342 : nth-of-unsafe ( seq n -- elt ) swap nth-unsafe ; inline
 343
 344 : set-nth-of-unsafe ( seq n elt -- seq ) swap pick set-nth-unsafe ; inline
 345
 346 : copy-nth-of-unsafe ( dst dst-i src src-i -- )
 347     nth-of-unsafe set-nth-of-unsafe drop ; inline
 348
 349 : copy-loop ( dst dst-i src src-i src-stop -- dst )
 350     2dup >= [
 351         4drop
 352     ] [
 353         [
 354             [ copy-nth-of-unsafe ] 4keep
 355             [ 1 + ] 2dip 1 +
 356         ] dip copy-loop
 357     ] if ; inline recursive
 358
 359 PRIVATE>
 360
 361 : subseq-as ( from to seq exemplar -- subseq )
 362     [ check-slice ] dip subseq-unsafe-as ;
 363
 364 : subseq ( from to seq -- subseq )
 365     dup subseq-as ;
 366
 367 : head ( seq n -- headseq ) head-to-index subseq ;
 368
 369 : tail ( seq n -- tailseq ) index-to-tail subseq ;
 370
 371 : rest ( seq -- tailseq ) 1 tail ;
 372
 373 : head* ( seq n -- headseq ) from-tail head ;
 374
 375 : tail* ( seq n -- tailseq ) from-tail tail ;
 376
 377 : but-last ( seq -- headseq ) 1 head* ;
 378
 379 : copy ( src i dst -- )
 380     3dup bounds-check-head
 381     [ swap length + ] dip lengthen
 382     copy-unsafe ; inline
 383
 384 M: sequence clone-like
 385     dupd new-sequence-like [ 0 swap copy-unsafe ] keep ; inline
 386
 387 M: immutable-sequence clone-like like ; inline
 388
 389 : push-all ( src dst -- ) [ length ] [ copy ] bi ; inline
 390
 391 <PRIVATE
 392
 393 : (append) ( seq1 seq2 accum -- accum )
 394     [ [ over length ] dip copy-unsafe ]
 395     [ 0 swap copy-unsafe ]
 396     [ ] tri ; inline
 397
 398 PRIVATE>
 399
 400 : append-as ( seq1 seq2 exemplar -- newseq )
 401     [ 2dup 2length + ] dip
 402     [ (append) ] new-like ; inline
 403
 404 : append ( seq1 seq2 -- newseq ) over append-as ;
 405
 406 : prepend-as ( seq1 seq2 exemplar -- newseq ) swapd append-as ; inline
 407
 408 : prepend ( seq1 seq2 -- newseq ) over prepend-as ;
 409
 410 : 3append-as ( seq1 seq2 seq3 exemplar -- newseq )
 411     [ 3dup 3length + + ] dip [
 412         [ [ 2over 2length + ] dip copy-unsafe ]
 413         [ (append) ] bi
 414     ] new-like ; inline
 415
 416 : 3append ( seq1 seq2 seq3 -- newseq ) pick 3append-as ;
 417
 418 : surround-as ( seq1 seq2 seq3 exemplar -- newseq )
 419     [ swap ] 2dip 3append-as ; inline
 420
 421 : surround ( seq1 seq2 seq3 -- newseq ) over surround-as ; inline
 422
 423 : 1surround-as ( seq1 seq2 exemplar  -- newseq ) dupd surround-as ; inline
 424
 425 : 1surround ( seq1 seq2 -- newseq ) dup 1surround-as ; inline
 426
 427 : glue-as ( seq1 seq2 seq3 exemplar -- newseq ) swapd 3append-as ; inline
 428
 429 : glue ( seq1 seq2 seq3 -- newseq ) pick glue-as ; inline
 430
 431 : change-nth ( ..a i seq quot: ( ..a elt -- ..b newelt ) -- ..b )
 432     [ [ nth ] dip call ] 2keepd set-nth-unsafe ; inline
 433
 434 : min-length ( seq1 seq2 -- n ) 2length min ; inline
 435
 436 : max-length ( seq1 seq2 -- n ) 2length max ; inline
 437
 438 <PRIVATE
 439
 440 : sequence-operator ( seq quot -- i n quot' )
 441     [ >underlying< [ nth-unsafe ] curry ] dip compose ; inline
 442
 443 : length-iterator ( seq -- n quot' )
 444     length-sequence [ nth-unsafe ] curry ; inline
 445
 446 : length-operator ( seq quot -- n quot' )
 447     [ length-iterator ] dip compose ; inline
 448
 449 : collect-into ( quot into -- quot' )
 450     [ [ keep ] dip set-nth-unsafe ] 2curry ; inline
 451
 452 : collect-from ( i n quot into -- )
 453     collect-into each-integer-from ; inline
 454
 455 : collect ( n quot into -- )
 456     collect-into each-integer ; inline
 457
 458 : sequence-index-operator ( seq quot -- n quot' )
 459     [ length-iterator [ keep ] curry ] dip compose ; inline
 460
 461 : map-into ( seq quot into -- )
 462     [ length-operator ] dip collect ; inline
 463
 464 : 2nth-unsafe ( n seq1 seq2 -- elt1 elt2 )
 465     [ nth-unsafe ] bi-curry@ bi ; inline
 466
 467 : 2length-iterator ( seq1 seq2 -- n quot )
 468     [ min-length check-length ] 2keep [ 2nth-unsafe ] 2curry ; inline
 469
 470 : 2length-operator ( seq1 seq2 quot -- n quot' )
 471     [ 2length-iterator ] dip compose ; inline
 472
 473 : 3nth-unsafe ( n seq1 seq2 seq3 -- elt1 elt2 elt3 )
 474     [ nth-unsafe ] tri-curry@ tri ; inline
 475
 476 : 3length-iterator ( seq1 seq2 seq3 -- n quot )
 477     [ 3length min min check-length ]
 478     [ [ 3nth-unsafe ] 3curry ] 3bi ; inline
 479
 480 : 3length-operator ( seq1 seq2 seq3 quot -- n quot' )
 481     [ 3length-iterator ] dip compose ; inline
 482
 483 : element/index ( i/f seq -- elt/f i/f )
 484     '[ [ _ nth ] [ f ] if* ] keep ; inline
 485
 486 : index/element ( i/f seq -- i/f elt/f )
 487     dupd '[ _ nth ] [ f ] if* ; inline
 488
 489 : (accumulate) ( seq identity quot -- identity seq quot' )
 490     swapd [ keepd ] curry ; inline
 491
 492 : (accumulate*) ( seq identity quot -- identity seq quot' )
 493     swapd [ dup ] compose ; inline
 494
 495 PRIVATE>
 496
 497 : each ( ... seq quot: ( ... x -- ... ) -- ... )
 498     sequence-operator each-integer-from ; inline
 499
 500 : each-from ( ... seq quot: ( ... x -- ... ) i -- ... )
 501     -rot length-operator each-integer-from ; inline
 502
 503 : reduce ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... result )
 504     swapd each ; inline
 505
 506 : map-integers-from-as ( ... from len quot: ( ... i -- ... elt ) exemplar -- ... newseq )
 507     overd [ [ collect-from ] keep ] new-like ; inline
 508
 509 : map-integers-as ( ... len quot: ( ... i -- ... elt ) exemplar -- ... newseq )
 510     overd [ [ collect ] keep ] new-like ; inline
 511
 512 : map-integers ( ... len quot: ( ... i -- ... elt ) -- ... newseq )
 513     { } map-integers-as ; inline
 514
 515 : map-as ( ... seq quot: ( ... elt -- ... newelt ) exemplar -- ... newseq )
 516     [ length-operator ] dip map-integers-as ; inline
 517
 518 : map ( ... seq quot: ( ... elt -- ... newelt ) -- ... newseq )
 519     over map-as ; inline
 520
 521 : replicate-as ( ... len quot: ( ... -- ... newelt ) exemplar -- ... newseq )
 522     [ [ drop ] prepose ] dip map-integers-as ; inline
 523
 524 : replicate ( ... len quot: ( ... -- ... newelt ) -- ... newseq )
 525     { } replicate-as ; inline
 526
 527 : map! ( ... seq quot: ( ... elt -- ... newelt ) -- ... seq )
 528     over [ map-into ] keep ; inline
 529
 530 : accumulate-as ( ... seq identity quot: ( ... prev elt -- ... next ) exemplar -- ... final newseq )
 531     [ (accumulate) ] dip map-as ; inline
 532
 533 : accumulate ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... final newseq )
 534     pick accumulate-as ; inline
 535
 536 : accumulate! ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... final seq )
 537     (accumulate) map! ; inline
 538
 539 : accumulate*-as ( ... seq identity quot: ( ... prev elt -- ... next ) exemplar -- ... newseq )
 540     [ (accumulate*) ] dip map-as nip ; inline
 541
 542 : accumulate* ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... newseq )
 543     pick accumulate*-as ; inline
 544
 545 : accumulate*! ( ... seq identity quot: ( ... prev elt -- ... next ) -- ... seq )
 546     (accumulate*) map! nip ; inline
 547
 548 : 2each ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ) -- ... )
 549     2length-operator each-integer ; inline
 550
 551 : 2each-from ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ) from -- ... )
 552     -roll 2length-operator each-integer-from ; inline
 553
 554 : 2reduce ( ... seq1 seq2 identity quot: ( ... prev elt1 elt2 -- ... next ) -- ... result )
 555     -rotd 2each ; inline
 556
 557 : 2map-as ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) exemplar -- ... newseq )
 558     [ 2length-operator ] dip map-integers-as ; inline
 559
 560 : 2map ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... newseq )
 561     pick 2map-as ; inline
 562
 563 : 2all? ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... ? )
 564     2length-operator all-integers? ; inline
 565
 566 : 2any? ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... ? )
 567     negate 2all? not ; inline
 568
 569 : 3each ( ... seq1 seq2 seq3 quot: ( ... elt1 elt2 elt3 -- ... ) -- ... )
 570     3length-operator each-integer ; inline
 571
 572 : 3map-as ( ... seq1 seq2 seq3 quot: ( ... elt1 elt2 elt3 -- ... newelt ) exemplar -- ... newseq )
 573     [ 3length-operator ] dip map-integers-as ; inline
 574
 575 : 3map ( ... seq1 seq2 seq3 quot: ( ... elt1 elt2 elt3 -- ... newelt ) -- ... newseq )
 576     pickd swap 3map-as ; inline
 577
 578 <PRIVATE
 579
 580 : bounds-check-call ( n seq quot -- obj1 obj2 )
 581     2over bounds-check? [ call ] [ 3drop f f ] if ; inline
 582
 583 : do-find-from ( ... n seq quot: ( ... elt -- ... ? ) -- ... i/f seq )
 584     [ length-operator find-integer-from ] keepd ; inline
 585
 586 : find-last-from-unsafe ( ... n seq quot: ( ... elt -- ... ? ) -- ... i/f seq )
 587     [ length-operator nip find-last-integer ] keepd ; inline
 588
 589 PRIVATE>
 590
 591 : find-from ( ... n seq quot: ( ... elt -- ... ? ) -- ... i elt )
 592     '[ _ do-find-from index/element ] bounds-check-call ; inline
 593
 594 : find ( ... seq quot: ( ... elt -- ... ? ) -- ... i elt )
 595     [ 0 ] 2dip do-find-from index/element ; inline
 596
 597 : find-last-from ( ... n seq quot: ( ... elt -- ... ? ) -- ... i elt )
 598     '[ _ find-last-from-unsafe index/element ] bounds-check-call ; inline
 599
 600 : find-last ( ... seq quot: ( ... elt -- ... ? ) -- ... i elt )
 601     [ index-of-last ] dip find-last-from ; inline
 602
 603 : find-index-from ( ... n seq quot: ( ... elt i -- ... ? ) -- ... i elt )
 604     '[
 605         _ [ sequence-index-operator find-integer-from ] keepd
 606         index/element
 607     ] bounds-check-call ; inline
 608
 609 : find-index ( ... seq quot: ( ... elt i -- ... ? ) -- ... i elt )
 610     [ 0 ] 2dip find-index-from ; inline
 611
 612 : all? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 613     sequence-operator all-integers-from? ; inline
 614
 615 : push-when ( ..a elt quot: ( ..a elt -- ..b ? ) accum -- ..b )
 616     [ keep ] dip rot [ push ] [ 2drop ] if ; inline
 617
 618 <PRIVATE
 619
 620 : (selector-as) ( quot length exemplar -- selector accum )
 621     new-resizable [ [ push-when ] 2curry ] keep ; inline
 622
 623 PRIVATE>
 624
 625 : selector-as ( quot exemplar -- selector accum )
 626     [ length ] keep (selector-as) ; inline
 627
 628 : selector ( quot -- selector accum )
 629     V{ } selector-as ; inline
 630
 631 : filter-as ( ... seq quot: ( ... elt -- ... ? ) exemplar -- ... subseq )
 632     pick length over [ (selector-as) [ each ] dip ] 2curry dip like ; inline
 633
 634 : filter ( ... seq quot: ( ... elt -- ... ? ) -- ... subseq )
 635     over filter-as ; inline
 636
 637 : reject-as ( ... seq quot: ( ... elt -- ... ? ) exemplar -- ... subseq )
 638     [ negate ] [ filter-as ] bi* ; inline
 639
 640 : reject ( ... seq quot: ( ... elt -- ... ? ) -- ... subseq )
 641     over reject-as ; inline
 642
 643 : push-either ( ..a elt quot: ( ..a elt -- ..b ? ) accum1 accum2 -- ..b )
 644     [ keep swap ] 2dip ? push ; inline
 645
 646 : 2selector ( quot -- selector accum1 accum2 )
 647     V{ } clone V{ } clone [ [ push-either ] 3curry ] 2keep ; inline
 648
 649 : partition ( ... seq quot: ( ... elt -- ... ? ) -- ... trueseq falseseq )
 650     over [ 2selector [ each ] 2dip ] dip [ like ] curry bi@ ; inline
 651
 652 : collector-as ( quot exemplar -- quot' vec )
 653     dup new-resizable-like [ [ push ] curry compose ] keep ; inline
 654
 655 : collector ( quot -- quot' vec )
 656     V{ } collector-as ; inline
 657
 658 : produce-as ( ..a pred: ( ..a -- ..b ? ) quot: ( ..b -- ..a obj ) exemplar -- ..b seq )
 659     dup [ collector-as [ while ] dip ] curry dip like ; inline
 660
 661 : produce ( ..a pred: ( ..a -- ..b ? ) quot: ( ..b -- ..a obj ) -- ..b seq )
 662     { } produce-as ; inline
 663
 664 : follow ( ... obj quot: ( ... prev -- ... result/f ) -- ... seq )
 665     [ dup ] swap [ keep ] curry produce nip ; inline
 666
 667 : each-index ( ... seq quot: ( ... elt index -- ... ) -- ... )
 668     sequence-index-operator each-integer ; inline
 669
 670 : map-index-as ( ... seq quot: ( ... elt index -- ... newelt ) exemplar -- ... newseq )
 671     [ dup length <iota> ] 2dip 2map-as ; inline
 672
 673 : map-index ( ... seq quot: ( ... elt index -- ... newelt ) -- ... newseq )
 674     over map-index-as ; inline
 675
 676 : interleave ( ... seq between quot: ( ... elt -- ... ) -- ... )
 677     pick empty? [ 3drop ] [
 678         [ [ drop first-unsafe ] dip call ]
 679         [ [ bi* ] 2curry 1 each-from ]
 680         3bi
 681     ] if ; inline
 682
 683 : reduce-index ( ... seq identity quot: ( ... prev elt index -- ... next ) -- ... result )
 684     swapd each-index ; inline
 685
 686 : index ( obj seq -- n )
 687     [ = ] with find drop ;
 688
 689 : index-from ( obj i seq -- n )
 690     rot [ = ] curry find-from drop ;
 691
 692 : last-index ( obj seq -- n )
 693     [ = ] with find-last drop ;
 694
 695 : last-index-from ( obj i seq -- n )
 696     rot [ = ] curry find-last-from drop ;
 697
 698 : indices ( obj seq -- indices )
 699     swap [ = ] curry [ swap ] prepose V{ } clone [
 700         [ push ] curry [ [ drop ] if ] curry compose each-index
 701     ] keep ;
 702
 703 <PRIVATE
 704
 705 : nths-unsafe ( indices seq -- seq' )
 706     [ [ nth-unsafe ] curry ] keep map-as ;
 707
 708 PRIVATE>
 709
 710 : nths ( indices seq -- seq' )
 711     [ [ nth ] curry ] keep map-as ;
 712
 713 : nths-of ( seq indices -- seq' )
 714     swap nths ; inline
 715
 716 : any? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 717     find drop >boolean ; inline
 718
 719 : none? ( ... seq quot: ( ... elt -- ... ? ) -- ... ? )
 720     any? not ; inline
 721
 722 : member? ( elt seq -- ? )
 723     [ = ] with any? ;
 724
 725 : member-eq? ( elt seq -- ? )
 726     [ eq? ] with any? ;
 727
 728 : remove ( elt seq -- newseq )
 729     [ = ] with reject ;
 730
 731 : remove-eq ( elt seq -- newseq )
 732     [ eq? ] with reject ;
 733
 734 : sift ( seq -- newseq )
 735     [ ] filter ;
 736
 737 : harvest ( seq -- newseq )
 738     [ empty? ] reject ;
 739
 740 <PRIVATE
 741
 742 : mismatch-unsafe ( n seq1 seq2 -- i )
 743     [ 2nth-unsafe = not ] 2curry find-integer ; inline
 744
 745 PRIVATE>
 746
 747 : mismatch ( seq1 seq2 -- i )
 748     [ min-length ] 2keep mismatch-unsafe ;
 749
 750 M: sequence <=>
 751     [ mismatch ] 2keep pick
 752     [ 2nth-unsafe <=> ] [ [ length ] compare nip ] if ;
 753
 754 : sequence= ( seq1 seq2 -- ? )
 755     2dup 2length dupd =
 756     [ -rot mismatch-unsafe not ] [ 3drop f ] if ; inline
 757
 758 ERROR: assert-sequence got expected ;
 759
 760 : assert-sequence= ( a b -- )
 761     2dup sequence= [ 2drop ] [ assert-sequence ] if ;
 762
 763 M: reversed equal? over reversed? [ sequence= ] [ 2drop f ] if ;
 764
 765 M: slice equal? over slice? [ sequence= ] [ 2drop f ] if ;
 766
 767 <PRIVATE
 768
 769 : sequence-hashcode-step ( oldhash newpart -- newhash )
 770     integer>fixnum swap [
 771         [ -2 fixnum-shift-fast ] [ 5 fixnum-shift-fast ] bi
 772         fixnum+fast fixnum+fast
 773     ] keep fixnum-bitxor ; inline
 774
 775 PRIVATE>
 776
 777 : sequence-hashcode ( n seq -- x )
 778     [ 0 ] 2dip [ hashcode* sequence-hashcode-step ] with each ; inline
 779
 780 M: sequence hashcode* [ sequence-hashcode ] recursive-hashcode ;
 781
 782 M: iota hashcode*
 783     over 0 <= [ 2drop 0 ] [
 784         nip length 0 swap [ sequence-hashcode-step ] each-integer
 785     ] if ;
 786
 787 M: reversed hashcode* [ sequence-hashcode ] recursive-hashcode ;
 788
 789 M: slice hashcode* [ sequence-hashcode ] recursive-hashcode ;
 790
 791 : move ( to from seq -- )
 792     2over =
 793     [ 3drop ] [ [ nth swap ] [ set-nth ] bi ] if ; inline
 794
 795 <PRIVATE
 796
 797 : move-unsafe* ( to from seq -- from-nth )
 798     2over =
 799     [ nth-unsafe nip ]
 800     [ [ nth-unsafe tuck swap ] [ set-nth-unsafe ] bi ] if ; inline
 801
 802 : filter-from! ( store from seq quot: ( ... elt -- ... ? ) -- seq )
 803     2over length < [
 804         [ [ move-unsafe* ] dip call ] 4keep
 805         [ swap [ 1 + ] when ] 3dip
 806         [ 1 + ] 2dip filter-from!
 807     ] [ drop [ nip set-length ] keep ] if ; inline recursive
 808
 809 : move-unsafe ( to from seq -- )
 810     2over =
 811     [ 3drop ] [ [ nth-unsafe swap ] [ set-nth-unsafe ] bi ] if ; inline
 812
 813 PRIVATE>
 814
 815 : filter! ( ... seq quot: ( ... elt -- ... ? ) -- ... seq )
 816     [ 0 0 ] 2dip filter-from! ; inline
 817
 818 : reject! ( ... seq quot: ( ... elt -- ... ? ) -- ... seq )
 819     negate filter! ; inline
 820
 821 : remove! ( elt seq -- seq )
 822     [ = ] with reject! ;
 823
 824 : remove-eq! ( elt seq -- seq )
 825     [ eq? ] with reject! ;
 826
 827 : prefix ( seq elt -- newseq )
 828     over [ over length 1 + ] dip [
 829         (1sequence) [ 1 swap copy-unsafe ] keep
 830     ] new-like ;
 831
 832 : suffix ( seq elt -- newseq )
 833     over [ over length 1 + ] dip [
 834         [ [ over length ] dip set-nth-unsafe ] keep
 835         [ 0 swap copy-unsafe ] keep
 836     ] new-like ;
 837
 838 : suffix! ( seq elt -- seq ) over push ; inline
 839
 840 : append! ( seq1 seq2 -- seq1 ) over push-all ; inline
 841
 842 : last ( seq -- elt )
 843     index-of-last bounds-check-head nth-unsafe ; inline
 844
 845 : last2 ( seq -- penultimate ultimate )
 846     index-of-last [ [ 1 - ] keep ] dip pick 0 <
 847     [ nip bounds-error ] [ '[ _ nth-unsafe ] bi@ ] if ; inline
 848
 849 <PRIVATE
 850
 851 : last-unsafe ( seq -- elt )
 852     index-of-last nth-unsafe ; inline
 853
 854 PRIVATE>
 855
 856 : set-last ( elt seq -- )
 857     index-of-last
 858     over 0 < [ bounds-error ] [ set-nth-unsafe ] if ; inline
 859
 860 : pop* ( seq -- ) index-of-last shorten ;
 861
 862 <PRIVATE
 863
 864 : move-backward ( shift from to seq -- )
 865     2over = [
 866         4drop
 867     ] [
 868         [ [ 2over + pick ] dip move-unsafe [ 1 + ] dip ] keep
 869         move-backward
 870     ] if ;
 871
 872 : open-slice ( shift from seq -- )
 873     pick 0 = [
 874         3drop
 875     ] [
 876         [ ] [ nip length + ] [ 2nip ] 3tri
 877         [ [ length ] keep [ over - ] 2dip move-backward ] 2dip
 878         set-length
 879     ] if ;
 880
 881 PRIVATE>
 882
 883 : delete-slice ( from to seq -- )
 884     check-slice [ over [ - ] dip ] dip open-slice ;
 885
 886 : remove-nth! ( n seq -- seq )
 887     [ [ dup 1 + ] dip delete-slice ] keep ;
 888
 889 : snip ( from to seq -- head tail )
 890     [ swap head ] [ swap tail ] bi-curry bi* ; inline
 891
 892 : snip-slice ( from to seq -- head tail )
 893     [ swap head-slice ] [ swap tail-slice ] bi-curry bi* ; inline
 894
 895 : replace-slice ( new from to seq -- seq' )
 896     snip-slice surround ;
 897
 898 : remove-nth ( n seq -- seq' )
 899     [ [ dup 1 + ] dip snip-slice ] keep append-as ;
 900
 901 : pop ( seq -- elt )
 902     index-of-last over 0 >=
 903     [ [ nth-unsafe ] [ shorten ] 2bi ]
 904     [ bounds-error ] if ;
 905
 906 : exchange ( m n seq -- )
 907     [ nip bounds-check 2drop ]
 908     [ bounds-check 3drop ]
 909     [ exchange-unsafe ]
 910     3tri ;
 911
 912 : midpoint@ ( seq -- n ) length 2/ ; inline
 913
 914 : reverse! ( seq -- seq )
 915     [
 916         [ midpoint@ ] [ length ] [ ] tri
 917         [ [ over - 1 - ] dip exchange-unsafe ] 2curry
 918         each-integer
 919     ] keep ;
 920
 921 : reverse ( seq -- newseq )
 922     [
 923         dup [ length ] keep new-sequence
 924         [ 0 swap copy-unsafe ] keep reverse!
 925     ] keep like ;
 926
 927 GENERIC: sum-lengths ( seq -- n )
 928
 929 M: object sum-lengths
 930     0 [ length + ] reduce ;
 931
 932 M: repetition sum-lengths
 933     [ length>> ] [ elt>> length ] bi * ;
 934
 935 : concat-as ( seq exemplar -- newseq )
 936     [
 937         [ dup sum-lengths ] dip new-resizable
 938         [ [ push-all ] curry each ] keep
 939     ] keep like ; inline
 940
 941 : concat ( seq -- newseq )
 942     [ { } ] [ dup first concat-as ] if-empty ;
 943
 944 <PRIVATE
 945
 946 : joined-length ( seq glue -- n )
 947     [ [ sum-lengths ] [ length 1 [-] ] bi ] dip length * + ;
 948
 949 PRIVATE>
 950
 951 : join-as ( seq glue exemplar -- newseq )
 952     over empty? [ nip concat-as ] [
 953         [
 954             2dup joined-length over new-resizable [
 955                 [ [ push-all ] 2curry ]
 956                 [ nip [ push-all ] curry ] 2bi
 957                 interleave
 958             ] keep
 959         ] dip like
 960     ] if ;
 961
 962 : join ( seq glue -- newseq )
 963     dup join-as ; inline
 964
 965 <PRIVATE
 966
 967 : padding ( ... seq n elt quot: ( ... seq1 seq2 -- ... newseq ) -- ... newseq )
 968     [
 969         [ over length [-] dup 0 = [ drop ] ] dip
 970         [ <repetition> ] curry
 971     ] dip compose if ; inline
 972
 973 PRIVATE>
 974
 975 : pad-head ( seq n elt -- padded )
 976     [ swap dup append-as ] padding ;
 977
 978 : pad-tail ( seq n elt -- padded )
 979     [ append ] padding ;
 980
 981 : shorter? ( seq1 seq2 -- ? ) 2length < ; inline
 982 : longer? ( seq1 seq2 -- ? ) 2length > ; inline
 983 : shorter ( seq1 seq2 -- seq ) [ 2length <= ] most ; inline
 984 : longer ( seq1 seq2 -- seq ) [ 2length >= ] most ; inline
 985
 986 : head? ( seq begin -- ? )
 987     2dup shorter? [
 988         2drop f
 989     ] [
 990         [ length [ head-slice ] keep swap ] keep
 991         mismatch-unsafe not
 992     ] if ;
 993
 994 : tail? ( seq end -- ? )
 995     2dup shorter? [
 996         2drop f
 997     ] [
 998         [ length [ tail-slice* ] keep swap ] keep
 999         mismatch-unsafe not
1000     ] if ;
1001
1002 : cut-slice ( seq n -- before-slice after-slice )
1003     [ head-slice ] [ tail-slice ] 2bi ; inline
1004
1005 : cut-slice* ( seq n -- before-slice after-slice )
1006     [ head-slice* ] [ tail-slice* ] 2bi ;
1007
1008 : insert-nth ( elt n seq -- seq' )
1009     swap cut-slice [ swap suffix ] dip append ;
1010
1011 : halves ( seq -- first-slice second-slice )
1012     dup midpoint@ cut-slice ; inline
1013
1014 <PRIVATE
1015
1016 : nth2-unsafe ( n seq -- a b )
1017     [ nth-unsafe ] [ [ 1 + ] dip nth-unsafe ] 2bi ; inline
1018
1019 : nth3-unsafe ( n seq -- a b c )
1020     [ nth2-unsafe ] [ [ 2 + ] dip nth-unsafe ] 2bi ; inline
1021
1022 : (binary-reduce) ( seq start quot: ( elt1 elt2 -- newelt ) from length -- value )
1023     ! We can't use case here since combinators depends on
1024     ! sequences
1025     dup 4 < [
1026         integer>fixnum {
1027             [ 2drop nip ]
1028             [ 2nip swap nth-unsafe ]
1029             [ -rot [ drop swap nth2-unsafe ] dip call ]
1030             [ -rot [ drop swap nth3-unsafe ] dip bi@ ]
1031         } dispatch
1032     ] [
1033         [ 2/ ] [ over - ] bi [ 2dup + ] dip
1034         [ (binary-reduce) ] [ 2curry ] curry 2bi@
1035         pick [ 3bi ] dip call
1036     ] if ; inline recursive
1037
1038 PRIVATE>
1039
1040 : binary-reduce ( seq start quot: ( elt1 elt2 -- newelt ) -- value )
1041     pick dup slice? [
1042         [ seq>> ] 3dip [ from>> 0 max ] [ to>> 0 max over - ] bi
1043     ] [
1044         length 0 max 0 swap
1045     ] if (binary-reduce) ; inline
1046
1047 : cut ( seq n -- before after )
1048     [ head ] [ tail ] 2bi ;
1049
1050 : cut* ( seq n -- before after )
1051     [ head* ] [ tail* ] 2bi ;
1052
1053 : subseq-starts-at? ( i seq subseq -- ? )
1054     [ length swap ] keep
1055     '[
1056         [ + _ nth-unsafe ] keep _ nth-unsafe =
1057     ] with all-integers? ; inline
1058
1059 : subseq-index-from ( n seq subseq -- i/f )
1060     [ 2length - 1 + ] 2keep
1061     '[ _ _ subseq-starts-at? ] find-integer-from ; inline
1062
1063 : subseq-index ( seq subseq -- i/f ) [ 0 ] 2dip subseq-index-from ; inline
1064
1065 : subseq-of? ( seq subseq -- ? ) subseq-index >boolean ; inline
1066
1067 : subseq-start-from ( subseq seq n -- i/f )
1068     spin subseq-index-from ; inline deprecated
1069
1070 : subseq-start ( subseq seq -- i/f ) swap subseq-index ; inline deprecated
1071
1072 : subseq? ( subseq seq -- ? ) subseq-start >boolean ; inline deprecated
1073
1074 : drop-prefix ( seq1 seq2 -- slice1 slice2 )
1075     2dup mismatch [ 2dup min-length ] unless*
1076     [ tail-slice ] curry bi@ ;
1077
1078 : unclip ( seq -- rest first )
1079     [ rest ] [ first-unsafe ] bi ;
1080
1081 : unclip-last ( seq -- butlast last )
1082     [ but-last ] [ last-unsafe ] bi ;
1083
1084 : unclip-slice ( seq -- rest-slice first )
1085     [ rest-slice ] [ first-unsafe ] bi ; inline
1086
1087 : map-reduce ( ..a seq map-quot: ( ..a elt -- ..a intermediate ) reduce-quot: ( ..a prev intermediate -- ..a next ) -- ..a result )
1088     [ [ [ first ] keep ] dip [ dip ] keep ] dip
1089     '[ swap _ dip swap @ ] 1 each-from ; inline
1090
1091 : 2map-reduce ( ..a seq1 seq2 map-quot: ( ..a elt1 elt2 -- ..a intermediate ) reduce-quot: ( ..a prev intermediate -- ..a next ) -- ..a result )
1092     [ [ [ [ first ] bi@ ] 2keep ] dip [ 2dip ] keep ] dip
1093     '[ rot _ dip swap @ ] 1 2each-from ; inline
1094
1095 <PRIVATE
1096
1097 : (map-find) ( seq quot find-quot -- result elt )
1098     [ [ f ] 2dip [ nip ] prepose [ dup ] compose ] dip call nip ; inline
1099
1100 PRIVATE>
1101
1102 : map-find ( ... seq quot: ( ... elt -- ... result/f ) -- ... result elt )
1103     [ find ] (map-find) ; inline
1104
1105 : map-find-last ( ... seq quot: ( ... elt -- ... result/f ) -- ... result elt )
1106     [ find-last ] (map-find) ; inline
1107
1108 : unclip-last-slice ( seq -- butlast-slice last )
1109     [ but-last-slice ] [ last-unsafe ] bi ; inline
1110
1111 <PRIVATE
1112
1113 : (trim-head) ( seq quot -- seq n )
1114     over [ negate find drop ] dip swap
1115     [ dup length ] unless* ; inline
1116
1117 : (trim-tail) ( seq quot -- seq n )
1118     over [ negate find-last drop ?1+ ] dip
1119     swap ; inline
1120
1121 PRIVATE>
1122
1123 : trim-head-slice ( ... seq quot: ( ... elt -- ... ? ) -- ... slice )
1124     (trim-head) tail-slice ; inline
1125
1126 : trim-head ( ... seq quot: ( ... elt -- ... ? ) -- ... newseq )
1127     (trim-head) tail ; inline
1128
1129 : trim-tail-slice ( ... seq quot: ( ... elt -- ... ? ) -- ... slice )
1130     (trim-tail) head-slice ; inline
1131
1132 : trim-tail ( ... seq quot: ( ... elt -- ... ? ) -- ... newseq )
1133     (trim-tail) head ; inline
1134
1135 : trim-slice ( ... seq quot: ( ... elt -- ... ? ) -- ... slice )
1136     [ trim-head-slice ] [ trim-tail-slice ] bi ; inline
1137
1138 : trim ( ... seq quot: ( ... elt -- ... ? ) -- ... newseq )
1139     [ trim-slice ] [ drop ] 2bi like ; inline
1140
1141 GENERIC: sum ( seq -- n )
1142 M: object sum 0 [ + ] binary-reduce ; inline
1143 M: iota sum length dup 1 - * 2/ ; inline
1144 M: repetition sum [ elt>> ] [ length>> ] bi * ; inline
1145
1146 : product ( seq -- n ) 1 [ * ] binary-reduce ;
1147
1148 GENERIC: minimum ( seq -- elt )
1149 M: sequence minimum [ ] [ min ] map-reduce ; inline
1150 M: iota minimum drop 0 ; inline
1151 M: reversed minimum seq>> minimum ; inline
1152 M: repetition minimum elt>> ; inline
1153
1154 GENERIC: maximum ( seq -- elt )
1155 M: sequence maximum [ ] [ max ] map-reduce ; inline
1156 M: iota maximum n>> 1 - ; inline
1157 M: reversed maximum seq>> maximum ; inline
1158 M: repetition maximum elt>> ; inline
1159
1160 ALIAS: infimum minimum deprecated
1161 ALIAS: supremum maximum deprecated
1162
1163 : map-sum ( ... seq quot: ( ... elt -- ... n ) -- ... n )
1164     [ 0 ] 2dip [ dip + ] curry [ swap ] prepose each ; inline
1165
1166 : count ( ... seq quot: ( ... elt -- ... ? ) -- ... n )
1167     [ 1 0 ? ] compose map-sum ; inline
1168
1169 : cartesian-each ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ) -- ... )
1170     [ with each ] 2curry each ; inline
1171
1172 : cartesian-map ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... newelt ) -- ... newseq )
1173     [ with { } map-as ] 2curry { } map-as ; inline
1174
1175 : cartesian-product-as ( seq1 seq2 exemplar -- newseq )
1176     [ 2sequence ] curry cartesian-map ; inline
1177
1178 : cartesian-product ( seq1 seq2 -- newseq )
1179     dup cartesian-product-as ; inline
1180
1181 : cartesian-find ( ... seq1 seq2 quot: ( ... elt1 elt2 -- ... ? ) -- ... elt1 elt2 )
1182     [ f ] 3dip [ with find swap ] 2curry [ nip ] prepose find nip swap ; inline
1183
1184 <PRIVATE
1185
1186 : select-by ( ... seq quot: ( ... elt -- ... x ) compare: ( obj1 obj2 -- ? ) -- ... elt )
1187     [
1188         [ keep swap ] curry [ [ first ] dip call ] 2keep
1189         [ curry 2dip pick over ] curry
1190     ] [
1191         [ [ 2drop ] [ 2nipd ] if ] compose
1192     ] bi* compose 1 each-from drop ; inline
1193
1194 PRIVATE>
1195
1196 : maximum-by ( ... seq quot: ( ... elt -- ... x ) -- ... elt )
1197     [ after? ] select-by ; inline
1198
1199 : minimum-by ( ... seq quot: ( ... elt -- ... x ) -- ... elt )
1200     [ before? ] select-by ; inline
1201
1202 ALIAS: supremum-by maximum-by deprecated
1203 ALIAS: infimum-by minimum-by deprecated
1204
1205 : shortest ( seqs -- elt ) [ length ] minimum-by ;
1206
1207 : longest ( seqs -- elt ) [ length ] maximum-by ;
1208
1209 ! We hand-optimize flip to such a degree because type hints
1210 ! cannot express that an array is an array of arrays yet, and
1211 ! this word happens to be performance-critical since the compiler
1212 ! itself uses it. Optimizing it like this reduced compile time.
1213 <PRIVATE
1214
1215 : generic-flip ( matrix -- newmatrix )
1216     [ [ length ] [ min ] map-reduce ] keep
1217     '[ _ [ nth-unsafe ] with { } map-as ] map-integers ; inline
1218
1219 USE: arrays
1220
1221 : array-flip ( matrix -- newmatrix )
1222     { array } declare
1223     [ [ { array } declare length>> ] [ min ] map-reduce ] keep
1224     '[ _ [ { array } declare array-nth ] with { } map-as ] map-integers ;
1225
1226 PRIVATE>
1227
1228 : flip ( matrix -- newmatrix )
1229     dup empty? [
1230         dup array? [
1231             dup [ array? ] all?
1232             [ array-flip ] [ generic-flip ] if
1233         ] [ generic-flip ] if
1234     ] unless ;