core/strings/strings.factor

   1 ! Copyright (C) 2003, 2010 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors alien.accessors byte-arrays kernel math.private
   4 sequences kernel.private math sequences.private slots.private ;
   5 IN: strings
   6
   7 <PRIVATE
   8
   9 : string-hashcode ( str -- n ) 3 slot ; inline
  10
  11 : set-string-hashcode ( n str -- ) 3 set-slot ; inline
  12
  13 : reset-string-hashcode ( str -- )
  14     f swap set-string-hashcode ; inline
  15
  16 : rehash-string ( str -- )
  17     1 over sequence-hashcode swap set-string-hashcode ; inline
  18
  19 : (aux) ( n string -- byte-array m )
  20     aux>> { byte-array } declare swap 1 fixnum-shift-fast ; inline
  21
  22 : small-char? ( ch -- ? )
  23     dup 0 fixnum>= [ 0x7f fixnum<= ] [ drop f ] if ; inline
  24
  25 : string-nth ( n string -- ch )
  26     2dup string-nth-fast dup small-char?
  27     [ 2nip ] [
  28         [ (aux) alien-unsigned-2 7 fixnum-shift-fast ] dip
  29         fixnum-bitxor
  30     ] if ; inline
  31
  32 : ensure-aux ( string -- string )
  33     dup aux>> [ dup length 2 * (byte-array) >>aux ] unless ; inline
  34
  35 : set-string-nth-slow ( ch n string -- )
  36     [ [ 0x80 fixnum-bitor ] 2dip set-string-nth-fast ]
  37     [
  38         ensure-aux
  39         [ -7 fixnum-shift-fast 1 fixnum-bitxor ] 2dip
  40         (aux) set-alien-unsigned-2
  41     ] 3bi ;
  42
  43 : set-string-nth ( ch n string -- )
  44     pick small-char?
  45     [ set-string-nth-fast ] [ set-string-nth-slow ] if ; inline
  46
  47 PRIVATE>
  48
  49 M: string equal?
  50     over string? [
  51         2dup [ hashcode ] bi@ eq?
  52         [ sequence= ] [ 2drop f ] if
  53     ] [
  54         2drop f
  55     ] if ;
  56
  57 M: string hashcode*
  58     nip
  59     dup string-hashcode
  60     [ ] [ dup rehash-string string-hashcode ] ?if ;
  61
  62 M: string length
  63     length>> ; inline
  64
  65 M: string nth-unsafe
  66     [ >fixnum ] dip string-nth ; inline
  67
  68 M: string set-nth-unsafe
  69     dup reset-string-hashcode
  70     [ >fixnum ] [ >fixnum ] [ ] tri* set-string-nth ; inline
  71
  72 M: string clone
  73     (clone) [ clone ] change-aux ; inline
  74
  75 M: string resize resize-string ; inline
  76
  77 : 1string ( ch -- str ) 1 swap <string> ; inline
  78
  79 : >string ( seq -- str ) "" clone-like ; inline
  80
  81 M: string new-sequence drop 0 <string> ; inline
  82
  83 INSTANCE: string sequence