core/splitting/splitting.factor

   1 ! Copyright (C) 2005, 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: arrays kernel math sbufs sequences sequences.private
   4 strings ;
   5 IN: splitting
   6
   7 <PRIVATE
   8
   9 : ?chomp ( seq begin tester chopper -- newseq ? )
  10     [ [ 2dup ] dip call ] dip
  11     [ [ length ] dip call t ] curry
  12     [ drop f ] if ; inline
  13
  14 PRIVATE>
  15
  16 : ?head ( seq begin -- newseq ? )
  17     [ head? ] [ tail ] ?chomp ;
  18
  19 : ?head-slice ( seq begin -- newseq ? )
  20     [ head? ] [ tail-slice ] ?chomp ;
  21
  22 : ?tail ( seq end -- newseq ? )
  23     [ tail? ] [ head* ] ?chomp ;
  24
  25 : ?tail-slice ( seq end -- newseq ? )
  26     [ tail? ] [ head-slice* ] ?chomp ;
  27
  28 <PRIVATE
  29
  30 : subseq-range ( seq subseq -- from/f to/f )
  31     [ subseq-index ] keep '[ dup _ length + ] [ f f ] if* ; inline
  32
  33 : (split1) ( seq subseq snip-quot -- before after )
  34     [ [ subseq-range ] keepd over ] dip [ 2nip f ] if ; inline
  35
  36 PRIVATE>
  37
  38 : split1 ( seq subseq -- before after )
  39     [ snip ] (split1) ;
  40
  41 : split1-slice ( seq subseq -- before-slice after-slice )
  42     [ snip-slice ] (split1) ;
  43
  44 : split-subseq ( seq subseq -- seqs )
  45     [
  46         1array
  47     ] [
  48         [ dup ] swap '[ _ split1-slice swap ] produce nip
  49     ] if-empty ;
  50
  51 : replace ( seq old new -- new-seq )
  52     pick [ [ split-subseq ] dip ] dip join-as ;
  53
  54 <PRIVATE
  55
  56 : (split1-when) ( ... seq quot: ( ... elt -- ... ? ) snip-quot -- ... before-slice after-slice )
  57     [ dupd find drop ] dip '[ dup 1 + rot @ ] [ f ] if* ; inline
  58
  59 PRIVATE>
  60
  61 : split1-when ( ... seq quot: ( ... elt -- ... ? ) -- ... before after )
  62     [ snip ] (split1-when) ; inline
  63
  64 : split1-when-slice ( ... seq quot: ( ... elt -- ... ? ) -- ... before-slice after-slice )
  65     [ snip-slice ] (split1-when) ; inline
  66
  67 : split1-last ( seq subseq -- before after )
  68     [ <reversed> ] bi@ split1 [ reverse ] bi@
  69     dup [ swap ] when ;
  70
  71 : split1-last-slice ( seq subseq -- before-slice after-slice )
  72     [ <reversed> ] bi@ split1-slice [ <reversed> ] bi@
  73     [ f ] [ swap ] if-empty ;
  74
  75 <PRIVATE
  76
  77 :: (split-when) ( seq quot: ( ... elt -- ... ? ) slice-quot -- pieces )
  78     0
  79     [ [ seq quot find-from drop dup ] keep -rot ]
  80     [ [ seq slice-quot call ] keep 1 + swap ]
  81     V{ } produce-as nip swap
  82     seq length seq slice-quot call suffix! { } like ; inline
  83
  84 PRIVATE>
  85
  86 : split-when ( ... seq quot: ( ... elt -- ... ? ) -- ... pieces )
  87     [ subseq-unsafe ] (split-when) ; inline
  88
  89 : split-when-slice ( ... seq quot: ( ... elt -- ... ? ) -- ... pieces )
  90     [ <slice-unsafe> ] (split-when) ; inline
  91
  92 : split ( seq separators -- pieces )
  93     '[ _ member? ] split-when ; inline
  94
  95 : split-slice ( seq separators -- pieces )
  96     '[ _ member? ] split-when-slice ; inline
  97
  98 : split-indices ( seq indices -- pieces )
  99     over length suffix 0 swap [
 100         [ pick subseq ] keep swap
 101     ] map 2nip ;
 102
 103 ! split-lines uses string-nth-fast which is 50% faster over
 104 ! nth-unsafe. be careful when changing the definition so that
 105 ! you don't unoptimize it.
 106 GENERIC: split-lines ( seq -- seq' )
 107
 108 ALIAS: string-lines split-lines
 109
 110 M: string split-lines
 111     [ V{ } clone 0 ] dip [ 2dup bounds-check? ] [
 112         2dup [ "\r\n" member? ] find-from swapd [
 113             over [ [ nip length ] keep ] unless
 114             [ "" subseq-as suffix! ] 2keep [ 1 + ] dip
 115         ] dip CHAR: \r eq? [
 116             2dup ?nth CHAR: \n eq? [ [ 1 + ] dip ] when
 117         ] when
 118     ] while 2drop { } like ;
 119
 120 M: sbuf split-lines "" like split-lines ;
 121
 122 : join-lines-as ( seq exemplar -- seq ) "\n" swap join-as ; inline
 123 : join-lines ( seq -- seq ) "" join-lines-as ; inline
 124 : split-words ( seq -- seq ) " " split ; inline
 125 : join-words-as ( seq exemplar -- seq ) " " swap join-as ; inline
 126 : join-words ( seq -- seq ) " " join-words-as ; inline