core/splitting/splitting.factor

   1 ! Copyright (C) 2005, 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: kernel math make strings arrays vectors sequences
   4 sets math.order accessors ;
   5 IN: splitting
   6
   7 <PRIVATE
   8
   9 : ?chomp ( seq begin tester chopper -- newseq ? )
  10     [ [ 2dup ] dip call ] dip
  11     [ [ length ] dip call t ] curry
  12     [ drop f ] if ; inline
  13
  14 PRIVATE>
  15
  16 : ?head ( seq begin -- newseq ? )
  17     [ head? ] [ tail ] ?chomp ;
  18
  19 : ?head-slice ( seq begin -- newseq ? )
  20     [ head? ] [ tail-slice ] ?chomp ;
  21
  22 : ?tail ( seq end -- newseq ? )
  23     [ tail? ] [ head* ] ?chomp ;
  24
  25 : ?tail-slice ( seq end -- newseq ? )
  26     [ tail? ] [ head-slice* ] ?chomp ;
  27
  28 <PRIVATE
  29
  30 : (split1) ( seq subseq quot -- before after )
  31     [
  32         swap [
  33             [ drop length ] [ start dup ] 2bi
  34             [ [ nip ] [ + ] 2bi t ]
  35             [ 2drop f f f ]
  36             if
  37         ] keep swap
  38     ] dip [ 2nip f ] if ; inline
  39
  40 PRIVATE>
  41
  42 : split1 ( seq subseq -- before after )
  43     [ snip ] (split1) ;
  44
  45 : split1-slice ( seq subseq -- before-slice after-slice )
  46     [ snip-slice ] (split1) ;
  47
  48 : split1-last ( seq subseq -- before after )
  49     [ <reversed> ] bi@ split1 [ reverse ] bi@
  50     dup [ swap ] when ;
  51
  52 : split1-last-slice ( seq subseq -- before-slice after-slice )
  53     [ <reversed> ] bi@ split1-slice [ <reversed> ] bi@
  54     [ f ] [ swap ] if-empty ;
  55
  56 <PRIVATE
  57
  58 : (split) ( n seq quot: ( ... elt -- ... ? ) -- )
  59     [ find-from drop ]
  60     [ [ [ 3dup swapd subseq , ] dip [ drop 1 + ] 2dip (split) ] 3curry ]
  61     [ drop [ swap [ tail ] unless-zero , ] 2curry ]
  62     3tri if* ; inline recursive
  63
  64 : split, ( ... seq quot: ( ... elt -- ... ? ) -- ... ) [ 0 ] 2dip (split) ; inline
  65
  66 PRIVATE>
  67
  68 : split ( seq separators -- pieces )
  69     [ [ member? ] curry split, ] { } make ;
  70
  71 : split-when ( ... seq quot: ( ... elt -- ... ? ) -- ... pieces )
  72     [ split, ] { } make ; inline
  73
  74 GENERIC: string-lines ( str -- seq )
  75
  76 M: string string-lines
  77     dup "\r\n" intersects? [
  78         "\n" split [
  79             but-last-slice [
  80                 "\r" ?tail drop "\r" split
  81             ] map
  82         ] keep last "\r" split suffix concat
  83     ] [
  84         1array
  85     ] if ;