core/words.factor

   1 ! Copyright (C) 2004, 2006 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 IN: help
   4 DEFER: remove-word-help
   5
   6 IN: words
   7 USING: arrays definitions errors generic graphs hashtables
   8 kernel kernel-internals math namespaces sequences strings
   9 vectors ;
  10
  11 ! Used by the compiler
  12 SYMBOL: changed-words
  13
  14 : word-changed? ( word -- ? )
  15     changed-words get [ hash-member? ] [ drop f ] if* ;
  16
  17 : changed-word ( word -- )
  18     dup changed-words get [ set-hash ] [ 2drop ] if* ;
  19
  20 : unchanged-word ( word -- )
  21     changed-words get [ remove-hash ] [ drop ] if* ;
  22
  23 M: word <=>
  24     [ dup word-name swap word-vocabulary 2array ] 2apply <=> ;
  25
  26 GENERIC: definer ( word -- definer )
  27
  28 PREDICATE: word undefined ( obj -- ? ) word-primitive 0 = ;
  29 M: undefined definer drop \ DEFER: ;
  30
  31 PREDICATE: word compound  ( obj -- ? ) word-primitive 1 = ;
  32 M: compound definer drop \ : ;
  33
  34 PREDICATE: word primitive ( obj -- ? ) word-primitive 2 > ;
  35 M: primitive definer drop \ PRIMITIVE: ;
  36
  37 PREDICATE: word symbol    ( obj -- ? ) word-primitive 2 = ;
  38 M: symbol definer drop \ SYMBOL: ;
  39
  40 : init-word ( word -- ) H{ } clone swap set-word-props ;
  41
  42 : word-prop ( word name -- value ) swap word-props hash ;
  43
  44 : remove-word-prop ( word name -- )
  45     swap word-props remove-hash ;
  46
  47 : set-word-prop ( word value name -- )
  48     over
  49     [ rot word-props set-hash ]
  50     [ nip remove-word-prop ] if ;
  51
  52 SYMBOL: vocabularies
  53
  54 : vocab ( name -- vocab ) vocabularies get hash ;
  55
  56 : lookup ( name vocab -- word ) vocab ?hash ;
  57
  58 : target-word ( word -- target )
  59     dup word-name swap word-vocabulary lookup ;
  60
  61 : interned? ( word -- ? ) dup target-word eq? ;
  62
  63 : uses ( word -- seq )
  64     word-def flatten
  65     [ word? ] subset
  66     [ global [ interned? ] bind ] subset
  67     prune ;
  68
  69 SYMBOL: crossref
  70
  71 : xref-word ( word -- )
  72     dup word-vocabulary [
  73         [ uses ] crossref get add-vertex
  74     ] [
  75         drop
  76     ] if ;
  77
  78 : usage ( word -- seq ) crossref get in-edges ;
  79
  80 : reset-props ( word seq -- ) [ remove-word-prop ] each-with ;
  81
  82 : custom-infer? ( word -- ? )
  83     dup "infer" word-prop swap "infer-vars" word-prop or ;
  84
  85 : unxref-word* ( word -- )
  86     {
  87         { [ dup compound? not ] [ drop ] }
  88         { [ dup custom-infer? ] [ drop ] }
  89         { [ t ] [
  90             dup changed-word
  91             {
  92                 "inferred-effect" "inferred-vars"
  93                 "base-case" "no-effect"
  94             } reset-props
  95         ] }
  96     } cond ;
  97
  98 : unxref-word ( word -- )
  99     dup [ usage ] closure [ unxref-word* ] each
 100     [ uses ] crossref get remove-vertex ;
 101
 102 : define ( word def primitive -- )
 103     pick changed-word
 104     pick unxref-word
 105     pick set-word-primitive
 106     over set-word-def
 107     dup update-xt
 108     xref-word ;
 109
 110 : define-symbol ( word -- )
 111     dup symbol? [ drop ] [ dup 2 define ] if ;
 112
 113 : intern-symbol ( word -- )
 114     dup undefined? [ define-symbol ] [ drop ] if ;
 115
 116 : define-compound ( word def -- ) 1 define ;
 117
 118 : reset-word ( word -- )
 119     {
 120         "parsing" "inline" "foldable"
 121         "predicating" "declared-effect"
 122     } reset-props ;
 123
 124 : reset-generic ( word -- )
 125     dup reset-word { "methods" "combination" } reset-props ;
 126
 127 : <word> ( name vocab -- word ) (word) dup init-word ;
 128
 129 : gensym ( -- word )
 130     "G:" \ gensym counter number>string append f <word> ;
 131
 132 : define-temp ( quot -- word )
 133     gensym [ swap define-compound ] keep ;
 134
 135 SYMBOL: bootstrapping?
 136
 137 : word ( -- word ) \ word get-global ;
 138
 139 : set-word ( word -- ) \ word set-global ;
 140
 141 : vocabs ( -- seq ) vocabularies get hash-keys natural-sort ;
 142
 143 : ensure-vocab ( name -- ) vocabularies get [ nest drop ] bind ;
 144
 145 : words ( vocab -- seq ) vocab dup [ hash-values ] when ;
 146
 147 : all-words ( -- seq )
 148     vocabularies get hash-values [ hash-values ] map concat ;
 149
 150 : xref-words ( -- )
 151     all-words [ uses ] crossref get build-graph ;
 152
 153 : create-vocab ( name -- vocab )
 154     vocabularies get [ nest ] bind ;
 155
 156 : reveal ( word -- )
 157     dup word-name over word-vocabulary create-vocab set-hash ;
 158
 159 TUPLE: check-create name vocab ;
 160 : check-create ( name vocab -- name vocab )
 161     dup string? [ <check-create> throw ] unless
 162     over string? [ <check-create> throw ] unless ;
 163
 164 : create ( name vocab -- word )
 165     check-create 2dup lookup dup
 166     [ 2nip ] [ drop <word> dup reveal ] if ;
 167
 168 : constructor-word ( name vocab -- word )
 169     >r "<" swap ">" 3append r> create ;
 170
 171 : forget-vocab ( vocab -- )
 172     words [ forget ] each ;
 173
 174 : bootstrap-word ( word -- target )
 175     bootstrapping? get [
 176         dup word-name swap word-vocabulary
 177         dup "syntax" = [ [ CHAR: ! add* ] 2apply ] when lookup
 178     ] when ;
 179
 180 : words-named ( str -- seq )
 181     all-words [ word-name = ] subset-with ;
 182
 183 ! Definition protocol
 184 M: word where "loc" word-prop ;
 185
 186 M: word subdefs drop f ;
 187
 188 : forget-word ( word -- )
 189     dup unxref-word
 190     dup remove-word-help
 191     dup unchanged-word
 192     crossref get [ dupd remove-hash ] when*
 193     dup word-name swap word-vocabulary vocab remove-hash ;
 194
 195 M: word forget forget-word ;