core/vocabs/loader/loader.factor

   1 ! Copyright (C) 2007, 2009 Eduardo Cavazos, Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: namespaces make sequences io io.files io.pathnames kernel
   4 assocs words vocabs definitions parser continuations hashtables
   5 sorting source-files arrays combinators strings system
   6 math.parser splitting init accessors sets ;
   7 IN: vocabs.loader
   8
   9 SYMBOL: vocab-roots
  10
  11 V{
  12     "resource:core"
  13     "resource:basis"
  14     "resource:extra"
  15     "resource:work"
  16 } clone vocab-roots set-global
  17
  18 : add-vocab-root ( root -- )
  19     vocab-roots get adjoin ;
  20
  21 SYMBOL: root-cache
  22
  23 root-cache [ H{ } clone ] initialize
  24
  25 ERROR: not-found-in-roots path ;
  26
  27 <PRIVATE
  28
  29 : find-root-for ( path -- path/f )
  30     vocab-roots get [ prepend-path exists? ] with find nip ;
  31
  32 M: string vocab-path ( string -- path/f )
  33     dup find-root-for [ prepend-path ] [ not-found-in-roots ] if* ;
  34
  35 PRIVATE>
  36
  37 : vocab-dir ( vocab -- dir )
  38     vocab-name
  39     os windows? { { CHAR: . CHAR: \\ } } { { CHAR: . CHAR: / } } ?
  40     substitute ;
  41
  42 : vocab-dir+ ( vocab str/f -- path )
  43     [ vocab-name "." split ] dip
  44     [ [ dup last ] dip append suffix ] when*
  45     path-separator join ;
  46
  47 : find-vocab-root ( vocab -- path/f )
  48     vocab-name dup root-cache get at
  49     [ ] [ ".factor" vocab-dir+ find-root-for ] ?if ;
  50
  51 : vocab-append-path ( vocab path -- newpath )
  52     swap find-vocab-root dup [ prepend-path ] [ 2drop f ] if ;
  53
  54 : vocab-source-path ( vocab -- path/f )
  55     dup ".factor" vocab-dir+ vocab-append-path ;
  56
  57 : vocab-docs-path ( vocab -- path/f )
  58     dup "-docs.factor" vocab-dir+ vocab-append-path ;
  59
  60 SYMBOL: load-help?
  61
  62 <PRIVATE
  63
  64 : load-source ( vocab -- )
  65     [
  66         +parsing+ >>source-loaded?
  67         dup vocab-source-path [ parse-file ] [ [ ] ] if*
  68         [ +parsing+ >>source-loaded? ] dip
  69         [ % ] [ call( -- ) ] if-bootstrapping
  70         +done+ >>source-loaded? drop
  71     ] [ ] [ f >>source-loaded? ] cleanup ;
  72
  73 : load-docs ( vocab -- )
  74     load-help? get [
  75         [
  76             +parsing+ >>docs-loaded?
  77             [ vocab-docs-path [ ?run-file ] when* ] keep
  78             +done+ >>docs-loaded?
  79         ] [ ] [ f >>docs-loaded? ] cleanup
  80     ] when drop ;
  81
  82 PRIVATE>
  83
  84 : require ( vocab -- )
  85     load-vocab drop ;
  86
  87 : reload ( name -- )
  88     dup vocab
  89     [ [ load-source ] [ load-docs ] bi ]
  90     [ require ]
  91     ?if ;
  92
  93 : run ( vocab -- )
  94     dup load-vocab vocab-main [
  95         execute( -- )
  96     ] [
  97         "The " write vocab-name write
  98         " vocabulary does not define an entry point." print
  99         "To define one, refer to \\ MAIN: help" print
 100     ] ?if ;
 101
 102 SYMBOL: blacklist
 103
 104 <PRIVATE
 105
 106 : add-to-blacklist ( error vocab -- )
 107     vocab-name blacklist get dup [ set-at ] [ 3drop ] if ;
 108
 109 GENERIC: (load-vocab) ( name -- vocab )
 110
 111 M: vocab (load-vocab)
 112     [
 113         dup source-loaded?>> +parsing+ eq? [
 114             dup source-loaded?>> [ dup load-source ] unless
 115             dup docs-loaded?>> [ dup load-docs ] unless
 116         ] unless
 117     ] [ [ swap add-to-blacklist ] keep rethrow ] recover ;
 118
 119 M: vocab-link (load-vocab)
 120     vocab-name create-vocab (load-vocab) ;
 121
 122 M: string (load-vocab)
 123     create-vocab (load-vocab) ;
 124
 125 PRIVATE>
 126
 127 [
 128     dup vocab-name blacklist get at* [ rethrow ] [
 129         drop dup find-vocab-root
 130         [ (load-vocab) ] [ dup vocab [ ] [ no-vocab ] ?if ] if
 131     ] if
 132 ] load-vocab-hook set-global
 133
 134 M: vocab-spec where vocab-source-path dup [ 1 2array ] when ;