core/splitting/splitting.factor

   1 ! Copyright (C) 2005, 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: arrays kernel math sbufs sequences sequences.private
   4 strings ;
   5 IN: splitting
   6
   7 <PRIVATE
   8
   9 : ?chomp ( seq begin tester chopper -- newseq ? )
  10     [ [ 2dup ] dip call ] dip
  11     [ [ length ] dip call t ] curry
  12     [ drop f ] if ; inline
  13
  14 PRIVATE>
  15
  16 : ?head ( seq begin -- newseq ? )
  17     [ head? ] [ tail ] ?chomp ;
  18
  19 : ?head-slice ( seq begin -- newseq ? )
  20     [ head? ] [ tail-slice ] ?chomp ;
  21
  22 : ?tail ( seq end -- newseq ? )
  23     [ tail? ] [ head* ] ?chomp ;
  24
  25 : ?tail-slice ( seq end -- newseq ? )
  26     [ tail? ] [ head-slice* ] ?chomp ;
  27
  28 : subseq-range ( seq subseq -- from/f to/f )
  29     tuck subseq-index [ dup rot length + ] [ drop f f ] if* ;
  30
  31 : ?snip ( from/f to/f seq -- before after )
  32     over [ snip ] [ 2nip f ] if ; inline
  33
  34 : ?snip-slice ( from/f to/f seq -- before after )
  35     over [ snip-slice ] [ 2nip f ] if ; inline
  36
  37 : split1 ( seq subseq -- before after )
  38     [ subseq-range ] keepd ?snip ; inline
  39
  40 : split1-slice ( seq subseq -- before-slice after-slice )
  41     [ subseq-range ] keepd ?snip-slice ; inline
  42
  43 : split-subseq ( seq subseq -- seqs )
  44     [
  45         1array
  46     ] [
  47         [ dup ] swap [ split1-slice swap ] curry produce nip
  48     ] if-empty ;
  49
  50 : replace ( seq old new -- new-seq )
  51     pick [ [ split-subseq ] dip ] dip join-as ;
  52
  53 : split1-when ( ... seq quot: ( ... elt -- ... ? ) -- ... before after )
  54     [ find drop ] keepd swap [ dup 1 + rot snip ] [ f ] if* ; inline
  55
  56 : split1-when-slice ( ... seq quot: ( ... elt -- ... ? ) -- ... before-slice after-slice )
  57     [ find drop ] keepd swap [ dup 1 + rot snip-slice ] [ f ] if* ; inline
  58
  59 : split1-last ( seq subseq -- before after )
  60     [ <reversed> ] bi@ split1 [ reverse ] bi@
  61     dup [ swap ] when ;
  62
  63 : split1-last-slice ( seq subseq -- before-slice after-slice )
  64     [ <reversed> ] bi@ split1-slice [ <reversed> ] bi@
  65     [ f ] [ swap ] if-empty ;
  66
  67 <PRIVATE
  68
  69 : (split) ( seq quot: ( ... elt -- ... ? ) slice-quot -- pieces )
  70     [ 0 ] 3dip pick [
  71         swap curry [ keep 1 + swap ] curry [
  72             [ find-from drop dup ] 2curry [ keep -rot ] curry
  73         ] dip V{ } produce-as nip
  74     ] 2keep swap [
  75         [ length swapd ] keep
  76     ] dip 2curry call suffix! { } like ; inline
  77
  78 PRIVATE>
  79
  80 : split-when ( ... seq quot: ( ... elt -- ... ? ) -- ... pieces )
  81     [ subseq-unsafe ] (split) ; inline
  82
  83 : split-when-slice ( ... seq quot: ( ... elt -- ... ? ) -- ... pieces )
  84     [ <slice-unsafe> ] (split) ; inline
  85
  86 : split ( seq separators -- pieces )
  87     [ member? ] curry split-when ; inline
  88
  89 : split-slice ( seq separators -- pieces )
  90     [ member? ] curry split-when-slice ; inline
  91
  92 : split-indices ( seq indices -- pieces )
  93     over length suffix 0 swap [
  94         [ pick subseq ] keep swap
  95     ] map 2nip ;
  96
  97 ! split-lines uses string-nth-fast which is 50% faster over
  98 ! nth-unsafe. be careful when changing the definition so that
  99 ! you don't unoptimize it.
 100 GENERIC: split-lines ( seq -- seq' )
 101
 102 ALIAS: string-lines split-lines
 103
 104 M: string split-lines
 105     [ V{ } clone 0 ] dip [ 2dup bounds-check? ] [
 106         2dup [ "\r\n" member? ] find-from swapd [
 107             over [ [ nip length ] keep ] unless
 108             [ "" subseq-as suffix! ] 2keep [ 1 + ] dip
 109         ] dip CHAR: \r eq? [
 110             2dup ?nth CHAR: \n eq? [ [ 1 + ] dip ] when
 111         ] when
 112     ] while 2drop { } like ;
 113
 114 M: sbuf split-lines "" like split-lines ;
 115
 116 : join-lines-as ( seq exemplar -- seq ) "\n" swap join-as ; inline
 117 : join-lines ( seq -- seq ) "" join-lines-as ; inline
 118 : split-words ( seq -- seq ) " " split ; inline
 119 : join-words-as ( seq exemplar -- seq ) " " swap join-as ; inline
 120 : join-words ( seq -- seq ) " " join-words-as ; inline