core/splitting/splitting.factor

   1 ! Copyright (C) 2005, 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: arrays kernel math sbufs sequences sequences.private
   4 strings ;
   5 IN: splitting
   6
   7 <PRIVATE
   8
   9 : ?chomp ( seq begin tester chopper -- newseq ? )
  10     [ [ 2dup ] dip call ] dip
  11     [ [ length ] dip call t ] curry
  12     [ drop f ] if ; inline
  13
  14 PRIVATE>
  15
  16 : ?head ( seq begin -- newseq ? )
  17     [ head? ] [ tail ] ?chomp ;
  18
  19 : ?head-slice ( seq begin -- newseq ? )
  20     [ head? ] [ tail-slice ] ?chomp ;
  21
  22 : ?tail ( seq end -- newseq ? )
  23     [ tail? ] [ head* ] ?chomp ;
  24
  25 : ?tail-slice ( seq end -- newseq ? )
  26     [ tail? ] [ head-slice* ] ?chomp ;
  27
  28 <PRIVATE
  29
  30 : (split1) ( seq subseq snip-quot -- before after )
  31     [
  32         swap [
  33             [ drop length ] [ start dup ] 2bi
  34             [ [ nip ] [ + ] 2bi t ]
  35             [ 2drop f f f ]
  36             if
  37         ] keep swap
  38     ] dip [ 2nip f ] if ; inline
  39
  40 PRIVATE>
  41
  42 : split1 ( seq subseq -- before after )
  43     [ snip ] (split1) ;
  44
  45 : split1-slice ( seq subseq -- before-slice after-slice )
  46     [ snip-slice ] (split1) ;
  47
  48 : split-subseq ( seq subseq -- seqs )
  49     [
  50         1array
  51     ] [
  52         [ dup ] swap [ split1-slice swap ] curry produce nip
  53     ] if-empty ;
  54
  55 : replace ( seq old new -- new-seq )
  56     pick [ [ split-subseq ] dip ] dip join-as ;
  57
  58 <PRIVATE
  59
  60 : (split1-when) ( ... seq quot: ( ... elt -- ... ? ) snip-quot -- ... before-slice after-slice )
  61     [ dupd find drop ] dip [ swap [ dup 1 + ] dip ] prepose [ f ] if* ; inline
  62
  63 PRIVATE>
  64
  65 : split1-when ( ... seq quot: ( ... elt -- ... ? ) -- ... before after )
  66     [ snip ] (split1-when) ; inline
  67
  68 : split1-when-slice ( ... seq quot: ( ... elt -- ... ? ) -- ... before-slice after-slice )
  69     [ snip-slice ] (split1-when) ; inline
  70
  71 : split1-last ( seq subseq -- before after )
  72     [ <reversed> ] bi@ split1 [ reverse ] bi@
  73     dup [ swap ] when ;
  74
  75 : split1-last-slice ( seq subseq -- before-slice after-slice )
  76     [ <reversed> ] bi@ split1-slice [ <reversed> ] bi@
  77     [ f ] [ swap ] if-empty ;
  78
  79 <PRIVATE
  80
  81 : (split) ( seq quot: ( ... elt -- ... ? ) slice-quot -- pieces )
  82     [ 0 ] 3dip pick [
  83         swap curry [ keep 1 + swap ] curry [
  84             [ find-from drop dup ] 2curry [ keep -rot ] curry
  85         ] dip produce nip
  86     ] 2keep swap [
  87         [ length swapd ] keep
  88     ] dip 2curry call suffix ; inline
  89
  90 PRIVATE>
  91
  92 : split-when ( ... seq quot: ( ... elt -- ... ? ) -- ... pieces )
  93     [ subseq-unsafe ] (split) ; inline
  94
  95 : split-when-slice ( ... seq quot: ( ... elt -- ... ? ) -- ... pieces )
  96     [ <slice-unsafe> ] (split) ; inline
  97
  98 : split ( seq separators -- pieces )
  99     [ member? ] curry split-when ; inline
 100
 101 : split-slice ( seq separators -- pieces )
 102     [ member? ] curry split-when-slice ; inline
 103
 104 : split-indices ( seq indices -- pieces )
 105     over length suffix 0 swap [
 106         [ pick subseq ] keep swap
 107     ] map 2nip ;
 108
 109 : string-lines ( seq -- seq' )
 110     [ V{ } clone 0 ] dip [ 2dup bounds-check? ] [
 111         2dup [ "\r\n" member? ] find-from swapd [
 112             over [ [ nip length ] keep ] unless
 113             [ "" subseq-as suffix! ] 2keep [ 1 + ] dip
 114         ] dip CHAR: \r eq? [
 115             2dup ?nth CHAR: \n eq? [ [ 1 + ] dip ] when
 116         ] when
 117     ] while 2drop { } like ;