core/splitting/splitting.factor

   1 ! Copyright (C) 2005, 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: arrays kernel math sbufs sequences sequences.private
   4 strings ;
   5 IN: splitting
   6
   7 <PRIVATE
   8
   9 : ?chomp ( seq begin tester chopper -- newseq ? )
  10     [ [ 2dup ] dip call ] dip
  11     [ [ length ] dip call t ] curry
  12     [ drop f ] if ; inline
  13
  14 PRIVATE>
  15
  16 : ?head ( seq begin -- newseq ? )
  17     [ head? ] [ tail ] ?chomp ;
  18
  19 : ?head-slice ( seq begin -- newseq ? )
  20     [ head? ] [ tail-slice ] ?chomp ;
  21
  22 : ?tail ( seq end -- newseq ? )
  23     [ tail? ] [ head* ] ?chomp ;
  24
  25 : ?tail-slice ( seq end -- newseq ? )
  26     [ tail? ] [ head-slice* ] ?chomp ;
  27
  28 <PRIVATE
  29
  30 : subseq-range ( seq subseq -- from/f to/f )
  31     [ subseq-index ] keep [ dupd length + ] curry [ f f ] if* ; inline
  32
  33 : (split1) ( seq subseq snip-quot -- before after )
  34     [ [ subseq-range ] keepd over ] dip [ 2nip f ] if ; inline
  35
  36 PRIVATE>
  37
  38 : split1 ( seq subseq -- before after )
  39     [ snip ] (split1) ;
  40
  41 : split1-slice ( seq subseq -- before-slice after-slice )
  42     [ snip-slice ] (split1) ;
  43
  44 : split-subseq ( seq subseq -- seqs )
  45     [
  46         1array
  47     ] [
  48         [ dup ] swap [ split1-slice swap ] curry produce nip
  49     ] if-empty ;
  50
  51 : replace ( seq old new -- new-seq )
  52     pick [ [ split-subseq ] dip ] dip join-as ;
  53
  54 <PRIVATE
  55
  56 : (split1-when) ( ... seq quot: ( ... elt -- ... ? ) snip-quot -- ... before-slice after-slice )
  57     [ dupd find drop ] dip [ swap [ dup 1 + ] dip ] prepose [ f ] if* ; inline
  58
  59 PRIVATE>
  60
  61 : split1-when ( ... seq quot: ( ... elt -- ... ? ) -- ... before after )
  62     [ snip ] (split1-when) ; inline
  63
  64 : split1-when-slice ( ... seq quot: ( ... elt -- ... ? ) -- ... before-slice after-slice )
  65     [ snip-slice ] (split1-when) ; inline
  66
  67 : split1-last ( seq subseq -- before after )
  68     [ <reversed> ] bi@ split1 [ reverse ] bi@
  69     dup [ swap ] when ;
  70
  71 : split1-last-slice ( seq subseq -- before-slice after-slice )
  72     [ <reversed> ] bi@ split1-slice [ <reversed> ] bi@
  73     [ f ] [ swap ] if-empty ;
  74
  75 <PRIVATE
  76
  77 : (split) ( seq quot: ( ... elt -- ... ? ) slice-quot -- pieces )
  78     [ 0 ] 3dip pick [
  79         swap curry [ keep 1 + swap ] curry [
  80             [ find-from drop dup ] 2curry [ keep -rot ] curry
  81         ] dip V{ } produce-as nip
  82     ] 2keep swap [
  83         [ length swapd ] keep
  84     ] dip 2curry call suffix! { } like ; inline
  85
  86 PRIVATE>
  87
  88 : split-when ( ... seq quot: ( ... elt -- ... ? ) -- ... pieces )
  89     [ subseq-unsafe ] (split) ; inline
  90
  91 : split-when-slice ( ... seq quot: ( ... elt -- ... ? ) -- ... pieces )
  92     [ <slice-unsafe> ] (split) ; inline
  93
  94 : split ( seq separators -- pieces )
  95     [ member? ] curry split-when ; inline
  96
  97 : split-slice ( seq separators -- pieces )
  98     [ member? ] curry split-when-slice ; inline
  99
 100 : split-indices ( seq indices -- pieces )
 101     over length suffix 0 swap [
 102         [ pick subseq ] keep swap
 103     ] map 2nip ;
 104
 105 ! split-lines uses string-nth-fast which is 50% faster over
 106 ! nth-unsafe. be careful when changing the definition so that
 107 ! you don't unoptimize it.
 108 GENERIC: split-lines ( seq -- seq' )
 109
 110 ALIAS: string-lines split-lines
 111
 112 M: string split-lines
 113     [ V{ } clone 0 ] dip [ 2dup bounds-check? ] [
 114         2dup [ "\r\n" member? ] find-from swapd [
 115             over [ [ nip length ] keep ] unless
 116             [ "" subseq-as suffix! ] 2keep [ 1 + ] dip
 117         ] dip CHAR: \r eq? [
 118             2dup ?nth CHAR: \n eq? [ [ 1 + ] dip ] when
 119         ] when
 120     ] while 2drop { } like ;
 121
 122 M: sbuf split-lines "" like split-lines ;
 123
 124 : join-lines-as ( seq exemplar -- seq ) "\n" swap join-as ; inline
 125 : join-lines ( seq -- seq ) "" join-lines-as ; inline
 126 : split-words ( seq -- seq ) " " split ; inline
 127 : join-words-as ( seq exemplar -- seq ) " " swap join-as ; inline
 128 : join-words ( seq -- seq ) " " join-words-as ; inline