core/vocabs/parser/parser.factor

   1 ! Copyright (C) 2007, 2010 Daniel Ehrenberg, Bruno Deferrari,
   2 ! Slava Pestov.
   3 ! See http://factorcode.org/license.txt for BSD license.
   4 USING: assocs hashtables kernel namespaces sequences
   5 sets strings vocabs sorting accessors arrays compiler.units
   6 combinators vectors splitting continuations math words
   7 parser.notes ;
   8 IN: vocabs.parser
   9
  10 ERROR: no-word-error name ;
  11
  12 : word-restarts ( possibilities -- restarts )
  13     natural-sort
  14     [ [ vocabulary>> "Use the " " vocabulary" surround ] keep ] { } map>assoc ;
  15
  16 : word-restarts-with-defer ( name possibilities -- restarts )
  17     word-restarts
  18     swap "Defer word in current vocabulary" swap 2array
  19     suffix ;
  20
  21 : <no-word-error> ( name possibilities -- error restarts )
  22     [ drop \ no-word-error boa ] [ word-restarts-with-defer ] 2bi ;
  23
  24 TUPLE: manifest
  25 current-vocab
  26 { search-vocab-names hashtable }
  27 { search-vocabs vector }
  28 { qualified-vocabs vector }
  29 { auto-used vector } ;
  30
  31 : <manifest> ( -- manifest )
  32     manifest new
  33         H{ } clone >>search-vocab-names
  34         V{ } clone >>search-vocabs
  35         V{ } clone >>qualified-vocabs
  36         V{ } clone >>auto-used ;
  37
  38 M: manifest clone
  39     call-next-method
  40         [ clone ] change-search-vocab-names
  41         [ clone ] change-search-vocabs
  42         [ clone ] change-qualified-vocabs
  43         [ clone ] change-auto-used ;
  44
  45 TUPLE: extra-words words ;
  46
  47 M: extra-words equal?
  48     over extra-words? [ [ words>> ] bi@ eq? ] [ 2drop f ] if ;
  49
  50 C: <extra-words> extra-words
  51
  52 : clear-manifest ( -- )
  53     manifest get
  54     [ search-vocab-names>> clear-assoc ]
  55     [ search-vocabs>> delete-all ]
  56     [ qualified-vocabs>> delete-all ]
  57     tri ;
  58
  59 ERROR: no-word-in-vocab word vocab ;
  60
  61 <PRIVATE
  62
  63 : (add-qualified) ( qualified -- )
  64     manifest get qualified-vocabs>> push ;
  65
  66 : (from) ( vocab words -- vocab words words' vocab )
  67     2dup swap load-vocab ;
  68
  69 : extract-words ( seq vocab -- assoc )
  70     [ words>> extract-keys dup ] [ name>> ] bi
  71     [ swap [ 2drop ] [ no-word-in-vocab ] if ] curry assoc-each ;
  72
  73 : excluding-words ( seq vocab -- assoc )
  74     [ nip words>> ] [ extract-words ] 2bi assoc-diff ;
  75
  76 : qualified-words ( prefix vocab -- assoc )
  77     words>> swap [ swap [ swap ":" glue ] dip ] curry assoc-map ;
  78
  79 : (lookup) ( name assoc -- word/f )
  80     at dup forward-reference? [ drop f ] when ;
  81
  82 : (use-words) ( assoc -- extra-words seq )
  83     <extra-words> manifest get qualified-vocabs>> ;
  84
  85 PRIVATE>
  86
  87 : set-current-vocab ( name -- )
  88     create-vocab
  89     [ manifest get (>>current-vocab) ]
  90     [ words>> <extra-words> (add-qualified) ] bi ;
  91
  92 : with-current-vocab ( name quot -- )
  93     manifest get clone manifest [
  94         [ set-current-vocab ] dip call
  95     ] with-variable ; inline
  96
  97 TUPLE: no-current-vocab ;
  98
  99 : no-current-vocab ( -- vocab )
 100     \ no-current-vocab boa
 101     { { "Define words in scratchpad vocabulary" "scratchpad" } }
 102     throw-restarts dup set-current-vocab ;
 103
 104 : current-vocab ( -- vocab )
 105     manifest get current-vocab>> [ no-current-vocab ] unless* ;
 106
 107 : begin-private ( -- )
 108     current-vocab name>> ".private" ?tail
 109     [ drop ] [ ".private" append set-current-vocab ] if ;
 110
 111 : end-private ( -- )
 112     current-vocab name>> ".private" ?tail
 113     [ set-current-vocab ] [ drop ] if ;
 114
 115 : using-vocab? ( vocab -- ? )
 116     vocab-name manifest get search-vocab-names>> key? ;
 117
 118 : use-vocab ( vocab -- )
 119     dup using-vocab?
 120     [ vocab-name "Already using ``" "'' vocabulary" surround note. ] [
 121         manifest get
 122         [ [ load-vocab ] dip search-vocabs>> push ]
 123         [ [ vocab-name ] dip search-vocab-names>> conjoin ]
 124         2bi
 125     ] if ;
 126
 127 : auto-use-vocab ( vocab -- )
 128     [ use-vocab ] [ manifest get auto-used>> push ] bi ;
 129
 130 : auto-used? ( -- ? ) manifest get auto-used>> length 0 > ;
 131
 132 : unuse-vocab ( vocab -- )
 133     dup using-vocab? [
 134         manifest get
 135         [ [ load-vocab ] dip search-vocabs>> remove-eq! drop ]
 136         [ [ vocab-name ] dip search-vocab-names>> delete-at ]
 137         2bi
 138     ] [ drop ] if ;
 139
 140 TUPLE: qualified vocab prefix words ;
 141
 142 : <qualified> ( vocab prefix -- qualified )
 143     (from) qualified-words qualified boa ;
 144
 145 : add-qualified ( vocab prefix -- )
 146     <qualified> (add-qualified) ;
 147
 148 TUPLE: from vocab names words ;
 149
 150 : <from> ( vocab words -- from )
 151     (from) extract-words from boa ;
 152
 153 : add-words-from ( vocab words -- )
 154     <from> (add-qualified) ;
 155
 156 TUPLE: exclude vocab names words ;
 157
 158 : <exclude> ( vocab words -- from )
 159     (from) excluding-words exclude boa ;
 160
 161 : add-words-excluding ( vocab words -- )
 162     <exclude> (add-qualified) ;
 163
 164 TUPLE: rename word vocab words ;
 165
 166 : <rename> ( word vocab new-name -- rename )
 167     [ 2dup load-vocab words>> dupd at [ ] [ swap no-word-in-vocab ] ?if ] dip
 168     associate rename boa ;
 169
 170 : add-renamed-word ( word vocab new-name -- )
 171     <rename> (add-qualified) ;
 172
 173 : use-words ( assoc -- ) (use-words) push ;
 174
 175 : unuse-words ( assoc -- ) (use-words) remove! drop ;
 176
 177 TUPLE: ambiguous-use-error words ;
 178
 179 : <ambiguous-use-error> ( words -- error restarts )
 180     [ \ ambiguous-use-error boa ] [ word-restarts ] bi ;
 181
 182 <PRIVATE
 183
 184 : (vocab-search) ( name assocs -- words n )
 185     [ words>> (lookup) ] with map
 186     sift dup length ;
 187
 188 : vocab-search ( name manifest -- word/f )
 189     search-vocabs>>
 190     (vocab-search) {
 191         { 0 [ drop f ] }
 192         { 1 [ first ] }
 193         [
 194             drop <ambiguous-use-error> throw-restarts
 195             dup [ vocabulary>> ] [ name>> 1array ] bi add-words-from
 196         ]
 197     } case ;
 198
 199 : qualified-search ( name manifest -- word/f )
 200     qualified-vocabs>>
 201     (vocab-search) 0 = [ drop f ] [ last ] if ;
 202
 203 PRIVATE>
 204
 205 : search-manifest ( name manifest -- word/f )
 206     2dup qualified-search dup [ 2nip ] [ drop vocab-search ] if ;
 207
 208 : search ( name -- word/f )
 209     manifest get search-manifest ;
 210
 211 <PRIVATE
 212
 213 GENERIC: update ( search-path-elt -- valid? )
 214
 215 : trim-forgotten ( qualified-vocab -- valid? )
 216     [ [ nip "forgotten" word-prop not ] assoc-filter ] change-words
 217     words>> assoc-empty? not ;
 218
 219 M: from update trim-forgotten ;
 220 M: rename update trim-forgotten ;
 221 M: extra-words update trim-forgotten ;
 222 M: exclude update trim-forgotten ;
 223
 224 M: qualified update
 225     dup vocab>> vocab [
 226         dup [ prefix>> ] [ vocab>> load-vocab ] bi qualified-words
 227         >>words
 228     ] [ drop f ] if ;
 229
 230 M: vocab update dup name>> vocab eq? ;
 231
 232 : update-manifest ( manifest -- )
 233     [ dup [ name>> vocab ] when ] change-current-vocab
 234     [ [ drop vocab ] assoc-filter ] change-search-vocab-names
 235     dup search-vocab-names>> keys [ vocab ] V{ } map-as >>search-vocabs
 236     qualified-vocabs>> [ update ] filter! drop ;
 237
 238 M: manifest definitions-changed ( assoc manifest -- )
 239     nip update-manifest ;
 240
 241 PRIVATE>
 242
 243 : with-manifest ( quot -- )
 244     <manifest> manifest [
 245         [ manifest get add-definition-observer call ]
 246         [ manifest get remove-definition-observer ]
 247         [ ]
 248         cleanup
 249     ] with-variable ; inline