core/vocabs/loader/loader.factor

   1 ! Copyright (C) 2007, 2010 Eduardo Cavazos, Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors arrays assocs continuations definitions init
   4 io io.files io.pathnames kernel make namespaces parser
   5 sequences sets splitting strings vocabs words ;
   6 IN: vocabs.loader
   7
   8 SYMBOL: vocab-roots
   9
  10 SYMBOL: add-vocab-root-hook
  11
  12 [
  13     V{
  14         "resource:core"
  15         "resource:basis"
  16         "resource:extra"
  17         "resource:work"
  18     } clone vocab-roots set-global
  19
  20     [ drop ] add-vocab-root-hook set-global
  21 ] "vocabs.loader" add-startup-hook
  22
  23 : add-vocab-root ( root -- )
  24     trim-tail-separators
  25     [ vocab-roots get adjoin ]
  26     [ add-vocab-root-hook get-global call( root -- ) ] bi ;
  27
  28 SYMBOL: root-cache
  29 root-cache [ H{ } clone ] initialize
  30
  31 ERROR: not-found-in-roots path ;
  32
  33 <PRIVATE
  34
  35 : find-root-for ( path -- path/f )
  36     vocab-roots get [ prepend-path exists? ] with find nip ;
  37
  38 M: string vocab-path ( string -- path/f )
  39     dup find-root-for [ prepend-path ] [ throw-not-found-in-roots ] if* ;
  40
  41 PRIVATE>
  42
  43 : vocab-dir ( vocab -- dir )
  44     vocab-name H{ { CHAR: . CHAR: / } } substitute ;
  45
  46 : append-vocab-dir ( vocab str/f -- path )
  47     [ vocab-name "." split ] dip
  48     [ [ dup last ] dip append suffix ] when*
  49     "/" join ;
  50
  51 : find-vocab-root ( vocab -- path/f )
  52     vocab-name root-cache get [
  53         dup ".private" tail? [ drop f ] [
  54             ".factor" append-vocab-dir find-root-for
  55         ] if
  56     ] cache ;
  57
  58 : vocab-append-path ( vocab path -- newpath )
  59     swap find-vocab-root [ prepend-path ] [ drop f ] if* ;
  60
  61 : vocab-source-path ( vocab -- path/f )
  62     dup ".factor" append-vocab-dir vocab-append-path ;
  63
  64 : vocab-docs-path ( vocab -- path/f )
  65     dup "-docs.factor" append-vocab-dir vocab-append-path ;
  66
  67 SYMBOL: load-help?
  68
  69 ! Defined by vocabs.metadata
  70 SYMBOL: check-vocab-hook
  71 check-vocab-hook [ [ drop ] ] initialize
  72
  73 <PRIVATE
  74
  75 SYMBOL: require-when-vocabs
  76 require-when-vocabs [ HS{ } clone ] initialize
  77
  78 SYMBOL: require-when-table
  79 require-when-table [ V{ } clone ] initialize
  80
  81 : load-conditional-requires ( vocab -- )
  82     vocab-name require-when-vocabs get in? [
  83         require-when-table get [
  84             [ [ lookup-vocab dup [ source-loaded?>> +done+ = ] when ] all? ] dip
  85             [ require ] curry when
  86         ] assoc-each
  87     ] when ;
  88
  89 : load-source ( vocab -- )
  90     dup check-vocab-hook get call( vocab -- )
  91     [
  92         +parsing+ >>source-loaded?
  93         dup vocab-source-path [ parse-file ] [ [ ] ] if*
  94         [ +parsing+ >>source-loaded? ] dip
  95         [ % ] [ call( -- ) ] if-bootstrapping
  96         +done+ >>source-loaded?
  97         load-conditional-requires
  98     ] [ ] [ f >>source-loaded? ] cleanup ;
  99
 100 : load-docs ( vocab -- )
 101     load-help? get [
 102         [
 103             +parsing+ >>docs-loaded?
 104             dup vocab-docs-path [ ?run-file ] when*
 105             +done+ >>docs-loaded?
 106         ] [ ] [ f >>docs-loaded? ] cleanup
 107     ] when drop ;
 108
 109 PRIVATE>
 110
 111 : require-when ( if then -- )
 112     over [ lookup-vocab ] all? [
 113         require drop
 114     ] [
 115         [ drop require-when-vocabs get adjoin-all ]
 116         [ 2array require-when-table get push ] 2bi
 117     ] if ;
 118
 119 : reload ( name -- )
 120     dup lookup-vocab
 121     [ [ load-source ] [ load-docs ] bi ]
 122     [ require ]
 123     ?if ;
 124
 125 : run ( vocab -- )
 126     dup load-vocab vocab-main [
 127         execute( -- )
 128     ] [
 129         "The " write vocab-name write
 130         " vocabulary does not define an entry point." print
 131         "To define one, refer to \\ MAIN: help" print
 132     ] ?if ;
 133
 134 SYMBOL: blacklist
 135
 136 : require-all ( vocabs -- )
 137     V{ } clone blacklist [ [ require ] each ] with-variable ;
 138
 139 <PRIVATE
 140
 141 : add-to-blacklist ( error vocab -- )
 142     vocab-name blacklist get [ set-at ] [ 2drop ] if* ;
 143
 144 GENERIC: (require) ( name -- )
 145
 146 M: vocab (require)
 147     [
 148         dup source-loaded?>> +parsing+ eq? [ drop ] [
 149             dup source-loaded?>> [ dup load-source ] unless
 150             dup docs-loaded?>> [ dup load-docs ] unless
 151             drop
 152         ] if
 153     ] [ [ swap add-to-blacklist ] keep rethrow ] recover ;
 154
 155 M: vocab-link (require)
 156     vocab-name (require) ;
 157
 158 M: string (require) create-vocab (require) ;
 159
 160 PRIVATE>
 161
 162 [
 163     dup vocab-name blacklist get at*
 164     [ rethrow ]
 165     [
 166         drop dup find-vocab-root
 167         [ (require) ]
 168         [ dup lookup-vocab [ drop ] [ throw-no-vocab ] if ]
 169         if
 170     ] if
 171 ] require-hook set-global
 172
 173 M: vocab-spec where vocab-source-path dup [ 1 2array ] when ;
 174
 175 ! put here to avoid circularity between vocabs.loader and source-files.errors
 176 { "source-files.errors" "debugger" } "source-files.errors.debugger" require-when