core/words/words.factor

   1 ! Copyright (C) 2004, 2010 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors arrays definitions kernel kernel.private
   4 slots.private math namespaces sequences strings vectors sbufs
   5 quotations assocs hashtables sorting vocabs math.order sets
   6 words.private ;
   7 IN: words
   8
   9 : word ( -- word ) \ word get-global ;
  10
  11 : set-word ( word -- ) \ word set-global ;
  12
  13 M: word execute (execute) ;
  14
  15 M: word ?execute execute( -- value ) ; inline
  16
  17 M: word <=>
  18     [ [ name>> ] [ vocabulary>> ] bi 2array ] compare ;
  19
  20 M: word definer drop \ : \ ; ;
  21
  22 M: word definition def>> ;
  23
  24 : word-prop ( word name -- value ) swap props>> at ;
  25
  26 : remove-word-prop ( word name -- ) swap props>> delete-at ;
  27
  28 : set-word-prop ( word value name -- )
  29     over
  30     [ pick props>> ?set-at >>props drop ]
  31     [ nip remove-word-prop ] if ;
  32
  33 : reset-props ( word seq -- ) [ remove-word-prop ] with each ;
  34
  35 <PRIVATE
  36
  37 : caller ( callstack -- word ) callstack>array <reversed> third ;
  38
  39 PRIVATE>
  40
  41 TUPLE: undefined word ;
  42 : undefined ( -- * ) callstack caller \ undefined boa throw ;
  43
  44 : undefined-def ( -- quot )
  45     #! 'f' inhibits tail call optimization in non-optimizing
  46     #! compiler, ensuring that we can pull out the caller word
  47     #! above.
  48     [ undefined f ] ;
  49
  50 PREDICATE: deferred < word ( obj -- ? ) def>> undefined-def = ;
  51 M: deferred definer drop \ DEFER: f ;
  52 M: deferred definition drop f ;
  53
  54 PREDICATE: primitive < word ( obj -- ? ) "primitive" word-prop ;
  55 M: primitive definer drop \ PRIMITIVE: f ;
  56 M: primitive definition drop f ;
  57
  58 : lookup ( name vocab -- word ) vocab-words at ;
  59
  60 : target-word ( word -- target )
  61     [ name>> ] [ vocabulary>> ] bi lookup ;
  62
  63 SYMBOL: bootstrapping?
  64
  65 : if-bootstrapping ( true false -- )
  66     [ bootstrapping? get ] 2dip if ; inline
  67
  68 : bootstrap-word ( word -- target )
  69     [ target-word ] [ ] if-bootstrapping ;
  70
  71 GENERIC: crossref? ( word -- ? )
  72
  73 M: word crossref?
  74     dup "forgotten" word-prop [ drop f ] [ vocabulary>> >boolean ] if ;
  75
  76 GENERIC: subwords ( word -- seq )
  77
  78 M: word subwords drop f ;
  79
  80 GENERIC: parent-word ( word -- word/f )
  81
  82 M: word parent-word drop f ;
  83
  84 : define ( word def -- )
  85     over changed-definition [ ] like >>def drop ;
  86
  87 : changed-effect ( word -- )
  88     [ dup changed-effects get set-in-unit ]
  89     [ dup primitive? [ drop ] [ changed-definition ] if ] bi ;
  90
  91 : set-stack-effect ( effect word -- )
  92     2dup "declared-effect" word-prop = [ 2drop ] [
  93         [ nip changed-effect ]
  94         [ nip subwords [ changed-effect ] each ]
  95         [ swap "declared-effect" set-word-prop ]
  96         2tri
  97     ] if ;
  98
  99 : define-declared ( word def effect -- )
 100     [ nip swap set-stack-effect ] [ drop define ] 3bi ;
 101
 102 : make-deprecated ( word -- )
 103     t "deprecated" set-word-prop ;
 104
 105 : inline? ( word -- ? ) "inline" word-prop ; inline
 106
 107 ERROR: cannot-be-inline word ;
 108
 109 GENERIC: make-inline ( word -- )
 110
 111 M: word make-inline
 112     dup inline? [ drop ] [
 113         [ t "inline" set-word-prop ]
 114         [ changed-effect ]
 115         bi
 116     ] if ;
 117
 118 : define-inline ( word def effect -- )
 119     [ define-declared ] [ 2drop make-inline ] 3bi ;
 120
 121 : make-recursive ( word -- )
 122     t "recursive" set-word-prop ;
 123
 124 GENERIC: flushable? ( word -- ? )
 125
 126 M: word flushable?
 127     [ "flushable" word-prop ]
 128     [ parent-word dup [ flushable? ] when ] bi or ;
 129
 130 : make-flushable ( word -- )
 131     t "flushable" set-word-prop ;
 132
 133 GENERIC: foldable? ( word -- ? )
 134
 135 M: word foldable?
 136     [ "foldable" word-prop ]
 137     [ parent-word dup [ foldable? ] when ] bi or ;
 138
 139 : make-foldable ( word -- )
 140     dup make-flushable t "foldable" set-word-prop ;
 141
 142 GENERIC: reset-word ( word -- )
 143
 144 M: word reset-word
 145     dup flushable? [ dup changed-conditionally ] when
 146     {
 147         "unannotated-def" "parsing" "inline" "recursive"
 148         "foldable" "flushable" "reading" "writing" "reader"
 149         "writer" "delimiter" "deprecated"
 150     } reset-props ;
 151
 152 : reset-generic ( word -- )
 153     [ subwords forget-all ]
 154     [ reset-word ]
 155     [
 156         f >>pic-def
 157         f >>pic-tail-def
 158         {
 159             "methods"
 160             "combination"
 161             "default-method"
 162             "engines"
 163             "decision-tree"
 164         } reset-props
 165     ] tri ;
 166
 167 : <word> ( name vocab -- word )
 168     2dup [ hashcode ] bi@ bitxor >fixnum (word) dup new-word ;
 169
 170 : <uninterned-word> ( name -- word )
 171     f \ <uninterned-word> counter >fixnum (word)
 172     new-words get [ dup new-word ] when ;
 173
 174 : gensym ( -- word )
 175     "( gensym )" <uninterned-word> ;
 176
 177 : define-temp ( quot effect -- word )
 178     [ gensym dup ] 2dip define-declared ;
 179
 180 : reveal ( word -- )
 181     dup [ name>> ] [ vocabulary>> ] bi dup vocab-words
 182     [ ] [ no-vocab ] ?if
 183     set-at ;
 184
 185 ERROR: bad-create name vocab ;
 186
 187 : check-create ( name vocab -- name vocab )
 188     2dup [ string? ] [ [ string? ] [ vocab? ] bi or ] bi* and
 189     [ bad-create ] unless ;
 190
 191 : create ( name vocab -- word )
 192     check-create 2dup lookup
 193     dup [ 2nip ] [
 194         drop
 195         vocab-name <word>
 196         dup reveal
 197         dup changed-definition
 198     ] if ;
 199
 200 : constructor-word ( name vocab -- word )
 201     [ "<" ">" surround ] dip create ;
 202
 203 PREDICATE: parsing-word < word "parsing" word-prop ;
 204
 205 M: parsing-word definer drop \ SYNTAX: \ ; ;
 206
 207 : define-syntax ( word quot -- )
 208     [ drop ] [ define ] 2bi t "parsing" set-word-prop ;
 209
 210 : delimiter? ( obj -- ? )
 211     dup word? [ "delimiter" word-prop ] [ drop f ] if ;
 212
 213 : deprecated? ( obj -- ? )
 214     dup word? [ "deprecated" word-prop ] [ drop f ] if ;
 215
 216 ! Definition protocol
 217 M: word where "loc" word-prop ;
 218
 219 M: word set-where swap "loc" set-word-prop ;
 220
 221 M: word forget*
 222     dup "forgotten" word-prop [ drop ] [
 223         [ subwords forget-all ]
 224         [ [ name>> ] [ vocabulary>> vocab-words ] bi delete-at ]
 225         [ t "forgotten" set-word-prop ]
 226         tri
 227     ] if ;
 228
 229 M: word hashcode*
 230     nip 1 slot { fixnum } declare ; inline foldable
 231
 232 M: word literalize <wrapper> ;
 233
 234 INSTANCE: word definition