core/vocabs/vocabs.factor

   1 ! Copyright (C) 2007, 2009 Eduardo Cavazos, Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors assocs definitions kernel namespaces sequences
   4 sorting splitting strings ;
   5 IN: vocabs
   6
   7 SYMBOL: dictionary
   8
   9 TUPLE: vocab < identity-tuple
  10 name words
  11 main help
  12 source-loaded? docs-loaded? ;
  13
  14 ! sources-loaded? slot is one of these three
  15 SYMBOL: +parsing+
  16 SYMBOL: +running+
  17 SYMBOL: +done+
  18
  19 : <vocab> ( name -- vocab )
  20     \ vocab new
  21         swap >>name
  22         H{ } clone >>words ;
  23
  24 ERROR: bad-vocab-name name ;
  25
  26 : check-vocab-name ( name -- name )
  27     dup string? [ bad-vocab-name ] unless
  28     dup [ ":/\\ " member? ] any? [ bad-vocab-name ] when ;
  29
  30 TUPLE: vocab-link name ;
  31
  32 C: <vocab-link> vocab-link
  33
  34 UNION: vocab-spec vocab vocab-link ;
  35
  36 GENERIC: vocab-name ( vocab-spec -- name )
  37
  38 M: vocab vocab-name name>> ;
  39
  40 M: vocab-link vocab-name name>> ;
  41
  42 M: object vocab-name check-vocab-name ;
  43
  44 : vocab-name* ( vocab-spec -- name )
  45     vocab-name ".private" ?tail drop ;
  46
  47 : private-vocab? ( vocab -- ? )
  48     vocab-name ".private" tail? ;
  49
  50 GENERIC: lookup-vocab ( vocab-spec -- vocab )
  51
  52 M: vocab lookup-vocab ;
  53
  54 M: object lookup-vocab ( name -- vocab ) vocab-name dictionary get at ;
  55
  56 GENERIC: vocab-words ( vocab-spec -- words )
  57
  58 M: vocab vocab-words words>> ;
  59
  60 M: object vocab-words lookup-vocab vocab-words ;
  61
  62 M: f vocab-words ;
  63
  64 GENERIC: vocab-help ( vocab-spec -- help )
  65
  66 M: vocab vocab-help help>> ;
  67
  68 M: object vocab-help lookup-vocab vocab-help ;
  69
  70 M: f vocab-help ;
  71
  72 GENERIC: vocab-main ( vocab-spec -- main )
  73
  74 M: vocab vocab-main main>> ;
  75
  76 M: object vocab-main lookup-vocab vocab-main ;
  77
  78 M: f vocab-main ;
  79
  80 SYMBOL: vocab-observers
  81
  82 GENERIC: vocab-changed ( vocab obj -- )
  83
  84 : add-vocab-observer ( obj -- )
  85     vocab-observers get push ;
  86
  87 : remove-vocab-observer ( obj -- )
  88     vocab-observers get remove-eq! drop ;
  89
  90 : notify-vocab-observers ( vocab -- )
  91     vocab-observers get [ vocab-changed ] with each ;
  92
  93 : create-vocab ( name -- vocab )
  94     check-vocab-name dictionary get
  95     [ <vocab> dup notify-vocab-observers ] cache ;
  96
  97 ERROR: no-vocab name ;
  98
  99 : vocabs ( -- seq )
 100     dictionary get keys natural-sort ;
 101
 102 : words ( vocab -- seq )
 103     vocab-words values ;
 104
 105 : all-words ( -- seq )
 106     dictionary get values [ words ] map concat ;
 107
 108 : words-named ( str -- seq )
 109     dictionary get values
 110     [ vocab-words at ] with map
 111     sift ;
 112
 113 : child-vocab? ( prefix name -- ? )
 114     2dup = pick empty? or
 115     [ 2drop t ] [ swap CHAR: . suffix head? ] if ;
 116
 117 : child-vocabs ( vocab -- seq )
 118     vocab-name vocabs [ child-vocab? ] with filter ;
 119
 120 GENERIC: >vocab-link ( name -- vocab )
 121
 122 M: vocab-spec >vocab-link ;
 123
 124 M: object >vocab-link dup lookup-vocab [ ] [ <vocab-link> ] ?if ;
 125
 126 : forget-vocab ( vocab -- )
 127     [ words forget-all ]
 128     [ vocab-name dictionary get delete-at ]
 129     [ notify-vocab-observers ] tri ;
 130
 131 M: vocab-spec forget* forget-vocab ;
 132
 133 SYMBOL: require-hook
 134
 135 PREDICATE: runnable-vocab < vocab
 136     vocab-main >boolean ;
 137
 138 INSTANCE: vocab-spec definition-mixin
 139
 140 : call-require-hook ( name -- )
 141     require-hook get call( name -- ) ;
 142
 143 GENERIC: require ( object -- )
 144
 145 M: vocab require name>> require ;
 146 M: vocab-link require name>> require ;
 147
 148 ! When calling "foo.private" require, load "foo" instead, but only when
 149 ! "foo.private" does not exist. The reason for this is that stage1 bootstrap
 150 ! starts out with some .private vocabs that contain primitives, and
 151 ! loading the public vocabs would cause circularity issues.
 152 M: string require ( vocab -- )
 153     dup ".private" ?tail [
 154         over lookup-vocab
 155         [ 2drop ]
 156         [ nip call-require-hook ]
 157         if
 158     ] [
 159         nip call-require-hook
 160     ] if ;
 161
 162 : load-vocab ( name -- vocab )
 163     [ require ] [ lookup-vocab ] bi ;