core/words/words.factor

   1 ! Copyright (C) 2004, 2008 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: arrays definitions graphs assocs kernel kernel.private
   4 slots.private math namespaces sequences strings vectors sbufs
   5 quotations assocs hashtables sorting words.private vocabs
   6 math.order sets ;
   7 IN: words
   8
   9 : word ( -- word ) \ word get-global ;
  10
  11 : set-word ( word -- ) \ word set-global ;
  12
  13 GENERIC: execute ( word -- )
  14
  15 M: word execute (execute) ;
  16
  17 M: word <=>
  18     [ dup word-name swap word-vocabulary 2array ] compare ;
  19
  20 M: word definer drop \ : \ ; ;
  21
  22 M: word definition word-def ;
  23
  24 ERROR: undefined ;
  25
  26 PREDICATE: deferred < word ( obj -- ? )
  27     word-def [ undefined ] = ;
  28 M: deferred definer drop \ DEFER: f ;
  29 M: deferred definition drop f ;
  30
  31 PREDICATE: symbol < word ( obj -- ? )
  32     dup <wrapper> 1array swap word-def sequence= ;
  33 M: symbol definer drop \ SYMBOL: f ;
  34 M: symbol definition drop f ;
  35
  36 PREDICATE: primitive < word ( obj -- ? )
  37     word-def [ do-primitive ] tail? ;
  38 M: primitive definer drop \ PRIMITIVE: f ;
  39 M: primitive definition drop f ;
  40
  41 : word-prop ( word name -- value ) swap word-props at ;
  42
  43 : remove-word-prop ( word name -- )
  44     swap word-props delete-at ;
  45
  46 : set-word-prop ( word value name -- )
  47     over
  48     [ pick word-props ?set-at swap set-word-props ]
  49     [ nip remove-word-prop ] if ;
  50
  51 : reset-props ( word seq -- ) [ remove-word-prop ] with each ;
  52
  53 : lookup ( name vocab -- word ) vocab-words at ;
  54
  55 : target-word ( word -- target )
  56     dup word-name swap word-vocabulary lookup ;
  57
  58 SYMBOL: bootstrapping?
  59
  60 : if-bootstrapping ( true false -- )
  61     bootstrapping? get -rot if ; inline
  62
  63 : bootstrap-word ( word -- target )
  64     [ target-word ] [ ] if-bootstrapping ;
  65
  66 GENERIC: crossref? ( word -- ? )
  67
  68 M: word crossref?
  69     dup "forgotten" word-prop [
  70         drop f
  71     ] [
  72         word-vocabulary >boolean
  73     ] if ;
  74
  75 GENERIC: compiled-crossref? ( word -- ? )
  76
  77 M: word compiled-crossref? crossref? ;
  78
  79 GENERIC# (quot-uses) 1 ( obj assoc -- )
  80
  81 M: object (quot-uses) 2drop ;
  82
  83 M: word (quot-uses)
  84     >r dup crossref? [ dup r> set-at ] [ r> 2drop ] if ;
  85
  86 : seq-uses ( seq assoc -- ) [ (quot-uses) ] curry each ;
  87
  88 M: array (quot-uses) seq-uses ;
  89
  90 M: callable (quot-uses) seq-uses ;
  91
  92 M: wrapper (quot-uses) >r wrapped r> (quot-uses) ;
  93
  94 : quot-uses ( quot -- assoc )
  95     global [ H{ } clone [ (quot-uses) ] keep ] bind ;
  96
  97 M: word uses ( word -- seq )
  98     word-def quot-uses keys ;
  99
 100 SYMBOL: compiled-crossref
 101
 102 compiled-crossref global [ H{ } assoc-like ] change-at
 103
 104 : compiled-xref ( word dependencies -- )
 105     [ drop crossref? ] assoc-filter
 106     2dup "compiled-uses" set-word-prop
 107     compiled-crossref get add-vertex* ;
 108
 109 : compiled-unxref ( word -- )
 110     dup "compiled-uses" word-prop
 111     compiled-crossref get remove-vertex* ;
 112
 113 : delete-compiled-xref ( word -- )
 114     dup compiled-unxref
 115     compiled-crossref get delete-at ;
 116
 117 : compiled-usage ( word -- assoc )
 118     compiled-crossref get at ;
 119
 120 : compiled-usages ( assoc -- seq )
 121     clone [
 122         dup [
 123             [
 124                 [ compiled-usage ] dip
 125                 +inlined+ eq? [
 126                     [ nip +inlined+ eq? ] assoc-filter
 127                 ] when
 128             ] dip swap update
 129         ] curry assoc-each
 130     ] keep keys ;
 131
 132 GENERIC: redefined ( word -- )
 133
 134 M: object redefined drop ;
 135
 136 : define ( word def -- )
 137     [ ] like
 138     over unxref
 139     over redefined
 140     over set-word-def
 141     dup +inlined+ changed-definition
 142     dup crossref? [ dup xref ] when drop ;
 143
 144 : define-declared ( word def effect -- )
 145     pick swap "declared-effect" set-word-prop
 146     define ;
 147
 148 : make-inline ( word -- )
 149     t "inline" set-word-prop ;
 150
 151 : make-flushable ( word -- )
 152     t "flushable" set-word-prop ;
 153
 154 : make-foldable ( word -- )
 155     dup make-flushable t "foldable" set-word-prop ;
 156
 157 : define-inline ( word quot -- )
 158     dupd define make-inline ;
 159
 160 : define-symbol ( word -- )
 161     dup [ ] curry define-inline ;
 162
 163 GENERIC: reset-word ( word -- )
 164
 165 M: word reset-word
 166     {
 167         "unannotated-def"
 168         "parsing" "inline" "foldable" "flushable"
 169         "predicating"
 170         "reading" "writing"
 171         "constructing"
 172         "declared-effect" "constructor-quot" "delimiter"
 173     } reset-props ;
 174
 175 GENERIC: subwords ( word -- seq )
 176
 177 M: word subwords drop f ;
 178
 179 : reset-generic ( word -- )
 180     dup subwords forget-all
 181     dup reset-word
 182     { "methods" "combination" "default-method" } reset-props ;
 183
 184 : gensym ( -- word )
 185     "( gensym )" f <word> ;
 186
 187 : define-temp ( quot -- word )
 188     gensym dup rot define ;
 189
 190 : reveal ( word -- )
 191     dup word-name over word-vocabulary dup vocab-words
 192     [ ] [ no-vocab ] ?if
 193     set-at ;
 194
 195 ERROR: bad-create name vocab ;
 196
 197 : check-create ( name vocab -- name vocab )
 198     2dup [ string? ] both?
 199     [ bad-create ] unless ;
 200
 201 : create ( name vocab -- word )
 202     check-create 2dup lookup
 203     dup [ 2nip ] [ drop <word> dup reveal ] if ;
 204
 205 : constructor-word ( name vocab -- word )
 206     >r "<" swap ">" 3append r> create ;
 207
 208 PREDICATE: parsing-word < word "parsing" word-prop ;
 209
 210 : delimiter? ( obj -- ? )
 211     dup word? [ "delimiter" word-prop ] [ drop f ] if ;
 212
 213 ! Definition protocol
 214 M: word where "loc" word-prop ;
 215
 216 M: word set-where swap "loc" set-word-prop ;
 217
 218 M: word forget*
 219     dup "forgotten" word-prop [
 220         dup delete-xref
 221         dup delete-compiled-xref
 222         dup word-name over word-vocabulary vocab-words delete-at
 223         dup t "forgotten" set-word-prop
 224     ] unless drop ;
 225
 226 M: word hashcode*
 227     nip 1 slot { fixnum } declare ;
 228
 229 M: word literalize <wrapper> ;
 230
 231 : ?word-name ( word -- name ) dup word? [ word-name ] when ;
 232
 233 : xref-words ( -- ) all-words [ xref ] each ;