core/words/words.factor

   1 ! Copyright (C) 2004, 2009 Slava Pestov.
   2 ! See http://factorcode.org/license.txt for BSD license.
   3 USING: accessors arrays definitions kernel kernel.private
   4 slots.private math namespaces sequences strings vectors sbufs
   5 quotations assocs hashtables sorting vocabs math.order sets
   6 words.private ;
   7 IN: words
   8
   9 : word ( -- word ) \ word get-global ;
  10
  11 : set-word ( word -- ) \ word set-global ;
  12
  13 M: word execute (execute) ;
  14
  15 M: word ?execute execute( -- value ) ; inline
  16
  17 M: word <=>
  18     [ [ name>> ] [ vocabulary>> ] bi 2array ] compare ;
  19
  20 M: word definer drop \ : \ ; ;
  21
  22 M: word definition def>> ;
  23
  24 ERROR: undefined ;
  25
  26 PREDICATE: deferred < word ( obj -- ? )
  27     def>> [ undefined ] = ;
  28 M: deferred definer drop \ DEFER: f ;
  29 M: deferred definition drop f ;
  30
  31 PREDICATE: primitive < word ( obj -- ? )
  32     [ def>> [ do-primitive ] tail? ]
  33     [ sub-primitive>> >boolean ]
  34     bi or ;
  35 M: primitive definer drop \ PRIMITIVE: f ;
  36 M: primitive definition drop f ;
  37
  38 : word-prop ( word name -- value ) swap props>> at ;
  39
  40 : remove-word-prop ( word name -- ) swap props>> delete-at ;
  41
  42 : set-word-prop ( word value name -- )
  43     over
  44     [ pick props>> ?set-at >>props drop ]
  45     [ nip remove-word-prop ] if ;
  46
  47 : reset-props ( word seq -- ) [ remove-word-prop ] with each ;
  48
  49 : lookup ( name vocab -- word ) vocab-words at ;
  50
  51 : target-word ( word -- target )
  52     [ name>> ] [ vocabulary>> ] bi lookup ;
  53
  54 SYMBOL: bootstrapping?
  55
  56 : if-bootstrapping ( true false -- )
  57     [ bootstrapping? get ] 2dip if ; inline
  58
  59 : bootstrap-word ( word -- target )
  60     [ target-word ] [ ] if-bootstrapping ;
  61
  62 GENERIC: crossref? ( word -- ? )
  63
  64 M: word crossref?
  65     dup "forgotten" word-prop [ drop f ] [ vocabulary>> >boolean ] if ;
  66
  67 : inline? ( word -- ? ) "inline" word-prop ; inline
  68
  69 GENERIC: subwords ( word -- seq )
  70
  71 M: word subwords drop f ;
  72
  73 : define ( word def -- )
  74     over changed-definition [ ] like >>def drop ;
  75
  76 : changed-effect ( word -- )
  77     [ dup changed-effects get set-in-unit ]
  78     [ dup primitive? [ drop ] [ changed-definition ] if ] bi ;
  79
  80 : set-stack-effect ( effect word -- )
  81     2dup "declared-effect" word-prop = [ 2drop ] [
  82         [ nip changed-effect ]
  83         [ nip subwords [ changed-effect ] each ]
  84         [ swap "declared-effect" set-word-prop ]
  85         2tri
  86     ] if ;
  87
  88 : define-declared ( word def effect -- )
  89     [ nip swap set-stack-effect ] [ drop define ] 3bi ;
  90
  91 : make-deprecated ( word -- )
  92     t "deprecated" set-word-prop ;
  93
  94 : make-inline ( word -- )
  95     dup inline? [ drop ] [
  96         [ t "inline" set-word-prop ]
  97         [ changed-effect ]
  98         bi
  99     ] if ;
 100
 101 : make-recursive ( word -- )
 102     t "recursive" set-word-prop ;
 103
 104 : make-flushable ( word -- )
 105     t "flushable" set-word-prop ;
 106
 107 : make-foldable ( word -- )
 108     dup make-flushable t "foldable" set-word-prop ;
 109
 110 : define-inline ( word def effect -- )
 111     [ define-declared ] [ 2drop make-inline ] 3bi ;
 112
 113 GENERIC: reset-word ( word -- )
 114
 115 M: word reset-word
 116     {
 117         "unannotated-def" "parsing" "inline" "recursive"
 118         "foldable" "flushable" "reading" "writing" "reader"
 119         "writer" "delimiter" "deprecated"
 120     } reset-props ;
 121
 122 : reset-generic ( word -- )
 123     [ subwords forget-all ]
 124     [ reset-word ]
 125     [
 126         f >>pic-def
 127         f >>pic-tail-def
 128         {
 129             "methods"
 130             "combination"
 131             "default-method"
 132             "engines"
 133             "decision-tree"
 134         } reset-props
 135     ] tri ;
 136
 137 : <word> ( name vocab -- word )
 138     2dup [ hashcode ] bi@ bitxor >fixnum (word) dup new-word ;
 139
 140 : <uninterned-word> ( name -- word )
 141     f \ <uninterned-word> counter >fixnum (word) ;
 142
 143 : gensym ( -- word )
 144     "( gensym )" <uninterned-word> ;
 145
 146 : define-temp ( quot effect -- word )
 147     [ gensym dup ] 2dip define-declared ;
 148
 149 : reveal ( word -- )
 150     dup [ name>> ] [ vocabulary>> ] bi dup vocab-words
 151     [ ] [ no-vocab ] ?if
 152     set-at ;
 153
 154 ERROR: bad-create name vocab ;
 155
 156 : check-create ( name vocab -- name vocab )
 157     2dup [ string? ] [ [ string? ] [ vocab? ] bi or ] bi* and
 158     [ bad-create ] unless ;
 159
 160 : create ( name vocab -- word )
 161     check-create 2dup lookup
 162     dup [ 2nip ] [ drop vocab-name <word> dup reveal ] if ;
 163
 164 : constructor-word ( name vocab -- word )
 165     [ "<" ">" surround ] dip create ;
 166
 167 PREDICATE: parsing-word < word "parsing" word-prop ;
 168
 169 M: parsing-word definer drop \ SYNTAX: \ ; ;
 170
 171 : define-syntax ( word quot -- )
 172     [ drop ] [ define ] 2bi t "parsing" set-word-prop ;
 173
 174 : delimiter? ( obj -- ? )
 175     dup word? [ "delimiter" word-prop ] [ drop f ] if ;
 176
 177 : deprecated? ( obj -- ? )
 178     dup word? [ "deprecated" word-prop ] [ drop f ] if ;
 179
 180 ! Definition protocol
 181 M: word where "loc" word-prop ;
 182
 183 M: word set-where swap "loc" set-word-prop ;
 184
 185 M: word forget*
 186     dup "forgotten" word-prop [ drop ] [
 187         [ [ name>> ] [ vocabulary>> vocab-words ] bi delete-at ]
 188         [ t "forgotten" set-word-prop ]
 189         bi
 190     ] if ;
 191
 192 M: word hashcode*
 193     nip 1 slot { fixnum } declare ; inline foldable
 194
 195 M: word literalize <wrapper> ;
 196
 197 INSTANCE: word definition