core/sets/sets-docs.factor

   1 USING: assocs hashtables help.markup help.syntax kernel
   2 quotations sequences vectors ;
   3 IN: sets
   4
   5 ARTICLE: "sets" "Sets"
   6 "A set is an unordered list of elements. Words for working with sets are in the " { $vocab-link "sets" } " vocabulary." $nl
   7 "All sets are instances of a mixin class:"
   8 { $subsections
   9     set
  10     set?
  11 }
  12 { $subsections "set-operations" "set-implementations" } ;
  13
  14 ABOUT: "sets"
  15
  16 ARTICLE: "set-operations" "Operations on sets"
  17 "To test if an object is a member of a set:"
  18 { $subsections in? }
  19 "All sets can be represented as a sequence, without duplicates, of their members:"
  20 { $subsections members }
  21 "To get the number of elements in a set:"
  22 { $subsections cardinality }
  23 "Sets can have members added or removed destructively:"
  24 { $subsections
  25     adjoin
  26     delete
  27     clear-set
  28     union!
  29     diff!
  30 }
  31 "To test if a set is the empty set:"
  32 { $subsections null? }
  33 "Basic mathematical operations, which any type of set may override for efficiency:"
  34 { $subsections
  35     diff
  36     intersect
  37     union
  38 }
  39 "Mathematical predicates on sets, which may be overridden for efficiency:"
  40 { $subsections
  41     intersects?
  42     subset?
  43     set=
  44 }
  45 "An optional generic word for creating sets of the same class as a given set:"
  46 { $subsections set-like }
  47 "An optional generic word for creating a set with a fast lookup operation, if the set itself has a slow lookup operation:"
  48 { $subsections fast-set }
  49 "For set types that allow duplicates, like sequence sets, some additional words test for duplication:"
  50 { $subsections
  51     all-unique?
  52     duplicates
  53 }
  54 "Utilities for sets and sequences:"
  55 { $subsections
  56      within
  57      without
  58 } ;
  59
  60 ARTICLE: "set-implementations" "Set implementations"
  61 "There are several implementations of sets in the Factor library. More can be added if they implement the words of the set protocol, the basic set operations."
  62 { $subsections
  63     "sequence-sets"
  64     "hash-sets"
  65     "bit-sets"
  66 } ;
  67
  68 ARTICLE: "sequence-sets" "Sequences as sets"
  69 "Any sequence can be used as a set. The members of this set are the elements of the sequence. Calling the word " { $link members } " on a sequence returns a copy of the sequence with only one listing of each member. Destructive operations " { $link adjoin } " and " { $link delete } " only work properly on growable sequences like " { $link vector } "s."
  70 $nl
  71 "Care must be taken in writing efficient code using sequence sets. Testing for membership with " { $link in? } ", as well as the destructive set operations, take time proportional to the size of the sequence. Another representation, like " { $link "hash-sets" } ", would take constant time for membership tests. But binary operations like " { $link union } " are asymptotically optimal, taking time proportional to the sum of the size of the inputs."
  72 $nl
  73 "As one particular example, " { $link POSTPONE: f } " is a representation of the empty set, since it is an empty sequence." ;
  74
  75 HELP: set
  76 { $class-description "The class of all sets. Custom implementations of the set protocol should be declared as instances of this mixin for all set implementation to work correctly." } ;
  77
  78 HELP: adjoin
  79 { $values { "elt" object } { "set" set } }
  80 { $description "Destructively adds " { $snippet "elt" } " to " { $snippet "set" } ". For sequences, this guarantees that this element is not duplicated, and that it is at the end of the sequence." $nl "Each mutable set type is expected to implement a method on this generic word." }
  81 { $examples
  82     { $example
  83         "USING: prettyprint sets kernel ;"
  84         "V{ \"beans\" \"salsa\" \"cheese\" } clone"
  85         "\"nachos\" over adjoin"
  86         "\"salsa\" over adjoin"
  87         "."
  88         "V{ \"beans\" \"cheese\" \"nachos\" \"salsa\" }"
  89     }
  90 }
  91 { $side-effects "set" } ;
  92
  93 HELP: ?adjoin
  94 { $values { "elt" object } { "set" set } { "?" "a boolean" } }
  95 { $description "A version of " { $link adjoin } " which returns whether the element was added to the set." }
  96 { $notes "This is slightly less efficient than " { $link adjoin } " due to the initial membership test." } ;
  97
  98 HELP: delete
  99 { $values { "elt" object } { "set" set } }
 100 { $description "Destructively removes " { $snippet "elt" } " from " { $snippet "set" } ". If the element is not present, this does nothing." $nl "Each mutable set type is expected to implement a method on this generic word." }
 101 { $side-effects "set" } ;
 102
 103 HELP: clear-set
 104 { $values { "set" set } }
 105 { $contract "Removes all entries from the set." }
 106 { $side-effects "set" } ;
 107
 108 HELP: members
 109 { $values { "set" set } { "seq" sequence } }
 110 { $description "Creates a sequence with a single copy of each member of the set." $nl "Each set type is expected to implement a method on this generic word." } ;
 111
 112 HELP: in?
 113 { $values { "elt" object } { "set" set } { "?" "a boolean" } }
 114 { $description "Tests whether the element is a member of the set." $nl "Each set type is expected to implement a method on this generic word as part of the set protocol." } ;
 115
 116 HELP: adjoin-at
 117 { $values { "value" object } { "key" object } { "assoc" assoc } }
 118 { $description "Adds " { $snippet "value" } " to the set stored at " { $snippet "key" } " of " { $snippet "assoc" } "." }
 119 { $side-effects "assoc" } ;
 120
 121 HELP: duplicates
 122 { $values { "set" set } { "seq" sequence } }
 123 { $description "Outputs a sequence consisting of elements which occur more than once in " { $snippet "set" } "." }
 124 { $examples
 125     { $example "USING: sets prettyprint ;" "{ 1 2 3 1 2 1 } duplicates ." "{ 1 2 1 }" }
 126 } ;
 127
 128 HELP: all-unique?
 129 { $values { "set" set } { "?" "a boolean" } }
 130 { $description "Tests whether a set contains any repeated elements." }
 131 { $example
 132     "USING: sets prettyprint ;"
 133     "{ 0 1 1 2 3 5 } all-unique? ."
 134     "f"
 135 } ;
 136
 137 HELP: diff
 138 { $values { "set1" set } { "set2" set } { "set" set } }
 139 { $description "Outputs a set consisting of elements present in " { $snippet "set1" } " but not " { $snippet "set2" } ", comparing elements for equality."
 140 "This word has a default definition which works for all sets, but set implementations may override the default for efficiency."
 141 } { $examples
 142     { $example "USING: sets prettyprint ;" "{ 1 2 3 } { 2 3 4 } diff ." "{ 1 }" }
 143 } ;
 144
 145 HELP: intersect
 146 { $values { "set1" set } { "set2" set } { "set" set } }
 147 { $description "Outputs a set consisting of elements present in both " { $snippet "set1" } " and " { $snippet "set2" } "."
 148 "This word has a default definition which works for all sets, but set implementations may override the default for efficiency." }
 149 { $examples
 150     { $example "USING: sets prettyprint ;" "{ 1 2 3 } { 2 3 4 } intersect ." "{ 2 3 }" }
 151 } ;
 152
 153 HELP: intersection
 154 { $values { "sets" sequence } { "set/f" "a " { $link set } " or " { $link f } } }
 155 { $description "Outputs the intersection of all the sets of the sequence " { $snippet "sets" } ", or " { $link f } " if " { $snippet "sets" } " is empty." } ;
 156
 157 HELP: union
 158 { $values { "set1" set } { "set2" set } { "set" set } }
 159 { $description "Outputs a set consisting of elements present in either " { $snippet "set1" } " or " { $snippet "set2" } " which does not contain duplicate values."
 160 "This word has a default definition which works for all sets, but set implementations may override the default for efficiency." }
 161 { $examples
 162     { $example "USING: sets prettyprint ;" "{ 1 2 3 } { 2 3 4 } union ." "{ 1 2 3 4 }" }
 163 } ;
 164
 165 { diff intersect union } related-words
 166
 167 HELP: union!
 168 { $values { "set1" set } { "set2" set } }
 169 { $description "Adds all members from " { $snippet "set2" } " to " { $snippet "set1" } "." }
 170 { $side-effects "set1" } ;
 171
 172 HELP: diff!
 173 { $values { "set1" set } { "set2" set } }
 174 { $description "Removes all members from " { $snippet "set1" } " contained in " { $snippet "set2" } "." }
 175 { $side-effects "set1" } ;
 176
 177 HELP: intersects?
 178 { $values { "set1" set } { "set2" set } { "?" "a boolean" } }
 179 { $description "Tests if " { $snippet "set1" } " and " { $snippet "set2" } " have any elements in common." }
 180 { $notes "If one of the sets is empty, the result is always " { $link f } "." } ;
 181
 182 HELP: subset?
 183 { $values { "set1" set } { "set2" set } { "?" "a boolean" } }
 184 { $description "Tests if every element of " { $snippet "set1" } " is contained in " { $snippet "set2" } "." }
 185 { $notes "If " { $snippet "set1" } " is empty, the result is always " { $link t } "." } ;
 186
 187 HELP: set=
 188 { $values { "set1" set } { "set2" set } { "?" "a boolean" } }
 189 { $description "Tests if both sets contain the same elements, disregrading order and duplicates." } ;
 190
 191 HELP: gather
 192 { $values
 193      { "seq" sequence } { "quot" quotation }
 194      { "newseq" sequence } }
 195 { $description "Maps a quotation onto a sequence, concatenates the results of the mapping, and removes duplicates." } ;
 196
 197 HELP: set-like
 198 { $values { "set" set } { "exemplar" set } { "set'" set } }
 199 { $description "If the conversion is defined for the exemplar, converts the set into a set of the exemplar's class. This is not guaranteed to create a new set, for example if the input set and exemplar are of the same class." $nl
 200 "Set implementations may optionally implement a method on this generic word. The default implementation returns its input set." }
 201 { $examples
 202     { $example "USING: sets prettyprint ;" "{ 1 2 3 } HS{ } set-like ." "HS{ 1 2 3 }" }
 203 } ;
 204
 205 HELP: within
 206 { $values { "seq" sequence } { "set" set } { "subseq" sequence } }
 207 { $description "Returns the subsequence of the given sequence consisting of members of the set. This may contain duplicates, if the sequence has duplicates." } ;
 208
 209 HELP: without
 210 { $values { "seq" sequence } { "set" set } { "subseq" sequence } }
 211 { $description "Returns the subsequence of the given sequence consisting of things that are not members of the set. This may contain duplicates, if the sequence has duplicates." } ;
 212
 213 HELP: null?
 214 { $values { "set" set } { "?" "a boolean" } }
 215 { $description "Tests whether the given set is empty. This outputs " { $snippet "t" } " when given a null set of any type." } ;
 216
 217 HELP: cardinality
 218 { $values { "set" set } { "n" "a non-negative integer" } }
 219 { $description "Returns the number of elements in the set. All sets support this operation." } ;
 220
 221 HELP: combine
 222 { $values { "sets" "a sequence of sets" } { "set/f" "a " { $link set } " or " { $link f } } }
 223 { $description "Outputs the union of a sequence of sets, or " { $link f } " if the sequence is empty." } ;