core/splitting/splitting.factor

   1 ! Copyright (C) 2005, 2008 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: kernel math make strings arrays vectors sequences
   4 sets math.order accessors ;
   5 IN: splitting
   6
   7 : ?head ( seq begin -- newseq ? )
   8     2dup head? [ length tail t ] [ drop f ] if ;
   9
  10 : ?head-slice ( seq begin -- newseq ? )
  11     2dup head? [ length tail-slice t ] [ drop f ] if ;
  12
  13 : ?tail ( seq end -- newseq ? )
  14     2dup tail? [ length head* t ] [ drop f ] if ;
  15
  16 : ?tail-slice ( seq end -- newseq ? )
  17     2dup tail? [ length head-slice* t ] [ drop f ] if ;
  18
  19 : split1 ( seq subseq -- before after )
  20     dup pick start dup [
  21         [ [ over ] dip head -rot length ] keep + tail
  22     ] [
  23         2drop f
  24     ] if ;
  25
  26 : split1-slice ( seq subseq -- before-slice after-slice )
  27     dup pick start dup [
  28         [ [ over ] dip head-slice -rot length ] keep + tail-slice
  29     ] [
  30         2drop f
  31     ] if ;
  32
  33 : split1-last ( seq subseq -- before after )
  34     [ <reversed> ] bi@ split1 [ reverse ] bi@
  35     dup [ swap ] when ;
  36
  37 : split1-last-slice ( seq subseq -- before-slice after-slice )
  38     [ <reversed> ] bi@ split1-slice [ <reversed> ] bi@
  39     [ f ] [ swap ] if-empty ;
  40
  41 : (split) ( separators n seq -- )
  42     3dup rot [ member? ] curry find-from drop
  43     [ [ swap subseq , ] 2keep 1+ swap (split) ]
  44     [ swap dup zero? [ drop ] [ tail ] if , drop ] if* ; inline recursive
  45
  46 : split, ( seq separators -- ) 0 rot (split) ;
  47
  48 : split ( seq separators -- pieces ) [ split, ] { } make ;
  49
  50 : string-lines ( str -- seq )
  51     dup "\r\n" intersect empty? [
  52         1array
  53     ] [
  54         "\n" split [
  55             but-last-slice [
  56                 "\r" ?tail drop "\r" split
  57             ] map
  58         ] keep peek "\r" split suffix concat
  59     ] if ;