core/vocabs/loader/loader.factor

   1 ! Copyright (C) 2007, 2010 Eduardo Cavazos, Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: namespaces make sequences io io.files io.pathnames kernel
   4 assocs words vocabs definitions parser continuations hashtables
   5 sorting source-files arrays combinators strings system
   6 math.parser splitting init accessors sets ;
   7 IN: vocabs.loader
   8
   9 SYMBOL: vocab-roots
  10
  11 SYMBOL: add-vocab-root-hook
  12
  13 [
  14     V{
  15         "resource:core"
  16         "resource:basis"
  17         "resource:extra"
  18         "resource:work"
  19     } clone vocab-roots set-global
  20
  21     [ drop ] add-vocab-root-hook set-global
  22 ] "vocabs.loader" add-startup-hook
  23
  24 : add-vocab-root ( root -- )
  25     trim-tail-separators
  26     [ vocab-roots get adjoin ]
  27     [ add-vocab-root-hook get-global call( root -- ) ] bi ;
  28
  29 SYMBOL: root-cache
  30
  31 root-cache [ H{ } clone ] initialize
  32
  33 ERROR: not-found-in-roots path ;
  34
  35 <PRIVATE
  36
  37 : find-root-for ( path -- path/f )
  38     vocab-roots get [ prepend-path exists? ] with find nip ;
  39
  40 M: string vocab-path ( string -- path/f )
  41     dup find-root-for [ prepend-path ] [ not-found-in-roots ] if* ;
  42
  43 PRIVATE>
  44
  45 : vocab-dir ( vocab -- dir )
  46     vocab-name { { CHAR: . CHAR: / } } substitute ;
  47
  48 : append-vocab-dir ( vocab str/f -- path )
  49     [ vocab-name "." split ] dip
  50     [ [ dup last ] dip append suffix ] when*
  51     "/" join ;
  52
  53 : find-vocab-root ( vocab -- path/f )
  54     vocab-name root-cache get
  55     [ ".factor" append-vocab-dir find-root-for ] cache ;
  56
  57 : vocab-append-path ( vocab path -- newpath )
  58     swap find-vocab-root dup [ prepend-path ] [ 2drop f ] if ;
  59
  60 : vocab-source-path ( vocab -- path/f )
  61     dup ".factor" append-vocab-dir vocab-append-path ;
  62
  63 : vocab-docs-path ( vocab -- path/f )
  64     dup "-docs.factor" append-vocab-dir vocab-append-path ;
  65
  66 SYMBOL: load-help?
  67
  68 ! Defined by vocabs.metadata
  69 SYMBOL: check-vocab-hook
  70
  71 check-vocab-hook [ [ drop ] ] initialize
  72
  73 <PRIVATE
  74
  75 SYMBOL: require-when-vocabs
  76 require-when-vocabs [ HS{ } clone ] initialize
  77
  78 SYMBOL: require-when-table
  79 require-when-table [ V{ } clone ] initialize
  80
  81 : load-conditional-requires ( vocab -- )
  82     vocab-name require-when-vocabs get in? [
  83         require-when-table get [
  84             [ [ lookup-vocab dup [ source-loaded?>> +done+ = ] when ] all? ] dip
  85             [ require ] curry when
  86         ] assoc-each
  87     ] when ;
  88
  89 : load-source ( vocab -- )
  90     dup check-vocab-hook get call( vocab -- )
  91     [
  92         +parsing+ >>source-loaded?
  93         dup vocab-source-path [ parse-file ] [ [ ] ] if*
  94         [ +parsing+ >>source-loaded? ] dip
  95         [ % ] [ call( -- ) ] if-bootstrapping
  96         +done+ >>source-loaded?
  97         load-conditional-requires
  98     ] [ ] [ f >>source-loaded? ] cleanup ;
  99
 100 : load-docs ( vocab -- )
 101     load-help? get [
 102         [
 103             +parsing+ >>docs-loaded?
 104             [ vocab-docs-path [ ?run-file ] when* ] keep
 105             +done+ >>docs-loaded?
 106         ] [ ] [ f >>docs-loaded? ] cleanup
 107     ] when drop ;
 108
 109 PRIVATE>
 110
 111 : require-when ( if then -- )
 112     over [ lookup-vocab ] all? [
 113         require drop
 114     ] [
 115         [ drop [ require-when-vocabs get adjoin ] each ]
 116         [ 2array require-when-table get push ] 2bi
 117     ] if ;
 118
 119 : reload ( name -- )
 120     dup lookup-vocab
 121     [ [ load-source ] [ load-docs ] bi ]
 122     [ require ]
 123     ?if ;
 124
 125 : run ( vocab -- )
 126     dup load-vocab vocab-main [
 127         execute( -- )
 128     ] [
 129         "The " write vocab-name write
 130         " vocabulary does not define an entry point." print
 131         "To define one, refer to \\ MAIN: help" print
 132     ] ?if ;
 133
 134 SYMBOL: blacklist
 135
 136 <PRIVATE
 137
 138 : add-to-blacklist ( error vocab -- )
 139     vocab-name blacklist get dup [ set-at ] [ 3drop ] if ;
 140
 141 GENERIC: (require) ( name -- )
 142
 143 M: vocab (require)
 144     [
 145         dup source-loaded?>> +parsing+ eq? [ drop ] [
 146             dup source-loaded?>> [ dup load-source ] unless
 147             dup docs-loaded?>> [ dup load-docs ] unless
 148             drop
 149         ] if
 150     ] [ [ swap add-to-blacklist ] keep rethrow ] recover ;
 151
 152 M: vocab-link (require)
 153     vocab-name (require) ;
 154
 155 M: string (require) create-vocab (require) ;
 156
 157 PRIVATE>
 158
 159 [
 160     dup vocab-name blacklist get at*
 161     [ rethrow ]
 162     [
 163         drop dup find-vocab-root
 164         [ (require) ]
 165         [ dup lookup-vocab [ drop ] [ no-vocab ] if ]
 166         if
 167     ] if
 168 ] require-hook set-global
 169
 170 M: vocab-spec where vocab-source-path dup [ 1 2array ] when ;