core/sets/sets-docs.factor

   1 USING: assocs hashtables help.markup help.syntax kernel
   2 quotations sequences vectors ;
   3 IN: sets
   4
   5 ARTICLE: "sets" "Sets"
   6 "A set is an unordered list of elements. Words for working with sets are in the " { $vocab-link "sets" } " vocabulary." $nl
   7 "All sets are instances of a mixin class:"
   8 { $subsections
   9     set
  10     set?
  11 }
  12 { $subsections "set-operations" "set-implementations" } ;
  13
  14 ABOUT: "sets"
  15
  16 ARTICLE: "set-operations" "Operations on sets"
  17 "To test if an object is a member of a set:"
  18 { $subsections in? }
  19 "All sets can be represented as a sequence, without duplicates, of their members:"
  20 { $subsections members }
  21 "Sets can have members added or removed destructively:"
  22 { $subsections
  23     adjoin
  24     delete
  25 }
  26 "To test if a set is the empty set:"
  27 { $subsections null? }
  28 "Basic mathematical operations, which any type of set may override for efficiency:"
  29 { $subsections
  30     diff
  31     intersect
  32     union
  33 }
  34 "Mathematical predicates on sets, which may be overridden for efficiency:"
  35 { $subsections
  36     intersects?
  37     subset?
  38     set=
  39 }
  40 "An optional generic word for creating sets of the same class as a given set:"
  41 { $subsections set-like }
  42 "An optional generic word for creating a set with a fast lookup operation, if the set itself has a slow lookup operation:"
  43 { $subsections fast-set }
  44 "For set types that allow duplicates, like sequence sets, some additional words test for duplication:"
  45 { $subsections
  46     all-unique?
  47     duplicates
  48 }
  49 "Utilities for sets and sequences:"
  50 { $subsections
  51      within
  52      without
  53 } ;
  54
  55 ARTICLE: "set-implementations" "Set implementations"
  56 "There are several implementations of sets in the Factor library. More can be added if they implement the words of the set protocol, the basic set operations."
  57 { $subsections
  58     "sequence-sets"
  59     "hash-sets"
  60     "bit-sets"
  61 } ;
  62
  63 ARTICLE: "sequence-sets" "Sequences as sets"
  64 "Any sequence can be used as a set. The members of this set are the elements of the sequence. Calling the word " { $link members } " on a sequence returns a copy of the sequence with only one listing of each member. Destructive operations " { $link adjoin } " and " { $link delete } " only work properly on growable sequences like " { $link vector } "s."
  65 $nl
  66 "Care must be taken in writing efficient code using sequence sets. Testing for membership with " { $link in? } ", as well as the destructive set operations, take time proportional to the size of the sequence. Another representation, like " { $link "hash-sets" } ", would take constant time for membership tests. But binary operations like " { $link union } " are asymptotically optimal, taking time proportional to the sum of the size of the inputs."
  67 $nl
  68 "As one particular example, " { $link POSTPONE: f } " is a representation of the empty set, since it is an empty sequence." ;
  69
  70 HELP: set
  71 { $class-description "The class of all sets. Custom implementations of the set protocol should be declared as instances of this mixin for all set implementation to work correctly." } ;
  72
  73 HELP: adjoin
  74 { $values { "elt" object } { "set" set } }
  75 { $description "Destructively adds " { $snippet "elt" } " to " { $snippet "set" } ". For sequences, this guarantees that this element is not duplicated, and that it is at the end of the sequence." $nl "Each mutable set type is expected to implement a method on this generic word." }
  76 { $examples
  77     { $example
  78         "USING: prettyprint sets kernel ;"
  79         "V{ \"beans\" \"salsa\" \"cheese\" } clone"
  80         "\"nachos\" over adjoin"
  81         "\"salsa\" over adjoin"
  82         "."
  83         "V{ \"beans\" \"cheese\" \"nachos\" \"salsa\" }"
  84     }
  85 }
  86 { $side-effects "set" } ;
  87
  88 HELP: delete
  89 { $values { "elt" object } { "set" set } }
  90 { $description "Destructively removes " { $snippet "elt" } " from " { $snippet "set" } ". If the element is not present, this does nothing." $nl "Each mutable set type is expected to implement a method on this generic word." }
  91 { $side-effects "set" } ;
  92
  93 HELP: members
  94 { $values { "set" set } { "seq" sequence } }
  95 { $description "Creates a sequence with a single copy of each member of the set." $nl "Each set type is expected to implement a method on this generic word." } ;
  96
  97 HELP: in?
  98 { $values { "elt" object } { "set" set } { "?" "a boolean" } }
  99 { $description "Tests whether the element is a member of the set." $nl "Each set type is expected to implement a method on this generic word as part of the set protocol." } ;
 100
 101 HELP: adjoin-at
 102 { $values { "value" object } { "key" object } { "assoc" assoc } }
 103 { $description "Adds " { $snippet "value" } " to the set stored at " { $snippet "key" } " of " { $snippet "assoc" } "." }
 104 { $side-effects "assoc" } ;
 105
 106 HELP: duplicates
 107 { $values { "set" set } { "seq" sequence } }
 108 { $description "Outputs a sequence consisting of elements which occur more than once in " { $snippet "set" } "." }
 109 { $examples
 110     { $example "USING: sets prettyprint ;" "{ 1 2 3 1 2 1 } duplicates ." "{ 1 2 1 }" }
 111 } ;
 112
 113 HELP: all-unique?
 114 { $values { "set" set } { "?" "a boolean" } }
 115 { $description "Tests whether a set contains any repeated elements." }
 116 { $example
 117     "USING: sets prettyprint ;"
 118     "{ 0 1 1 2 3 5 } all-unique? ."
 119     "f"
 120 } ;
 121
 122 HELP: diff
 123 { $values { "set1" set } { "set2" set } { "set" set } }
 124 { $description "Outputs a set consisting of elements present in " { $snippet "set1" } " but not " { $snippet "set2" } ", comparing elements for equality."
 125 "This word has a default definition which works for all sets, but set implementations may override the default for efficiency."
 126 } { $examples
 127     { $example "USING: sets prettyprint ;" "{ 1 2 3 } { 2 3 4 } diff ." "{ 1 }" }
 128 } ;
 129
 130 HELP: intersect
 131 { $values { "set1" set } { "set2" set } { "set" set } }
 132 { $description "Outputs a set consisting of elements present in both " { $snippet "set1" } " and " { $snippet "set2" } "."
 133 "This word has a default definition which works for all sets, but set implementations may override the default for efficiency." }
 134 { $examples
 135     { $example "USING: sets prettyprint ;" "{ 1 2 3 } { 2 3 4 } intersect ." "{ 2 3 }" }
 136 } ;
 137
 138 HELP: union
 139 { $values { "set1" set } { "set2" set } { "set" set } }
 140 { $description "Outputs a set consisting of elements present in either " { $snippet "set1" } " or " { $snippet "set2" } " which does not contain duplicate values."
 141 "This word has a default definition which works for all sets, but set implementations may override the default for efficiency." }
 142 { $examples
 143     { $example "USING: sets prettyprint ;" "{ 1 2 3 } { 2 3 4 } union ." "{ 1 2 3 4 }" }
 144 } ;
 145
 146 { diff intersect union } related-words
 147
 148 HELP: intersects?
 149 { $values { "set1" set } { "set2" set } { "?" "a boolean" } }
 150 { $description "Tests if " { $snippet "set1" } " and " { $snippet "set2" } " have any elements in common." }
 151 { $notes "If one of the sets is empty, the result is always " { $link f } "." } ;
 152
 153 HELP: subset?
 154 { $values { "set1" set } { "set2" set } { "?" "a boolean" } }
 155 { $description "Tests if every element of " { $snippet "set1" } " is contained in " { $snippet "set2" } "." }
 156 { $notes "If " { $snippet "set1" } " is empty, the result is always " { $link t } "." } ;
 157
 158 HELP: set=
 159 { $values { "set1" set } { "set2" set } { "?" "a boolean" } }
 160 { $description "Tests if both sets contain the same elements, disregrading order and duplicates." } ;
 161
 162 HELP: gather
 163 { $values
 164      { "seq" sequence } { "quot" quotation }
 165      { "newseq" sequence } }
 166 { $description "Maps a quotation onto a sequence, concatenates the results of the mapping, and removes duplicates." } ;
 167
 168 HELP: set-like
 169 { $values { "set" set } { "exemplar" set } { "set'" set } }
 170 { $description "If the conversion is defined for the exemplar, converts the set into a set of the exemplar's class. This is not guaranteed to create a new set, for example if the input set and exemplar are of the same class." $nl
 171 "Set implementations may optionally implement a method on this generic word. The default implementation returns its input set." }
 172 { $examples
 173     { $example "USING: sets prettyprint ;" "{ 1 2 3 } HS{ } set-like ." "HS{ 1 2 3 }" }
 174 } ;
 175
 176 HELP: within
 177 { $values { "seq" sequence } { "set" set } { "subseq" sequence } }
 178 { $description "Returns the subsequence of the given sequence consisting of members of the set. This may contain duplicates, if the sequence has duplicates." } ;
 179
 180 HELP: without
 181 { $values { "seq" sequence } { "set" set } { "subseq" sequence } }
 182 { $description "Returns the subsequence of the given sequence consisting of things that are not members of the set. This may contain duplicates, if the sequence has duplicates." } ;
 183
 184 HELP: null?
 185 { $values { "set" set } { "?" "a boolean" } }
 186 { $description "Tests whether the given set is empty. This outputs " { $snippet "t" } " when given a null set of any type." } ;