core/vocabs/loader/loader.factor

   1 ! Copyright (C) 2007, 2010 Eduardo Cavazos, Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors arrays assocs continuations definitions init
   4 io io.files io.pathnames kernel make namespaces parser
   5 sequences sets splitting strings vocabs words ;
   6 IN: vocabs.loader
   7
   8 SYMBOL: vocab-roots
   9
  10 SYMBOL: add-vocab-root-hook
  11
  12 [
  13     V{
  14         "resource:core"
  15         "resource:basis"
  16         "resource:extra"
  17         "resource:work"
  18     } clone vocab-roots set-global
  19
  20     [ drop ] add-vocab-root-hook set-global
  21 ] "vocabs.loader" add-startup-hook
  22
  23 : add-vocab-root ( root -- )
  24     trim-tail-separators
  25     [ vocab-roots get adjoin ]
  26     [ add-vocab-root-hook get-global call( root -- ) ] bi ;
  27
  28 SYMBOL: root-cache
  29
  30 root-cache [ H{ } clone ] initialize
  31
  32 ERROR: not-found-in-roots path ;
  33
  34 <PRIVATE
  35
  36 : find-root-for ( path -- path/f )
  37     vocab-roots get [ prepend-path exists? ] with find nip ;
  38
  39 M: string vocab-path ( string -- path/f )
  40     dup find-root-for [ prepend-path ] [ not-found-in-roots ] if* ;
  41
  42 PRIVATE>
  43
  44 : vocab-dir ( vocab -- dir )
  45     vocab-name H{ { CHAR: . CHAR: / } } substitute ;
  46
  47 : append-vocab-dir ( vocab str/f -- path )
  48     [ vocab-name "." split ] dip
  49     [ [ dup last ] dip append suffix ] when*
  50     "/" join ;
  51
  52 : find-vocab-root ( vocab -- path/f )
  53     vocab-name root-cache get [
  54         dup ".private" tail? [ drop f ] [
  55             ".factor" append-vocab-dir find-root-for
  56         ] if
  57     ] cache ;
  58
  59 : vocab-append-path ( vocab path -- newpath )
  60     swap find-vocab-root dup [ prepend-path ] [ 2drop f ] if ;
  61
  62 : vocab-source-path ( vocab -- path/f )
  63     dup ".factor" append-vocab-dir vocab-append-path ;
  64
  65 : vocab-docs-path ( vocab -- path/f )
  66     dup "-docs.factor" append-vocab-dir vocab-append-path ;
  67
  68 SYMBOL: load-help?
  69
  70 ! Defined by vocabs.metadata
  71 SYMBOL: check-vocab-hook
  72
  73 check-vocab-hook [ [ drop ] ] initialize
  74
  75 <PRIVATE
  76
  77 SYMBOL: require-when-vocabs
  78 require-when-vocabs [ HS{ } clone ] initialize
  79
  80 SYMBOL: require-when-table
  81 require-when-table [ V{ } clone ] initialize
  82
  83 : load-conditional-requires ( vocab -- )
  84     vocab-name require-when-vocabs get in? [
  85         require-when-table get [
  86             [ [ lookup-vocab dup [ source-loaded?>> +done+ = ] when ] all? ] dip
  87             [ require ] curry when
  88         ] assoc-each
  89     ] when ;
  90
  91 : load-source ( vocab -- )
  92     dup check-vocab-hook get call( vocab -- )
  93     [
  94         +parsing+ >>source-loaded?
  95         dup vocab-source-path [ parse-file ] [ [ ] ] if*
  96         [ +parsing+ >>source-loaded? ] dip
  97         [ % ] [ call( -- ) ] if-bootstrapping
  98         +done+ >>source-loaded?
  99         load-conditional-requires
 100     ] [ ] [ f >>source-loaded? ] cleanup ;
 101
 102 : load-docs ( vocab -- )
 103     load-help? get [
 104         [
 105             +parsing+ >>docs-loaded?
 106             dup vocab-docs-path [ ?run-file ] when*
 107             +done+ >>docs-loaded?
 108         ] [ ] [ f >>docs-loaded? ] cleanup
 109     ] when drop ;
 110
 111 PRIVATE>
 112
 113 : require-when ( if then -- )
 114     over [ lookup-vocab ] all? [
 115         require drop
 116     ] [
 117         [ drop [ require-when-vocabs get adjoin ] each ]
 118         [ 2array require-when-table get push ] 2bi
 119     ] if ;
 120
 121 : reload ( name -- )
 122     dup lookup-vocab
 123     [ [ load-source ] [ load-docs ] bi ]
 124     [ require ]
 125     ?if ;
 126
 127 : run ( vocab -- )
 128     dup load-vocab vocab-main [
 129         execute( -- )
 130     ] [
 131         "The " write vocab-name write
 132         " vocabulary does not define an entry point." print
 133         "To define one, refer to \\ MAIN: help" print
 134     ] ?if ;
 135
 136 SYMBOL: blacklist
 137
 138 <PRIVATE
 139
 140 : add-to-blacklist ( error vocab -- )
 141     vocab-name blacklist get dup [ set-at ] [ 3drop ] if ;
 142
 143 GENERIC: (require) ( name -- )
 144
 145 M: vocab (require)
 146     [
 147         dup source-loaded?>> +parsing+ eq? [ drop ] [
 148             dup source-loaded?>> [ dup load-source ] unless
 149             dup docs-loaded?>> [ dup load-docs ] unless
 150             drop
 151         ] if
 152     ] [ [ swap add-to-blacklist ] keep rethrow ] recover ;
 153
 154 M: vocab-link (require)
 155     vocab-name (require) ;
 156
 157 M: string (require) create-vocab (require) ;
 158
 159 PRIVATE>
 160
 161 [
 162     dup vocab-name blacklist get at*
 163     [ rethrow ]
 164     [
 165         drop dup find-vocab-root
 166         [ (require) ]
 167         [ dup lookup-vocab [ drop ] [ no-vocab ] if ]
 168         if
 169     ] if
 170 ] require-hook set-global
 171
 172 M: vocab-spec where vocab-source-path dup [ 1 2array ] when ;
 173
 174 ! put here to avoid circularity between vocabs.loader and source-files.errors
 175 { "source-files.errors" "debugger" } "source-files.errors.debugger" require-when