core/vocabs/loader/loader.factor

   1 ! Copyright (C) 2007, 2010 Eduardo Cavazos, Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors arrays assocs continuations definitions init
   4 io io.files io.pathnames kernel make namespaces parser
   5 sequences sets splitting strings vocabs words ;
   6 IN: vocabs.loader
   7
   8 SYMBOL: vocab-roots
   9
  10 SYMBOL: add-vocab-root-hook
  11
  12 CONSTANT: default-vocab-roots {
  13     "resource:core"
  14     "resource:basis"
  15     "resource:extra"
  16     "resource:work"
  17 }
  18
  19 [
  20     default-vocab-roots V{ } like vocab-roots set-global
  21
  22     [ drop ] add-vocab-root-hook set-global
  23 ] "vocabs.loader" add-startup-hook
  24
  25 : add-vocab-root ( root -- )
  26     trim-tail-separators dup vocab-roots get ?adjoin
  27     [ add-vocab-root-hook get-global call( root -- ) ] [ drop ] if ;
  28
  29 SYMBOL: root-cache
  30 root-cache [ H{ } clone ] initialize
  31
  32 ERROR: not-found-in-roots path ;
  33
  34 <PRIVATE
  35
  36 : find-root-for ( path -- path/f )
  37     vocab-roots get [ prepend-path exists? ] with find nip ;
  38
  39 M: string vocab-path
  40     dup find-root-for [ prepend-path ] [ not-found-in-roots ] if* ;
  41
  42 PRIVATE>
  43
  44 : vocab-dir ( vocab -- dir )
  45     vocab-name H{ { CHAR: . CHAR: / } } substitute ;
  46
  47 : append-vocab-dir ( vocab str/f -- path )
  48     [ vocab-name "." split ] dip
  49     [ [ dup last ] dip append suffix ] when*
  50     "/" join ;
  51
  52 : find-vocab-root ( vocab -- path/f )
  53     vocab-name root-cache get [
  54         dup ".private" tail? [ drop f ] [
  55             ".factor" append-vocab-dir find-root-for
  56         ] if
  57     ] cache ;
  58
  59 : vocab-exists? ( name -- ? )
  60     dup lookup-vocab [ ] [ find-vocab-root ] ?if ;
  61
  62 : vocab-append-path ( vocab path -- newpath )
  63     swap find-vocab-root [ prepend-path ] [ drop f ] if* ;
  64
  65 : vocab-source-path ( vocab -- path/f )
  66     dup ".factor" append-vocab-dir vocab-append-path ;
  67
  68 : vocab-docs-path ( vocab -- path/f )
  69     dup "-docs.factor" append-vocab-dir vocab-append-path ;
  70
  71 SYMBOL: load-help?
  72
  73 ! Defined by vocabs.metadata
  74 SYMBOL: check-vocab-hook
  75 check-vocab-hook [ [ drop ] ] initialize
  76
  77 <PRIVATE
  78
  79 SYMBOL: require-when-vocabs
  80 require-when-vocabs [ HS{ } clone ] initialize
  81
  82 SYMBOL: require-when-table
  83 require-when-table [ V{ } clone ] initialize
  84
  85 : load-conditional-requires ( vocab -- )
  86     vocab-name require-when-vocabs get in? [
  87         require-when-table get [
  88             [ [ lookup-vocab dup [ source-loaded?>> +done+ = ] when ] all? ] dip
  89             [ require ] curry when
  90         ] assoc-each
  91     ] when ;
  92
  93 : load-source ( vocab -- )
  94     dup check-vocab-hook get call( vocab -- )
  95     [
  96         +parsing+ >>source-loaded?
  97         dup vocab-source-path [ parse-file ] [ [ ] ] if*
  98         [ +parsing+ >>source-loaded? ] dip
  99         [ % ] [ call( -- ) ] if-bootstrapping
 100         +done+ >>source-loaded?
 101         load-conditional-requires
 102     ] [ ] [ f >>source-loaded? ] cleanup ;
 103
 104 : load-docs ( vocab -- )
 105     load-help? get [
 106         [
 107             +parsing+ >>docs-loaded?
 108             dup vocab-docs-path [ ?run-file ] when*
 109             +done+ >>docs-loaded?
 110         ] [ ] [ f >>docs-loaded? ] cleanup
 111     ] when drop ;
 112
 113 PRIVATE>
 114
 115 : require-when ( if then -- )
 116     over [ lookup-vocab ] all? [
 117         require drop
 118     ] [
 119         [ drop require-when-vocabs get adjoin-all ]
 120         [ 2array require-when-table get push ] 2bi
 121     ] if ;
 122
 123 : reload ( name -- )
 124     dup lookup-vocab
 125     [ [ load-source ] [ load-docs ] bi ]
 126     [ require ]
 127     ?if ;
 128
 129 : run ( vocab -- )
 130     dup load-vocab vocab-main [
 131         execute( -- )
 132     ] [
 133         "The " write vocab-name write
 134         " vocabulary does not define an entry point." print
 135         "To define one, refer to \\ MAIN: help" print
 136     ] ?if ;
 137
 138 SYMBOL: blacklist
 139
 140 : require-all ( vocabs -- )
 141     V{ } clone blacklist [ [ require ] each ] with-variable ;
 142
 143 <PRIVATE
 144
 145 : add-to-blacklist ( error vocab -- )
 146     vocab-name blacklist get [ set-at ] [ 2drop ] if* ;
 147
 148 GENERIC: (require) ( name -- )
 149
 150 M: vocab (require)
 151     [
 152         dup source-loaded?>> +parsing+ eq? [ drop ] [
 153             dup source-loaded?>> [ dup load-source ] unless
 154             dup docs-loaded?>> [ dup load-docs ] unless
 155             drop
 156         ] if
 157     ] [ [ swap add-to-blacklist ] keep rethrow ] recover ;
 158
 159 M: vocab-link (require)
 160     vocab-name (require) ;
 161
 162 M: string (require)
 163     dup check-vocab-hook get call( vocab -- )
 164     create-vocab (require) ;
 165
 166 PRIVATE>
 167
 168 [
 169     dup vocab-name blacklist get at*
 170     [ rethrow ]
 171     [
 172         drop dup find-vocab-root
 173         [ (require) ]
 174         [ dup lookup-vocab [ drop ] [ no-vocab ] if ]
 175         if
 176     ] if
 177 ] require-hook set-global
 178
 179 M: vocab-spec where vocab-source-path dup [ 1 2array ] when ;
 180
 181 ! put here to avoid circularity between vocabs.loader and source-files.errors
 182 { "source-files.errors" "debugger" } "source-files.errors.debugger" require-when