core/vocabs/loader/loader.factor

   1 ! Copyright (C) 2007, 2010 Eduardo Cavazos, Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: namespaces make sequences io io.files io.pathnames kernel
   4 assocs words vocabs definitions parser continuations hashtables
   5 sorting source-files arrays combinators strings system
   6 math.parser splitting init accessors sets ;
   7 IN: vocabs.loader
   8
   9 SYMBOL: vocab-roots
  10
  11 SYMBOL: add-vocab-root-hook
  12
  13 [
  14     V{
  15         "resource:core"
  16         "resource:basis"
  17         "resource:extra"
  18         "resource:work"
  19     } clone vocab-roots set-global
  20
  21     [ drop ] add-vocab-root-hook set-global
  22 ] "vocabs.loader" add-startup-hook
  23
  24 : add-vocab-root ( root -- )
  25     trim-tail-separators
  26     [ vocab-roots get adjoin ]
  27     [ add-vocab-root-hook get-global call( root -- ) ] bi ;
  28
  29 SYMBOL: root-cache
  30
  31 root-cache [ H{ } clone ] initialize
  32
  33 ERROR: not-found-in-roots path ;
  34
  35 <PRIVATE
  36
  37 : find-root-for ( path -- path/f )
  38     vocab-roots get [ prepend-path exists? ] with find nip ;
  39
  40 M: string vocab-path ( string -- path/f )
  41     dup find-root-for [ prepend-path ] [ not-found-in-roots ] if* ;
  42
  43 PRIVATE>
  44
  45 : vocab-dir ( vocab -- dir )
  46     vocab-name { { CHAR: . CHAR: / } } substitute ;
  47
  48 : vocab-dir+ ( vocab str/f -- path )
  49     [ vocab-name "." split ] dip
  50     [ [ dup last ] dip append suffix ] when*
  51     "/" join ;
  52
  53 : find-vocab-root ( vocab -- path/f )
  54     vocab-name dup root-cache get at
  55     [ ] [ ".factor" vocab-dir+ find-root-for ] ?if ;
  56
  57 : vocab-append-path ( vocab path -- newpath )
  58     swap find-vocab-root dup [ prepend-path ] [ 2drop f ] if ;
  59
  60 : vocab-source-path ( vocab -- path/f )
  61     dup ".factor" vocab-dir+ vocab-append-path ;
  62
  63 : vocab-docs-path ( vocab -- path/f )
  64     dup "-docs.factor" vocab-dir+ vocab-append-path ;
  65
  66 SYMBOL: load-help?
  67
  68 ! Defined by vocabs.metadata
  69 SYMBOL: check-vocab-hook
  70
  71 check-vocab-hook [ [ drop ] ] initialize
  72
  73 DEFER: require
  74
  75 <PRIVATE
  76
  77 SYMBOL: require-when-vocabs
  78 require-when-vocabs [ HS{ } clone ] initialize
  79
  80 SYMBOL: require-when-table
  81 require-when-table [ V{ } clone ] initialize
  82
  83 : load-conditional-requires ( vocab -- )
  84     vocab-name require-when-vocabs get in? [
  85         require-when-table get [
  86             [ [ vocab dup [ source-loaded?>> +done+ = ] when ] all? ] dip
  87             [ require ] curry when
  88         ] assoc-each
  89     ] when ;
  90
  91 : load-source ( vocab -- )
  92     dup check-vocab-hook get call( vocab -- )
  93     [
  94         +parsing+ >>source-loaded?
  95         dup vocab-source-path [ parse-file ] [ [ ] ] if*
  96         [ +parsing+ >>source-loaded? ] dip
  97         [ % ] [ call( -- ) ] if-bootstrapping
  98         +done+ >>source-loaded?
  99         load-conditional-requires
 100     ] [ ] [ f >>source-loaded? ] cleanup ;
 101
 102 : load-docs ( vocab -- )
 103     load-help? get [
 104         [
 105             +parsing+ >>docs-loaded?
 106             [ vocab-docs-path [ ?run-file ] when* ] keep
 107             +done+ >>docs-loaded?
 108         ] [ ] [ f >>docs-loaded? ] cleanup
 109     ] when drop ;
 110
 111 PRIVATE>
 112
 113 : require ( vocab -- )
 114     load-vocab drop ;
 115
 116 : require-when ( if then -- )
 117     over [ vocab ] all? [
 118         require drop
 119     ] [
 120         [ drop [ require-when-vocabs get adjoin ] each ]
 121         [ 2array require-when-table get push ] 2bi
 122     ] if ;
 123
 124 : reload ( name -- )
 125     dup vocab
 126     [ [ load-source ] [ load-docs ] bi ]
 127     [ require ]
 128     ?if ;
 129
 130 : run ( vocab -- )
 131     dup load-vocab vocab-main [
 132         execute( -- )
 133     ] [
 134         "The " write vocab-name write
 135         " vocabulary does not define an entry point." print
 136         "To define one, refer to \\ MAIN: help" print
 137     ] ?if ;
 138
 139 SYMBOL: blacklist
 140
 141 <PRIVATE
 142
 143 : add-to-blacklist ( error vocab -- )
 144     vocab-name blacklist get dup [ set-at ] [ 3drop ] if ;
 145
 146 GENERIC: (load-vocab) ( name -- vocab )
 147
 148 M: vocab (load-vocab)
 149     [
 150         dup source-loaded?>> +parsing+ eq? [
 151             dup source-loaded?>> [ dup load-source ] unless
 152             dup docs-loaded?>> [ dup load-docs ] unless
 153         ] unless
 154     ] [ [ swap add-to-blacklist ] keep rethrow ] recover ;
 155
 156 M: vocab-link (load-vocab)
 157     vocab-name (load-vocab) ;
 158
 159 M: string (load-vocab) create-vocab (load-vocab) ;
 160
 161 PRIVATE>
 162
 163 [
 164     dup vocab-name blacklist get at* [ rethrow ] [
 165         drop dup find-vocab-root
 166         [ (load-vocab) ] [ dup vocab [ ] [ no-vocab ] ?if ] if
 167     ] if
 168 ] load-vocab-hook set-global
 169
 170 M: vocab-spec where vocab-source-path dup [ 1 2array ] when ;